configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 8, 3, 1, GST_CVS="no", GST_CVS="yes")
  16
  17 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  18
  19 dnl our libraries and install dirs use major.minor as a version
  20 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  21 dnl we override it here if we need to for the release candidate
  22 #GST_MAJORMINOR=0.8
  23 AC_SUBST(GST_MAJORMINOR)
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 dnl for 0.8.3 release, gst_play_get_all_by_interface was added, so update
  31 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  32 AM_PROG_LIBTOOL
  33
  34 dnl FIXME take something else ?
  35 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  36 AM_CONFIG_HEADER(config.h)
  37
  38 dnl Add parameters for aclocal
  39 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  40 ACLOCAL_FLAGS="-I m4 -I common/m4"
  41 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_STDC
  45 AM_PROG_AS
  46 AS="${CC}"
  47 AS_PROG_OBJC
  48
  49 dnl the gettext stuff needed
  50 AM_GNU_GETTEXT_VERSION(0.11.5)
  51 AM_GNU_GETTEXT([external])
  52
  53 GETTEXT_PACKAGE=gst-plugins-$GST_MAJORMINOR
  54 AC_SUBST(GETTEXT_PACKAGE)
  55 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  56                    [gettext package name])
  57
  58 dnl define LOCALEDIR in config.h
  59 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  60 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  61                    [gettext locale dir])
  62
  63 dnl decide on error flags
  64 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  65
  66 if test "x$GST_WALL" = "xyes"; then
  67    GST_ERROR="$GST_ERROR -Wall"
  68
  69    if test "x$GST_CVS" = "xyes"; then
  70      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  71    fi
  72 fi
  73
  74 dnl determine c++ compiler
  75 AC_PROG_CXX
  76 dnl determine if c++ is available on this system
  77 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  78 dnl determine c++ preprocessor
  79 AC_PROG_CXXCPP
  80 AC_ISC_POSIX
  81
  82 AC_HEADER_STDC([])
  83 AC_C_INLINE
  84 AX_CREATE_STDINT_H
  85
  86 dnl Check for malloc.h
  87 AC_CHECK_HEADER(malloc.h,[
  88   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  89 ])
  90
  91 dnl Check for a way to display the function name in debug output
  92 GST_CHECK_FUNCTION()
  93
  94 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  95 dnl messages printed when running cvs builds
  96 if test "x$GST_CVS" = "xyes"; then
  97   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  98 fi
  99
 100 dnl Check for FIONREAD ioctl declaration :
 101 GST_CHECK_FIONREAD()
 102
 103 dnl ############################################
 104 dnl # Super Duper options for plug-in building #
 105 dnl ############################################
 106
 107 dnl ext plug-ins; plug-ins that have external dependencies
 108 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 109 [HAVE_EXTERNAL=yes],enabled,
 110 [
 111   AC_MSG_WARN(building external plug-ins)
 112   BUILD_EXTERNAL="yes"
 113 ],[
 114   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 115   BUILD_EXTERNAL="no"
 116 ])
 117 # make BUILD_EXTERNAL available to Makefile.am
 118 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 119
 120 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 121 dnl read 'builds, but might not work'UTO
 122 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 123 [HAVE_EXPERIMENTAL=yes],disabled,
 124 [
 125   AC_MSG_WARN(building experimental plug-ins)
 126   USE_TARKIN="yes"
 127 ],[
 128   AC_MSG_NOTICE(not building experimental plug-ins)
 129   USE_TARKIN="no"
 130 ])
 131
 132 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 133 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 134 HAVE_BROKEN=yes,disabled,
 135 [
 136   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 137 ],[
 138   AC_MSG_NOTICE([not building broken plug-ins])
 139 ])
 140
 141 dnl ##############################
 142 dnl # Do automated configuration #
 143 dnl ##############################
 144
 145 dnl Check for tools:
 146 dnl ================
 147
 148 dnl allow for different autotools
 149 AS_AUTOTOOLS_ALTERNATE()
 150
 151 dnl modify pkg-config path
 152 AC_ARG_WITH(pkg-config-path,
 153    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 154    [export PKG_CONFIG_PATH=${withval}])
 155
 156 dnl check architecture
 157 GST_ARCH()
 158
 159 dnl Check for nasm
 160 AC_PATH_PROG(NASM_PATH, nasm, no)
 161 AC_SUBST(NASM_PATH)
 162 if test x$NASM_PATH = xno; then
 163   AC_MSG_WARN(Couldn't find nasm)
 164   HAVE_NASM="no"
 165 else
 166   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 167   HAVE_NASM="yes"
 168 fi
 169
 170 dnl check for gconftool-2
 171 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 172 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 173   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 174   if test x$GCONFTOOL = xno; then
 175     AC_MSG_WARN(Not installing GConf schemas)
 176     HAVE_GCONFTOOL="no"
 177   else
 178     AM_GCONF_SOURCE_2
 179     HAVE_GCONFTOOL="yes"
 180   fi
 181   AC_SUBST(HAVE_GCONFTOOL)
 182 ])
 183
 184 dnl check for GConf libraries
 185 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 186 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 187   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 188   AC_SUBST(GCONF_CFLAGS)
 189   AC_SUBST(GCONF_LIBS)
 190 ])
 191
 192 dnl check for gstreamer
 193 dnl uninstalled is selected preferentially -- see pkg-config(1)
 194 GST_REQ=0.8.4
 195 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 196   HAVE_GST="yes", HAVE_GST="no")
 197
 198 if test "x$HAVE_GST" = "xno"; then
 199   AC_MSG_ERROR(no GStreamer found)
 200 fi
 201
 202 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 203 if test -z $GST_TOOLS_DIR; then
 204   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 205 fi
 206 AC_SUBST(GST_TOOLS_DIR)
 207
 208 dnl check for gstreamer-control; uninstalled is selected preferentially
 209 PKG_CHECK_MODULES(GST_CONTROL, gstreamer-control-$GST_MAJORMINOR >= $GST_REQ,
 210   HAVE_GST_CONTROL="yes", HAVE_GST_CONTROL="no")
 211
 212 if test "x$HAVE_GST_CONTROL" = "xno"; then
 213   AC_MSG_ERROR(no GStreamer Control Libs found)
 214 fi
 215
 216 AC_SUBST(GST_CONTROL_LIBS)
 217
 218 dnl Determine endianness
 219 AC_C_BIGENDIAN
 220
 221 dnl Check for fast float to int casting as defined in C99
 222 AC_C99_FUNC_LRINT()
 223 AC_C99_FUNC_LRINTF()
 224
 225 dnl Check for essential libraries first:
 226 dnl ====================================
 227
 228 GST_GLIB2_CHECK()
 229
 230 dnl Check for additional libraries that we might use:
 231 dnl =================================================
 232 dnl GTK
 233 HAVE_GTK=NO
 234 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 235 if test "x$HAVE_GTK_22" = "xyes"; then
 236   HAVE_GTK=yes
 237   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 238   AC_SUBST(GTK_VERSION)
 239   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 240   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 241   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 242   AC_SUBST(GTK_BASE_DIR)
 243 else
 244   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 245 fi
 246 if test "x$HAVE_GTK_20" = "xyes"; then
 247   HAVE_GTK=yes
 248 fi
 249 GTK_CFLAGS=$GTK2_CFLAGS
 250 GTK_LIBS=$GTK2_LIBS
 251 AC_SUBST(GTK_LIBS)
 252 AC_SUBST(GTK_CFLAGS)
 253 AC_SUBST(HAVE_GTK)
 254
 255 # gdk_pixbuf gstreamer loader is considered experimental, so disable
 256 # by default
 257 if test "x$HAVE_GTK_22" = "xyes"; then
 258   HAVE_GDK_LOADERS=yes
 259 else
 260   HAVE_GDK_LOADERS=no
 261 fi
 262
 263 # we set the defaults always to make sure we have non-empty variables
 264 # for the Makefile
 265
 266 # by default, stick to prefix
 267 GDK_PIXBUF_LOADER_DIR=${libdir}/gtk-2.0/\${GTK_VERSION}/loaders
 268 GDK_PIXBUF_CONF_DIR=${sysconfdir}/gtk-2.0
 269
 270
 271 AC_ARG_ENABLE(gdk-pixbuf-loader,
 272   AC_HELP_STRING([--enable-gdk-pixbuf-loader],
 273               [whether to enable building of gdk_pixbuf loader]),
 274               :, HAVE_GDK_LOADERS="no")
 275
 276 if test "x$HAVE_GDK_LOADERS" = "xyes"; then
 277   AC_PATH_PROG(QUERYLOADERS, gdk-pixbuf-query-loaders, no)
 278   # allow customization of pixbuf loader install location
 279   # when nothing specified, adhere to prefix settings
 280   # when called without any option with this argument, autodetect
 281   # when called with a path, set to the given path
 282
 283   AC_ARG_WITH(gdk-pixbuf-loader-dir,
 284      AC_HELP_STRING([--with-gdk-pixbuf-loader-dir],
 285         [directory to install the gdk_pixbuf loader (none for pkg-config default)]),
 286      [
 287       if test "x${withval}" != xyes ; then
 288         GDK_PIXBUF_LOADER_DIR="${withval}"
 289       else
 290         GDK_PIXBUF_LOADER_DIR="$GDK_PIXBUF_LIBDIR/gtk-2.0/\$GTK_VERSION/loaders"
 291       fi
 292      ]
 293   )
 294   AS_AC_EXPAND(GDK_PIXBUF_LOADER_DIR, $GDK_PIXBUF_LOADER_DIR)
 295   AC_SUBST(GDK_PIXBUF_LOADER_DIR)
 296   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loaders in $GDK_PIXBUF_LOADER_DIR])
 297
 298   # allow customization of pixbuf loader configuration file
 299   # when nothing specified, adhere to prefix settings
 300   # when called without any option with this argument, autodetect
 301   # when called with a path, set to the given path
 302
 303   AC_ARG_WITH(gdk-pixbuf-conf-dir,
 304      AC_HELP_STRING([--with-gdk-pixbuf-conf-dir],
 305         [directory to install the gdk_pixbuf config (none for pkg-config default)]),
 306      [
 307       if test "x${withval}" != xyes ; then
 308         GDK_PIXBUF_CONF_DIR="${withval}"
 309       else
 310         GDK_PIXBUF_CONF_DIR="$GDK_PIXBUF_PREFIXDIR/etc/gtk-2.0/"
 311       fi
 312      ]
 313   )
 314   AS_AC_EXPAND(GDK_PIXBUF_CONF_DIR, $GDK_PIXBUF_CONF_DIR)
 315   AC_SUBST(GDK_PIXBUF_CONF_DIR)
 316   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loader config in $GDK_PIXBUF_CONF_DIR])
 317 fi
 318 AM_CONDITIONAL(HAVE_GDK_LOADERS, test "x$HAVE_GDK_LOADERS" = "xyes")
 319
 320 PKG_CHECK_MODULES(LIBOIL, liboil-0.1, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 321 AC_SUBST(LIBOIL_CFLAGS)
 322 AC_SUBST(LIBOIL_LIBS)
 323 if test "x${HAVE_LIBOIL}" = xyes ; then
 324   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 325   true
 326 fi
 327
 328 dnl ===========================================================================
 329 dnl ============================= gst plug-ins ================================
 330 dnl ===========================================================================
 331
 332 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 333 AC_SUBST(plugindir)
 334
 335 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 336 AC_SUBST(GST_PLUGIN_LDFLAGS)
 337
 338 dnl these are all the gst plug-ins, compilable without additional libs
 339 GST_PLUGINS_ALL="\
 340         ac3parse \
 341         adder \
 342         alpha \
 343         asfdemux \
 344         audioconvert \
 345         audioscale \
 346         audiorate \
 347         auparse \
 348         avi \
 349         cdxaparse \
 350         chart \
 351         colorspace \
 352         cutter \
 353         debug \
 354         deinterlace \
 355         effectv \
 356         festival \
 357         ffmpegcolorspace \
 358         filter \
 359         flx \
 360         goom \
 361         interleave \
 362         law \
 363         level \
 364         matroska \
 365         median \
 366         mixmatrix \
 367         mpeg1sys \
 368         mpeg1videoparse \
 369         mpeg2sub \
 370         mpegaudio \
 371         mpegaudioparse \
 372         mpegstream \
 373         monoscope \
 374         multifilesink \
 375         multipart \
 376         overlay \
 377         passthrough \
 378         playback \
 379         playondemand \
 380         qtdemux \
 381         realmedia \
 382         rtjpeg \
 383         rtp \
 384         silence \
 385         sine \
 386         smooth \
 387         smpte \
 388         spectrum \
 389         speed \
 390         stereo \
 391         switch \
 392         synaesthesia \
 393         tags \
 394         tcp \
 395         typefind \
 396         udp \
 397         vbidec \
 398         videobox \
 399         videocrop \
 400         videodrop \
 401         videoflip \
 402         videofilter \
 403         videomixer \
 404         videorate \
 405         videoscale \
 406         videotestsrc \
 407         volenv \
 408         volume \
 409         wavenc \
 410         wavparse \
 411         y4m"
 412
 413 dnl see if we can build C++ plug-ins
 414 if test "x$HAVE_CXX" = "xyes"; then
 415   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 416                   modplug"
 417 else
 418   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 419 fi
 420
 421 AC_SUBST(GST_PLUGINS_ALL)
 422
 423 GST_PLUGINS_SELECTED=""
 424
 425 AC_ARG_WITH(plugins,
 426     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 427     [for i in `echo $withval | tr , ' '`; do
 428         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 429         then
 430             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 431         else
 432             echo "plug-in $i not recognized, ignoring..."
 433         fi
 434     done],
 435     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 436
 437 AC_SUBST(GST_PLUGINS_SELECTED)
 438
 439 dnl ==========================================================================
 440 dnl ============================= sys plug-ins ================================
 441 dnl ==========================================================================
 442
 443 dnl *** DXR3 card ***
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 445 GST_CHECK_FEATURE(DXR3, [DXR3 hardware MPEG DVD decoder],
 446   dxr3videosink dxr3audiosink dxr3spusink, [
 447   HAVE_DXR3=yes
 448   AC_CHECK_HEADER(linux/em8300.h, ,
 449                   [ AC_MSG_WARN([DXR3/em8300 header file not found]) &&
 450                     HAVE_DXR3=no ] )
 451   AC_CHECK_HEADER(linux/soundcard.h, ,
 452                   [ AC_MSG_WARN([Generic sound header file not found]) &&
 453                     HAVE_DXR3=no ] )
 454 ])
 455
 456 dnl *** OSS audio *** (Linux, *BSD)
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 458 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 459   HAVE_OSS="yes"
 460   dnl Linux and newer BSD versions :
 461   AC_CHECK_HEADER(sys/soundcard.h, [
 462     AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 463     ] , [
 464     dnl Some old BSD versions :
 465     AC_CHECK_HEADER(soundcard.h, [
 466       AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 467       ], [
 468       dnl Some old BSD versions :
 469       AC_CHECK_HEADER(machine/soundcard.h, [
 470         AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,, [Define if OSS includes are in /machine/])
 471         ], [
 472         HAVE_OSS="no"
 473       ])
 474     ])
 475   ])
 476 ])
 477
 478 dnl *** OS X audio ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 480 GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudiosrc osxaudiosink, [
 481   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 482 ])
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489 ])
 490 dnl in case header OpenGL/gl.h is found on other platforms
 491 case "$host" in
 492   *-*darwin*)
 493     dnl do nothing
 494     ;;
 495   *)
 496     HAVE_OSX_VIDEO="no"
 497     ;;
 498 esac
 499
 500 dnl *** QuickCam ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 502 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 503   if test "x$HAVE_CPU_I386" != "xyes";
 504   then
 505     HAVE_QCAM="no"
 506   else
 507     AC_CHECK_HEADER(sys/io.h, HAVE_QCAM="yes", HAVE_QCAM="no")
 508   fi
 509   if test "x$HAVE_QCAM" != "xyes";
 510   then
 511     AC_MSG_WARN([QuickCam only works on i386-linux])
 512   fi
 513 ])
 514
 515 dnl *** Sun Audio ***
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 517 GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudiosink, [
 518   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 519 ])
 520
 521 dnl *** Video CD ***
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 523 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 524   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 525 ])
 526
 527 dnl *** OpenGL ***
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENGL, true)
 529 GST_CHECK_FEATURE(OPENGL, [Open GL], glsink, [
 530   AC_CHECK_HEADER(GL/gl.h, HAVE_OPENGL="yes", HAVE_OPENGL="no")
 531 ])
 532
 533 dnl *** CDROM Audio ***
 534 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 535 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 536   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 537   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 538 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 539
 540   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 541         case "$host" in
 542                 *-sun-* | *-*-linux*)
 543                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 544                 ;;
 545                 *-*-freebsd*)
 546                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 547                 ;;
 548                 *-*-netbsd* | *-*-openbsd*)
 549                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 550                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 551                 ;;
 552                 *-*darwin*)
 553                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 554                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 555                 ;;
 556 dnl             *-irix-*)
 557 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 558 dnl             ;;
 559     esac
 560
 561         HAVE_CDROM="yes"
 562   else
 563         HAVE_CDROM="no"
 564   fi
 565 ])
 566
 567 dnl Check for X11
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 569 GST_CHECK_FEATURE(X, [X libraries and plugins],
 570                   [ximagesink], [
 571   AC_PATH_XTRA
 572   dnl now try to find the HEADER
 573   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 574
 575   if test "x$HAVE_X" = "xno"
 576   then
 577     AC_MSG_NOTICE([cannot find X11 development files])
 578   else
 579     dnl this is much more than we want
 580     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 581     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 582     dnl it does not add the libs; therefore we add them here
 583     X_LIBS="$X_LIBS -lX11"
 584     AC_SUBST(X_CFLAGS)
 585     AC_SUBST(X_LIBS)
 586   fi
 587   AC_SUBST(HAVE_X)
 588 ])
 589
 590 dnl *** XVideo ***
 591 dnl Look for the PIC library first, Debian requires it.
 592 dnl Check debian-devel archives for gory details.
 593 dnl 20020110:
 594 dnl At the moment XFree86 doesn't distribute shared libXv due
 595 dnl to unstable API.  On many platforms you CAN NOT link a shared
 596 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 597 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 598 dnl version of the static lib for plug-ins to link to when it is
 599 dnl inappropriate to link the main application to libXv directly.
 600 dnl FIXME: add check if this platform can support linking to a
 601 dnl        non-PIC libXv, if not then don not use Xv.
 602 dnl FIXME: perhaps warn user if they have a shared libXv since
 603 dnl        this is an error until XFree86 starts shipping one
 604
 605 dnl Check for Xv extension
 606 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 607 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 608                   [xvimagesink], [
 609   if test x$HAVE_X = xyes; then
 610     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 611                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 612                  $X_LIBS -lXext)
 613
 614     if test x$HAVE_XVIDEO = xyes; then
 615       XVIDEO_LIBS="-lXv_pic -lXext"
 616       AC_SUBST(XVIDEO_LIBS)
 617     else
 618       dnl try again using something else if we didn't find it first
 619       if test x$HAVE_XVIDEO = xno; then
 620         AC_CHECK_LIB(Xv, XvQueryExtension,
 621                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 622                    $X_LIBS -lXext)
 623
 624         if test x$HAVE_XVIDEO = xyes; then
 625           XVIDEO_LIBS="-lXv -lXext"
 626           AC_SUBST(XVIDEO_LIBS)
 627         fi
 628       fi
 629     fi
 630   fi
 631 ])
 632
 633 dnl check for X Shm
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 635 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 636   if test x$HAVE_X = xyes; then
 637     AC_CHECK_LIB(Xext, XShmAttach,
 638                  HAVE_XSHM="yes", HAVE_XSHM="no",
 639                  $X_LIBS)
 640     if test "x$HAVE_XSHM" = "xyes"; then
 641       XSHM_LIBS="-lXext"
 642     else
 643       dnl On AIX, it is in XextSam instead, but we still need -lXext
 644       AC_CHECK_LIB(XextSam, XShmAttach,
 645                    HAVE_XSHM="yes", HAVE_XSHM="no",
 646                    $X_LIBS)
 647       if test "x$HAVE_XSHM" = "xyes"; then
 648         XSHM_LIBS="-lXext -lXextSam"
 649       fi
 650     fi
 651   fi
 652 ], , [
 653   AC_SUBST(HAVE_XSHM)
 654   AC_SUBST(XSHM_LIBS)
 655 ] )
 656
 657 dnl v4l/v4l2 checks have been moved down because they require X
 658
 659 dnl *** Video 4 Linux ***
 660 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 662 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 663   # first check X
 664   HAVE_V4L="no"
 665   if test "$HAVE_X" = "yes"
 666   then
 667     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [
 668 #include <sys/types.h>
 669 #define _LINUX_TIME_H
 670 #include <linux/videodev.h>
 671     ])
 672   fi
 673 ])
 674
 675 dnl *** Video 4 Linux 2 ***
 676 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 678 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 679   HAVE_V4L2="no"
 680   if test "$HAVE_X" = "yes"
 681   then
 682     AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 683     AC_TRY_COMPILE([
 684 #include <sys/types.h>
 685 #include <linux/types.h>
 686 #define _LINUX_TIME_H
 687 #include <linux/videodev2.h>
 688 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 689 #error too early v4l2 version or no v4l2 at all
 690 #endif
 691     ], [
 692 return 0;
 693     ], [ HAVE_V4L2="yes" && AC_MSG_RESULT(yes)],
 694        [ HAVE_V4L2="no"  && AC_MSG_RESULT(no) &&
 695          AC_CHECK_HEADER(linux/videodev2.h,
 696                          [ AC_MSG_WARN([video4linux2 headers were found, but they're old. Please update v4l2 to compile the v4l2 plugins])],
 697                          [ AC_MSG_WARN([video4linux2 was not found])])
 698        ])
 699   fi
 700   dnl check for missing v4l2_buffer declaration (see #135919)
 701   if [ test x$HAVE_V4L2 = xyes ]; then
 702     MISSING_DECL=0
 703     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 704     AC_TRY_COMPILE([
 705 #include <sys/types.h>
 706 #include <linux/types.h>
 707 #define _LINUX_TIME_H
 708 #include <linux/videodev2.h>
 709     ],[
 710 struct v4l2_buffer buf;
 711 buf.index = 0;
 712 return 0;
 713     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 714     if [ test x$MISSING_DECL = x1 ]; then
 715       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 716     fi
 717   fi
 718 ])
 719
 720 dnl Next, check for the optional libraries:
 721 dnl These are all libraries used in building plug-ins
 722 dnl ================================================
 723 dnl let's try and sort them alphabetically, shall we ?
 724
 725 if test "x$BUILD_EXTERNAL" = "xyes"; then
 726
 727 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 728
 729 dnl *** a52dec ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 731 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 732   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 733 ])
 734
 735 dnl *** aalib ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 737 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 738   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 739   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 740 ])
 741
 742 dnl *** alsa ***
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 744 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 745   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 746     HAVE_ALSA="yes"
 747     AC_SUBST(ALSA_CFLAGS)
 748     AC_SUBST(ALSA_LIBS)
 749   ], [
 750     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 751   ])
 752 ])
 753
 754 dnl *** arts ***
 755 dnl if mcopidl can't be found there's no use in compiling it
 756 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 757 if test "x$HAVE_MCOPIDL" = "xno";
 758 then
 759   USE_ARTS=no
 760 fi
 761
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 763 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 764   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 765 ])
 766
 767 dnl *** artsc ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 769 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 770   GST_CHECK_ARTSC()
 771 ])
 772
 773 dnl *** audiofile ***
 774 dnl this check uses the GST_CHECK_CONFIGPROG macro
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 776 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 777   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 778   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 779   dnl check with pkg-config first
 780   PKG_CHECK_MODULES(AUDIOFILE, audiofile, HAVE_AUDIOFILE="yes", HAVE_AUDIOFILE="no")
 781   if test "x$HAVE_AUDIOFILE" = "xno"; then
 782     GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 783     dnl we need this function
 784     AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 785     AC_CHECK_LIB(audiofile, af_virtual_file_new, , HAVE_AUDIOFILE="no")
 786   fi])
 787
 788 dnl *** CDParanoia ***
 789 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 790 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 791   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 792                       cdda_open, -lm,
 793                       cdda_interface.h,
 794                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 795                       HEADER_DIR="no"
 796                       FOUND_CDPARANOIA="yes")
 797   if test "x$FOUND_CDPARANOIA" != "xyes";
 798   then
 799     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 800                         cdda_open, -lm,
 801                         cdda/cdda_interface.h,
 802                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 803                         HEADER_DIR="yes"
 804                         FOUND_CDPARANOIA="yes")
 805   fi
 806   if test "x$HEADER_DIR" = "xyes";
 807   then
 808     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 809                        defined if cdda headers are in a cdda/ directory)
 810   fi
 811   AC_SUBST(CDPARANOIA_LIBS)
 812 ])
 813 dnl FIXME : add second check somehow if that is necessary
 814 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 815 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 816
 817 dnl *** dirac ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRAC, true)
 819 GST_CHECK_FEATURE(DIRAC, [dirac plug-ins], dirac, [
 820   PKG_CHECK_MODULES(DIRAC, dirac, HAVE_DIRAC="yes", HAVE_DIRAC="no")
 821   AC_SUBST(DIRAC_CFLAGS)
 822   AC_SUBST(DIRAC_LIBS)
 823 ])
 824
 825 dnl *** DIVX ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 827 GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 828   HAVE_DIVX=yes
 829   AC_CHECK_HEADER(encore2.h, ,
 830                   [ AC_MSG_WARN([Divx4linux encore headers not found]) &&
 831                     HAVE_DIVX=no ] )
 832   if [ test x$HAVE_DIVX = xyes ]; then
 833     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 834     AC_TRY_COMPILE([
 835 #include <encore2.h>
 836 #if ENCORE_VERSION != 20021024
 837 #error Wrong version of divx encore libraries
 838 #endif
 839     ], [
 840 return 0;
 841     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 842        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 843          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 844   fi
 845   if [ test x$HAVE_DIVX = xyes ]; then
 846     AC_CHECK_HEADER(decore.h, ,
 847                     [ AC_MSG_WARN([Divx4linux decoder headers not found]) &&
 848                       HAVE_DIVX=no ] )
 849   fi
 850   if [ test x$HAVE_DIVX = xyes ]; then
 851     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 852     AC_TRY_COMPILE([
 853 #include <decore.h>
 854 #if DECORE_VERSION != 20021112
 855 #error Wrong version of divx decore libraries
 856 #endif
 857     ], [
 858 return 0;
 859     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 860        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 861          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 862   fi
 863   LIBS="-lm"
 864   if test x$HAVE_DIVX = xyes; then
 865     AC_CHECK_LIB(divxencore, encore, ,
 866                  [ AC_MSG_WARN([Divx4linux encore libs not found]) &&
 867                    HAVE_DIVX=no ] )
 868   fi
 869   if test x$HAVE_DIVX = xyes; then
 870     AC_CHECK_LIB(divxdecore, decore, ,
 871                  [ AC_MSG_WARN([Divx4linux decore libs not found]) &&
 872                    HAVE_DIVX=no ] )
 873   fi
 874   if test x$HAVE_DIVX = xyes; then
 875     DIVXENC_LIBS="-ldivxencore -lm"
 876     DIVXDEC_LIBS="-ldivxdecore -lm"
 877     AC_SUBST(DIVXENC_LIBS)
 878     AC_SUBST(DIVXDEC_LIBS)
 879   fi
 880 ])
 881
 882 dnl *** DTS ***
 883 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 884 GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 885   GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h, DTS_LIBS="-ldts_pic -lm")
 886   AC_SUBST(DTS_LIBS)
 887 ])
 888
 889 dnl *** dvdread ***
 890 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 891 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 892   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 893   AC_SUBST(DVDREAD_LIBS)
 894 ])
 895
 896 dnl *** dvdnav ***
 897 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 898 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 899   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 900   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 901   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 902   if test x"$HAVE_DVDNAV" = x"yes"; then
 903     dnl check version
 904     DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
 905     DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
 906     DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
 907     DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
 908     if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 909        [[ "$DVDNAV_MINOR" -lt "1" ]]; then
 910       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 911       HAVE_DVDNAV="no"
 912     elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 913          [[ "$DVDNAV_MINOR" -eq "1" ]] && \
 914          [[ "$DVDNAV_MICRO" -lt "7" ]]; then
 915       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 916       HAVE_DVDNAV="no"
 917     fi
 918   fi
 919   dnl now check for dvdread/nav_print.h - see #133002
 920   AC_CHECK_HEADER(dvdread/nav_print.h, , [
 921       AC_MSG_WARN([header dvdread/nav_print.h from dvdread missing])
 922       HAVE_DVDNAV="no"
 923   ])
 924   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 925 ])
 926
 927 dnl **** ESound ****
 928 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 929 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 930   PKG_CHECK_MODULES(ESD, esound >= 0.2.12, [
 931     HAVE_ESD="yes"
 932     AC_SUBST(ESD_CFLAGS)
 933     AC_SUBST(ESD_LIBS)
 934   ], [
 935     AM_PATH_ESD(0.2.12, HAVE_ESD="yes", HAVE_ESD="no")
 936     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 937   ])
 938 ])
 939
 940 dnl **** Free AAC Encoder (FAAC) ****
 941 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 942 GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 943   GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h, FAAC_LIBS="-lfaac -lm")
 944   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 945   AC_SUBST(FAAC_LIBS)
 946 ])
 947
 948 dnl **** Free AAC Decoder (FAAD) ****
 949 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 950 GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 951   HAVE_FAAD="yes"
 952   GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h, FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 953   if test $HAVE_FAAD = "yes"; then
 954     AC_MSG_CHECKING([Checking for FAAD >= 2])
 955     AC_TRY_COMPILE([
 956 #include <faad.h>
 957 #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 958 #error Not faad2
 959 #endif
 960     ], [ return 0; ],
 961        [ HAVE_FAAD="yes" && AC_MSG_RESULT(yes)],
 962        [ HAVE_FAAD="no"  && AC_MSG_RESULT(no)])
 963   fi;
 964   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 965   AC_SUBST(FAAD_LIBS)
 966 ])
 967
 968 dnl **** festival ****
 969 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 970 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 971   dnl NOTE: just using local net connection now, add this lib check
 972   dnl       in the future if needed
 973   dnl AC_LANG_PUSH(C++)
 974   dnl dnl FIXME: took out func to check for
 975   dnl dnl This check puts festival_tidy_up in extern "C".
 976   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 977   dnl dnl mangling C++ nonsense and symbols can't resolve
 978   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 979   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 980   dnl AC_LANG_POP(C++)
 981   dnl AC_SUBST(FESTIVAL_LIBS)
 982 dnl  HAVE_FESTIVAL=yes
 983 dnl])
 984
 985 dnl *** FLAC ***
 986 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 987 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 988   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 989   AC_SUBST(FLAC_LIBS)
 990 ])
 991
 992 dnl *** GDK pixbuf ***
 993 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 994 GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbufsrc, [
 995   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 996 ])
 997
 998 dnl *** Gnome VFS ***
 999 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
