configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.3,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 28, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.3
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AC_HELP_STRING([--with-install-plugins-helper],
  99     [specify path of helper script to call to install plugins]),
 100   [
 101     case "${withval}" in
 102       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 104       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 105     esac
 106   ],
 107   [
 108     dnl Default value
 109     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 110   ]
 111 )
 112 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 113 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 114     [plugin install helper script])
 115 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 116
 117 AG_GST_ARG_WITH_PLUGINS
 118
 119 AG_GST_ARG_ENABLE_EXTERNAL
 120
 121 AG_GST_ARG_ENABLE_EXPERIMENTAL
 122
 123 dnl *** checks for platform ***
 124 AG_GST_PLATFORM
 125
 126 dnl * hardware/architecture *
 127
 128 dnl common/m4/gst-arch.m4
 129 dnl check CPU type
 130 AG_GST_ARCH
 131
 132 dnl check for large file support
 133 dnl affected plugins must include config.h
 134 AC_SYS_LARGEFILE
 135
 136 dnl *** checks for programs ***
 137
 138 dnl find a compiler
 139 AC_PROG_CC
 140 AC_PROG_CC_STDC
 141
 142 dnl check if the compiler supports '-c' and '-o' options
 143 AM_PROG_CC_C_O
 144
 145 dnl determine if c++ is available on this system
 146 AC_PROG_CXX
 147 dnl CXX may be set to some default even if no c++ compiler is available
 148 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 149 AC_LANG_PUSH([C++])
 150 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 151 AC_LANG_POP([C++])
 152 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 153 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 154
 155 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 156 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 157
 158 dnl check for gobject-introspection
 159 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 160
 161 dnl check for documentation tools
 162 GTK_DOC_CHECK([1.3])
 163 AS_PATH_PYTHON([2.1])
 164 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 165
 166 dnl *** checks for libraries ***
 167
 168 dnl libm, for sin() etc.
 169 AC_CHECK_LIBM
 170 AC_SUBST(LIBM)
 171
 172 dnl *** checks for header files ***
 173
 174 dnl check if we have ANSI C header files
 175 AC_HEADER_STDC
 176
 177 ac_cppflags_save="$CPPFLAGS"
 178 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 179 AC_COMPILE_IFELSE([
 180   AC_LANG_PROGRAM([[
 181 #include <libxml/HTMLparser.h>
 182 ]],[[
 183 #ifndef LIBXML_HTML_ENABLED
 184 #error libxml2 has no HTML support
 185 #endif /* LIBXML_HTML_ENABLED */
 186 ]])], [
 187   HAVE_LIBXML_HTML="yes"
 188 ], [
 189   HAVE_LIBXML_HTML="no"
 190 ])
 191 CPPFLAGS="$ac_cppflags_save"
 192 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 193
 194 dnl used in gst/tcp
 195 AC_CHECK_HEADERS([sys/socket.h],
 196   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 197 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 198
 199 dnl used in gst-libs/gst/pbutils and associated unit test
 200 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 201
 202 dnl also, Windows does not have long long
 203 AX_CREATE_STDINT_H
 204
 205 dnl *** checks for functions ***
 206 AC_CHECK_FUNCS([localtime_r gmtime_r])
 207
 208 dnl *** checks for math functions ***
 209 LIBS_SAVE=$LIBS
 210 LIBS="$LIBS $LIBM"
 211 AC_CHECK_FUNCS(log2)
 212 LIBS=$LIBS_SAVE
 213
 214 dnl *** checks for types/defines ***
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl *** checks for library functions ***
 221
 222 dnl check for fseeko()
 223 AC_FUNC_FSEEKO
 224
 225 dnl Check for fast float to int casting as defined in C99
 226 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 227 save_libs=$LIBS
 228 LIBS="$LIBS $LIBM"
 229 AC_C99_FUNC_LRINT
 230 AC_C99_FUNC_LRINTF
 231 LIBS=$save_libs
 232
 233 dnl Check for a way to display the function name in debug output
 234 AG_GST_CHECK_FUNCTION
 235
 236 dnl *** checks for dependency libraries ***
 237
 238 dnl GLib
 239 GLIB_REQ=2.31.14
 240 AG_GST_GLIB_CHECK([$GLIB_REQ])
 241
 242 ORC_CHECK([0.4.11])
 243
 244 dnl checks for gstreamer
 245 dnl uninstalled is selected preferentially -- see pkg-config(1)
 246 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 247 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 248 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 249 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 250 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 251
 252 dnl Check for documentation xrefs
 253 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 254 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 255 AC_SUBST(GLIB_PREFIX)
 256 AC_SUBST(GST_PREFIX)
 257
 258 dnl GTK is optional and only used in examples
 259 HAVE_GTK=no
 260 HAVE_GTK_X11=no
 261 GTK_REQ=3.0.0
 262 if test "x$BUILD_EXAMPLES" = "xyes"; then
 263   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 264   dnl some examples need gtk+-x11
 265   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 266   AC_SUBST(GTK_LIBS)
 267   AC_SUBST(GTK_CFLAGS)
 268 fi
 269 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 270 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 271
 272 dnl QT is optional and only used in examples
 273 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 274   HAVE_QT_GV=yes
 275   HAVE_QT=yes
 276 ], [
 277   HAVE_QT_GV=no
 278   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 279 ])
 280 if test "x$HAVE_QT" = "xyes"; then
 281   AC_MSG_CHECKING([Qt moc])
 282   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 283   AC_MSG_RESULT($QT4_MOC)
 284   AC_SUBST(QT4_MOC)
 285 fi
 286 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 287 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 288
 289 dnl chck for linux headers needed by the joystick seek example
 290 AC_COMPILE_IFELSE(
 291 [
 292   AC_LANG_PROGRAM([
 293     #include <linux/input.h>
 294     #include <linux/joystick.h>
 295   ],[
 296     struct js_event js;
 297     js.type = JS_EVENT_AXIS;
 298   ])
 299 ], [
 300   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 301 ], [
 302   HAVE_LINUX_JOYSTICK_HEADERS="no"
 303 ])
 304 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 305
 306 dnl Check for -Bsymbolic-functions linker flag used to avoid
 307 dnl intra-library PLT jumps, if available.
 308 AC_ARG_ENABLE(Bsymbolic,
 309               [AC_HELP_STRING([--disable-Bsymbolic],
 310                               [avoid linking with -Bsymbolic])],,
 311               [SAVED_LDFLAGS="${LDFLAGS}"
 312                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 313                LDFLAGS=-Wl,-Bsymbolic-functions
 314                AC_TRY_LINK([], [int main (void) { return 0; }],
 315                            AC_MSG_RESULT(yes)
 316                            enable_Bsymbolic=yes,
 317                            AC_MSG_RESULT(no)
 318                            enable_Bsymbolic=no)
 319                LDFLAGS="${SAVED_LDFLAGS}"])
 320
 321
 322 dnl *** set variables based on configure arguments ***
 323
 324 dnl set license and copyright notice
 325 GST_LICENSE="LGPL"
 326 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 327 AC_SUBST(GST_LICENSE)
 328
 329 dnl set location of plugin directory
 330 AG_GST_SET_PLUGINDIR
 331
 332 dnl set release date/time
 333 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 334   ["${srcdir}/gst-plugins-base.doap"],
 335   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 336
 337 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 338 dnl make sure it doesn't complain about unused variables if debugging is disabled
 339 NO_WARNINGS=""
 340 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 341
 342 dnl define an ERROR_CFLAGS Makefile variable
 343 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 344 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 345     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 346     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 347     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 348     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 349
 350 dnl define an ERROR_CXXFLAGS Makefile variable
 351 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 352     -Wmissing-declarations -Wredundant-decls -Wundef
 353     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 354     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 355     -Wno-multichar $NO_WARNINGS])
 356
 357 dnl define correct level for debugging messages
 358 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 359
 360 dnl used in examples
 361 AG_GST_DEFAULT_ELEMENTS
 362
 363 dnl needed for encoding-target
 364 GST_DATADIR="$GST_PREFIX/share"
 365 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 366 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 367
 368 dnl behaviour of speex based audio resampler
 369 AC_MSG_CHECKING(which audio resample format to use for integer)
 370 AC_ARG_WITH([audioresample_format],
 371         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 372         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 373 AC_MSG_RESULT($ac_cv_audioresample_format)
 374 case $ac_cv_audioresample_format in
 375   int)
 376     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 377     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 378   ;;
 379   float)
 380     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 381     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 382   ;;
 383   auto)
 384     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 385     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 386 esac
 387
 388 dnl *** plug-ins to include ***
 389
 390 dnl these are all the gst plug-ins, compilable without additional libs
 391 AG_GST_CHECK_PLUGIN(adder)
 392 AG_GST_CHECK_PLUGIN(app)
 393 AG_GST_CHECK_PLUGIN(audioconvert)
 394 AG_GST_CHECK_PLUGIN(audiorate)
 395 AG_GST_CHECK_PLUGIN(audiotestsrc)
 396 AG_GST_CHECK_PLUGIN(encoding)
 397 AG_GST_CHECK_PLUGIN(videoconvert)
 398 AG_GST_CHECK_PLUGIN(gdp)
 399 AG_GST_CHECK_PLUGIN(gio)
 400 AG_GST_CHECK_PLUGIN(playback)
 401 AG_GST_CHECK_PLUGIN(audioresample)
 402 AG_GST_CHECK_PLUGIN(subparse)
 403 AG_GST_CHECK_PLUGIN(tcp)
 404 AG_GST_CHECK_PLUGIN(typefind)
 405 AG_GST_CHECK_PLUGIN(videotestsrc)
 406 AG_GST_CHECK_PLUGIN(videorate)
 407 AG_GST_CHECK_PLUGIN(videoscale)
 408 AG_GST_CHECK_PLUGIN(volume)
 409
 410 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 411 AM_CONDITIONAL(USE_XML, false)
 412 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 413
 414 dnl disable plug-ins that require libxml2's HTML support if it is not available
 415 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 416   AG_GST_DISABLE_PLUGIN(subparse)
 417 fi
 418
 419 dnl iso-codes is optional, used by libgsttag
 420 AC_ARG_ENABLE(iso-codes,
 421 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 422 [case "${enableval}" in
 423   yes) enable_iso_codes=yes ;;
 424   no)  enable_iso_codes=no ;;
 425   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 426 esac
 427 ],
 428 [enable_iso_codes=yes]) dnl Default value
 429
 430 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 431 if test "x$enable_iso_codes" = "xyes"; then
 432   AC_MSG_RESULT([yes])
 433   have_iso_codes=no
 434   AC_MSG_CHECKING([whether iso-codes are available on this system])
 435   if $PKG_CONFIG iso-codes; then
 436     AC_MSG_RESULT([yes])
 437     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 438     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 439       AC_MSG_RESULT([yes])
 440       AC_MSG_CHECKING([for iso-codes prefix])
 441       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 442       if test -d "$ISO_CODES_PREFIX"; then
 443         AC_MSG_RESULT([yes])
 444         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 445         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 446         ISO_639_DOMAIN="iso_639"
 447         AC_MSG_CHECKING([ISO_639_DOMAIN])
 448         AC_MSG_RESULT([$ISO_639_DOMAIN])
 449         have_iso_codes=yes
 450         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 451         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 452         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 453         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 454       else
 455         AC_MSG_RESULT([no])
 456       fi
 457     else
 458       AC_MSG_RESULT([no])
 459     fi
 460   else
 461     AC_MSG_RESULT([no])
 462   fi
 463   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 464 else
 465   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 466   AM_CONDITIONAL(USE_ISO_CODES, false)
 467 fi
 468
 469 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 470 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 471 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 472   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 473       HAVE_ZLIB="yes"
 474     ], [
 475       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 476         HAVE_ZLIB="yes"
 477         ZLIB_LIBS="-lz"
 478         AC_SUBST(ZLIB_LIBS)
 479       ])
 480     ])
 481 ])
 482
 483 dnl *** sys plug-ins ***
 484
 485 echo
 486 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 487 echo
 488
 489 dnl *** X11 ***
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 491 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 492                   [ximagesink], [
 493   AC_PATH_XTRA
 494   ac_cflags_save="$CFLAGS"
 495   ac_cppflags_save="$CPPFLAGS"
 496   CFLAGS="$CFLAGS $X_CFLAGS"
 497   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 498
 499   dnl now try to find the HEADER
 500   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 501
 502   if test "x$HAVE_X" = "xno"
 503   then
 504     AC_MSG_NOTICE([cannot find X11 development files])
 505   else
 506     dnl this is much more than we want
 507     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 508     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 509     dnl it does not add the libs; therefore we add them here
 510     X_LIBS="$X_LIBS -lX11"
 511     AC_SUBST(X_CFLAGS)
 512     AC_SUBST(X_LIBS)
 513   fi
 514   AC_SUBST(HAVE_X)
 515   CFLAGS="$ac_cflags_save"
 516   CPPFLAGS="$ac_cppflags_save"
 517 ])
 518
 519 dnl Check for Xv extension
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 521 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 522                   [xvimagesink], [
 523   AG_GST_CHECK_XV
 524 ])
 525
 526 dnl check for X Shm
 527 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 528 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 529   if test x$HAVE_X = xyes; then
 530     AC_CHECK_LIB(Xext, XShmAttach,
 531                  HAVE_XSHM="yes", HAVE_XSHM="no",
 532                  $X_LIBS)
 533     if test "x$HAVE_XSHM" = "xyes"; then
 534       XSHM_LIBS="-lXext"
 535     else
 536       dnl On AIX, it is in XextSam instead, but we still need -lXext
 537       AC_CHECK_LIB(XextSam, XShmAttach,
 538                    HAVE_XSHM="yes", HAVE_XSHM="no",
 539                    $X_LIBS)
 540       if test "x$HAVE_XSHM" = "xyes"; then
 541         XSHM_LIBS="-lXext -lXextSam"
 542       fi
 543     fi
 544   fi
 545 ], , [
 546   AC_SUBST(HAVE_XSHM)
 547   AC_SUBST(XSHM_LIBS)
 548 ])
 549
 550 dnl *** ext plug-ins ***
 551 dnl keep this list sorted alphabetically !
 552
 553 if test "x$BUILD_EXTERNAL" = "xyes"; then
 554
 555 echo
 556 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 557 echo
 558
 559 dnl *** alsa ***
 560 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 561 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 562   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 563     HAVE_ALSA="yes"
 564     AC_SUBST(ALSA_CFLAGS)
 565     AC_SUBST(ALSA_LIBS)
 566   ], [
 567     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 568   ])
 569 ])
 570
 571 dnl *** CDParanoia ***
 572 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 573 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 574 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 575   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 576     HAVE_CDPARANOIA="yes"
 577   ], [
 578     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 579                         cdda_open, -lm,
 580                         cdda_interface.h,
 581                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 582                         HEADER_DIR="no"
 583                         FOUND_CDPARANOIA="yes")
 584     if test "x$FOUND_CDPARANOIA" != "xyes";
 585     then
 586       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 587                           cdda_open, -lm,
 588                           cdda/cdda_interface.h,
 589                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 590                           HEADER_DIR="yes"
 591                           FOUND_CDPARANOIA="yes")
 592     fi
 593     if test "x$HEADER_DIR" = "xyes";
 594     then
 595       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 596                          defined if cdda headers are in a cdda/ directory)
 597     fi
 598     if test "x$FOUND_CDPARANOIA" = "xyes";
 599     then
 600       AC_CHECK_LIB(cdda_paranoia,
 601                    paranoia_cachemodel_size,
 602                    : ,
 603                    HAVE_CDPARANOIA=no,
 604                  [-lcdda_interface])
 605     fi
 606
 607     AC_SUBST(CDPARANOIA_LIBS)
 608   ])
 609 ])
 610 dnl FIXME : add second check somehow if that is necessary
 611 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 612 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 613
 614 dnl *** ivorbis ***
 615 dnl AM_PATH_IVORBIS only takes two options
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 617 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 618   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 619   if test $HAVE_IVORBIS = no
 620   then
 621     IVORBIS_LIBS=
 622     IVORBIS_CFLAGS=
 623     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 624       [IVORBIS_LIBS=-lvorbisidec
 625       HAVE_IVORBIS=yes
 626       case $host in
 627       arm-*-*)
 628         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 629       esac
 630       ],
 631       HAVE_IVORBIS=no)
 632     AC_SUBST(IVORBIS_LIBS)
 633     AC_SUBST(IVORBIS_CFLAGS)
 634   else
 635     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 636       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 637       USE_TREMOLO=no)
 638   fi
 639 ])
 640
 641 dnl *** libvisual ***
 642 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 643 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 644   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 645   if test $HAVE_LIBVISUAL = no
 646   then
 647     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 648     if test x$HAVE_LIBVISUAL = xyes; then
 649       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 650     fi
 651   else
 652     if test x$HAVE_LIBVISUAL = xyes; then
 653       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 654     fi
 655   fi
 656   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 657   if test x$LIBVIS_PLUGINSDIR != x; then
 658     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 659         "$LIBVIS_PLUGINSDIR",
 660         [directory in which the detected libvisual's plugins are located])
 661   fi
 662 ])
 663
 664 dnl *** ogg ***
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 666 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 667   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 668   if test $HAVE_OGG = no
 669   then
 670     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 671     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 672   fi
 673 ])
 674
 675 dnl *** pango ***
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 677 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 678   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 679 ])
 680
 681 dnl *** theora ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 683 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 684   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 685 ])
 686
 687 dnl *** vorbis ***
 688 dnl AM_PATH_VORBIS only takes two options
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 690 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 691   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 692   if test $HAVE_VORBIS = no
 693   then
 694     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 695     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 696   fi
 697 ])
 698
 699 if test "x$HAVE_VORBIS" = "xyes"; then
 700   ac_cflags_save="$CFLAGS"
 701   AC_COMPILE_IFELSE([
 702     AC_LANG_PROGRAM([[
 703 #include <vorbis/codec.h>
 704                      ]],[[
 705 vorbis_dsp_state *v;
 706
 707 vorbis_synthesis_restart (v);
 708                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 709   if test "x$HAVE_VSR" = "xyes"; then
 710     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 711                        [defined if vorbis_synthesis_restart is present])
 712   fi
 713   CFLAGS="$ac_cflags_save"
 714 fi
 715
 716 else
 717
 718 dnl not building plugins with external dependencies,
 719 dnl but we still need to set the conditionals
 720 AM_CONDITIONAL(USE_ALSA, false)
 721 AM_CONDITIONAL(USE_CDPARANOIA, false)
 722 AM_CONDITIONAL(USE_IVORBIS, false)
 723 AM_CONDITIONAL(USE_LIBVISUAL, false)
 724 AM_CONDITIONAL(USE_OGG, false)
 725 AM_CONDITIONAL(USE_PANGO, false)
 726 AM_CONDITIONAL(USE_THEORA, false)
 727 AM_CONDITIONAL(USE_VORBIS, false)
 728
 729 fi dnl of EXT plugins
 730
 731 dnl seeking needs freetype, so check for it here
 732 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 733   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 734 ])
 735 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 736 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 737 AC_SUBST(FT2_CFLAGS)
 738 AC_SUBST(FT2_LIBS)
 739
 740 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 741
 742 dnl Overview:
 743 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 744 dnl GST_*:              flags shared by built objects to link against GStreamer
 745 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 746 dnl                          (compare to other modules) or for i18n
 747 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 748 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 749 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 750 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 751
 752 dnl GST_OPTION_CFLAGS
 753 if test "x$USE_DEBUG" = xyes; then
 754    PROFILE_CFLAGS="-g"
 755 fi
 756 AC_SUBST(PROFILE_CFLAGS)
 757
 758 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 759   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 760   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 761 else
 762   DEPRECATED_CFLAGS=""
 763 fi
 764 AC_SUBST(DEPRECATED_CFLAGS)
 765
 766 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 767 dnl at make time with e.g. make ERROR_CFLAGS=""
 768 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 769 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 770 AC_SUBST(GST_OPTION_CFLAGS)
 771 AC_SUBST(GST_OPTION_CXXFLAGS)
 772
 773 dnl our libraries need to be versioned correctly
 774 AC_SUBST(GST_LT_LDFLAGS)
 775
 776 dnl GST_PLUGINS_BASE_CFLAGS
 777 dnl prefer internal headers to already installed ones
 778 dnl also add builddir include for enumtypes and marshal
 779 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 780 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 781
 782 dnl FIXME: do we want to rename to GST_ALL_* ?
 783 dnl add GST_OPTION_CFLAGS, but overridable
 784 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 785 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 786 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 787 AC_SUBST(GST_CFLAGS)
 788 AC_SUBST(GST_CXXFLAGS)
 789 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 790 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 791 AC_SUBST(GST_LIBS)
 792
 793 dnl LDFLAGS really should only contain flags, not libs - they get added before
 794 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 795 GST_ALL_LDFLAGS="-no-undefined"
 796 if test "x${enable_Bsymbolic}" = "xyes"; then
 797   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 798 fi
 799 AC_SUBST(GST_ALL_LDFLAGS)
 800
 801 dnl GST_LIB_LDFLAGS
 802 dnl linker flags shared by all libraries
 803 dnl LDFLAGS modifier defining exported symbols from built libraries
 804 dnl (export _gst_foo but not __gst_foo)
 805 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 806 AC_SUBST(GST_LIB_LDFLAGS)
 807
 808 dnl this really should only contain flags, not libs - they get added before
 809 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 810 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 811 AC_SUBST(GST_PLUGIN_LDFLAGS)
 812
 813 dnl *** output files ***
 814
 815 AC_CONFIG_FILES(
 816 Makefile
 817 gst-plugins-base.spec
 818 gst/Makefile
 819 gst/adder/Makefile
 820 gst/app/Makefile
 821 gst/audioconvert/Makefile
 822 gst/audiorate/Makefile
 823 gst/audiotestsrc/Makefile
 824 gst/encoding/Makefile
 825 gst/videoconvert/Makefile
 826 gst/gdp/Makefile
 827 gst/gio/Makefile
 828 gst/playback/Makefile
 829 gst/audioresample/Makefile
 830 gst/subparse/Makefile
 831 gst/tcp/Makefile
 832 gst/typefind/Makefile
 833 gst/videotestsrc/Makefile
 834 gst/videorate/Makefile
 835 gst/videoscale/Makefile
 836 gst/volume/Makefile
 837 sys/Makefile
 838 sys/ximage/Makefile
 839 sys/xvimage/Makefile
 840 ext/Makefile
 841 ext/alsa/Makefile
 842 ext/cdparanoia/Makefile
 843 ext/libvisual/Makefile
 844 ext/ogg/Makefile
 845 ext/pango/Makefile
 846 ext/theora/Makefile
 847 ext/vorbis/Makefile
 848 gst-libs/Makefile
 849 gst-libs/gst/Makefile
 850 gst-libs/gst/audio/Makefile
 851 gst-libs/gst/app/Makefile
 852 gst-libs/gst/fft/Makefile
 853 gst-libs/gst/interfaces/Makefile
 854 gst-libs/gst/riff/Makefile
 855 gst-libs/gst/rtp/Makefile
 856 gst-libs/gst/rtsp/Makefile
 857 gst-libs/gst/sdp/Makefile
 858 gst-libs/gst/tag/Makefile
 859 gst-libs/gst/pbutils/Makefile
 860 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 861 gst-libs/gst/video/Makefile
 862 tools/Makefile
 863 pkgconfig/Makefile
 864 pkgconfig/gstreamer-audio.pc
 865 pkgconfig/gstreamer-audio-uninstalled.pc
 866 pkgconfig/gstreamer-app.pc
 867 pkgconfig/gstreamer-app-uninstalled.pc
 868 pkgconfig/gstreamer-fft.pc
 869 pkgconfig/gstreamer-fft-uninstalled.pc
 870 pkgconfig/gstreamer-interfaces.pc
 871 pkgconfig/gstreamer-interfaces-uninstalled.pc
 872 pkgconfig/gstreamer-pbutils.pc
 873 pkgconfig/gstreamer-pbutils-uninstalled.pc
 874 pkgconfig/gstreamer-riff.pc
 875 pkgconfig/gstreamer-riff-uninstalled.pc
 876 pkgconfig/gstreamer-rtp.pc
 877 pkgconfig/gstreamer-rtp-uninstalled.pc
 878 pkgconfig/gstreamer-rtsp.pc
 879 pkgconfig/gstreamer-rtsp-uninstalled.pc
 880 pkgconfig/gstreamer-sdp.pc
 881 pkgconfig/gstreamer-sdp-uninstalled.pc
 882 pkgconfig/gstreamer-tag.pc
 883 pkgconfig/gstreamer-tag-uninstalled.pc
 884 pkgconfig/gstreamer-video.pc
 885 pkgconfig/gstreamer-video-uninstalled.pc
 886 pkgconfig/gstreamer-plugins-base.pc
 887 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 888 tests/Makefile
 889 tests/check/Makefile
 890 tests/examples/Makefile
 891 tests/examples/app/Makefile
 892 tests/examples/audio/Makefile
 893 tests/examples/dynamic/Makefile
 894 tests/examples/encoding/Makefile
 895 tests/examples/fft/Makefile
 896 tests/examples/gio/Makefile
 897 tests/examples/overlay/Makefile
 898 tests/examples/seek/Makefile
 899 tests/examples/snapshot/Makefile
 900 tests/examples/playback/Makefile
 901 tests/examples/playrec/Makefile
 902 tests/files/Makefile
 903 tests/icles/Makefile
 904 tests/icles/playback/Makefile
 905 docs/Makefile
 906 docs/design/Makefile
 907 docs/libs/Makefile
 908 docs/plugins/Makefile
 909 docs/version.entities
 910 po/Makefile.in
 911 common/Makefile
 912 common/m4/Makefile
 913 m4/Makefile
 914 )
 915
 916 dnl Create the config.h file for Visual Studio builds
 917 dnl Beware of spaces and /'s in some of the shell variable contents.
 918 sed \
 919     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 920     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 921     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 922     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 923     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 924     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 925     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 926     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 927     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 928     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 929     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 930     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 931     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 932     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 933     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 934     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 935     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 936     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 937     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 938     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 939     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 940     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 941     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 942     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 943     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 944     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 945     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 946     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 947     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 948     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 949     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 950     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 951     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 952     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 953     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 954     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 955     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 956     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 957     config.h.in >win32/common/config.h-new
 958
 959
 960
 961 AC_OUTPUT
 962
 963 AG_GST_OUTPUT_PLUGINS
 964 ORC_OUTPUT
 965