configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AC_HELP_STRING([--with-install-plugins-helper],
  99     [specify path of helper script to call to install plugins]),
 100   [
 101     case "${withval}" in
 102       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 104       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 105     esac
 106   ],
 107   [
 108     dnl Default value
 109     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 110   ]
 111 )
 112 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 113 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 114     [plugin install helper script])
 115 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 116
 117 AG_GST_ARG_WITH_PLUGINS
 118
 119 AG_GST_ARG_ENABLE_EXTERNAL
 120
 121 AG_GST_ARG_ENABLE_EXPERIMENTAL
 122
 123 dnl *** checks for platform ***
 124 AG_GST_PLATFORM
 125
 126 dnl * hardware/architecture *
 127
 128 dnl common/m4/gst-arch.m4
 129 dnl check CPU type
 130 AG_GST_ARCH
 131
 132 dnl check for large file support
 133 dnl affected plugins must include config.h
 134 AC_SYS_LARGEFILE
 135
 136 dnl *** checks for programs ***
 137
 138 dnl find a compiler
 139 AC_PROG_CC
 140 AC_PROG_CC_STDC
 141
 142 dnl check if the compiler supports '-c' and '-o' options
 143 AM_PROG_CC_C_O
 144
 145 dnl determine if c++ is available on this system
 146 AC_PROG_CXX
 147 dnl CXX may be set to some default even if no c++ compiler is available
 148 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 149 AC_LANG_PUSH([C++])
 150 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 151 AC_LANG_POP([C++])
 152 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 153 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 154
 155 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 156 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 157
 158 dnl check for gobject-introspection
 159 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 160
 161 dnl check for documentation tools
 162 GTK_DOC_CHECK([1.3])
 163 AS_PATH_PYTHON([2.1])
 164 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 165
 166 dnl *** checks for libraries ***
 167
 168 dnl libm, for sin() etc.
 169 AC_CHECK_LIBM
 170 AC_SUBST(LIBM)
 171
 172 dnl *** checks for header files ***
 173
 174 dnl check if we have ANSI C header files
 175 AC_HEADER_STDC
 176
 177 ac_cppflags_save="$CPPFLAGS"
 178 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 179 AC_COMPILE_IFELSE(
 180   AC_LANG_PROGRAM([
 181 #include <libxml/HTMLparser.h>
 182                      ],[
 183 #ifndef LIBXML_HTML_ENABLED
 184 #error libxml2 has no HTML support
 185 #endif /* LIBXML_HTML_ENABLED */
 186                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 187 CPPFLAGS="$ac_cppflags_save"
 188 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 189
 190 dnl used in gst-libs/gst/pbutils and associated unit test
 191 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 192
 193 dnl also, Windows does not have long long
 194 AX_CREATE_STDINT_H
 195
 196 dnl *** checks for functions ***
 197 AC_CHECK_FUNCS([localtime_r gmtime_r])
 198
 199 dnl *** checks for math functions ***
 200 LIBS_SAVE=$LIBS
 201 LIBS="$LIBS $LIBM"
 202 AC_CHECK_FUNCS(log2)
 203 LIBS=$LIBS_SAVE
 204
 205 dnl *** checks for types/defines ***
 206
 207 dnl *** checks for structures ***
 208
 209 dnl *** checks for compiler characteristics ***
 210
 211 dnl *** checks for library functions ***
 212
 213 dnl check for fseeko()
 214 AC_FUNC_FSEEKO
 215
 216 dnl Check for fast float to int casting as defined in C99
 217 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 218 save_libs=$LIBS
 219 LIBS="$LIBS $LIBM"
 220 AC_C99_FUNC_LRINT
 221 AC_C99_FUNC_LRINTF
 222 LIBS=$save_libs
 223
 224 dnl Check for a way to display the function name in debug output
 225 AG_GST_CHECK_FUNCTION
 226
 227 dnl *** checks for dependency libraries ***
 228
 229 dnl GLib
 230 GLIB_REQ=2.31.10
 231 AG_GST_GLIB_CHECK([$GLIB_REQ])
 232
 233 ORC_CHECK([0.4.11])
 234
 235 dnl checks for gstreamer
 236 dnl uninstalled is selected preferentially -- see pkg-config(1)
 237 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 238 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 239 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 240 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 241 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 242
 243 dnl Check for documentation xrefs
 244 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 245 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 246 AC_SUBST(GLIB_PREFIX)
 247 AC_SUBST(GST_PREFIX)
 248
 249 dnl GTK is optional and only used in examples
 250 HAVE_GTK=no
 251 HAVE_GTK_X11=no
 252 GTK_REQ=3.0.0
 253 if test "x$BUILD_EXAMPLES" = "xyes"; then
 254   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 255   dnl some examples need gtk+-x11
 256   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 257   AC_SUBST(GTK_LIBS)
 258   AC_SUBST(GTK_CFLAGS)
 259 fi
 260 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 261 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 262
 263 dnl QT is optional and only used in examples
 264 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 265   HAVE_QT_GV=yes
 266   HAVE_QT=yes
 267 ], [
 268   HAVE_QT_GV=no
 269   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 270 ])
 271 if test "x$HAVE_QT" = "xyes"; then
 272   AC_MSG_CHECKING([Qt moc])
 273   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 274   AC_MSG_RESULT($QT4_MOC)
 275   AC_SUBST(QT4_MOC)
 276 fi
 277 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 278 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 279
 280 dnl chck for linux headers needed by the joystick seek example
 281 AC_COMPILE_IFELSE(
 282 [
 283   AC_LANG_PROGRAM([
 284     #include <linux/input.h>
 285     #include <linux/joystick.h>
 286   ],[
 287     struct js_event js;
 288     js.type = JS_EVENT_AXIS;
 289   ])
 290 ], [
 291   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 292 ], [
 293   HAVE_LINUX_JOYSTICK_HEADERS="no"
 294 ])
 295 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 296
 297 dnl Check for -Bsymbolic-functions linker flag used to avoid
 298 dnl intra-library PLT jumps, if available.
 299 AC_ARG_ENABLE(Bsymbolic,
 300               [AC_HELP_STRING([--disable-Bsymbolic],
 301                               [avoid linking with -Bsymbolic])],,
 302               [SAVED_LDFLAGS="${LDFLAGS}"
 303                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 304                LDFLAGS=-Wl,-Bsymbolic-functions
 305                AC_TRY_LINK([], [int main (void) { return 0; }],
 306                            AC_MSG_RESULT(yes)
 307                            enable_Bsymbolic=yes,
 308                            AC_MSG_RESULT(no)
 309                            enable_Bsymbolic=no)
 310                LDFLAGS="${SAVED_LDFLAGS}"])
 311
 312
 313 dnl *** set variables based on configure arguments ***
 314
 315 dnl set license and copyright notice
 316 GST_LICENSE="LGPL"
 317 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 318 AC_SUBST(GST_LICENSE)
 319
 320 dnl set location of plugin directory
 321 AG_GST_SET_PLUGINDIR
 322
 323 dnl set release date/time
 324 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 325   ["${srcdir}/gst-plugins-base.doap"],
 326   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 327
 328 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 329 dnl make sure it doesn't complain about unused variables if debugging is disabled
 330 NO_WARNINGS=""
 331 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 332
 333 dnl define an ERROR_CFLAGS Makefile variable
 334 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 335 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 336     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 337     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 338     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 339     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 340
 341 dnl define an ERROR_CXXFLAGS Makefile variable
 342 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 343     -Wmissing-declarations -Wredundant-decls -Wundef
 344     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 345     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 346     -Wno-multichar $NO_WARNINGS])
 347
 348 dnl define correct level for debugging messages
 349 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 350
 351 dnl used in examples
 352 AG_GST_DEFAULT_ELEMENTS
 353
 354 dnl needed for encoding-target
 355 GST_DATADIR="$GST_PREFIX/share"
 356 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 357 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 358
 359 dnl behaviour of speex based audio resampler
 360 AC_MSG_CHECKING(which audio resample format to use for integer)
 361 AC_ARG_WITH([audioresample_format],
 362         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 363         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 364 AC_MSG_RESULT($ac_cv_audioresample_format)
 365 case $ac_cv_audioresample_format in
 366   int)
 367     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 368     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 369   ;;
 370   float)
 371     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 372     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 373   ;;
 374   auto)
 375     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 376     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 377 esac
 378
 379 dnl *** plug-ins to include ***
 380
 381 dnl these are all the gst plug-ins, compilable without additional libs
 382 AG_GST_CHECK_PLUGIN(adder)
 383 AG_GST_CHECK_PLUGIN(app)
 384 AG_GST_CHECK_PLUGIN(audioconvert)
 385 AG_GST_CHECK_PLUGIN(audiorate)
 386 AG_GST_CHECK_PLUGIN(audiotestsrc)
 387 AG_GST_CHECK_PLUGIN(encoding)
 388 AG_GST_CHECK_PLUGIN(videoconvert)
 389 AG_GST_CHECK_PLUGIN(gdp)
 390 AG_GST_CHECK_PLUGIN(gio)
 391 AG_GST_CHECK_PLUGIN(playback)
 392 AG_GST_CHECK_PLUGIN(audioresample)
 393 AG_GST_CHECK_PLUGIN(subparse)
 394 AG_GST_CHECK_PLUGIN(tcp)
 395 AG_GST_CHECK_PLUGIN(typefind)
 396 AG_GST_CHECK_PLUGIN(videotestsrc)
 397 AG_GST_CHECK_PLUGIN(videorate)
 398 AG_GST_CHECK_PLUGIN(videoscale)
 399 AG_GST_CHECK_PLUGIN(volume)
 400
 401 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 402 AM_CONDITIONAL(USE_XML, false)
 403 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 404
 405 dnl disable plug-ins that require libxml2's HTML support if it is not available
 406 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 407   AG_GST_DISABLE_PLUGIN(subparse)
 408 fi
 409
 410 dnl iso-codes is optional, used by libgsttag
 411 AC_ARG_ENABLE(iso-codes,
 412 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 413 [case "${enableval}" in
 414   yes) enable_iso_codes=yes ;;
 415   no)  enable_iso_codes=no ;;
 416   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 417 esac
 418 ],
 419 [enable_iso_codes=yes]) dnl Default value
 420
 421 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 422 if test "x$enable_iso_codes" = "xyes"; then
 423   AC_MSG_RESULT([yes])
 424   have_iso_codes=no
 425   AC_MSG_CHECKING([whether iso-codes are available on this system])
 426   if $PKG_CONFIG iso-codes; then
 427     AC_MSG_RESULT([yes])
 428     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 429     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 430       AC_MSG_RESULT([yes])
 431       AC_MSG_CHECKING([for iso-codes prefix])
 432       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 433       if test -d "$ISO_CODES_PREFIX"; then
 434         AC_MSG_RESULT([yes])
 435         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 436         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 437         ISO_639_DOMAIN="iso_639"
 438         AC_MSG_CHECKING([ISO_639_DOMAIN])
 439         AC_MSG_RESULT([$ISO_639_DOMAIN])
 440         have_iso_codes=yes
 441         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 442         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 443         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 444         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 445       else
 446         AC_MSG_RESULT([no])
 447       fi
 448     else
 449       AC_MSG_RESULT([no])
 450     fi
 451   else
 452     AC_MSG_RESULT([no])
 453   fi
 454   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 455 else
 456   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 457   AM_CONDITIONAL(USE_ISO_CODES, false)
 458 fi
 459
 460 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 462 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 463   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 464       HAVE_ZLIB="yes"
 465     ], [
 466       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 467         HAVE_ZLIB="yes"
 468         ZLIB_LIBS="-lz"
 469         AC_SUBST(ZLIB_LIBS)
 470       ])
 471     ])
 472 ])
 473
 474 dnl *** sys plug-ins ***
 475
 476 echo
 477 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 478 echo
 479
 480 dnl *** X11 ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 482 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 483                   [ximagesink], [
 484   AC_PATH_XTRA
 485   ac_cflags_save="$CFLAGS"
 486   ac_cppflags_save="$CPPFLAGS"
 487   CFLAGS="$CFLAGS $X_CFLAGS"
 488   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 489
 490   dnl now try to find the HEADER
 491   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 492
 493   if test "x$HAVE_X" = "xno"
 494   then
 495     AC_MSG_NOTICE([cannot find X11 development files])
 496   else
 497     dnl this is much more than we want
 498     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 499     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 500     dnl it does not add the libs; therefore we add them here
 501     X_LIBS="$X_LIBS -lX11"
 502     AC_SUBST(X_CFLAGS)
 503     AC_SUBST(X_LIBS)
 504   fi
 505   AC_SUBST(HAVE_X)
 506   CFLAGS="$ac_cflags_save"
 507   CPPFLAGS="$ac_cppflags_save"
 508 ])
 509
 510 dnl Check for Xv extension
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 512 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 513                   [xvimagesink], [
 514   AG_GST_CHECK_XV
 515 ])
 516
 517 dnl check for X Shm
 518 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 519 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 520   if test x$HAVE_X = xyes; then
 521     AC_CHECK_LIB(Xext, XShmAttach,
 522                  HAVE_XSHM="yes", HAVE_XSHM="no",
 523                  $X_LIBS)
 524     if test "x$HAVE_XSHM" = "xyes"; then
 525       XSHM_LIBS="-lXext"
 526     else
 527       dnl On AIX, it is in XextSam instead, but we still need -lXext
 528       AC_CHECK_LIB(XextSam, XShmAttach,
 529                    HAVE_XSHM="yes", HAVE_XSHM="no",
 530                    $X_LIBS)
 531       if test "x$HAVE_XSHM" = "xyes"; then
 532         XSHM_LIBS="-lXext -lXextSam"
 533       fi
 534     fi
 535   fi
 536 ], , [
 537   AC_SUBST(HAVE_XSHM)
 538   AC_SUBST(XSHM_LIBS)
 539 ])
 540
 541 dnl *** ext plug-ins ***
 542 dnl keep this list sorted alphabetically !
 543
 544 if test "x$BUILD_EXTERNAL" = "xyes"; then
 545
 546 echo
 547 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 548 echo
 549
 550 dnl *** alsa ***
 551 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 552 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 553   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 554     HAVE_ALSA="yes"
 555     AC_SUBST(ALSA_CFLAGS)
 556     AC_SUBST(ALSA_LIBS)
 557   ], [
 558     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 559   ])
 560 ])
 561
 562 dnl *** CDParanoia ***
 563 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 565 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 566   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 567     HAVE_CDPARANOIA="yes"
 568   ], [
 569     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 570                         cdda_open, -lm,
 571                         cdda_interface.h,
 572                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 573                         HEADER_DIR="no"
 574                         FOUND_CDPARANOIA="yes")
 575     if test "x$FOUND_CDPARANOIA" != "xyes";
 576     then
 577       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 578                           cdda_open, -lm,
 579                           cdda/cdda_interface.h,
 580                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 581                           HEADER_DIR="yes"
 582                           FOUND_CDPARANOIA="yes")
 583     fi
 584     if test "x$HEADER_DIR" = "xyes";
 585     then
 586       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 587                          defined if cdda headers are in a cdda/ directory)
 588     fi
 589     if test "x$FOUND_CDPARANOIA" = "xyes";
 590     then
 591       AC_CHECK_LIB(cdda_paranoia,
 592                    paranoia_cachemodel_size,
 593                    : ,
 594                    HAVE_CDPARANOIA=no,
 595                  [-lcdda_interface])
 596     fi
 597
 598     AC_SUBST(CDPARANOIA_LIBS)
 599   ])
 600 ])
 601 dnl FIXME : add second check somehow if that is necessary
 602 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 603 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 604
 605 dnl *** ivorbis ***
 606 dnl AM_PATH_IVORBIS only takes two options
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 608 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 609   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 610   if test $HAVE_IVORBIS = no
 611   then
 612     IVORBIS_LIBS=
 613     IVORBIS_CFLAGS=
 614     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 615       [IVORBIS_LIBS=-lvorbisidec
 616       HAVE_IVORBIS=yes
 617       case $host in
 618       arm-*-*)
 619         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 620       esac
 621       ],
 622       HAVE_IVORBIS=no)
 623     AC_SUBST(IVORBIS_LIBS)
 624     AC_SUBST(IVORBIS_CFLAGS)
 625   else
 626     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 627       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 628       USE_TREMOLO=no)
 629   fi
 630 ])
 631
 632 dnl *** libvisual ***
 633 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 634 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 635   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 636   if test $HAVE_LIBVISUAL = no
 637   then
 638     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 639     if test x$HAVE_LIBVISUAL = xyes; then
 640       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 641     fi
 642   else
 643     if test x$HAVE_LIBVISUAL = xyes; then
 644       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 645     fi
 646   fi
 647   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 648   if test x$LIBVIS_PLUGINSDIR != x; then
 649     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 650         "$LIBVIS_PLUGINSDIR",
 651         [directory in which the detected libvisual's plugins are located])
 652   fi
 653 ])
 654
 655 dnl *** ogg ***
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 657 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 658   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 659   if test $HAVE_OGG = no
 660   then
 661     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 662     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 663   fi
 664 ])
 665
 666 dnl *** pango ***
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 668 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 669   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 670 ])
 671
 672 dnl *** theora ***
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 674 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 675   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 676 ])
 677
 678 dnl *** vorbis ***
 679 dnl AM_PATH_VORBIS only takes two options
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 681 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 682   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 683   if test $HAVE_VORBIS = no
 684   then
 685     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 686     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 687   fi
 688 ])
 689
 690 if test "x$HAVE_VORBIS" = "xyes"; then
 691   ac_cflags_save="$CFLAGS"
 692   AC_COMPILE_IFELSE(
 693     AC_LANG_PROGRAM([
 694 #include <vorbis/codec.h>
 695                      ],[
 696 vorbis_dsp_state *v;
 697
 698 vorbis_synthesis_restart (v);
 699                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 700   if test "x$HAVE_VSR" = "xyes"; then
 701     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 702                        [defined if vorbis_synthesis_restart is present])
 703   fi
 704   CFLAGS="$ac_cflags_save"
 705 fi
 706
 707 else
 708
 709 dnl not building plugins with external dependencies,
 710 dnl but we still need to set the conditionals
 711 AM_CONDITIONAL(USE_ALSA, false)
 712 AM_CONDITIONAL(USE_CDPARANOIA, false)
 713 AM_CONDITIONAL(USE_IVORBIS, false)
 714 AM_CONDITIONAL(USE_LIBVISUAL, false)
 715 AM_CONDITIONAL(USE_OGG, false)
 716 AM_CONDITIONAL(USE_PANGO, false)
 717 AM_CONDITIONAL(USE_THEORA, false)
 718 AM_CONDITIONAL(USE_VORBIS, false)
 719
 720 fi dnl of EXT plugins
 721
 722 dnl seeking needs freetype, so check for it here
 723 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 724   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 725 ])
 726 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 727 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 728 AC_SUBST(FT2_CFLAGS)
 729 AC_SUBST(FT2_LIBS)
 730
 731 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 732
 733 dnl Overview:
 734 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 735 dnl GST_*:              flags shared by built objects to link against GStreamer
 736 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 737 dnl                          (compare to other modules) or for i18n
 738 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 739 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 740 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 741 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 742
 743 dnl GST_OPTION_CFLAGS
 744 if test "x$USE_DEBUG" = xyes; then
 745    PROFILE_CFLAGS="-g"
 746 fi
 747 AC_SUBST(PROFILE_CFLAGS)
 748
 749 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 750   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 751   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 752 else
 753   DEPRECATED_CFLAGS=""
 754 fi
 755 AC_SUBST(DEPRECATED_CFLAGS)
 756
 757 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 758 dnl at make time with e.g. make ERROR_CFLAGS=""
 759 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 760 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 761 AC_SUBST(GST_OPTION_CFLAGS)
 762 AC_SUBST(GST_OPTION_CXXFLAGS)
 763
 764 dnl our libraries need to be versioned correctly
 765 AC_SUBST(GST_LT_LDFLAGS)
 766
 767 dnl GST_PLUGINS_BASE_CFLAGS
 768 dnl prefer internal headers to already installed ones
 769 dnl also add builddir include for enumtypes and marshal
 770 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 771 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 772
 773 dnl FIXME: do we want to rename to GST_ALL_* ?
 774 dnl add GST_OPTION_CFLAGS, but overridable
 775 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 776 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 777 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 778 AC_SUBST(GST_CFLAGS)
 779 AC_SUBST(GST_CXXFLAGS)
 780 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 781 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 782 AC_SUBST(GST_LIBS)
 783
 784 dnl LDFLAGS really should only contain flags, not libs - they get added before
 785 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 786 GST_ALL_LDFLAGS="-no-undefined"
 787 if test "x${enable_Bsymbolic}" = "xyes"; then
 788   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 789 fi
 790 AC_SUBST(GST_ALL_LDFLAGS)
 791
 792 dnl GST_LIB_LDFLAGS
 793 dnl linker flags shared by all libraries
 794 dnl LDFLAGS modifier defining exported symbols from built libraries
 795 dnl (export _gst_foo but not __gst_foo)
 796 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 797 AC_SUBST(GST_LIB_LDFLAGS)
 798
 799 dnl this really should only contain flags, not libs - they get added before
 800 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 801 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 802 AC_SUBST(GST_PLUGIN_LDFLAGS)
 803
 804 dnl *** output files ***
 805
 806 AC_CONFIG_FILES(
 807 Makefile
 808 gst-plugins-base.spec
 809 gst/Makefile
 810 gst/adder/Makefile
 811 gst/app/Makefile
 812 gst/audioconvert/Makefile
 813 gst/audiorate/Makefile
 814 gst/audiotestsrc/Makefile
 815 gst/encoding/Makefile
 816 gst/videoconvert/Makefile
 817 gst/gdp/Makefile
 818 gst/gio/Makefile
 819 gst/playback/Makefile
 820 gst/audioresample/Makefile
 821 gst/subparse/Makefile
 822 gst/tcp/Makefile
 823 gst/typefind/Makefile
 824 gst/videotestsrc/Makefile
 825 gst/videorate/Makefile
 826 gst/videoscale/Makefile
 827 gst/volume/Makefile
 828 sys/Makefile
 829 sys/ximage/Makefile
 830 sys/xvimage/Makefile
 831 ext/Makefile
 832 ext/alsa/Makefile
 833 ext/cdparanoia/Makefile
 834 ext/libvisual/Makefile
 835 ext/ogg/Makefile
 836 ext/pango/Makefile
 837 ext/theora/Makefile
 838 ext/vorbis/Makefile
 839 gst-libs/Makefile
 840 gst-libs/gst/Makefile
 841 gst-libs/gst/audio/Makefile
 842 gst-libs/gst/app/Makefile
 843 gst-libs/gst/fft/Makefile
 844 gst-libs/gst/interfaces/Makefile
 845 gst-libs/gst/riff/Makefile
 846 gst-libs/gst/rtp/Makefile
 847 gst-libs/gst/rtsp/Makefile
 848 gst-libs/gst/sdp/Makefile
 849 gst-libs/gst/tag/Makefile
 850 gst-libs/gst/pbutils/Makefile
 851 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 852 gst-libs/gst/video/Makefile
 853 tools/Makefile
 854 pkgconfig/Makefile
 855 pkgconfig/gstreamer-audio.pc
 856 pkgconfig/gstreamer-audio-uninstalled.pc
 857 pkgconfig/gstreamer-app.pc
 858 pkgconfig/gstreamer-app-uninstalled.pc
 859 pkgconfig/gstreamer-fft.pc
 860 pkgconfig/gstreamer-fft-uninstalled.pc
 861 pkgconfig/gstreamer-interfaces.pc
 862 pkgconfig/gstreamer-interfaces-uninstalled.pc
 863 pkgconfig/gstreamer-pbutils.pc
 864 pkgconfig/gstreamer-pbutils-uninstalled.pc
 865 pkgconfig/gstreamer-riff.pc
 866 pkgconfig/gstreamer-riff-uninstalled.pc
 867 pkgconfig/gstreamer-rtp.pc
 868 pkgconfig/gstreamer-rtp-uninstalled.pc
 869 pkgconfig/gstreamer-rtsp.pc
 870 pkgconfig/gstreamer-rtsp-uninstalled.pc
 871 pkgconfig/gstreamer-sdp.pc
 872 pkgconfig/gstreamer-sdp-uninstalled.pc
 873 pkgconfig/gstreamer-tag.pc
 874 pkgconfig/gstreamer-tag-uninstalled.pc
 875 pkgconfig/gstreamer-video.pc
 876 pkgconfig/gstreamer-video-uninstalled.pc
 877 pkgconfig/gstreamer-plugins-base.pc
 878 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 879 tests/Makefile
 880 tests/check/Makefile
 881 tests/examples/Makefile
 882 tests/examples/app/Makefile
 883 tests/examples/audio/Makefile
 884 tests/examples/dynamic/Makefile
 885 tests/examples/encoding/Makefile
 886 tests/examples/fft/Makefile
 887 tests/examples/gio/Makefile
 888 tests/examples/overlay/Makefile
 889 tests/examples/seek/Makefile
 890 tests/examples/snapshot/Makefile
 891 tests/examples/playrec/Makefile
 892 tests/files/Makefile
 893 tests/icles/Makefile
 894 tests/icles/playback/Makefile
 895 docs/Makefile
 896 docs/design/Makefile
 897 docs/libs/Makefile
 898 docs/plugins/Makefile
 899 docs/version.entities
 900 po/Makefile.in
 901 common/Makefile
 902 common/m4/Makefile
 903 m4/Makefile
 904 )
 905
 906 dnl Create the config.h file for Visual Studio builds
 907 dnl Beware of spaces and /'s in some of the shell variable contents.
 908 sed \
 909     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 910     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 911     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 912     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 913     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 914     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 915     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 916     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 917     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 918     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 919     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 920     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 921     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 922     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 923     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 924     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 925     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 926     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 927     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 928     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 929     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 930     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 931     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 932     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 933     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 934     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 935     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 936     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 937     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 938     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 939     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 940     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 941     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 942     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 943     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 944     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 945     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 946     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 947     config.h.in >win32/common/config.h-new
 948
 949
 950
 951 AC_OUTPUT
 952
 953 AG_GST_OUTPUT_PLUGINS
 954 ORC_OUTPUT
 955