configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.1.4,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use major.minor as a version
  39 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  40 dnl we override it here if we need to for the release candidate of new series
  41 GST_API_VERSION=1.0
  42 AC_SUBST(GST_API_VERSION)
  43
  44 AG_GST_LIBTOOL_PREPARE
  45 AS_LIBTOOL(GST, 104, 0, 104)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.1.4
  49 GST_PBREQ=1.1.4
  50
  51 ORC_REQ=0.4.16
  52 ORC_CHECK([$ORC_REQ])
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl *** check for arguments to configure ***
  63
  64 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  65
  66 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  67 AG_GST_ARG_WITH_PACKAGE_NAME
  68 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 dnl *** checks for platform ***
  73
  74 dnl * hardware/architecture *
  75
  76 dnl common/m4/gst-arch.m4
  77 dnl check CPU type
  78 AG_GST_ARCH
  79
  80 dnl *** checks for programs ***
  81
  82 dnl find a compiler
  83 AC_PROG_CC
  84 AC_PROG_CC_STDC
  85
  86 dnl check if the compiler supports '-c' and '-o' options
  87 AM_PROG_CC_C_O
  88
  89 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  90 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  91
  92 dnl check for documentation tools
  93 AG_GST_DOCBOOK_CHECK
  94 GTK_DOC_CHECK([1.12])
  95 AS_PATH_PYTHON([2.1])
  96 AG_GST_PLUGIN_DOCS([1.3],[2.1])
  97
  98 dnl *** checks for libraries ***
  99
 100 dnl check for libm, for sin()
 101 LT_LIB_M
 102 AC_SUBST(LIBM)
 103
 104 dnl *** checks for header files ***
 105
 106 dnl check if we have ANSI C header files
 107 AC_HEADER_STDC
 108
 109 dnl *** checks for types/defines ***
 110
 111 dnl *** checks for structures ***
 112
 113 dnl *** checks for compiler characteristics ***
 114
 115 dnl *** checks for library functions ***
 116
 117 dnl *** checks for dependancy libraries ***
 118
 119 dnl checks for gstreamer
 120 dnl uninstalled is selected preferentially -- see pkg-config(1)
 121 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 122 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 123 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 124 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 125 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 126
 127 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 128 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 129
 130 dnl *** set variables based on configure arguments ***
 131
 132 dnl set location of plugin directory
 133 AG_GST_SET_PLUGINDIR
 134
 135 dnl build static plugins or not
 136 AC_MSG_CHECKING([whether to build static plugins or not])
 137 AC_ARG_ENABLE(
 138   static-plugins,
 139   AC_HELP_STRING(
 140     [--enable-static-plugins],
 141     [build static plugins @<:@default=no@:>@]),
 142   [AS_CASE(
 143     [$enableval], [no], [], [yes], [],
 144     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 145   [enable_static_plugins=no])
 146 AC_MSG_RESULT([$enable_static_plugins])
 147 if test "x$enable_static_plugins" = xyes; then
 148   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 149     [Define if static plugins should be built])
 150   GST_PLUGIN_LIBTOOLFLAGS=""
 151 else
 152   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 153 fi
 154 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 155 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 156
 157 dnl define an ERROR_CFLAGS Makefile variable
 158 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 159     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 160     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 161     -Winit-self -Wmissing-include-dirs -Waddress
 162     -Waggregate-return -Wno-multichar -Wnested-externs ])
 163
 164 dnl define correct level for debugging messages
 165 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 166
 167 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 168
 169 dnl Overview:
 170 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 171 dnl GST_*:              flags shared by built objects to link against GStreamer
 172 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 173 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 174 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 175 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 176
 177 dnl GST_OPTION_CFLAGS
 178 if test "x$USE_DEBUG" = xyes; then
 179    PROFILE_CFLAGS="-g"
 180 fi
 181 AC_SUBST(PROFILE_CFLAGS)
 182
 183 if test "x$GST_GIT" = "xyes"; then
 184   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 185 else
 186   DEPRECATED_CFLAGS=""
 187 fi
 188 AC_SUBST(DEPRECATED_CFLAGS)
 189
 190 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 191 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 192
 193 AC_SUBST(GST_OPTION_CFLAGS)
 194
 195 dnl FIXME: do we want to rename to GST_ALL_* ?
 196 dnl prefer internal headers to already installed ones
 197 dnl also add builddir include for enumtypes and marshal
 198 dnl add GST_OPTION_CFLAGS, but overridable
 199 GST_CFLAGS="$GST_CFLAGS"
 200 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 201 AC_SUBST(GST_CFLAGS)
 202 AC_SUBST(GST_LIBS)
 203
 204 GST_ALL_LDFLAGS="-no-undefined"
 205 AC_SUBST(GST_ALL_LDFLAGS)
 206
 207 dnl this really should only contain flags, not libs - they get added before
 208 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 209 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 210 AC_SUBST(GST_PLUGIN_LDFLAGS)
 211
 212 dnl Add MacOSX specific flags
 213 AC_CANONICAL_HOST
 214 case $host_os in
 215      darwin*)
 216         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 217         ;;
 218      *)
 219         DARWIN_LDFLAGS=""
 220         ;;
 221 esac
 222 AC_SUBST(DARWIN_LDFLAGS)
 223
 224 dnl *** Check for bz2
 225 save_LIBS=$LIBS
 226 LIBS="$LIBS -lbz2"
 227 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 228 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 229 AC_MSG_RESULT($HAVE_BZ2)
 230 LIBS=$save_LIBS
 231 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 232 if test "x$HAVE_BZ2" = "xno"; then
 233   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 234 fi
 235
 236 AC_ARG_ENABLE(lgpl,
 237               [AC_HELP_STRING([--enable-lgpl], [build a LGPL licensed gst-libav])])
 238 AM_CONDITIONAL(GST_LIBAV_ENABLE_LGPL, test "x$enable_lgpl" = "xyes")
 239 if test "x$enable_lgpl" = "xyes"; then
 240   AC_DEFINE([GST_LIBAV_ENABLE_LGPL], [], [Defined if building a LGPL-only version of gst-libav])
 241 fi
 242
 243 dnl *** configure external libs ***
 244
 245 HAVE_LIBAV_UNINSTALLED=1
 246
 247 AC_ARG_WITH(system-libav,
 248             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 249
 250 if test "x$with_system_libav" = "xyes"; then
 251   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavutil)
 252   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 253   saved_CPPFLAGS="$CPPFLAGS"
 254   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 255   AC_CHECK_HEADERS([avi.h])
 256   CPPFLAGS="$saved_CPPFLAGS"
 257   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 258   HAVE_LIBAV_UNINSTALLED=0
 259   AC_MSG_NOTICE([Using system-installed libav code])
 260   AC_MSG_WARN([
 261   ======================================================================
 262    WARNING: you have chosen to build gst-libav against a random
 263    external version of Libav instead of building it against the tested
 264    internal Libav snapshot that is included with gst-libav.
 265
 266    This is a very bad idea.  So bad in fact that words cannot express
 267    just how bad it is.  Suffice to say that it is BAD.
 268
 269    The GStreamer developers cannot and will not support a gst-libav
 270    built this way.  Any bug reports that indicate there is an external
 271    version of Libav involved will be closed immediately without further
 272    investigation.
 273
 274    The reason such a setup can't be supported is that the Libav API
 275    and ABI is in constant flux, yet there aren't any official releases
 276    of the Libav library to develop against.  This makes it impossible
 277    to guarantee that gst-libav will work reliably, or even compile,
 278    with a randomly picked version Libav.  Even if gst-libav compiles
 279    and superficially appears to work fine against your chosen external
 280    Libav version, that might just not be the case on other systems, or
 281    even the same system at a later time, or when using decoders,
 282    encoders, demuxers or muxers that have not been tested.
 283
 284    Please do not create or distribute binary packages of gst-Libav
 285    that link against an external libav. Thank you!
 286   ======================================================================
 287   ])
 288
 289   dnl No, this is not too extreme, we want people to see and read the above
 290   sleep 15
 291 else
 292
 293   AC_MSG_NOTICE([Using local Libav snapshot])
 294
 295   dnl libgstlibav.la: include dirs
 296   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 297                 -I \$(top_builddir)/gst-libs/ext/libav \
 298                  -Wno-deprecated-declarations"
 299
 300   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 301               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 302               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 303   if test "x$enable_static_plugins" = xyes; then
 304       dnl with static linking we can't use the .a archive directly as they would
 305       dnl be included in the final libgstlibav.a as a file and won't be usable.
 306       dnl libav*.a must be copied to the final destination too
 307       LIBAV_LIBS="-lavformat -lavcodec -lavutil"
 308   else
 309       dnl libgstlibav.la: libs to statically link to
 310       LIBAV_LIBS="$LIBAV_DEPS"
 311   fi
 312
 313   dnl
 314   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 315                   -I \$(top_builddir)/gst-libs/ext/libav \
 316                   -Wno-deprecated-declarations"
 317
 318   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 319                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 320   if test "x$enable_static_plugins" = xyes; then
 321       dnl with static linking we can't use the .a archive directly as they would
 322       dnl be included in the final libgstswscale.a as a file and won't be usable.
 323       dnl libav*.a must be copied to the final destination too
 324       SWSCALE_LIBS="-lswscale -lavutil"
 325   else
 326       dnl libgstswscale.la: libs to statically link to
 327       SWSCALE_LIBS="$SWSCALE_DEPS"
 328   fi
 329
 330   LIBAV_SUBDIRS=gst-libs
 331   AC_DEFINE(HAVE_AVI_H)
 332   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 333
 334   AC_ARG_WITH(libav-extra-configure,
 335       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 336       [extra configure options for internal libav ./configure script]),,
 337       with_libav=no)
 338
 339   # basic arguments
 340   emblibav_configure_args="--prefix=$prefix"
 341
 342   # Enable pic and static so that we get .a files, but with PIC code.
 343   emblibav_configure_args="$emblibav_configure_args --disable-avserver --disable-avplay\
 344         --disable-avconv --disable-avprobe --enable-static --enable-pic \
 345         --disable-encoder=flac --disable-decoder=cavs --disable-protocols --disable-devices\
 346         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau\
 347         --disable-filters --disable-doc --enable-optimizations"
 348
 349   if test "x$enable_lgpl" != "xyes"; then
 350     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 351   fi
 352
 353   # if we are cross-compiling, tell libav so
 354   case $host in
 355       *android*)
 356         target_os=linux
 357       ;;
 358       *)
 359         target_os=`echo $host_os | sed 's/-gnu//'`
 360       ;;
 361   esac
 362
 363   if test "x$cross_compiling" = xyes; then
 364     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 365         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 366   fi
 367
 368   case $host_os in
 369     mingw32*)
 370       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 371       WIN32_LIBS="-lws2_32"
 372       ;;
 373     *)
 374       WIN32_LIBS=
 375       ;;
 376   esac
 377
 378   if test x"$AR" != x; then
 379     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 380   fi
 381
 382   if test x"$AS" != x; then
 383     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 384   fi
 385
 386   if test x"$CC" != x; then
 387     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 388   fi
 389
 390   if test x"$LD" != x; then
 391     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 392   fi
 393
 394   if test x"$NM" != x; then
 395     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 396   fi
 397
 398   dnl checks for extra enable/disable flags
 399   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 400   # Let's check if we can disable the building of the libav binary
 401   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 402   if test "$can_disable" != ""; then
 403     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 404   fi
 405   dnl check if libswscale needs enabling explicitly
 406   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 407   if test "$can_enable" != ""; then
 408     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 409   fi
 410
 411   # append extra configure options to emblibav_configure_args if needed
 412   if test "x$with_libav_extra_configure" != "xno"; then
 413     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 414   fi
 415
 416   AC_SUBST(LIBAV_CO_DIR)
 417   AC_SUBST(LIBAV_SVN)
 418   AC_SUBST(LIBAV_REVISION)
 419   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 420   AC_CONFIG_COMMANDS([configure-embedded-libav],
 421     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 422      origdir=`pwd`
 423      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 424      dnl to detect out-of-tree builds
 425      if test -z "$srcdir" -o "$srcdir" = .; then
 426        confcmd=./configure
 427      else
 428        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 429      fi
 430
 431      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 432      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 433          eval "$confcmd $emblibav_configure_args" ||
 434          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 435      cd "$origdir"
 436     ],
 437     [emblibav_configure_args="$emblibav_configure_args"])
 438   AC_MSG_NOTICE([Using included Libav code])
 439 fi
 440
 441 AC_SUBST(LIBAV_CFLAGS)
 442 AC_SUBST(LIBAV_DEPS)
 443 AC_SUBST(LIBAV_LIBS)
 444 AC_SUBST(LIBAV_SUBDIRS)
 445 AC_SUBST(SWSCALE_CFLAGS)
 446 AC_SUBST(SWSCALE_DEPS)
 447 AC_SUBST(SWSCALE_LIBS)
 448 AC_SUBST(WIN32_LIBS)
 449
 450 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 451   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 452 fi
 453 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 454
 455 AC_CONFIG_FILES(
 456 Makefile
 457 common/Makefile
 458 common/m4/Makefile
 459 gst-libav.spec
 460 ext/Makefile
 461 ext/libav/Makefile
 462 ext/libswscale/Makefile
 463 gst-libs/Makefile
 464 gst-libs/ext/Makefile
 465 docs/Makefile
 466 docs/version.entities
 467 tests/Makefile
 468 tests/check/Makefile
 469 tests/files/Makefile
 470 pkgconfig/Makefile
 471 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 472 )
 473 AC_OUTPUT
 474
 475 ORC_OUTPUT