configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.9.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl CURRENT, REVISION, AGE
  40 dnl - library source changed -> increment REVISION
  41 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  42 dnl - interfaces added -> increment AGE
  43 dnl - interfaces removed -> AGE = 0
  44 dnl sets GST_LT_LDFLAGS
  45 AS_LIBTOOL(GST, 6, 0, 6)
  46
  47 dnl FIXME: this macro doesn't actually work;
  48 dnl the generated libtool script has no support for the listed tags.
  49 dnl So this needs to be fixed first if we want to use this
  50 dnl AS_LIBTOOL_TAGS
  51
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.9.1
  56
  57 dnl *** autotools stuff ****
  58
  59 dnl allow for different autotools
  60 AS_AUTOTOOLS_ALTERNATE
  61
  62 dnl Add parameters for aclocal
  63 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  64
  65 dnl set up gettext
  66 dnl the version check needs to stay here because autopoint greps for it
  67 AM_GNU_GETTEXT_VERSION([0.11.5])
  68 AM_GNU_GETTEXT([external])
  69 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  70
  71 dnl *** check for arguments to configure ***
  72
  73 GST_ARG_DEBUG
  74 GST_ARG_PROFILING
  75 GST_ARG_VALGRIND
  76 GST_ARG_GCOV
  77
  78 GST_ARG_EXAMPLES
  79
  80 GST_ARG_WITH_PKG_CONFIG_PATH
  81 GST_ARG_WITH_PACKAGE_NAME
  82 GST_ARG_WITH_PACKAGE_ORIGIN
  83
  84 dnl these are all the gst plug-ins, compilable without additional libs
  85 GST_PLUGINS_ALL="\
  86         adder \
  87         audioconvert \
  88         audiorate \
  89         audioresample \
  90         audiotestsrc \
  91         ffmpegcolorspace \
  92         playback \
  93         typefind \
  94         videotestsrc \
  95         videorate \
  96         videoscale \
  97         volume \
  98         "
  99 AC_SUBST(GST_PLUGINS_ALL)
 100
 101 GST_PLUGINS_SELECTED=""
 102
 103 AC_ARG_WITH(plugins,
 104     AC_HELP_STRING([--with-plugins],
 105       [comma-separated list of plug-ins to compile]),
 106     [for i in `echo $withval | tr , ' '`; do
 107         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 108         then
 109             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 110         else
 111             echo "plug-in $i not recognized, ignoring..."
 112         fi
 113     done],
 114     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 115
 116 AC_SUBST(GST_PLUGINS_SELECTED)
 117
 118 dnl ext plug-ins; plug-ins that have external dependencies
 119 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 120   [HAVE_EXTERNAL=yes], enabled,
 121   [
 122     AC_MSG_NOTICE(building external plug-ins)
 123     BUILD_EXTERNAL="yes"
 124   ],[
 125     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 126     BUILD_EXTERNAL="no"
 127   ])
 128 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 129
 130 dnl *** checks for platform ***
 131
 132 dnl * hardware/architecture *
 133
 134 dnl common/m4/gst-arch.m4
 135 dnl check CPU type
 136 GST_ARCH
 137
 138 dnl *** checks for programs ***
 139
 140 dnl find a compiler
 141 AC_PROG_CC
 142
 143 dnl determine c++ compiler
 144 AC_PROG_CXX
 145 dnl determine if c++ is available on this system
 146 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 147
 148 dnl determine c++ preprocessor
 149 dnl FIXME: do we need this ?
 150 AC_PROG_CXXCPP
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for documentation tools
 156 GTK_DOC_CHECK([1.3])
 157 AS_PATH_PYTHON([2.1])
 158 GST_PLUGIN_DOCS([1.3],[2.1])
 159
 160 dnl *** checks for libraries ***
 161
 162 dnl For interactive UNIX (a Sun thing)
 163 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 164 AC_ISC_POSIX
 165
 166 dnl *** checks for header files ***
 167
 168 dnl check if we have ANSI C header files
 169 AC_HEADER_STDC
 170
 171 dnl used in gst/ffmpegcolorspace/mem.c
 172 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 173 AC_CHECK_HEADERS([malloc.h])
 174
 175 dnl used in gst/subparse/gstsubparse.c
 176 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 177 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 178
 179 dnl used in gst/tcp
 180 AC_CHECK_HEADERS([sys/socket.h],
 181   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 182 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 183
 184 dnl ffmpegcolorspace includes _stdint.h
 185 dnl also, Windows does not have long long
 186 AX_CREATE_STDINT_H
 187
 188 dnl *** checks for types/defines ***
 189
 190 dnl Check for FIONREAD ioctl declaration
 191 dnl used in gst/tcp
 192 GST_CHECK_FIONREAD
 193
 194 dnl *** checks for structures ***
 195
 196 dnl *** checks for compiler characteristics ***
 197
 198 dnl make sure we can use "inline" from C code
 199 AC_C_INLINE
 200
 201 dnl *** checks for library functions ***
 202
 203 dnl Check for fast float to int casting as defined in C99
 204 dnl used in gst-libs/gst/floatcast/floatcast.h
 205 AC_C99_FUNC_LRINT
 206 AC_C99_FUNC_LRINTF
 207
 208 dnl Check for a way to display the function name in debug output
 209 GST_CHECK_FUNCTION
 210
 211 dnl *** checks for dependancy libraries ***
 212
 213 dnl GLib is required
 214 GST_GLIB_CHECK([2.6])
 215
 216 dnl liboil is required
 217 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.6, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 218 if test "x$HAVE_LIBOIL" != "xyes"
 219 then
 220   AC_ERROR([liboil-0.3.6 or later is required])
 221 fi
 222
 223 dnl checks for gstreamer
 224 dnl uninstalled is selected preferentially -- see pkg-config(1)
 225 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 226 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 227 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 228 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 229 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 230
 231 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 232 dnl check for "check", unit testing library/header
 233 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 234 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 235
 236 dnl GTK is optional and used in examples
 237 HAVE_GTK=NO
 238 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 239 if test "x$HAVE_GTK_22" = "xyes"; then
 240   HAVE_GTK=yes
 241   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 242   AC_SUBST(GTK_VERSION)
 243   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 244   AC_SUBST(GTK_BASE_DIR)
 245 else
 246   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 247 fi
 248 if test "x$HAVE_GTK_20" = "xyes"; then
 249   HAVE_GTK=yes
 250 fi
 251 GTK_CFLAGS=$GTK2_CFLAGS
 252 GTK_LIBS=$GTK2_LIBS
 253 AC_SUBST(GTK_LIBS)
 254 AC_SUBST(GTK_CFLAGS)
 255 AC_SUBST(HAVE_GTK)
 256 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 257
 258 dnl *** set variables based on configure arguments ***
 259
 260 dnl set license and copyright notice
 261 GST_LICENSE="LGPL"
 262 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 263 AC_SUBST(GST_LICENSE)
 264
 265 dnl set location of plugin directory
 266 GST_SET_PLUGINDIR
 267
 268 dnl define an ERROR_CFLAGS Makefile variable
 269 GST_SET_ERROR_CFLAGS($GST_CVS)
 270
 271 dnl define correct level for debugging messages
 272 GST_SET_LEVEL_DEFAULT($GST_CVS)
 273
 274 dnl used in examples
 275 GST_DEFAULT_ELEMENTS
 276
 277 dnl *** sys plug-ins ***
 278
 279 echo
 280 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 281 echo
 282
 283 dnl *** X11 ***
 284 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 285 GST_CHECK_FEATURE(X, [X libraries and plugins],
 286                   [ximagesink], [
 287   AC_PATH_XTRA
 288   ac_cflags_save="$CFLAGS"
 289   ac_cppflags_save="$CPPFLAGS"
 290   CFLAGS="$CFLAGS $X_CFLAGS"
 291   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 292
 293   dnl now try to find the HEADER
 294   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 295
 296   if test "x$HAVE_X" = "xno"
 297   then
 298     AC_MSG_NOTICE([cannot find X11 development files])
 299   else
 300     dnl this is much more than we want
 301     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 302     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 303     dnl it does not add the libs; therefore we add them here
 304     X_LIBS="$X_LIBS -lX11"
 305     AC_SUBST(X_CFLAGS)
 306     AC_SUBST(X_LIBS)
 307   fi
 308   AC_SUBST(HAVE_X)
 309   CFLAGS="$ac_cflags_save"
 310   CPPFLAGS="$ac_cppflags_save"
 311 ])
 312
 313 dnl Check for Xv extension
 314 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 315 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 316                   [xvimagesink], [
 317   GST_CHECK_XV
 318 ])
 319
 320 dnl check for X Shm
 321 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 322 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 323   if test x$HAVE_X = xyes; then
 324     AC_CHECK_LIB(Xext, XShmAttach,
 325                  HAVE_XSHM="yes", HAVE_XSHM="no",
 326                  $X_LIBS)
 327     if test "x$HAVE_XSHM" = "xyes"; then
 328       XSHM_LIBS="-lXext"
 329     else
 330       dnl On AIX, it is in XextSam instead, but we still need -lXext
 331       AC_CHECK_LIB(XextSam, XShmAttach,
 332                    HAVE_XSHM="yes", HAVE_XSHM="no",
 333                    $X_LIBS)
 334       if test "x$HAVE_XSHM" = "xyes"; then
 335         XSHM_LIBS="-lXext -lXextSam"
 336       fi
 337     fi
 338   fi
 339 ], , [
 340   AC_SUBST(HAVE_XSHM)
 341   AC_SUBST(XSHM_LIBS)
 342 ])
 343
 344 dnl v4l/v4l2 checks have been moved down because they require X
 345
 346 dnl *** Video 4 Linux ***
 347 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 348 dnl renamed to GST_V4L in accordance with V4L2 below
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 350 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 351   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 352 #include <sys/types.h>
 353 #define _LINUX_TIME_H
 354 #define __user
 355 #include <linux/videodev.h>
 356   ])
 357
 358   dnl we can build v4l without Xv, but then we won't have XOverlay support
 359   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 360   then
 361     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 362     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 363   fi
 364 ])
 365
 366 dnl *** ext plug-ins ***
 367 dnl keep this list sorted alphabetically !
 368
 369 if test "x$BUILD_EXTERNAL" = "xyes"; then
 370
 371 echo
 372 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 373 echo
 374
 375 dnl *** alsa ***
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 377 GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 378   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 379     HAVE_ALSA="yes"
 380     AC_SUBST(ALSA_CFLAGS)
 381     AC_SUBST(ALSA_LIBS)
 382   ], [
 383     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 384   ])
 385 ])
 386
 387 dnl *** CDParanoia ***
 388 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 389 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 390   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 391                       cdda_open, -lm,
 392                       cdda_interface.h,
 393                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 394                       HEADER_DIR="no"
 395                       FOUND_CDPARANOIA="yes")
 396   if test "x$FOUND_CDPARANOIA" != "xyes";
 397   then
 398     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 399                         cdda_open, -lm,
 400                         cdda/cdda_interface.h,
 401                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 402                         HEADER_DIR="yes"
 403                         FOUND_CDPARANOIA="yes")
 404   fi
 405   if test "x$HEADER_DIR" = "xyes";
 406   then
 407     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 408                        defined if cdda headers are in a cdda/ directory)
 409   fi
 410   AC_SUBST(CDPARANOIA_LIBS)
 411 ])
 412 dnl FIXME : add second check somehow if that is necessary
 413 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 414 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 415
 416 dnl *** GNOME VFS ***
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 418 GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 419   GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 420 ])
 421
 422 dnl *** libvisual ***
 423 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 424 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 425   GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 426   if test $HAVE_LIBVISUAL = no
 427   then
 428     GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 429   fi
 430 ])
 431
 432 dnl *** ogg ***
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 434 GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 435   GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 436   if test $HAVE_OGG = no
 437   then
 438     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 439     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 440   fi
 441 ])
 442
 443 dnl *** pango ***
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 445 GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 446   GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 447 ])
 448
 449 dnl *** theora ***
 450 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 451 GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 452   GST_PKG_CHECK_MODULES(THEORA, theora)
 453   if test $HAVE_THEORA = no
 454   then
 455     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 456     AC_SUBST(THEORA_LIBS)
 457   fi
 458 ])
 459
 460 dnl *** vorbis ***
 461 dnl AM_PATH_VORBIS only takes two options
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 463 GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 464   GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 465   if test $HAVE_VORBIS = no
 466   then
 467     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 468     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 469   fi
 470 ])
 471
 472 if test "x$HAVE_VORBIS" = "xyes"; then
 473   ac_cflags_save="$CFLAGS"
 474   dnl FIXME: does this work on non-gcc? -- Company
 475   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 476   CFLAGS="-Wall -Werror"
 477   AC_COMPILE_IFELSE(
 478     AC_LANG_PROGRAM([
 479 #include <vorbis/codec.h>
 480                      ],[
 481 vorbis_dsp_state *v;
 482
 483 vorbis_synthesis_restart (v);
 484                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 485   if test "x$HAVE_VSR" = "xyes"; then
 486     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 487                        [defined if vorbis_synthesis_restart is present])
 488   fi
 489   CFLAGS="$ac_cflags_save"
 490 fi
 491
 492 else
 493
 494 dnl not building plugins with external dependencies,
 495 dnl but we still need to set the conditionals
 496 AM_CONDITIONAL(USE_ALSA, false)
 497 AM_CONDITIONAL(USE_CDPARANOIA, false)
 498 AM_CONDITIONAL(USE_GNOME_VFS, false)
 499 AM_CONDITIONAL(USE_LIBVISUAL, false)
 500 AM_CONDITIONAL(USE_OGG, false)
 501 AM_CONDITIONAL(USE_PANGO, false)
 502 AM_CONDITIONAL(USE_THEORA, false)
 503 AM_CONDITIONAL(USE_VORBIS, false)
 504
 505 fi dnl of EXT plugins
 506
 507 dnl seeking needs freetype, so check for it here
 508 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 509   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 510 ])
 511 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 512 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 513 AC_SUBST(FT2_CFLAGS)
 514 AC_SUBST(FT2_LIBS)
 515
 516 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 517
 518 dnl Overview:
 519 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 520 dnl GST_*:              flags shared by built objects to link against GStreamer
 521 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 522 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 523 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 524 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 525
 526 dnl GST_OPTION_CFLAGS
 527 if test "x$USE_DEBUG" = xyes; then
 528    PROFILE_CFLAGS="-g"
 529 fi
 530 AC_SUBST(PROFILE_CFLAGS)
 531
 532 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 533 AC_SUBST(DEPRECATED_CFLAGS)
 534
 535 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 536 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 537 AC_SUBST(GST_OPTION_CFLAGS)
 538
 539 dnl our libraries need to be versioned correctly
 540 AC_SUBST(GST_LT_LDFLAGS)
 541
 542 dnl FIXME: do we want to rename to GST_ALL_* ?
 543 dnl prefer internal headers to already installed ones
 544 dnl also add builddir include for enumtypes and marshal
 545 dnl add GST_OPTION_CFLAGS, but overridable
 546 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 547 AC_SUBST(GST_CFLAGS)
 548 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 549 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 550 AC_SUBST(GST_LIBS)
 551
 552 dnl LDFLAGS really should only contain flags, not libs - they get added before
 553 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 554 GST_ALL_LDFLAGS="-no-undefined"
 555 AC_SUBST(GST_ALL_LDFLAGS)
 556
 557 dnl GST_LIB_LDFLAGS
 558 dnl linker flags shared by all libraries
 559 dnl LDFLAGS modifier defining exported symbols from built libraries
 560 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 561 AC_SUBST(GST_LIB_LDFLAGS)
 562
 563 dnl this really should only contain flags, not libs - they get added before
 564 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 565 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 566 AC_SUBST(GST_PLUGIN_LDFLAGS)
 567
 568 dnl *** output files ***
 569
 570 AC_CONFIG_FILES(
 571 Makefile
 572 gst-plugins-base.spec
 573 gst/Makefile
 574 gst/adder/Makefile
 575 gst/audioconvert/Makefile
 576 gst/audiorate/Makefile
 577 gst/audioresample/Makefile
 578 gst/audiotestsrc/Makefile
 579 gst/ffmpegcolorspace/Makefile
 580 gst/playback/Makefile
 581 gst/subparse/Makefile
 582 gst/tcp/Makefile
 583 gst/typefind/Makefile
 584 gst/videotestsrc/Makefile
 585 gst/videorate/Makefile
 586 gst/videoscale/Makefile
 587 gst/volume/Makefile
 588 sys/Makefile
 589 sys/ximage/Makefile
 590 sys/xvimage/Makefile
 591 sys/v4l/Makefile
 592 ext/Makefile
 593 ext/alsa/Makefile
 594 ext/cdparanoia/Makefile
 595 ext/gnomevfs/Makefile
 596 ext/libvisual/Makefile
 597 ext/ogg/Makefile
 598 ext/pango/Makefile
 599 ext/theora/Makefile
 600 ext/vorbis/Makefile
 601 gst-libs/Makefile
 602 gst-libs/gst/Makefile
 603 gst-libs/gst/audio/Makefile
 604 gst-libs/gst/cdda/Makefile
 605 gst-libs/gst/floatcast/Makefile
 606 gst-libs/gst/interfaces/Makefile
 607 gst-libs/gst/netbuffer/Makefile
 608 gst-libs/gst/riff/Makefile
 609 gst-libs/gst/rtp/Makefile
 610 gst-libs/gst/tag/Makefile
 611 gst-libs/gst/video/Makefile
 612 tools/Makefile
 613 win32/common/config.h
 614 pkgconfig/Makefile
 615 pkgconfig/gstreamer-plugins-base.pc
 616 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 617 tests/Makefile
 618 tests/check/Makefile
 619 tests/examples/Makefile
 620 tests/examples/seek/Makefile
 621 tests/examples/volume/Makefile
 622 tests/icles/Makefile
 623 docs/Makefile
 624 docs/libs/Makefile
 625 docs/plugins/Makefile
 626 docs/version.entities
 627 po/Makefile.in
 628 common/Makefile
 629 common/m4/Makefile
 630 m4/Makefile
 631 )
 632 AC_OUTPUT
 633
 634 GST_OUTPUT_PLUGINS