configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.15.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 14, 0, 14)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AM_PROG_LIBTOOL
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.11.5])
  66 AM_GNU_GETTEXT([external])
  67 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 dnl subsystems - can influence other decisions so needs to be high up
  72 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  73 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  74 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  75 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  76 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  77 dnl define a substitution to use in docs/gst/gstreamer.types
  78 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  79 then
  80   GST_LOADSAVE_DOC_TYPES="%"
  81 else
  82   GST_LOADSAVE_DOC_TYPES=
  83 fi
  84 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  85 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  86 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  87 if test "x$GST_DISABLE_PARSE" = xyes; then
  88   AC_DEFINE(GST_DISABLE_PARSE, 1,
  89     [Define if pipeline parsing code is disabled])
  90 fi
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  92 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  94 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  96 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  97 dnl define a substitution to use in docs/gst/gstreamer.types
  98 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  99 then
 100   GST_REGISTRY_DOC_TYPES="%"
 101 else
 102   GST_REGISTRY_DOC_TYPES=
 103 fi
 104 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 106 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 108 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_INDEX" = "xyes"
 111 then
 112   GST_INDEX_DOC_TYPES="%"
 113 else
 114   GST_INDEX_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_INDEX_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 122 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 123
 124 AG_GST_ARG_DEBUG
 125 AG_GST_ARG_PROFILING
 126 AG_GST_ARG_VALGRIND
 127 AG_GST_ARG_GCOV
 128
 129 AG_GST_ARG_EXAMPLES
 130
 131 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 132 AG_GST_ARG_WITH_PACKAGE_NAME
 133 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 134
 135 dnl use a cache dir for storing element registry info.
 136 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 137
 138 AC_ARG_WITH(cachedir,
 139   AC_HELP_STRING([--with-cachedir],
 140     [specify path to use for plugin and command completion registries]),
 141   [
 142     case "${withval}" in
 143       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 144       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 145       *)   GST_CACHE_DIR="${withval}" ;;
 146     esac
 147   ],
 148   [:]) dnl Default value
 149
 150 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 151 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 152 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 153
 154 dnl building of tests
 155 AC_ARG_ENABLE(tests,
 156   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 157   [
 158     case "${enableval}" in
 159       yes) BUILD_TESTS=yes ;;
 160       no)  BUILD_TESTS=no ;;
 161       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 162     esac
 163   ],
 164 [BUILD_TESTS=yes]) dnl Default value
 165 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 166
 167 dnl tests known to fail
 168 AC_ARG_ENABLE(failing-tests,
 169   AC_HELP_STRING([--disable-failing-tests],
 170     [disable building tests known to fail]),
 171   [
 172     case "${enableval}" in
 173       yes) BUILD_FAILING_TESTS=yes ;;
 174       no)  BUILD_FAILING_TESTS=no ;;
 175       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 176     esac
 177   ],
 178   [BUILD_FAILING_TESTS=no]) dnl Default value
 179 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 180 if test x$BUILD_FAILING_TESTS = xyes; then
 181   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 182 else
 183   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 184 fi
 185
 186 dnl poison destroyed objects
 187 AC_ARG_ENABLE(poisoning,
 188   AC_HELP_STRING([--enable-poisoning],
 189     [enable poisoning of deallocated objects]),
 190   [
 191     case "${enableval}" in
 192       yes) USE_POISONING=yes ;;
 193       no)  USE_POISONING=no ;;
 194       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 195     esac
 196   ],
 197   [USE_POISONING=no]) dnl Default value
 198 if test "x$USE_POISONING" = xyes; then
 199   AC_DEFINE(USE_POISONING, 1,
 200     [Define if we should poison deallocated memory])
 201 fi
 202
 203 dnl Use binary registry
 204 AC_ARG_ENABLE(binary-registry,
 205   AC_HELP_STRING([--enable-binary-registry],
 206     [enable experimental binary registry]),
 207   [
 208     case "${enableval}" in
 209       yes) USE_BINARY_REGISTRY=yes ;;
 210       no)  USE_BINARY_REGISTRY=no ;;
 211       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 212     esac
 213   ],
 214   [USE_BINARY_REGISTRY=no]) dnl Default value
 215 if test "x$USE_BINARY_REGISTRY" = xyes; then
 216   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 217     [Define if we should use binary registry instead xml registry])
 218 fi
 219 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 220
 221 dnl *** checks for platform ***
 222
 223 dnl * hardware/architecture *
 224
 225 dnl common/m4/gst-arch.m4
 226 dnl check CPU type
 227 AG_GST_ARCH
 228 dnl substitution for win32/common/config.h
 229 HOST_CPU=$host_cpu
 230 AC_SUBST(HOST_CPU)
 231
 232 dnl common/m4/gst-arch.m4
 233 dnl check for unaligned access
 234 AG_GST_UNALIGNED_ACCESS
 235 dnl create a configure variable for gst/gstconfig.h
 236 if test x${as_cv_unaligned_access} = xyes ; then
 237   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 238 else
 239   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 240 fi
 241 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 242
 243 dnl * software *
 244
 245 dnl check for large file support
 246 dnl affected plugins must include config.h
 247 AC_SYS_LARGEFILE
 248
 249 dnl HAVE_WIN32 currently means "disable POSIXisms".
 250 case "$host" in
 251   *-*-mingw*)
 252     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 253     ;;
 254   *)
 255     ;;
 256 esac
 257
 258 dnl *** checks for programs ***
 259
 260 dnl find a compiler
 261 AC_PROG_CC
 262
 263 dnl check if the compiler supports '-c' and '-o' options
 264 AM_PROG_CC_C_O
 265
 266 dnl find an assembler
 267 AM_PROG_AS
 268
 269 dnl Perl is used in building documentation and in the version checks
 270 AC_PATH_PROG(PERL_PATH, perl, no)
 271 if test x$PERL_PATH = xno; then
 272   AC_MSG_ERROR(Could not find perl)
 273 fi
 274
 275 dnl we require flex and bison for building the parser
 276 AG_GST_BISON_CHECK
 277 AG_GST_FLEX_CHECK
 278
 279 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 280 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 281
 282 dnl check for documentation tools
 283 AG_GST_DOCBOOK_CHECK
 284 GTK_DOC_CHECK([1.3])
 285 AS_PATH_PYTHON([2.1])
 286 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 287
 288 dnl *** checks for libraries ***
 289
 290 dnl For interactive UNIX (a Sun thing)
 291 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 292 AC_ISC_POSIX
 293
 294 dnl check for libm, for sin()
 295 AC_CHECK_LIBM
 296 AC_SUBST(LIBM)
 297
 298 dnl *** checks for header files ***
 299
 300 dnl check if we have ANSI C header files
 301 AC_HEADER_STDC
 302
 303 dnl Check for ucontext.h
 304 AC_CHECK_HEADERS([ucontext.h])
 305
 306 dnl Check for sys/socket.h
 307 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 308 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 309
 310 dnl check for sys/times.h for tests/examples/adapter/
 311 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 312 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 313 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 314
 315 dnl Check for process.h for getpid() on win32
 316 AC_CHECK_HEADERS([process.h])
 317
 318 dnl Check for sys/utsname.h for uname
 319 AC_CHECK_HEADERS([sys/utsname.h])
 320
 321 dnl Check for stdio_ext.f for __fbufsize
 322 AC_CHECK_HEADERS([stdio_ext.h])
 323
 324 dnl *** checks for types/defines ***
 325
 326 dnl *** checks for structures ***
 327
 328 dnl *** checks for compiler characteristics ***
 329
 330 dnl make sure we can use "inline" from C code
 331 AC_C_INLINE
 332
 333 OPT_CFLAGS=
 334 dnl Check for some compiler flags that optimize our code.
 335 if test "x$GCC" = xyes; then
 336   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 337 fi
 338
 339 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 340 dnl flag
 341 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 342 dnl symbolic register names in inline asm
 343 if test x$HAVE_CPU_PPC = xyes ; then
 344   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 345     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 346 fi
 347
 348 dnl *** checks for library functions ***
 349
 350 AC_CHECK_FUNCS([sigaction])
 351
 352 dnl we use fork in the registry code
 353 AC_CHECK_FUNCS([fork])
 354
 355 dnl check for fseeko()
 356 AC_FUNC_FSEEKO
 357 dnl check for ftello()
 358 AC_CHECK_FUNCS([ftello])
 359
 360 AC_CHECK_FUNCS([fgetpos])
 361 AC_CHECK_FUNCS([fsetpos])
 362
 363 dnl check for mmap()
 364 AC_FUNC_MMAP
 365 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 366
 367 dnl Check for POSIX timers
 368 AC_CHECK_FUNCS(clock_gettime, [], [
 369   AC_CHECK_LIB(rt, clock_gettime, [
 370     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 371     LIBS="$LIBS -lrt"
 372   ])
 373 ])
 374
 375 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,AC_TRY_RUN([
 376 #include <time.h>
 377 #ifdef HAVE_UNISTD_H
 378 #include <unistd.h>
 379 #endif
 380       int main() {
 381 #if defined(_POSIX_TIMERS) && _POSIX_TIMERS >= 0 && defined(CLOCK_REALTIME)
 382         return 0;
 383 #else
 384         return 1;
 385 #endif
 386       }],gst_cv_posix_timers=yes,gst_cv_posix_timers=no))
 387
 388 if test "$gst_cv_posix_timers" = "yes"; then
 389   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 390   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 391 else
 392   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 393 fi
 394 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 395 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 396
 397 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,AC_TRY_RUN([
 398 #include <time.h>
 399 #ifdef HAVE_UNISTD_H
 400 #include <unistd.h>
 401 #endif
 402       int main() {
 403 #if defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC)
 404         return 0;
 405 #else
 406         return 1;
 407 #endif
 408       }],gst_cv_monotonic_clock=yes,gst_cv_monotonic_clock=no))
 409
 410 if test "$gst_cv_monotonic_clock" = "yes"; then
 411   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 412   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 413 else
 414   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 415 fi
 416 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 417 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 418
 419 dnl Check for a way to display the function name in debug output
 420 AG_GST_CHECK_FUNCTION
 421
 422 dnl test for register_printf_function
 423 AC_CHECK_FUNC(register_printf_function,
 424   [
 425     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 426     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 427     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 428     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 429       [Defined if we have register_printf_function ()])
 430   ], [
 431     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 432     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 433     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 434   ]
 435 )
 436 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 437 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 438 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 439
 440 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 441 save_cflags="$CFLAGS"
 442 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 443 AC_CHECK_LIB(dl, dladdr,
 444    AC_DEFINE(HAVE_DLADDR, 1,
 445              [Defined if we have dladdr ()]))
 446 CFLAGS="$save_cflags"
 447
 448 dnl check for inet_aton()
 449 save_libs="$LIBS"
 450 AC_CHECK_FUNC(inet_aton, ,
 451    AC_CHECK_LIB(nsl, inet_aton, ,
 452       AC_CHECK_LIB(socket, inet_aton, ,
 453          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 454 INET_ATON_LIBS=$LIBS
 455 AC_SUBST(INET_ATON_LIBS)
 456 LIBS="$save_libs"
 457
 458 dnl *** checks for dependency libraries ***
 459
 460 dnl GLib
 461
 462 AG_GST_GLIB_CHECK([2.8])
 463
 464 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 465 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 466 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 467
 468 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 469 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 470
 471 dnl Check for documentation xrefs
 472 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 473 AC_SUBST(GLIB_PREFIX)
 474
 475 dnl libxml 2 is optional in some cases
 476 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 477    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 478    test "x$USE_BINARY_REGISTRY" = "xyes" )
 479 then
 480   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 481   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 482 else
 483   dnl check for libxml2 with minimum req version
 484   AG_GST_LIBXML2_CHECK(2.4.9)
 485   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 486 fi
 487 AC_SUBST(GST_DISABLE_XML_DEFINE)
 488
 489 dnl check for "check", unit testing library/header
 490 AM_PATH_CHECK(0.9.2,
 491     [
 492         HAVE_CHECK=yes
 493         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 494         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 495     ],
 496     HAVE_CHECK=no)
 497 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 498
 499 dnl pkg-config check that for libcheck that works for cross-compiling
 500 dnl but not normal compilation on Fedora & Ubuntu:
 501 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 502 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 503 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 504 dnl )
 505
 506 dnl *** set variables based on configure arguments
 507
 508 dnl set license and copyright notice
 509 GST_LICENSE="LGPL"
 510 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 511 AC_SUBST(GST_LICENSE)
 512
 513 dnl define LIBDIR so we can inform people where we live
 514 AS_AC_EXPAND(LIBDIR, $libdir)
 515 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 516
 517 dnl set location of plugin directory
 518 AG_GST_SET_PLUGINDIR
 519
 520 dnl FIXME: add LIBXML_PKG here if we use it
 521 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 522 AC_SUBST(GST_PKG_DEPS)
 523
 524 dnl define an ERROR_CFLAGS Makefile variable
 525 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 526
 527 dnl define correct level for debugging messages
 528 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 529
 530 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 531
 532 dnl Overview:
 533 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 534 dnl GST_ALL_*:          vars shared by all built objects
 535 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 536 dnl GST_OBJ_*:          additional vars to link to the core library
 537 dnl                     include GST_ALL_*
 538 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 539 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 540
 541 dnl GST_OPTION_CFLAGS
 542 if test "x$USE_DEBUG" = xyes; then
 543    PROFILE_CFLAGS="-g"
 544 fi
 545 AC_SUBST(PROFILE_CFLAGS)
 546
 547 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 548 # functionality from the API that gstreamer uses
 549 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 550 if test "x$GST_CVS" = "xyes"; then
 551   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 552 else
 553   DEPRECATED_CFLAGS=""
 554 fi
 555 AC_SUBST(DEPRECATED_CFLAGS)
 556
 557 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 558 dnl make DEPRECATED_CFLAGS=''
 559 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 560 AC_SUBST(GST_OPTION_CFLAGS)
 561
 562 dnl GST_ALL_*
 563 dnl vars common to for all internal objects (core libs, elements, applications)
 564 dnl CFLAGS:
 565 dnl - XML needs to be added because xmlPtr is used in core
 566 dnl - src and build dirs need to be added because every piece that gets built
 567 dnl   will need the GStreamer source and generated headers
 568 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 569 dnl       from LibXML except for in the core library
 570 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 571
 572 dnl FIXME: check if LTLIBINTL is needed everywhere
 573 dnl I presume it is given that it contains the symbols that _() stuff maps to
 574 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 575
 576 dnl LDFLAGS really should only contain flags, not libs - they get added before
 577 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 578 GST_ALL_LDFLAGS="-no-undefined"
 579
 580 AC_SUBST(GST_ALL_CFLAGS)
 581 AC_SUBST(GST_ALL_LIBS)
 582 AC_SUBST(GST_ALL_LDFLAGS)
 583
 584 dnl GST_LIB_LDFLAGS
 585 dnl linker flags shared by all libraries
 586 dnl LDFLAGS modifier defining exported symbols from built libraries
 587 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 588 AC_SUBST(GST_LIB_LDFLAGS)
 589 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 590 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 591 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 592 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 593   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 594 fi
 595 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 596
 597 dnl GST_OBJ_*
 598 dnl default vars for all internal objects built on libgstreamer
 599 dnl includes GST_ALL_*
 600 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 601 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 602 AC_SUBST(GST_OBJ_CFLAGS)
 603 AC_SUBST(GST_OBJ_LIBS)
 604
 605 dnl GST_PLUGIN_LDFLAGS
 606 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 607 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 608 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 609
 610 AC_CONFIG_FILES(
 611 Makefile
 612 gst/Makefile
 613 gst/gstconfig.h
 614 gst/gstversion.h
 615 gst/parse/Makefile
 616 libs/Makefile
 617 libs/gst/Makefile
 618 libs/gst/base/Makefile
 619 libs/gst/check/Makefile
 620 libs/gst/controller/Makefile
 621 libs/gst/dataprotocol/Makefile
 622 libs/gst/net/Makefile
 623 plugins/Makefile
 624 plugins/indexers/Makefile
 625 plugins/elements/Makefile
 626 po/Makefile.in
 627 tests/Makefile
 628 tests/benchmarks/Makefile
 629 tests/check/Makefile
 630 tests/misc/Makefile
 631 tests/examples/Makefile
 632 tests/examples/adapter/Makefile
 633 tests/examples/controller/Makefile
 634 tests/examples/helloworld/Makefile
 635 tests/examples/launch/Makefile
 636 tests/examples/manual/Makefile
 637 tests/examples/metadata/Makefile
 638 tests/examples/queue/Makefile
 639 tests/examples/typefind/Makefile
 640 tests/examples/xml/Makefile
 641 tools/Makefile
 642 common/Makefile
 643 common/m4/Makefile
 644 docs/Makefile
 645 docs/design/Makefile
 646 docs/faq/Makefile
 647 docs/gst/Makefile
 648 docs/gst/gstreamer.types
 649 docs/libs/Makefile
 650 docs/plugins/Makefile
 651 docs/manual/Makefile
 652 docs/pwg/Makefile
 653 docs/slides/Makefile
 654 docs/xsl/Makefile
 655 docs/version.entities
 656 win32/common/config.h
 657 pkgconfig/Makefile
 658 stamp.h
 659 pkgconfig/gstreamer.pc
 660 pkgconfig/gstreamer-uninstalled.pc
 661 pkgconfig/gstreamer-base.pc
 662 pkgconfig/gstreamer-base-uninstalled.pc
 663 pkgconfig/gstreamer-check.pc
 664 pkgconfig/gstreamer-check-uninstalled.pc
 665 pkgconfig/gstreamer-controller.pc
 666 pkgconfig/gstreamer-controller-uninstalled.pc
 667 pkgconfig/gstreamer-dataprotocol.pc
 668 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 669 pkgconfig/gstreamer-net.pc
 670 pkgconfig/gstreamer-net-uninstalled.pc
 671 gst-element-check.m4
 672 gstreamer.spec
 673 )
 674
 675 AC_OUTPUT