1000 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
1001   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
1002   AC_SUBST(GNOME_VFS_CFLAGS)
1003   AC_SUBST(GNOME_VFS_LIBS)
1004 ])
1005
1006 dnl *** gsm ***
1007 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
1008 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
1009   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
1010   if test $HAVE_GSM != "yes"; then
1011     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
1012     if test $HAVE_GSM = "yes"; then
1013       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
1014     fi
1015   fi
1016   AC_SUBST(GSM_LIBS)
1017 ])
1018
1019 dnl *** Hermes ***
1020 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
1021 GST_CHECK_FEATURE(HERMES, [Hermes library], hermescolorspace, [
1022   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
1023 ], AC_SUBST(HERMES_LIBS))
1024
1025 dnl *** http ***
1026 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
1027 dnl GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
1028 dnl  dnl FIXME: need to check for header
1029 dnl  GHTTP_LIBS=
1030 dnl  GST_HTTPSRC_GET_TYPE=
1031 dnl  if test x$USE_GLIB2 = xyes; then
1032 dnl    AC_MSG_WARN(ghttp disabled for glib2.0)
1033 dnl  else
1034 dnl    AC_CHECK_LIB(ghttp, ghttp_request_new,
1035 dnl      [HTTP_LIBS="-lghttp"
1036 dnl       GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
1037 dnl       HAVE_HTTP=yes
1038 dnl      ], :, $LIBS)
1039 dnl  fi
1040 dnl  AC_SUBST(HTTP_LIBS)
1041 dnl  AC_SUBST(GST_HTTPSRC_GET_TYPE)
1042 dnl ])
1043
1044 dnl *** ivorbis ***
1045 dnl AM_PATH_IVORBIS only takes two options
1046 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
1047 GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
1048   IVORBIS_LIBS=
1049   IVORBIS_CFLAGS=
1050   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
1051     [IVORBIS_LIBS=-lvorbisidec
1052      HAVE_IVORBIS=yes],
1053     HAVE_IVORBIS=no)
1054   AC_SUBST(IVORBIS_LIBS)
1055   AC_SUBST(IVORBIS_CFLAGS)
1056 ])
1057
1058 dnl *** Jack ***
1059 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
1060 GST_CHECK_FEATURE(JACK, Jack, jack, [
1061   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
1062   AC_SUBST(JACK_CFLAGS)
1063   AC_SUBST(JACK_LIBS)
1064 ])
1065
1066 dnl *** jpeg ***
1067 dnl FIXME: we could use header checks here as well IMO
1068 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
1069 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
1070   AC_ARG_WITH(jpeg-mmx,
1071     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
1072   OLD_LIBS="$LIBS"
1073   if test x$with_jpeg_mmx != x; then
1074     LIBS="$LIBS -L$with_jpeg_mmx"
1075   fi
1076   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
1077   JPEG_LIBS="$LIBS -ljpeg-mmx"
1078   LIBS="$OLD_LIBS"
1079   if test x$HAVE_JPEG != xyes; then
1080     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
1081     JPEG_LIBS="-ljpeg"
1082   fi
1083   AC_SUBST(JPEG_LIBS)
1084 ])
1085
1086 dnl *** KDE / Qt ***
1087
1088 dnl * Qt *
1089
1090 qt_dirs="$QTDIR /usr/lib/qt3 /usr/lib/qt /usr/share/qt3 /usr/local/qt"
1091
1092 dnl Build include path search path from the list of Qt dirs
1093
1094 qt_include_dirs=""
1095 for dir in $qt_dirs; do
1096   qt_include_dirs="$qt_include_dirs $dir/include $dir"
1097 done
1098
1099 qt_include_dirs="$qt_include_dirs /usr/include/qt /usr/include /usr/X11R6/include/X11/qt /usr/X11R6/include/qt /usr/include/qt3"
1100
1101 for dir in $qt_include_dirs; do
1102   if test -r "$dir/qglobal.h"; then
1103     qt_include_dir=$dir
1104     break
1105   fi
1106 done
1107
1108 for dir in $qt_dirs; do
1109   qt_lib_dirs="$qt_lib_dirs $dir/lib $dir"
1110 done
1111
1112 qt_lib_dirs="$qt_lib_dirs /usr/X11R6/lib /usr/lib"
1113
1114 for dir in $qt_lib_dirs; do
1115   try="ls -1 $dir/libqt-mt.*"
1116   if test -n "`$try 2> /dev/null`"; then
1117     qt_lib_dir=$dir
1118     break
1119   fi
1120 done
1121
1122 dnl * KDE *
1123
1124 translit(dnm, m, l) AM_CONDITIONAL(USE_KIO, true)
1125 GST_CHECK_FEATURE(KIO, [kio], kio, [
1126   AC_PATH_PROG(KDE_MOC, moc, no)
1127   if test x$KDE_MOC = xno; then
1128     HAVE_KIO="no"
1129   else
1130     AC_PATH_PROG(KDE_CONFIG, kde-config, no)
1131
1132     if test x$KDE_CONFIG != xno; then
1133       KDE_PREFIX=`$KDE_CONFIG --prefix`
1134     fi
1135
1136     kde_include_dirs="/usr/lib/kde/include /usr/local/kde/include /usr/local/include /usr/kde/include /usr/include/kde /usr/include /opt/kde3/include /opt/kde/include"
1137     kde_lib_dirs="/usr/lib/kde/lib /usr/local/kde/lib /usr/kde/lib /usr/lib/kde /usr/lib/kde3 /usr/lib /usr/X11R6/lib /usr/local/lib /opt/kde3/lib /opt/kde/lib /usr/X11R6/kde/lib"
1138
1139     if test -n "$KDE_PREFIX"; then
1140       kde_include_dirs="$KDE_PREFIX/include $KDE_PREFIX/include/kde $KDE_PREFIX $kde_include_dirs"
1141       kde_lib_dirs="$KDE_PREFIX/lib $KDE_PREFIX $kde_lib_dirs"
1142     fi
1143     if test -n "$KDEDIR"; then
1144       kde_include_dirs="$KDEDIR/include $KDEDIR/include/kde $KDEDIR $kde_include_dirs"
1145       kde_lib_dirs="$KDEDIR/lib $KDEDIR $kde_lib_dirs"
1146     fi
1147
1148     for dir in $kde_include_dirs; do
1149       if test -r "$dir/kglobal.h" && test -r "$dir/kdemacros.h"; then
1150         kde_include_dir=$dir
1151         break
1152       fi
1153     done
1154
1155     for dir in $kde_lib_dirs; do
1156       try="ls -1 $dir/libkio.*"
1157       if test -n "`$try 2> /dev/null`"; then
1158         kde_lib_dir=$dir
1159         break
1160       fi
1161     done
1162
1163     if test -n $kde_include_dir && test -n $kde_lib_dir; then
1164       KIO_CFLAGS="-I$kde_include_dir -I$qt_include_dir"
1165       KIO_LIBS="-L$KDE_PREFIX/lib -L$qt_lib_dir -lkio -lqt-mt"
1166       AC_LANG_PUSH(C++)
1167       save_LIBS="$LIBS"
1168       save_CPPFLAGS="$CPPFLAGS"
1169       LIBS="$LIBS $KIO_LIBS"
1170       CPPFLAGS="$CPPFLAGS $KIO_CFLAGS"
1171       AC_TRY_LINK([
1172 #include <kio/job.h>
1173                    ], [
1174   KIO::get ("bla")
1175                    ], HAVE_KIO="yes", HAVE_KIO="no")
1176       LIBS="$save_LIBS"
1177       CPPFLAGS="$save_CPPFLAGS"
1178       AC_LANG_POP(C++)
1179       AC_SUBST(KIO_CFLAGS)
1180       AC_SUBST(KIO_LIBS)
1181     else
1182       HAVE_KIO="no"
1183     fi
1184   fi
1185 ])
1186
1187 dnl *** ladspa ***
1188 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
1189 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
1190   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
1191 ])
1192
1193 dnl *** lame ***
1194 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
1195 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
1196   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
1197 ])
1198 AC_SUBST(LAME_LIBS)
1199
1200 dnl *** libcaca ***
1201 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
1202 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
1203   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
1204   AC_SUBST(LIBCACA_CFLAGS)
1205   AC_SUBST(LIBCACA_LIBS)
1206 ])
1207
1208 dnl *** libcolorspace ***
1209 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
1210 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
1211   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
1212   AC_SUBST(LCS_CFLAGS)
1213   AC_SUBST(LCS_LIBS)
1214 ])
1215
1216 dnl *** libdv ***
1217 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
1218 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
1219   PKG_CHECK_MODULES(LIBDV, libdv >= 0.100, HAVE_LIBDV="yes", HAVE_LIBDV="no")
1220   AC_SUBST(LIBDV_CFLAGS)
1221   AC_SUBST(LIBDV_LIBS)
1222 ])
1223
1224 dnl *** libfame ***
1225 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
1226 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
1227   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
1228   AC_SUBST(LIBFAME_CFLAGS)
1229   AC_SUBST(LIBFAME_LIBS)
1230 ])
1231
1232 dnl *** libpng ***
1233 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1234 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
1235   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
1236   AC_SUBST(LIBPNG_CFLAGS)
1237   AC_SUBST(LIBPNG_LIBS)
1238 ])
1239
1240 dnl *** librfb ***
1241 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBRFB, true)
1242 GST_CHECK_FEATURE(LIBRFB, [librfb Remote Framebuffer], rfbsrc, [
1243   PKG_CHECK_MODULES(LIBRFB, librfb-0.1, HAVE_LIBRFB="yes", HAVE_LIBRFB="no")
1244   AC_SUBST(LIBRFB_CFLAGS)
1245   AC_SUBST(LIBRFB_LIBS)
1246 ])
1247
1248 dnl *** libvisual ***
1249 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
1250 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
1251   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.1.1, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
1252   AC_SUBST(LIBVISUAL_CFLAGS)
1253   AC_SUBST(LIBVISUAL_LIBS)
1254 ])
1255
1256 dnl *** mad ***
1257 dnl FIXME: we could use header checks here as well IMO
1258 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
1259 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
1260   dnl check with pkg-config first
1261   PKG_CHECK_MODULES(MAD, mad >= 0.15 id3tag >= 0.15, HAVE_MAD="yes", HAVE_MAD="no")
1262   if test "x$HAVE_MAD" = "xno"; then
1263     dnl fall back to oldskool detection
1264     AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
1265     if test "x$HAVE_MAD" = "xyes"; then
1266       HAVE_MAD="no"
1267       save_LIBS=$LIBS
1268       LIBS="-lz"
1269       AC_CHECK_LIB(id3tag, id3_tag_options, HAVE_MAD="yes" MAD_LIBS="-lmad -lid3tag -lz")
1270       LIBS=$save_LIBS
1271     fi
1272   fi
1273 ])
1274 AC_SUBST(MAD_LIBS)
1275
1276 dnl *** mikmod ***
1277 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
1278 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
1279   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
1280   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
1281   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMOD_CFLAGS")
1282 ])
1283
1284 dnl *** mpeg2dec ***
1285 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
1286 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
1287   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0,
1288       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
1289   AC_SUBST(MPEG2DEC_CFLAGS)
1290   AC_SUBST(MPEG2DEC_LIBS)
1291 ])
1292
1293 dnl *** mpeg2enc ***
1294 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
1295 GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
1296   HAVE_MPEG2ENC="no"
1297   dnl we require a c++ compiler for this one
1298   if [ test x$HAVE_CXX = xyes ]; then
1299     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
1300     dnl since many distros include mjpegtools specifically without mplex
1301     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
1302     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
1303       dnl switch over to c++ to test things
1304       AC_LANG_CPLUSPLUS
1305       OLD_CPPFLAGS="$CPPFLAGS"
1306       CPPFLAGS="$CPPFLAGS $MPEG2ENC_CFLAGS"
1307       AC_CHECK_HEADER(mpeg2encoder.hh, [
1308         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
1309         OLD_LIBS="$LIBS"
1310         LIBS="$LIBS $MPEG2ENC_LIBS"
1311         AC_MSG_CHECKING([for valid mpeg2enc objects])
1312         AC_TRY_RUN([
1313 #include <mpeg2encoder.hh>
1314 #include <mpeg2encoptions.hh>
1315
1316 int
1317 main (int   argc,
1318       char *argv[])
1319 {
1320   MPEG2EncOptions *options = new MPEG2EncOptions ();
1321   MPEG2Encoder encoder (*options);
1322   return 0;
1323 }
1324         ],[
1325           HAVE_MPEG2ENC="yes"
1326           AC_SUBST(MPEG2ENC_CFLAGS)
1327           AC_SUBST(MPEG2ENC_LIBS)
1328           AC_MSG_RESULT(yes)
1329         ], AC_MSG_RESULT(no))
1330         LIBS="$OLD_LIBS"
1331       ])
1332       CPPFLAGS="$OLD_CPPFLAGS"
1333       AC_LANG_C
1334     ],
1335     HAVE_MPEG2ENC="no")
1336   fi
1337 ])
1338
1339 dnl *** mplex ***
1340 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
1341 GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
1342   HAVE_MPLEX="no"
1343   dnl we require a c++ compiler for this one
1344   if [ test x$HAVE_CXX = xyes ]; then
1345     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
1346     dnl since many distros include mjpegtools specifically without mplex
1347     dnl and mpeg2enc, we check for mplex on its own, too.
1348     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.6.1.93, [
1349       dnl switch over to c++ to test things
1350       AC_LANG_CPLUSPLUS
1351       OLD_CPPFLAGS="$CPPFLAGS"
1352       CPPFLAGS="$CPPFLAGS $MPLEX_CFLAGS"
1353       AC_CHECK_HEADER(interact.hpp, [
1354         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 -lm"
1355         OLD_LIBS="$LIBS"
1356         LIBS="$LIBS $MPLEX_LIBS"
1357         AC_MSG_CHECKING([for valid mplex objects])
1358         AC_TRY_RUN([
1359 #include <interact.hpp>
1360 #include <outputstrm.hpp>
1361 #include <multiplexor.hpp>
1362
1363 int
1364 main (int   argc,
1365       char *argv[])
1366 {
1367   class TestOutputStream : public OutputStream {
1368   public:
1369     TestOutputStream () : OutputStream () { }
1370     void Write (uint8_t *a, unsigned int b) { }
1371     void NextSegment () { }
1372     off_t SegmentSize () { }
1373     void Close () { }
1374     int Open () { }
1375   };
1376   MultiplexJob *job = new MultiplexJob ();
1377   vector<IBitStream *> inputs;
1378   job->SetupInputStreams (inputs);
1379   TestOutputStream *out = new TestOutputStream ();
1380   Multiplexor mux (*job, *out);
1381   return 0;
1382 }
1383         ],[
1384           HAVE_MPLEX="yes"
1385           AC_SUBST(MPLEX_CFLAGS)
1386           AC_SUBST(MPLEX_LIBS)
1387           AC_MSG_RESULT(yes)
1388         ], AC_MSG_RESULT(no))
1389         LIBS="$OLD_LIBS"
1390       ])
1391       CPPFLAGS="$OLD_CPPFLAGS"
1392       AC_LANG_C
1393     ], HAVE_MPLEX="no")
1394   fi
1395 ])
1396
1397 dnl *** musicbrainz ***
1398 dnl libmusicbrainz <= 2.0.2 has symbol clashes with ffmpeg
1399 dnl however, our ffmpeg patch was accepted upstream
1400 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
1401 GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz], musicbrainz, [
1402   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.0.2,
1403       HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
1404   AC_SUBST(MUSICBRAINZ_CFLAGS)
1405   AC_SUBST(MUSICBRAINZ_LIBS)
1406 ])
1407
1408 dnl *** nas ***
1409 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
1410 GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
1411   HAVE_NAS="no"
1412   if test "x$HAVE_X" = "xyes"; then
1413     save_cppflags=$CFLAGS
1414     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1415     GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
1416       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
1417     CPPFLAGS="$save_cppflags"
1418   fi
1419   AC_SUBST(NAS_CFLAGS)
1420   AC_SUBST(NAS_LIBS)
1421 ])
1422
1423 dnl *** pango ***
1424 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
1425 GST_CHECK_FEATURE(PANGO, [pango], pango, [
1426   PKG_CHECK_MODULES(PANGO, pango pangoft2,
1427       HAVE_PANGO="yes", HAVE_PANGO="no")
1428   AC_SUBST(PANGO_CFLAGS)
1429   AC_SUBST(PANGO_LIBS)
1430 ])
1431
1432 dnl *** raw1394 ***
1433 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
1434 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
1435   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_new_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
1436   AC_SUBST(RAW1394_LIBS)
1437 ])
1438
1439 dnl *** SDL ***
1440 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
1441 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
1442   dnl sdlvideosink depends on the xoverlay interface, which depends on X
1443   if test x$HAVE_X = xyes; then
1444     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
1445   fi
1446 ])
1447
1448 dnl *** shout ***
1449 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
1450 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
1451   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
1452   AC_SUBST(SHOUT_LIBS)
1453 ])
1454
1455 dnl *** shout2 ***
1456 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
1457 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
1458   PKG_CHECK_MODULES(SHOUT2, shout >= 2.0, [
1459     HAVE_SHOUT2="yes"
1460     AC_SUBST(SHOUT2_CFLAGS)
1461     AC_SUBST(SHOUT2_LIBS)
1462   ], [
1463     AM_PATH_SHOUT2(HAVE_SHOUT2="yes", HAVE_SHOUT2="no")
1464     AC_SUBST(SHOUT2_CFLAGS)
1465     AC_SUBST(SHOUT2_LIBS)
1466   ])
1467 ])
1468
1469 dnl *** sidplay ***
1470 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
1471 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
1472   GST_PATH_SIDPLAY()
1473 ])
1474
1475 dnl *** smoothwave ***
1476 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
1477 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
1478   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
1479 ])
1480
1481
1482 dnl *** snapshot ***
1483 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1484 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
1485   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz -lm, png.h, LIBPNG_LIBS="-lpng -lz -lm")
1486   AC_SUBST(LIBPNG_LIBS)
1487 ])
1488
1489 dnl *** speex 1.0.x or >= 1.1.5 (1.1.4 and earlier were not API/ABI compatible ***
1490 dnl speex_jitter.h is 1.1 only
1491 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
1492 GST_CHECK_FEATURE(SPEEX, [speex plug-in], speex, [
1493   GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex.h, [
1494     AC_CHECK_HEADER(speex_jitter.h, [
1495       dnl speex 1.1.x :
1496       GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex.h, [
1497         dnl speex 1.1.5 or + :
1498         HAVE_SPEEX="yes"
1499         SPEEX_LIBS="-lspeex"
1500         AC_SUBST(SPEEX_CFLAGS)
1501         AC_SUBST(SPEEX_LIBS)
1502       ],[
1503         HAVE_SPEEX="no"
1504       ])
1505     ], [
1506       dnl speex 1.0.x :
1507       HAVE_SPEEX="yes"
1508       SPEEX_LIBS="-lspeex"
1509       AC_SUBST(SPEEX_CFLAGS)
1510       AC_SUBST(SPEEX_LIBS)
1511     ])
1512   ])
1513 ])
1514
1515 dnl *** sndfile ***
1516 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
1517 GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
1518   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.0, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
1519   AC_SUBST(SNDFILE_CFLAGS)
1520   AC_SUBST(SNDFILE_LIBS)
1521 ])
1522
1523 dnl *** swfdec ***
1524 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1525 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1526   PKG_CHECK_MODULES(SWFDEC, swfdec >= 0.1.3.1, HAVE_SWFDEC=yes, HAVE_SWFDEC=no)
1527   AC_SUBST(SWFDEC_CFLAGS)
1528   AC_SUBST(SWFDEC_LIBS)
1529 ])
1530
1531 dnl *** tarkin ***
1532 dnl for now the sources are included in the plug-in
1533 dnl and should be moved to ext-libs/ perhaps
1534 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
1535 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
1536   HAVE_TARKIN="yes"
1537 ])
1538
1539 dnl *** ogg ***
1540 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
1541 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
1542   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
1543     HAVE_OGG="yes"
1544     AC_SUBST(OGG_CFLAGS)
1545     AC_SUBST(OGG_LIBS)
1546   ], [
1547     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
1548     AS_SCRUB_INCLUDE(OGG_CFLAGS)
1549   ])
1550 ])
1551
1552 dnl *** theora ***
1553 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
1554 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
1555   PKG_CHECK_MODULES(THEORA, theora, [
1556     HAVE_THEORA="yes"
1557     AC_SUBST(THEORA_LIBS)
1558     AC_SUBST(THEORA_CFLAGS)
1559   ], [
1560     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
1561     AC_SUBST(THEORA_LIBS)
1562   ])
1563 ])
1564
1565 dnl *** vorbis ***
1566 dnl AM_PATH_VORBIS only takes two options
1567 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
1568 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
1569   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
1570     HAVE_VORBIS="yes"
1571   ], [
1572     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
1573     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
1574   ])
1575 ])
1576 if test "x$HAVE_VORBIS" = "xyes"; then
1577   ac_cflags_save="$CFLAGS"
1578   dnl FIXME: does this work on non-gcc? -- Company
1579   CFLAGS="-Wall -Werror"
1580   AC_COMPILE_IFELSE(
1581     AC_LANG_PROGRAM([
1582 #include <vorbis/codec.h>
1583                      ],[
1584 vorbis_dsp_state *v;
1585
1586 vorbis_synthesis_restart (v);
1587                      ]), HAVE_VSR=yes, HAVE_VSR=no)
1588   if test "x$HAVE_VSR" = "xyes"; then
1589     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
1590                        [defined if vorbis_synthesis_restart is present])
1591   fi
1592   CFLAGS="$ac_cflags_save"
1593 fi
1594
1595 dnl *** xine ***
1596 translit(dnm, m, l) AM_CONDITIONAL(USE_XINE, true)
1597 GST_CHECK_FEATURE(XINE, [xine wrapper], xine, [
1598   PKG_CHECK_MODULES(XINE, libxine >= 1.0.0, HAVE_XINE=yes, HAVE_XINE=no)
1599   AC_SUBST(XINE_CFLAGS)
1600   AC_SUBST(XINE_LIBS)
1601 ],disabled)
1602
1603 dnl *** XVID ***
1604 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1605 GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1606   HAVE_XVID=no
1607   AC_CHECK_HEADER(xvid.h, [
1608     OLD_LIBS="$LIBS"
1609     LIBS="-lm"
1610     AC_CHECK_LIB(xvidcore, xvid_encore, [
1611       AC_CHECK_LIB(xvidcore, xvid_decore, [
1612         AC_CHECK_LIB(xvidcore, xvid_global, [
1613           AC_MSG_CHECKING([for uptodate XviD API version])
1614           AC_TRY_RUN([
1615 #include <xvid.h>
1616 #if XVID_API != XVID_MAKE_API(4,0)
1617 #error "Incompatible XviD API version"
1618 #endif
1619 int main () { return 0; }
1620           ],[ AC_MSG_RESULT(yes)
1621             XVID_LIBS="-lxvidcore -lm"
1622             AC_SUBST(XVID_LIBS)
1623             HAVE_XVID=yes
1624           ], AC_MSG_RESULT(no) )
1625         ], )
1626       ], )
1627     ], )
1628     LIBS="$OLD_LIBS"
1629   ], )
1630 ])
1631
1632
1633 fi dnl of EXT plugins
1634
1635 dnl Check for atomic.h
1636 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
1637 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
1638 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
1639 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
1640 if test x$HAVE_ATOMIC_H = xyes; then
1641   AC_TRY_RUN([
1642 #include "asm/atomic.h"
1643 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
1644   ],, [
1645     # Not successful
1646     if test x$HAVE_ATOMIC_H = xyes; then
1647       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
1648     fi
1649     HAVE_ATOMIC_H=no
1650   ], [
1651     # Cross compiling
1652     AC_MSG_RESULT(yes)
1653     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
1654   ])
1655 fi
1656
1657
1658 dnl ######################################################################
1659 dnl # Check command line parameters, and set shell variables accordingly #
1660 dnl ######################################################################
1661
1662 AC_ARG_ENABLE(libmmx,
1663   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
1664 [case "${enableval}" in
1665   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
1666   no)  USE_LIBMMX=no ;;
1667   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
1668 esac],
1669 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
1670
1671 AC_ARG_ENABLE(atomic,
1672   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
1673 [case "${enableval}" in
1674   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1675   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1676   no)  USE_ATOMIC_H=no;;
1677   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
1678 esac],
1679 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
1680
1681 AC_ARG_ENABLE(profiling,
1682   AC_HELP_STRING([--enable-profiling],
1683                  [-pg to compiler commandline, for profiling]),
1684 [case "${enableval}" in
1685   yes) USE_PROFILING=yes ;;
1686   no)  UES_PROFILING=no ;;
1687   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
1688 esac],
1689 [USE_PROFILING=no]) dnl Default value
1690
1691 AC_ARG_ENABLE(tests,
1692   AC_HELP_STRING([--disable-tests],[disable building test apps]),
1693 [case "${enableval}" in
1694   yes) BUILD_TESTS=yes ;;
1695   no)  BUILD_TESTS=no ;;
1696   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
1697 esac],
1698 [BUILD_TESTS=yes]) dnl Default value
1699
1700 AC_ARG_ENABLE(examples,
1701   AC_HELP_STRING([--disable-examples],[disable building examples]),
1702 [case "${enableval}" in
1703   yes) BUILD_EXAMPLES=yes ;;
1704   no)  BUILD_EXAMPLES=no ;;
1705   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
1706 esac],
1707 [BUILD_EXAMPLES=yes]) dnl Default value
1708
1709 dnl seeking needs freetype, so check for it here
1710 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
1711   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
1712 ])
1713 dnl make the HAVE_FT2 variable available to automake and Makefile.am
1714 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
1715 AC_SUBST(FT2_CFLAGS)
1716 AC_SUBST(FT2_LIBS)
1717
1718 dnl ################################################
1719 dnl # Set defines according to variables set above #
1720 dnl ################################################
1721
1722
1723 if test "x$USE_LIBMMX" = xyes; then
1724   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
1725 fi
1726
1727 if test "x$USE_ATOMIC_H" = xyes; then
1728   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
1729 fi
1730
1731 # do not use deprecated stuff
1732 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
1733
1734 if test "x$USE_DEBUG" = xyes; then
1735   GST_CFLAGS="$GST_CFLAGS -g"
1736 fi
1737
1738 dnl #############################
1739 dnl # Set automake conditionals #
1740 dnl #############################
1741
1742 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
1743 dnl HAVE_ and it is likely to be easier to stick with the old name
1744 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
1745
1746 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
1747
1748 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
1749 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
1750
1751 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
1752 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
1753 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
1754 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
1755 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
1756 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
1757 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
1758 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
1759 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
1760 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
1761
1762 dnl prefer internal headers to already installed ones
1763 dnl also add builddir include for enumtypes and marshal
1764 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_ERROR"
1765
1766 AC_SUBST(GST_LIBS)
1767 AC_SUBST(GST_CFLAGS)
1768
1769 dnl ###########################
1770 dnl # Configure external libs #
1771 dnl ###########################
1772
1773 dnl ############################
1774 dnl # Set up some more defines #
1775 dnl ############################
1776
1777 dnl set license and copyright notice
1778 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
1779 dnl package name in plugins
1780 AC_ARG_WITH(package-name,
1781 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
1782 [case "${withval}" in
1783   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1784   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1785   *) GST_PACKAGE="${withval}" ;;
1786 esac],
1787 [GST_PACKAGE="GStreamer Plugins"]) dnl Default value
1788 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
1789 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
1790 dnl package origin URL
1791 AC_ARG_WITH(package-origin,
1792 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
1793 [case "${withval}" in
1794   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1795   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1796   *) GST_ORIGIN="${withval}" ;;
1797 esac],
1798 [GST_ORIGIN="http://gstreamer.net/"]) dnl Default value
1799 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
1800 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
1801
1802 dnl #########################
1803 dnl # Make the output files #
1804 dnl #########################
1805
1806 AC_CONFIG_FILES(
1807 Makefile
1808 gst-plugins.spec
1809 gst/Makefile
1810 gst/ac3parse/Makefile
1811 gst/adder/Makefile
1812 gst/alpha/Makefile
1813 gst/audioconvert/Makefile
1814 gst/audioscale/Makefile
1815 gst/audiorate/Makefile
1816 gst/auparse/Makefile
1817 gst/avi/Makefile
1818 gst/asfdemux/Makefile
1819 gst/cdxaparse/Makefile
1820 gst/chart/Makefile
1821 gst/colorspace/Makefile
1822 gst/cutter/Makefile
1823 gst/debug/Makefile
1824 gst/deinterlace/Makefile
1825 gst/effectv/Makefile
1826 gst/festival/Makefile
1827 gst/ffmpegcolorspace/Makefile
1828 gst/filter/Makefile
1829 gst/flx/Makefile
1830 gst/goom/Makefile
1831 gst/interleave/Makefile
1832 gst/law/Makefile
1833 gst/level/Makefile
1834 gst/matroska/Makefile
1835 gst/median/Makefile
1836 gst/mixmatrix/Makefile
1837 gst/mpeg1sys/Makefile
1838 gst/mpeg1videoparse/Makefile
1839 gst/mpeg2sub/Makefile
1840 gst/mpegaudio/Makefile
1841 gst/mpegaudioparse/Makefile
1842 gst/mpegstream/Makefile
1843 gst/modplug/Makefile
1844 gst/modplug/libmodplug/Makefile
1845 gst/monoscope/Makefile
1846 gst/multifilesink/Makefile
1847 gst/multipart/Makefile
1848 gst/overlay/Makefile
1849 gst/passthrough/Makefile
1850 gst/playback/Makefile
1851 gst/playondemand/Makefile
1852 gst/qtdemux/Makefile
1853 gst/realmedia/Makefile
1854 gst/rtjpeg/Makefile
1855 gst/rtp/Makefile
1856 gst/silence/Makefile
1857 gst/sine/Makefile
1858 gst/smooth/Makefile
1859 gst/smpte/Makefile
1860 gst/spectrum/Makefile
1861 gst/speed/Makefile
1862 gst/stereo/Makefile
1863 gst/switch/Makefile
1864 gst/synaesthesia/Makefile
1865 gst/tags/Makefile
1866 gst/tcp/Makefile
1867 gst/typefind/Makefile
1868 gst/udp/Makefile
1869 gst/vbidec/Makefile
1870 gst/videobox/Makefile
1871 gst/videocrop/Makefile
1872 gst/videodrop/Makefile
1873 gst/videofilter/Makefile
1874 gst/videoflip/Makefile
1875 gst/videomixer/Makefile
1876 gst/videorate/Makefile
1877 gst/videoscale/Makefile
1878 gst/videotestsrc/Makefile
1879 gst/volenv/Makefile
1880 gst/volume/Makefile
1881 gst/wavenc/Makefile
1882 gst/wavparse/Makefile
1883 gst/y4m/Makefile
1884 sys/Makefile
1885 sys/cdrom/Makefile
1886 sys/dxr3/Makefile
1887 sys/glsink/Makefile
1888 sys/oss/Makefile
1889 sys/osxaudio/Makefile
1890 sys/osxvideo/Makefile
1891 sys/qcam/Makefile
1892 sys/sunaudio/Makefile
1893 sys/v4l/Makefile
1894 sys/v4l2/Makefile
1895 sys/vcd/Makefile
1896 sys/ximage/Makefile
1897 sys/xvimage/Makefile
1898 ext/Makefile
1899 ext/a52dec/Makefile
1900 ext/aalib/Makefile
1901 ext/alsa/Makefile
1902 ext/arts/Makefile
1903 ext/artsd/Makefile
1904 ext/audiofile/Makefile
1905 ext/cdparanoia/Makefile
1906 ext/dirac/Makefile
1907 ext/divx/Makefile
1908 ext/dts/Makefile
1909 ext/dv/Makefile
1910 ext/dvdread/Makefile
1911 ext/dvdnav/Makefile
1912 ext/esd/Makefile
1913 ext/faac/Makefile
1914 ext/faad/Makefile
1915 ext/flac/Makefile
1916 ext/gdk_pixbuf/Makefile
1917 ext/gnomevfs/Makefile
1918 ext/gsm/Makefile
1919 ext/hermes/Makefile
1920 dnl ext/http/Makefile
1921 ext/jack/Makefile
1922 ext/jpeg/Makefile
1923 ext/kio/Makefile
1924 ext/ladspa/Makefile
1925 ext/lame/Makefile
1926 ext/ivorbis/Makefile
1927 ext/lcs/Makefile
1928 ext/libcaca/Makefile
1929 ext/libfame/Makefile
1930 ext/libpng/Makefile
1931 ext/librfb/Makefile
1932 ext/libvisual/Makefile
1933 ext/mad/Makefile
1934 ext/mikmod/Makefile
1935 ext/mpeg2dec/Makefile
1936 ext/mpeg2enc/Makefile
1937 ext/mplex/Makefile
1938 ext/musicbrainz/Makefile
1939 ext/nas/Makefile
1940 ext/ogg/Makefile
1941 ext/pango/Makefile
1942 ext/raw1394/Makefile
1943 ext/sdl/Makefile
1944 ext/shout/Makefile
1945 ext/shout2/Makefile
1946 ext/sidplay/Makefile
1947 ext/smoothwave/Makefile
1948 ext/snapshot/Makefile
1949 ext/speex/Makefile
1950 ext/sndfile/Makefile
1951 ext/swfdec/Makefile
1952 ext/tarkin/Makefile
1953 ext/theora/Makefile
1954 ext/vorbis/Makefile
1955 ext/xine/Makefile
1956 ext/xvid/Makefile
1957 gst-libs/Makefile
1958 gst-libs/gst/Makefile
1959 gst-libs/gst/audio/Makefile
1960 gst-libs/gst/colorbalance/Makefile
1961 gst-libs/gst/floatcast/Makefile
1962 gst-libs/gst/gconf/Makefile
1963 gst-libs/gst/idct/Makefile
1964 gst-libs/gst/media-info/Makefile
1965 gst-libs/gst/mixer/Makefile
1966 gst-libs/gst/navigation/Makefile
1967 gst-libs/gst/play/Makefile
1968 gst-libs/gst/propertyprobe/Makefile
1969 gst-libs/gst/resample/Makefile
1970 gst-libs/gst/riff/Makefile
1971 gst-libs/gst/tag/Makefile
1972 gst-libs/gst/tuner/Makefile
1973 gst-libs/gst/video/Makefile
1974 gst-libs/gst/xoverlay/Makefile
1975 gst-libs/gst/xwindowlistener/Makefile
1976 gst-libs/ext/Makefile
1977 examples/dynparams/Makefile
1978 examples/capsfilter/Makefile
1979 examples/seeking/Makefile
1980 examples/indexing/Makefile
1981 examples/gstplay/Makefile
1982 examples/switch/Makefile
1983 examples/Makefile
1984 testsuite/spider/Makefile
1985 testsuite/alsa/Makefile
1986 testsuite/multifilesink/Makefile
1987 testsuite/Makefile
1988 tools/Makefile
1989 gconf/Makefile
1990 gconf/gstreamer.schemas
1991 pkgconfig/Makefile
1992 pkgconfig/gstreamer-gconf.pc
1993 pkgconfig/gstreamer-gconf-uninstalled.pc
1994 pkgconfig/gstreamer-interfaces.pc
1995 pkgconfig/gstreamer-interfaces-uninstalled.pc
1996 pkgconfig/gstreamer-libs.pc
1997 pkgconfig/gstreamer-libs-uninstalled.pc
1998 pkgconfig/gstreamer-media-info.pc
1999 pkgconfig/gstreamer-media-info-uninstalled.pc
2000 pkgconfig/gstreamer-play.pc
2001 pkgconfig/gstreamer-play-uninstalled.pc
2002 pkgconfig/gstreamer-plugins.pc
2003 pkgconfig/gstreamer-plugins-uninstalled.pc
2004 po/Makefile.in
2005 common/Makefile
2006 common/m4/Makefile
2007 m4/Makefile
2008 )
2009 AC_OUTPUT
2010
2011 echo -n "configure: *** Plug-ins that will be built :"
2012 echo -e "$GST_PLUGINS_YES" | sort
2013 echo
2014 echo -n "configure: *** Plug-ins that will not be built :"
2015 echo -e "$GST_PLUGINS_NO" | sort
2016 echo
2017 if test "x$BUILD_EXTERNAL" = "xno"; then
2018   echo "configure: *** No external plug-ins will be built"
2019 fi