configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 1.0.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 dnl CURRENT, REVISION, AGE
  48 dnl - library source changed -> increment REVISION
  49 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  50 dnl - interfaces added -> increment AGE
  51 dnl - interfaces removed -> AGE = 0
  52 dnl sets GST_LT_LDFLAGS
  53 AS_LIBTOOL(GST, 1, 0, 1)
  54
  55 dnl *** required versions of GStreamer stuff ***
  56 GST_REQ=1.0.0
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_PKG_CONFIG_PATH
  88
  89 dnl let distro override plugin install helper path
  90 AC_ARG_WITH(install-plugins-helper,
  91   AC_HELP_STRING([--with-install-plugins-helper],
  92     [specify path of helper script to call to install plugins]),
  93   [
  94     case "${withval}" in
  95       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  96       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  97       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  98     esac
  99   ],
 100   [
 101     dnl Default value
 102     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 103   ]
 104 )
 105 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 106 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 107     [plugin install helper script])
 108 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 109
 110 AG_GST_ARG_WITH_PLUGINS
 111
 112 AG_GST_ARG_ENABLE_EXTERNAL
 113
 114 AG_GST_ARG_ENABLE_EXPERIMENTAL
 115
 116 dnl *** checks for platform ***
 117 AG_GST_PLATFORM
 118
 119 dnl * hardware/architecture *
 120
 121 dnl common/m4/gst-arch.m4
 122 dnl check CPU type
 123 AG_GST_ARCH
 124
 125 dnl check for large file support
 126 dnl affected plugins must include config.h
 127 AC_SYS_LARGEFILE
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133 AC_PROG_CC_STDC
 134
 135 dnl check if the compiler supports '-c' and '-o' options
 136 AM_PROG_CC_C_O
 137
 138 dnl determine if c++ is available on this system
 139 AC_PROG_CXX
 140 dnl CXX may be set to some default even if no c++ compiler is available
 141 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 142 AC_LANG_PUSH([C++])
 143 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 144 AC_LANG_POP([C++])
 145 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 146 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 147
 148 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 149 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 150
 151 dnl check for gobject-introspection
 152 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 153
 154 dnl check for documentation tools
 155 GTK_DOC_CHECK([1.12])
 156 AS_PATH_PYTHON([2.1])
 157 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 158
 159 dnl *** checks for libraries ***
 160
 161 dnl libm, for sin() etc.
 162 LT_LIB_M
 163 AC_SUBST(LIBM)
 164
 165 dnl *** checks for header files ***
 166
 167 dnl check if we have ANSI C header files
 168 AC_HEADER_STDC
 169
 170 dnl check for GCC specific SSE headers
 171 dnl these are used by the speex resampler code
 172 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE([
 177   AC_LANG_PROGRAM([[
 178 #include <libxml/HTMLparser.h>
 179 ]],[[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183 ]])], [
 184   HAVE_LIBXML_HTML="yes"
 185 ], [
 186   HAVE_LIBXML_HTML="no"
 187 ])
 188 CPPFLAGS="$ac_cppflags_save"
 189 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/pbutils and associated unit test
 197 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 198
 199 dnl also, Windows does not have long long
 200 AX_CREATE_STDINT_H
 201
 202 dnl *** checks for functions ***
 203 AC_CHECK_FUNCS([localtime_r gmtime_r])
 204
 205 dnl *** checks for math functions ***
 206 LIBS_SAVE=$LIBS
 207 LIBS="$LIBS $LIBM"
 208 AC_CHECK_FUNCS(log2)
 209 LIBS=$LIBS_SAVE
 210
 211 dnl *** checks for types/defines ***
 212
 213 dnl *** checks for structures ***
 214
 215 dnl *** checks for compiler characteristics ***
 216
 217 dnl *** checks for library functions ***
 218
 219 dnl check for fseeko()
 220 AC_FUNC_FSEEKO
 221
 222 dnl Check for fast float to int casting as defined in C99
 223 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 224 save_libs=$LIBS
 225 LIBS="$LIBS $LIBM"
 226 AC_C99_FUNC_LRINT
 227 AC_C99_FUNC_LRINTF
 228 LIBS=$save_libs
 229
 230 dnl Check for a way to display the function name in debug output
 231 AG_GST_CHECK_FUNCTION
 232
 233 dnl *** checks for dependency libraries ***
 234
 235 dnl GLib
 236 GLIB_REQ=2.32
 237 AG_GST_GLIB_CHECK([$GLIB_REQ])
 238
 239 ORC_CHECK([0.4.16])
 240
 241 dnl checks for gstreamer
 242 dnl uninstalled is selected preferentially -- see pkg-config(1)
 243 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 244 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 245 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 246 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 247 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 248
 249 dnl Check for documentation xrefs
 250 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 251 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 252 AC_SUBST(GLIB_PREFIX)
 253 AC_SUBST(GST_PREFIX)
 254
 255 dnl GTK is optional and only used in examples
 256 HAVE_GTK=no
 257 HAVE_GTK_X11=no
 258 GTK_REQ=3.0.0
 259 if test "x$BUILD_EXAMPLES" = "xyes"; then
 260   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   dnl some examples need gtk+-x11
 262   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 263   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 264   AC_SUBST(GTK_LIBS)
 265   AC_SUBST(GTK_CFLAGS)
 266 fi
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 269 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 270
 271 dnl QT is optional and only used in examples
 272 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 273   HAVE_QT_GV=yes
 274   HAVE_QT=yes
 275 ], [
 276   HAVE_QT_GV=no
 277   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 278 ])
 279 if test "x$HAVE_QT" = "xyes"; then
 280   AC_MSG_CHECKING([Qt moc])
 281   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 282   AC_MSG_RESULT($QT4_MOC)
 283   AC_SUBST(QT4_MOC)
 284 fi
 285 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 286 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 287
 288 dnl chck for linux headers needed by the joystick seek example
 289 AC_COMPILE_IFELSE(
 290 [
 291   AC_LANG_PROGRAM([
 292     #include <linux/input.h>
 293     #include <linux/joystick.h>
 294   ],[
 295     struct js_event js;
 296     js.type = JS_EVENT_AXIS;
 297   ])
 298 ], [
 299   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 300 ], [
 301   HAVE_LINUX_JOYSTICK_HEADERS="no"
 302 ])
 303 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 304
 305 dnl Check for -Bsymbolic-functions linker flag used to avoid
 306 dnl intra-library PLT jumps, if available.
 307 AC_ARG_ENABLE(Bsymbolic,
 308               [AC_HELP_STRING([--disable-Bsymbolic],
 309                               [avoid linking with -Bsymbolic])],,
 310               [SAVED_LDFLAGS="${LDFLAGS}"
 311                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 312                LDFLAGS=-Wl,-Bsymbolic-functions
 313                AC_TRY_LINK([], [int main (void) { return 0; }],
 314                            AC_MSG_RESULT(yes)
 315                            enable_Bsymbolic=yes,
 316                            AC_MSG_RESULT(no)
 317                            enable_Bsymbolic=no)
 318                LDFLAGS="${SAVED_LDFLAGS}"])
 319
 320
 321 dnl *** set variables based on configure arguments ***
 322
 323 dnl set license and copyright notice
 324 GST_LICENSE="LGPL"
 325 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 326 AC_SUBST(GST_LICENSE)
 327
 328 dnl set location of plugin directory
 329 AG_GST_SET_PLUGINDIR
 330
 331 dnl set release date/time
 332 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 333   ["${srcdir}/gst-plugins-base.doap"],
 334   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 335
 336 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 337 dnl make sure it doesn't complain about unused variables if debugging is disabled
 338 NO_WARNINGS=""
 339 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 340
 341 dnl define an ERROR_CFLAGS Makefile variable
 342 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 343 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 344     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 345     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 346     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 347     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 348
 349 dnl define an ERROR_CXXFLAGS Makefile variable
 350 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 351     -Wmissing-declarations -Wredundant-decls -Wundef
 352     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 353     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 354     -Wno-multichar $NO_WARNINGS])
 355
 356 dnl define correct level for debugging messages
 357 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 358
 359 dnl used in examples
 360 AG_GST_DEFAULT_ELEMENTS
 361
 362 dnl needed for encoding-target
 363 GST_DATADIR="$GST_PREFIX/share"
 364 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 365 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 366
 367 dnl behaviour of speex based audio resampler
 368 AC_MSG_CHECKING(which audio resample format to use for integer)
 369 AC_ARG_WITH([audioresample_format],
 370         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 371         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 372 AC_MSG_RESULT($ac_cv_audioresample_format)
 373 case $ac_cv_audioresample_format in
 374   int)
 375     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 376     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 377   ;;
 378   float)
 379     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 380     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 381   ;;
 382   auto)
 383     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 384     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 385 esac
 386
 387 dnl *** plug-ins to include ***
 388
 389 dnl these are all the gst plug-ins, compilable without additional libs
 390 AG_GST_CHECK_PLUGIN(adder)
 391 AG_GST_CHECK_PLUGIN(app)
 392 AG_GST_CHECK_PLUGIN(audioconvert)
 393 AG_GST_CHECK_PLUGIN(audiorate)
 394 AG_GST_CHECK_PLUGIN(audiotestsrc)
 395 AG_GST_CHECK_PLUGIN(encoding)
 396 AG_GST_CHECK_PLUGIN(videoconvert)
 397 AG_GST_CHECK_PLUGIN(gio)
 398 AG_GST_CHECK_PLUGIN(playback)
 399 AG_GST_CHECK_PLUGIN(audioresample)
 400 AG_GST_CHECK_PLUGIN(subparse)
 401 AG_GST_CHECK_PLUGIN(tcp)
 402 AG_GST_CHECK_PLUGIN(typefind)
 403 AG_GST_CHECK_PLUGIN(videotestsrc)
 404 AG_GST_CHECK_PLUGIN(videorate)
 405 AG_GST_CHECK_PLUGIN(videoscale)
 406 AG_GST_CHECK_PLUGIN(volume)
 407
 408 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 409 AM_CONDITIONAL(USE_XML, false)
 410 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 411
 412 dnl disable plug-ins that require libxml2's HTML support if it is not available
 413 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 414   AG_GST_DISABLE_PLUGIN(subparse)
 415 fi
 416
 417 dnl iso-codes is optional, used by libgsttag
 418 AC_ARG_ENABLE(iso-codes,
 419 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 420 [case "${enableval}" in
 421   yes) enable_iso_codes=yes ;;
 422   no)  enable_iso_codes=no ;;
 423   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 424 esac
 425 ],
 426 [enable_iso_codes=yes]) dnl Default value
 427
 428 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 429 if test "x$enable_iso_codes" = "xyes"; then
 430   AC_MSG_RESULT([yes])
 431   have_iso_codes=no
 432   AC_MSG_CHECKING([whether iso-codes are available on this system])
 433   if $PKG_CONFIG iso-codes; then
 434     AC_MSG_RESULT([yes])
 435     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 436     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 437       AC_MSG_RESULT([yes])
 438       AC_MSG_CHECKING([for iso-codes prefix])
 439       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 440       if test -d "$ISO_CODES_PREFIX"; then
 441         AC_MSG_RESULT([yes])
 442         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 443         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 444         ISO_639_DOMAIN="iso_639"
 445         AC_MSG_CHECKING([ISO_639_DOMAIN])
 446         AC_MSG_RESULT([$ISO_639_DOMAIN])
 447         have_iso_codes=yes
 448         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 449         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 450         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 451         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 452       else
 453         AC_MSG_RESULT([no])
 454       fi
 455     else
 456       AC_MSG_RESULT([no])
 457     fi
 458   else
 459     AC_MSG_RESULT([no])
 460   fi
 461   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 462 else
 463   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 464   AM_CONDITIONAL(USE_ISO_CODES, false)
 465 fi
 466
 467 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 469 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 470   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 471       HAVE_ZLIB="yes"
 472     ], [
 473       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 474         HAVE_ZLIB="yes"
 475         ZLIB_LIBS="-lz"
 476         AC_SUBST(ZLIB_LIBS)
 477       ])
 478     ])
 479 ])
 480
 481 dnl *** sys plug-ins ***
 482
 483 echo
 484 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 485 echo
 486
 487 dnl *** X11 ***
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 489 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 490                   [ximagesink], [
 491   AC_PATH_XTRA
 492   ac_cflags_save="$CFLAGS"
 493   ac_cppflags_save="$CPPFLAGS"
 494   CFLAGS="$CFLAGS $X_CFLAGS"
 495   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 496
 497   dnl now try to find the HEADER
 498   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 499
 500   if test "x$HAVE_X" = "xno"
 501   then
 502     AC_MSG_NOTICE([cannot find X11 development files])
 503   else
 504     dnl this is much more than we want
 505     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 506     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 507     dnl it does not add the libs; therefore we add them here
 508     X_LIBS="$X_LIBS -lX11"
 509     AC_SUBST(X_CFLAGS)
 510     AC_SUBST(X_LIBS)
 511   fi
 512   AC_SUBST(HAVE_X)
 513   CFLAGS="$ac_cflags_save"
 514   CPPFLAGS="$ac_cppflags_save"
 515 ])
 516
 517 dnl Check for Xv extension
 518 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 519 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 520                   [xvimagesink], [
 521   AG_GST_CHECK_XV
 522 ])
 523
 524 dnl check for X Shm
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 526 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 527   if test x$HAVE_X = xyes; then
 528     AC_CHECK_LIB(Xext, XShmAttach,
 529                  HAVE_XSHM="yes", HAVE_XSHM="no",
 530                  $X_LIBS)
 531     if test "x$HAVE_XSHM" = "xyes"; then
 532       XSHM_LIBS="-lXext"
 533     else
 534       dnl On AIX, it is in XextSam instead, but we still need -lXext
 535       AC_CHECK_LIB(XextSam, XShmAttach,
 536                    HAVE_XSHM="yes", HAVE_XSHM="no",
 537                    $X_LIBS)
 538       if test "x$HAVE_XSHM" = "xyes"; then
 539         XSHM_LIBS="-lXext -lXextSam"
 540       fi
 541     fi
 542   fi
 543 ], , [
 544   AC_SUBST(HAVE_XSHM)
 545   AC_SUBST(XSHM_LIBS)
 546 ])
 547
 548 dnl *** ext plug-ins ***
 549 dnl keep this list sorted alphabetically !
 550
 551 if test "x$BUILD_EXTERNAL" = "xyes"; then
 552
 553 echo
 554 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 555 echo
 556
 557 dnl *** alsa ***
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 559 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 560   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 561     HAVE_ALSA="yes"
 562     AC_SUBST(ALSA_CFLAGS)
 563     AC_SUBST(ALSA_LIBS)
 564   ], [
 565     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 566   ])
 567 ])
 568
 569 dnl *** CDParanoia ***
 570 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 572 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 573   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 574     HAVE_CDPARANOIA="yes"
 575   ], [
 576     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 577                         cdda_open, -lm,
 578                         cdda_interface.h,
 579                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 580                         HEADER_DIR="no"
 581                         FOUND_CDPARANOIA="yes")
 582     if test "x$FOUND_CDPARANOIA" != "xyes";
 583     then
 584       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 585                           cdda_open, -lm,
 586                           cdda/cdda_interface.h,
 587                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 588                           HEADER_DIR="yes"
 589                           FOUND_CDPARANOIA="yes")
 590     fi
 591     if test "x$HEADER_DIR" = "xyes";
 592     then
 593       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 594                          defined if cdda headers are in a cdda/ directory)
 595     fi
 596     if test "x$FOUND_CDPARANOIA" = "xyes";
 597     then
 598       AC_CHECK_LIB(cdda_paranoia,
 599                    paranoia_cachemodel_size,
 600                    : ,
 601                    HAVE_CDPARANOIA=no,
 602                  [-lcdda_interface])
 603     fi
 604
 605     AC_SUBST(CDPARANOIA_LIBS)
 606   ])
 607 ])
 608 dnl FIXME : add second check somehow if that is necessary
 609 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 610 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 611
 612 dnl *** ivorbis ***
 613 dnl AM_PATH_IVORBIS only takes two options
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 615 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 616   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 617   if test $HAVE_IVORBIS = no
 618   then
 619     IVORBIS_LIBS=
 620     IVORBIS_CFLAGS=
 621     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 622       [IVORBIS_LIBS=-lvorbisidec
 623       HAVE_IVORBIS=yes
 624       case $host in
 625       arm-*-*)
 626         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 627       esac
 628       ],
 629       HAVE_IVORBIS=no)
 630     AC_SUBST(IVORBIS_LIBS)
 631     AC_SUBST(IVORBIS_CFLAGS)
 632   else
 633     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 634       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 635       USE_TREMOLO=no)
 636   fi
 637 ])
 638
 639 dnl *** libvisual ***
 640 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 641 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 642   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 643   if test $HAVE_LIBVISUAL = no
 644   then
 645     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 646     if test x$HAVE_LIBVISUAL = xyes; then
 647       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 648     fi
 649   else
 650     if test x$HAVE_LIBVISUAL = xyes; then
 651       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 652     fi
 653   fi
 654   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 655   if test x$LIBVIS_PLUGINSDIR != x; then
 656     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 657         "$LIBVIS_PLUGINSDIR",
 658         [directory in which the detected libvisual's plugins are located])
 659   fi
 660 ])
 661
 662 dnl *** ogg ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 664 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 665   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 666   if test $HAVE_OGG = no
 667   then
 668     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 669     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 670   fi
 671 ])
 672
 673 dnl *** pango ***
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 675 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 676   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 677 ])
 678
 679 dnl *** theora ***
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 681 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 682   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 683 ])
 684
 685 dnl *** vorbis ***
 686 dnl AM_PATH_VORBIS only takes two options
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 688 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 689   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 690   if test $HAVE_VORBIS = no
 691   then
 692     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 693     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 694   fi
 695 ])
 696
 697 if test "x$HAVE_VORBIS" = "xyes"; then
 698   ac_cflags_save="$CFLAGS"
 699   AC_COMPILE_IFELSE([
 700     AC_LANG_PROGRAM([[
 701 #include <vorbis/codec.h>
 702                      ]],[[
 703 vorbis_dsp_state *v;
 704
 705 vorbis_synthesis_restart (v);
 706                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 707   if test "x$HAVE_VSR" = "xyes"; then
 708     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 709                        [defined if vorbis_synthesis_restart is present])
 710   fi
 711   CFLAGS="$ac_cflags_save"
 712 fi
 713
 714 else
 715
 716 dnl not building plugins with external dependencies,
 717 dnl but we still need to set the conditionals
 718 AM_CONDITIONAL(USE_ALSA, false)
 719 AM_CONDITIONAL(USE_CDPARANOIA, false)
 720 AM_CONDITIONAL(USE_IVORBIS, false)
 721 AM_CONDITIONAL(USE_LIBVISUAL, false)
 722 AM_CONDITIONAL(USE_OGG, false)
 723 AM_CONDITIONAL(USE_PANGO, false)
 724 AM_CONDITIONAL(USE_THEORA, false)
 725 AM_CONDITIONAL(USE_VORBIS, false)
 726
 727 fi dnl of EXT plugins
 728
 729 dnl seeking needs freetype, so check for it here
 730 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 731   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 732 ])
 733 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 734 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 735 AC_SUBST(FT2_CFLAGS)
 736 AC_SUBST(FT2_LIBS)
 737
 738 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 739
 740 dnl Overview:
 741 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 742 dnl GST_*:              flags shared by built objects to link against GStreamer
 743 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 744 dnl                          (compare to other modules) or for i18n
 745 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 746 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 747 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 748 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 749
 750 dnl GST_OPTION_CFLAGS
 751 if test "x$USE_DEBUG" = xyes; then
 752    PROFILE_CFLAGS="-g"
 753 fi
 754 AC_SUBST(PROFILE_CFLAGS)
 755
 756 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 757   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 758   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 759 else
 760   DEPRECATED_CFLAGS=""
 761 fi
 762 AC_SUBST(DEPRECATED_CFLAGS)
 763
 764 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 765 dnl at make time with e.g. make ERROR_CFLAGS=""
 766 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 767 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 768 AC_SUBST(GST_OPTION_CFLAGS)
 769 AC_SUBST(GST_OPTION_CXXFLAGS)
 770
 771 dnl our libraries need to be versioned correctly
 772 AC_SUBST(GST_LT_LDFLAGS)
 773
 774 dnl GST_PLUGINS_BASE_CFLAGS
 775 dnl prefer internal headers to already installed ones
 776 dnl also add builddir include for enumtypes and marshal
 777 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 778 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 779
 780 dnl FIXME: do we want to rename to GST_ALL_* ?
 781 dnl add GST_OPTION_CFLAGS, but overridable
 782 GST_CFLAGS="$GST_CFLAGS"
 783 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 784 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 785 AC_SUBST(GST_CFLAGS)
 786 AC_SUBST(GST_CXXFLAGS)
 787 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 788 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 789 AC_SUBST(GST_LIBS)
 790
 791 dnl LDFLAGS really should only contain flags, not libs - they get added before
 792 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 793 GST_ALL_LDFLAGS="-no-undefined"
 794 if test "x${enable_Bsymbolic}" = "xyes"; then
 795   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 796 fi
 797 AC_SUBST(GST_ALL_LDFLAGS)
 798
 799 dnl GST_LIB_LDFLAGS
 800 dnl linker flags shared by all libraries
 801 dnl LDFLAGS modifier defining exported symbols from built libraries
 802 dnl (export _gst_foo but not __gst_foo)
 803 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 804 AC_SUBST(GST_LIB_LDFLAGS)
 805
 806 dnl this really should only contain flags, not libs - they get added before
 807 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 808 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 809 AC_SUBST(GST_PLUGIN_LDFLAGS)
 810
 811 dnl *** output files ***
 812
 813 AC_CONFIG_FILES(
 814 Makefile
 815 gst-plugins-base.spec
 816 gst/Makefile
 817 gst/adder/Makefile
 818 gst/app/Makefile
 819 gst/audioconvert/Makefile
 820 gst/audiorate/Makefile
 821 gst/audiotestsrc/Makefile
 822 gst/encoding/Makefile
 823 gst/videoconvert/Makefile
 824 gst/gio/Makefile
 825 gst/playback/Makefile
 826 gst/audioresample/Makefile
 827 gst/subparse/Makefile
 828 gst/tcp/Makefile
 829 gst/typefind/Makefile
 830 gst/videotestsrc/Makefile
 831 gst/videorate/Makefile
 832 gst/videoscale/Makefile
 833 gst/volume/Makefile
 834 sys/Makefile
 835 sys/ximage/Makefile
 836 sys/xvimage/Makefile
 837 ext/Makefile
 838 ext/alsa/Makefile
 839 ext/cdparanoia/Makefile
 840 ext/libvisual/Makefile
 841 ext/ogg/Makefile
 842 ext/pango/Makefile
 843 ext/theora/Makefile
 844 ext/vorbis/Makefile
 845 gst-libs/Makefile
 846 gst-libs/gst/Makefile
 847 gst-libs/gst/audio/Makefile
 848 gst-libs/gst/app/Makefile
 849 gst-libs/gst/fft/Makefile
 850 gst-libs/gst/riff/Makefile
 851 gst-libs/gst/rtp/Makefile
 852 gst-libs/gst/rtsp/Makefile
 853 gst-libs/gst/sdp/Makefile
 854 gst-libs/gst/tag/Makefile
 855 gst-libs/gst/pbutils/Makefile
 856 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 857 gst-libs/gst/video/Makefile
 858 tools/Makefile
 859 pkgconfig/Makefile
 860 pkgconfig/gstreamer-audio.pc
 861 pkgconfig/gstreamer-audio-uninstalled.pc
 862 pkgconfig/gstreamer-app.pc
 863 pkgconfig/gstreamer-app-uninstalled.pc
 864 pkgconfig/gstreamer-fft.pc
 865 pkgconfig/gstreamer-fft-uninstalled.pc
 866 pkgconfig/gstreamer-pbutils.pc
 867 pkgconfig/gstreamer-pbutils-uninstalled.pc
 868 pkgconfig/gstreamer-riff.pc
 869 pkgconfig/gstreamer-riff-uninstalled.pc
 870 pkgconfig/gstreamer-rtp.pc
 871 pkgconfig/gstreamer-rtp-uninstalled.pc
 872 pkgconfig/gstreamer-rtsp.pc
 873 pkgconfig/gstreamer-rtsp-uninstalled.pc
 874 pkgconfig/gstreamer-sdp.pc
 875 pkgconfig/gstreamer-sdp-uninstalled.pc
 876 pkgconfig/gstreamer-tag.pc
 877 pkgconfig/gstreamer-tag-uninstalled.pc
 878 pkgconfig/gstreamer-video.pc
 879 pkgconfig/gstreamer-video-uninstalled.pc
 880 pkgconfig/gstreamer-plugins-base.pc
 881 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 882 tests/Makefile
 883 tests/check/Makefile
 884 tests/examples/Makefile
 885 tests/examples/app/Makefile
 886 tests/examples/audio/Makefile
 887 tests/examples/dynamic/Makefile
 888 tests/examples/encoding/Makefile
 889 tests/examples/fft/Makefile
 890 tests/examples/gio/Makefile
 891 tests/examples/overlay/Makefile
 892 tests/examples/seek/Makefile
 893 tests/examples/snapshot/Makefile
 894 tests/examples/playback/Makefile
 895 tests/examples/playrec/Makefile
 896 tests/files/Makefile
 897 tests/icles/Makefile
 898 tests/icles/playback/Makefile
 899 docs/Makefile
 900 docs/design/Makefile
 901 docs/libs/Makefile
 902 docs/plugins/Makefile
 903 docs/version.entities
 904 po/Makefile.in
 905 common/Makefile
 906 common/m4/Makefile
 907 m4/Makefile
 908 )
 909
 910 dnl Create the config.h file for Visual Studio builds
 911 dnl Beware of spaces and /'s in some of the shell variable contents.
 912 sed \
 913     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 914     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 915     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 916     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 917     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 918     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 919     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 920     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 921     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 922     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 923     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 924     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 925     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 926     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 927     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 928     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 929     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 930     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 931     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 932     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 933     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 934     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 935     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 936     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 937     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 938     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 939     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 940     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 941     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 942     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 943     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 944     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 945     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 946     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 947     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 948     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 949     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 950     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 951     config.h.in >win32/common/config.h-new
 952
 953
 954
 955 AC_OUTPUT
 956
 957 AG_GST_OUTPUT_PLUGINS
 958 ORC_OUTPUT
 959