configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.35.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 24, 0, 24)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.35.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl used in gst/ffmpegcolorspace/mem.c
 175 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 176 AC_CHECK_HEADERS([malloc.h])
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE(
 181   AC_LANG_PROGRAM([
 182 #include <libxml/HTMLparser.h>
 183                      ],[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 188 CPPFLAGS="$ac_cppflags_save"
 189 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/rtsp
 197 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 198 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 199   WIN32_LIBS="-lws2_32"
 200   AC_SUBST(WIN32_LIBS)
 201 fi
 202
 203 dnl check for hstrerror, for gst-libs/gst/rtsp
 204 save_libs="$LIBS"
 205 AC_CHECK_FUNC(hstrerror, ,
 206     AC_CHECK_LIB(resolv, hstrerror, ,
 207         [AC_DEFINE(NO_HSTRERROR, 1,
 208              [Define if you have no native hstrerror() function.])]))
 209 HSTRERROR_LIBS=$LIBS
 210 AC_SUBST(HSTRERROR_LIBS)
 211 LIBS="$save_libs"
 212
 213 dnl used in gst-libs/gst/pbutils and associated unit test
 214 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 215
 216 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 217
 218 dnl ffmpegcolorspace includes _stdint.h
 219 dnl also, Windows does not have long long
 220 AX_CREATE_STDINT_H
 221
 222 dnl *** checks for functions ***
 223 AC_CHECK_FUNCS([localtime_r gmtime_r])
 224
 225 dnl *** checks for math functions ***
 226 LIBS_SAVE=$LIBS
 227 LIBS="$LIBS $LIBM"
 228 AC_CHECK_FUNCS(log2)
 229 LIBS=$LIBS_SAVE
 230
 231 dnl *** checks for types/defines ***
 232
 233 dnl Check for FIONREAD ioctl declaration
 234 dnl used in gst/tcp
 235 GST_CHECK_FIONREAD
 236
 237 dnl *** checks for structures ***
 238
 239 dnl *** checks for compiler characteristics ***
 240
 241 dnl *** checks for library functions ***
 242
 243 dnl check for fseeko()
 244 AC_FUNC_FSEEKO
 245
 246 dnl Check for fast float to int casting as defined in C99
 247 dnl used in gst-libs/gst/floatcast/floatcast.h
 248 save_libs=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_C99_FUNC_LRINT
 251 AC_C99_FUNC_LRINTF
 252 LIBS=$save_libs
 253
 254 dnl Check for a way to display the function name in debug output
 255 AG_GST_CHECK_FUNCTION
 256
 257 dnl *** checks for socket and nsl libraries ***
 258 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 259 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 260
 261 dnl *** checks for dependency libraries ***
 262
 263 dnl GLib is required
 264 AG_GST_GLIB_CHECK([2.24])
 265
 266 ORC_CHECK([0.4.11])
 267
 268 dnl checks for gstreamer
 269 dnl uninstalled is selected preferentially -- see pkg-config(1)
 270 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 271 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 273 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 274 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 275 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 276
 277 dnl Check for documentation xrefs
 278 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 279 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 280 AC_SUBST(GLIB_PREFIX)
 281 AC_SUBST(GST_PREFIX)
 282
 283 dnl GTK is optional and only used in examples
 284 HAVE_GTK=no
 285 HAVE_GTK_X11=no
 286 GTK2_REQ=2.14.0
 287 GTK3_REQ=2.91.3
 288 if test "x$BUILD_EXAMPLES" = "xyes"; then
 289   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 290   AC_ARG_WITH([gtk],
 291     AC_HELP_STRING([--with-gtk=3.0|2.0],
 292                    [which gtk+ version to compile against (default: 2.0)]),
 293     [case "$with_gtk" in
 294         2.0) GTK_REQ=$GTK2_REQ ;;
 295         3.0) GTK_REQ=$GTK3_REQ ;;
 296         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 297     esac],
 298     [with_gtk=2.0
 299      GTK_REQ=$GTK2_REQ])
 300   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 301   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 302   dnl some examples need gtk+-x11
 303   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 304   AC_SUBST(GTK_LIBS)
 305   AC_SUBST(GTK_CFLAGS)
 306 fi
 307 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 308 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 309
 310 dnl QT is optional and only used in examples
 311 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 312   HAVE_QT_GV=yes
 313   HAVE_QT=yes
 314 ], [
 315   HAVE_QT_GV=no
 316   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 317 ])
 318 if test "x$HAVE_QT" = "xyes"; then
 319   AC_MSG_CHECKING([Qt moc])
 320   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 321   AC_MSG_RESULT($QT4_MOC)
 322   AC_SUBST(QT4_MOC)
 323 fi
 324 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 325 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 326
 327 dnl chck for linux headers needed by the joystick seek example
 328 AC_COMPILE_IFELSE(
 329 [
 330   AC_LANG_PROGRAM([
 331     #include <linux/input.h>
 332     #include <linux/joystick.h>
 333   ],[
 334     struct js_event js;
 335     js.type = JS_EVENT_AXIS;
 336   ])
 337 ], [
 338   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 339 ], [
 340   HAVE_LINUX_JOYSTICK_HEADERS="no"
 341 ])
 342 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 343
 344 dnl Check for -Bsymbolic-functions linker flag used to avoid
 345 dnl intra-library PLT jumps, if available.
 346 AC_ARG_ENABLE(Bsymbolic,
 347               [AC_HELP_STRING([--disable-Bsymbolic],
 348                               [avoid linking with -Bsymbolic])],,
 349               [SAVED_LDFLAGS="${LDFLAGS}"
 350                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 351                LDFLAGS=-Wl,-Bsymbolic-functions
 352                AC_TRY_LINK([], [int main (void) { return 0; }],
 353                            AC_MSG_RESULT(yes)
 354                            enable_Bsymbolic=yes,
 355                            AC_MSG_RESULT(no)
 356                            enable_Bsymbolic=no)
 357                LDFLAGS="${SAVED_LDFLAGS}"])
 358
 359
 360 dnl *** set variables based on configure arguments ***
 361
 362 dnl set license and copyright notice
 363 GST_LICENSE="LGPL"
 364 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 365 AC_SUBST(GST_LICENSE)
 366
 367 dnl set location of plugin directory
 368 AG_GST_SET_PLUGINDIR
 369
 370 dnl set release date/time
 371 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 372   ["${srcdir}/gst-plugins-base.doap"],
 373   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 374
 375 dnl define an ERROR_CFLAGS Makefile variable
 376 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 377 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 378     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 379     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 380     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 381     -Wno-multichar -Wnested-externs ])
 382
 383 dnl define an ERROR_CXXFLAGS Makefile variable
 384 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 385     -Wmissing-declarations -Wredundant-decls -Wundef
 386     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 387     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 388     -Wno-multichar])
 389
 390 dnl define correct level for debugging messages
 391 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 392
 393 dnl used in examples
 394 AG_GST_DEFAULT_ELEMENTS
 395
 396 dnl needed for encoding-target
 397 GST_DATADIR="$GST_PREFIX/share"
 398 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 399 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 400
 401 dnl behaviour of speex based audio resampler
 402 AC_MSG_CHECKING(which audio resample format to use for integer)
 403 AC_ARG_WITH([audioresample_format],
 404         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 405         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 406 AC_MSG_RESULT($ac_cv_audioresample_format)
 407 case $ac_cv_audioresample_format in
 408   int)
 409     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 410     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 411   ;;
 412   float)
 413     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 414     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 415   ;;
 416   auto)
 417     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 418     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 419 esac
 420
 421 dnl *** plug-ins to include ***
 422
 423 dnl these are all the gst plug-ins, compilable without additional libs
 424 AG_GST_CHECK_PLUGIN(adder)
 425 AG_GST_CHECK_PLUGIN(app)
 426 AG_GST_CHECK_PLUGIN(audioconvert)
 427 AG_GST_CHECK_PLUGIN(audiorate)
 428 AG_GST_CHECK_PLUGIN(audiotestsrc)
 429 AG_GST_CHECK_PLUGIN(encoding)
 430 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 431 AG_GST_CHECK_PLUGIN(gdp)
 432 AG_GST_CHECK_PLUGIN(playback)
 433 AG_GST_CHECK_PLUGIN(audioresample)
 434 AG_GST_CHECK_PLUGIN(subparse)
 435 AG_GST_CHECK_PLUGIN(tcp)
 436 AG_GST_CHECK_PLUGIN(typefind)
 437 AG_GST_CHECK_PLUGIN(videotestsrc)
 438 AG_GST_CHECK_PLUGIN(videorate)
 439 AG_GST_CHECK_PLUGIN(videoscale)
 440 AG_GST_CHECK_PLUGIN(volume)
 441
 442 dnl check for gstreamer core features (subsystems)
 443 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 444 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 445 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 446 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 447
 448 dnl disable plug-ins that require libxml2's HTML support if it is not available
 449 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 450   AG_GST_DISABLE_PLUGIN(subparse)
 451 fi
 452
 453 dnl disable plug-ins that require sys/socket.h if it is not available
 454 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 455   AG_GST_DISABLE_PLUGIN(tcp)
 456 fi
 457
 458 dnl iso-codes is optional, used by libgsttag
 459 AC_ARG_ENABLE(iso-codes,
 460 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 461 [case "${enableval}" in
 462   yes) enable_iso_codes=yes ;;
 463   no)  enable_iso_codes=no ;;
 464   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 465 esac
 466 ],
 467 [enable_iso_codes=yes]) dnl Default value
 468
 469 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 470 if test "x$enable_iso_codes" = "xyes"; then
 471   AC_MSG_RESULT([yes])
 472   have_iso_codes=no
 473   AC_MSG_CHECKING([whether iso-codes are available on this system])
 474   if $PKG_CONFIG iso-codes; then
 475     AC_MSG_RESULT([yes])
 476     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 477     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 478       AC_MSG_RESULT([yes])
 479       AC_MSG_CHECKING([for iso-codes prefix])
 480       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 481       if test -d "$ISO_CODES_PREFIX"; then
 482         AC_MSG_RESULT([yes])
 483         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 484         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 485         ISO_639_DOMAIN="iso_639"
 486         AC_MSG_CHECKING([ISO_639_DOMAIN])
 487         AC_MSG_RESULT([$ISO_639_DOMAIN])
 488         have_iso_codes=yes
 489         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 490         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 491         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 492         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 493       else
 494         AC_MSG_RESULT([no])
 495       fi
 496     else
 497       AC_MSG_RESULT([no])
 498     fi
 499   else
 500     AC_MSG_RESULT([no])
 501   fi
 502   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 503 else
 504   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 505   AM_CONDITIONAL(USE_ISO_CODES, false)
 506 fi
 507
 508 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 510 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 511   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 512       HAVE_ZLIB="yes"
 513     ], [
 514       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 515         HAVE_ZLIB="yes"
 516         ZLIB_LIBS="-lz"
 517         AC_SUBST(ZLIB_LIBS)
 518       ])
 519     ])
 520 ])
 521
 522 dnl *** sys plug-ins ***
 523
 524 echo
 525 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 526 echo
 527
 528 dnl *** X11 ***
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 530 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 531                   [ximagesink], [
 532   AC_PATH_XTRA
 533   ac_cflags_save="$CFLAGS"
 534   ac_cppflags_save="$CPPFLAGS"
 535   CFLAGS="$CFLAGS $X_CFLAGS"
 536   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 537
 538   dnl now try to find the HEADER
 539   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 540
 541   if test "x$HAVE_X" = "xno"
 542   then
 543     AC_MSG_NOTICE([cannot find X11 development files])
 544   else
 545     dnl this is much more than we want
 546     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 547     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 548     dnl it does not add the libs; therefore we add them here
 549     X_LIBS="$X_LIBS -lX11"
 550     AC_SUBST(X_CFLAGS)
 551     AC_SUBST(X_LIBS)
 552   fi
 553   AC_SUBST(HAVE_X)
 554   CFLAGS="$ac_cflags_save"
 555   CPPFLAGS="$ac_cppflags_save"
 556 ])
 557
 558 dnl Check for Xv extension
 559 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 560 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 561                   [xvimagesink], [
 562   AG_GST_CHECK_XV
 563 ])
 564
 565 dnl check for X Shm
 566 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 567 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 568   if test x$HAVE_X = xyes; then
 569     AC_CHECK_LIB(Xext, XShmAttach,
 570                  HAVE_XSHM="yes", HAVE_XSHM="no",
 571                  $X_LIBS)
 572     if test "x$HAVE_XSHM" = "xyes"; then
 573       XSHM_LIBS="-lXext"
 574     else
 575       dnl On AIX, it is in XextSam instead, but we still need -lXext
 576       AC_CHECK_LIB(XextSam, XShmAttach,
 577                    HAVE_XSHM="yes", HAVE_XSHM="no",
 578                    $X_LIBS)
 579       if test "x$HAVE_XSHM" = "xyes"; then
 580         XSHM_LIBS="-lXext -lXextSam"
 581       fi
 582     fi
 583   fi
 584 ], , [
 585   AC_SUBST(HAVE_XSHM)
 586   AC_SUBST(XSHM_LIBS)
 587 ])
 588
 589 dnl v4l/v4l2 checks have been moved down because they require X
 590
 591 dnl *** Video 4 Linux ***
 592 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 593 dnl renamed to GST_V4L in accordance with V4L2 below
 594 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 595 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 596   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 597 #include <sys/types.h>
 598 #define _LINUX_TIME_H
 599 #define __user
 600 #include <linux/videodev.h>
 601   ])
 602
 603   dnl we can build v4l without Xv, but then we won't have XOverlay support
 604   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 605   then
 606     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 607     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 608   fi
 609 ])
 610
 611 # Optional gudev for device probing
 612 AC_ARG_WITH([gudev],
 613   AC_HELP_STRING([--with-gudev],
 614     [device detection with gudev]),
 615   [],
 616   [with_gudev=check])
 617 if test x$HAVE_GST_V4L = xyes; then
 618   if test x$with_gudev != xno; then
 619       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 620           [ have_gudev=yes
 621             AC_DEFINE(HAVE_GUDEV, 1,
 622                [Whether gudev is available for device detection])
 623             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 624           ], [
 625           have_gudev=no
 626           ])
 627   else
 628     have_gudev=no
 629   fi
 630 fi
 631 AC_SUBST(GUDEV_CFLAGS)
 632 AC_SUBST(GUDEV_LIBS)
 633
 634 dnl *** ext plug-ins ***
 635 dnl keep this list sorted alphabetically !
 636
 637 if test "x$BUILD_EXTERNAL" = "xyes"; then
 638
 639 echo
 640 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 641 echo
 642
 643 dnl *** alsa ***
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 645 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 646   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 647     HAVE_ALSA="yes"
 648     AC_SUBST(ALSA_CFLAGS)
 649     AC_SUBST(ALSA_LIBS)
 650   ], [
 651     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 652   ])
 653 ])
 654
 655 dnl *** CDParanoia ***
 656 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 658 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 659   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 660     HAVE_CDPARANOIA="yes"
 661   ], [
 662     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 663                         cdda_open, -lm,
 664                         cdda_interface.h,
 665                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 666                         HEADER_DIR="no"
 667                         FOUND_CDPARANOIA="yes")
 668     if test "x$FOUND_CDPARANOIA" != "xyes";
 669     then
 670       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 671                           cdda_open, -lm,
 672                           cdda/cdda_interface.h,
 673                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 674                           HEADER_DIR="yes"
 675                           FOUND_CDPARANOIA="yes")
 676     fi
 677     if test "x$HEADER_DIR" = "xyes";
 678     then
 679       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 680                          defined if cdda headers are in a cdda/ directory)
 681     fi
 682     if test "x$FOUND_CDPARANOIA" = "xyes";
 683     then
 684       AC_CHECK_LIB(cdda_paranoia,
 685                    paranoia_cachemodel_size,
 686                    : ,
 687                    HAVE_CDPARANOIA=no,
 688                  [-lcdda_interface])
 689     fi
 690
 691     AC_SUBST(CDPARANOIA_LIBS)
 692   ])
 693 ])
 694 dnl FIXME : add second check somehow if that is necessary
 695 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 696 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 697
 698 dnl *** GNOME VFS ***
 699 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 700 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 701   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 702       HAVE_GNOME_VFS="yes"
 703       AC_SUBST(GNOME_VFS_CFLAGS)
 704       AC_SUBST(GNOME_VFS_LIBS)
 705       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 706       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 707              [The GnomeVFS modules directory.])
 708     ],[
 709       HAVE_GNOME_VFS="no"
 710     ]
 711     )
 712 ])
 713
 714 dnl *** ivorbis ***
 715 dnl AM_PATH_IVORBIS only takes two options
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 717 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 718   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 719   if test $HAVE_IVORBIS = no
 720   then
 721     IVORBIS_LIBS=
 722     IVORBIS_CFLAGS=
 723     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 724       [IVORBIS_LIBS=-lvorbisidec
 725       HAVE_IVORBIS=yes
 726       case $host in
 727       arm-*-*)
 728         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 729       esac
 730       ],
 731       HAVE_IVORBIS=no)
 732     AC_SUBST(IVORBIS_LIBS)
 733     AC_SUBST(IVORBIS_CFLAGS)
 734   else
 735     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 736       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 737       USE_TREMOLO=no)
 738   fi
 739 ])
 740
 741 dnl *** libgio ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 743 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 744   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 745     HAVE_GIO="yes"
 746     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 747     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 748            [The GIO modules directory.])
 749     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 750     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 751            [The GIO library directory.])
 752   ], [
 753     HAVE_GIO="no"
 754   ])
 755   AC_SUBST(GIO_CFLAGS)
 756   AC_SUBST(GIO_LIBS)
 757   AC_SUBST(GIO_LDFLAGS)
 758 ])
 759
 760 dnl *** libvisual ***
 761 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 762 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 763   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 764   if test $HAVE_LIBVISUAL = no
 765   then
 766     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 767     if test x$HAVE_LIBVISUAL = xyes; then
 768       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 769     fi
 770   else
 771     if test x$HAVE_LIBVISUAL = xyes; then
 772       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 773     fi
 774   fi
 775   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 776   if test x$LIBVIS_PLUGINSDIR != x; then
 777     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 778         "$LIBVIS_PLUGINSDIR",
 779         [directory in which the detected libvisual's plugins are located])
 780   fi
 781 ])
 782
 783 dnl *** ogg ***
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 785 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 786   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 787   if test $HAVE_OGG = no
 788   then
 789     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 790     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 791   fi
 792 ])
 793
 794 dnl *** pango ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 796 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 797   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 798 ])
 799
 800 dnl *** theora ***
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 802 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 803   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 804 ])
 805
 806 dnl *** vorbis ***
 807 dnl AM_PATH_VORBIS only takes two options
 808 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 809 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 810   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 811   if test $HAVE_VORBIS = no
 812   then
 813     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 814     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 815   fi
 816 ])
 817
 818 if test "x$HAVE_VORBIS" = "xyes"; then
 819   ac_cflags_save="$CFLAGS"
 820   AC_COMPILE_IFELSE(
 821     AC_LANG_PROGRAM([
 822 #include <vorbis/codec.h>
 823                      ],[
 824 vorbis_dsp_state *v;
 825
 826 vorbis_synthesis_restart (v);
 827                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 828   if test "x$HAVE_VSR" = "xyes"; then
 829     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 830                        [defined if vorbis_synthesis_restart is present])
 831   fi
 832   CFLAGS="$ac_cflags_save"
 833 fi
 834
 835 else
 836
 837 dnl not building plugins with external dependencies,
 838 dnl but we still need to set the conditionals
 839 AM_CONDITIONAL(USE_ALSA, false)
 840 AM_CONDITIONAL(USE_CDPARANOIA, false)
 841 AM_CONDITIONAL(USE_GIO, false)
 842 AM_CONDITIONAL(USE_GNOME_VFS, false)
 843 AM_CONDITIONAL(USE_IVORBIS, false)
 844 AM_CONDITIONAL(USE_LIBVISUAL, false)
 845 AM_CONDITIONAL(USE_OGG, false)
 846 AM_CONDITIONAL(USE_PANGO, false)
 847 AM_CONDITIONAL(USE_THEORA, false)
 848 AM_CONDITIONAL(USE_VORBIS, false)
 849
 850 fi dnl of EXT plugins
 851
 852 dnl seeking needs freetype, so check for it here
 853 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 854   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 855 ])
 856 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 857 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 858 AC_SUBST(FT2_CFLAGS)
 859 AC_SUBST(FT2_LIBS)
 860
 861 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 862
 863 dnl Overview:
 864 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 865 dnl GST_*:              flags shared by built objects to link against GStreamer
 866 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 867 dnl                          (compare to other modules) or for i18n
 868 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 869 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 870 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 871 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 872
 873 dnl GST_OPTION_CFLAGS
 874 if test "x$USE_DEBUG" = xyes; then
 875    PROFILE_CFLAGS="-g"
 876 fi
 877 AC_SUBST(PROFILE_CFLAGS)
 878
 879 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 880   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 881   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 882 else
 883   DEPRECATED_CFLAGS=""
 884 fi
 885 AC_SUBST(DEPRECATED_CFLAGS)
 886
 887 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 888 dnl at make time with e.g. make ERROR_CFLAGS=""
 889 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 890 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 891 AC_SUBST(GST_OPTION_CFLAGS)
 892 AC_SUBST(GST_OPTION_CXXFLAGS)
 893
 894 dnl our libraries need to be versioned correctly
 895 AC_SUBST(GST_LT_LDFLAGS)
 896
 897 dnl GST_PLUGINS_BASE_CFLAGS
 898 dnl prefer internal headers to already installed ones
 899 dnl also add builddir include for enumtypes and marshal
 900 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 901 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 902
 903 dnl FIXME: do we want to rename to GST_ALL_* ?
 904 dnl add GST_OPTION_CFLAGS, but overridable
 905 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 906 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 907 AC_SUBST(GST_CFLAGS)
 908 AC_SUBST(GST_CXXFLAGS)
 909 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 910 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 911 AC_SUBST(GST_LIBS)
 912
 913 dnl LDFLAGS really should only contain flags, not libs - they get added before
 914 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 915 GST_ALL_LDFLAGS="-no-undefined"
 916 if test "x${enable_Bsymbolic}" = "xyes"; then
 917   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 918 fi
 919 AC_SUBST(GST_ALL_LDFLAGS)
 920
 921 dnl GST_LIB_LDFLAGS
 922 dnl linker flags shared by all libraries
 923 dnl LDFLAGS modifier defining exported symbols from built libraries
 924 dnl (export _gst_foo but not __gst_foo)
 925 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 926 AC_SUBST(GST_LIB_LDFLAGS)
 927
 928 dnl this really should only contain flags, not libs - they get added before
 929 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 930 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 931 AC_SUBST(GST_PLUGIN_LDFLAGS)
 932
 933 dnl *** output files ***
 934
 935 AC_CONFIG_FILES(
 936 Makefile
 937 gst-plugins-base.spec
 938 gst/Makefile
 939 gst/adder/Makefile
 940 gst/app/Makefile
 941 gst/audioconvert/Makefile
 942 gst/audiorate/Makefile
 943 gst/audiotestsrc/Makefile
 944 gst/encoding/Makefile
 945 gst/ffmpegcolorspace/Makefile
 946 gst/gdp/Makefile
 947 gst/playback/Makefile
 948 gst/audioresample/Makefile
 949 gst/subparse/Makefile
 950 gst/tcp/Makefile
 951 gst/typefind/Makefile
 952 gst/videotestsrc/Makefile
 953 gst/videorate/Makefile
 954 gst/videoscale/Makefile
 955 gst/volume/Makefile
 956 sys/Makefile
 957 sys/ximage/Makefile
 958 sys/xvimage/Makefile
 959 sys/v4l/Makefile
 960 ext/Makefile
 961 ext/alsa/Makefile
 962 ext/cdparanoia/Makefile
 963 ext/gnomevfs/Makefile
 964 ext/gio/Makefile
 965 ext/libvisual/Makefile
 966 ext/ogg/Makefile
 967 ext/pango/Makefile
 968 ext/theora/Makefile
 969 ext/vorbis/Makefile
 970 gst-libs/Makefile
 971 gst-libs/gst/Makefile
 972 gst-libs/gst/audio/Makefile
 973 gst-libs/gst/app/Makefile
 974 gst-libs/gst/cdda/Makefile
 975 gst-libs/gst/fft/Makefile
 976 gst-libs/gst/floatcast/Makefile
 977 gst-libs/gst/interfaces/Makefile
 978 gst-libs/gst/netbuffer/Makefile
 979 gst-libs/gst/riff/Makefile
 980 gst-libs/gst/rtp/Makefile
 981 gst-libs/gst/rtsp/Makefile
 982 gst-libs/gst/sdp/Makefile
 983 gst-libs/gst/tag/Makefile
 984 gst-libs/gst/pbutils/Makefile
 985 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 986 gst-libs/gst/video/Makefile
 987 tools/Makefile
 988 pkgconfig/Makefile
 989 pkgconfig/gstreamer-audio.pc
 990 pkgconfig/gstreamer-audio-uninstalled.pc
 991 pkgconfig/gstreamer-app.pc
 992 pkgconfig/gstreamer-app-uninstalled.pc
 993 pkgconfig/gstreamer-cdda.pc
 994 pkgconfig/gstreamer-cdda-uninstalled.pc
 995 pkgconfig/gstreamer-fft.pc
 996 pkgconfig/gstreamer-fft-uninstalled.pc
 997 pkgconfig/gstreamer-floatcast.pc
 998 pkgconfig/gstreamer-floatcast-uninstalled.pc
 999 pkgconfig/gstreamer-interfaces.pc
1000 pkgconfig/gstreamer-interfaces-uninstalled.pc
1001 pkgconfig/gstreamer-netbuffer.pc
1002 pkgconfig/gstreamer-netbuffer-uninstalled.pc
1003 pkgconfig/gstreamer-pbutils.pc
1004 pkgconfig/gstreamer-pbutils-uninstalled.pc
1005 pkgconfig/gstreamer-riff.pc
1006 pkgconfig/gstreamer-riff-uninstalled.pc
1007 pkgconfig/gstreamer-rtp.pc
1008 pkgconfig/gstreamer-rtp-uninstalled.pc
1009 pkgconfig/gstreamer-rtsp.pc
1010 pkgconfig/gstreamer-rtsp-uninstalled.pc
1011 pkgconfig/gstreamer-sdp.pc
1012 pkgconfig/gstreamer-sdp-uninstalled.pc
1013 pkgconfig/gstreamer-tag.pc
1014 pkgconfig/gstreamer-tag-uninstalled.pc
1015 pkgconfig/gstreamer-video.pc
1016 pkgconfig/gstreamer-video-uninstalled.pc
1017 pkgconfig/gstreamer-plugins-base.pc
1018 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1019 tests/Makefile
1020 tests/check/Makefile
1021 tests/examples/Makefile
1022 tests/examples/app/Makefile
1023 tests/examples/audio/Makefile
1024 tests/examples/dynamic/Makefile
1025 tests/examples/encoding/Makefile
1026 tests/examples/gio/Makefile
1027 tests/examples/overlay/Makefile
1028 tests/examples/seek/Makefile
1029 tests/examples/snapshot/Makefile
1030 tests/examples/playrec/Makefile
1031 tests/examples/volume/Makefile
1032 tests/examples/v4l/Makefile
1033 tests/files/Makefile
1034 tests/icles/Makefile
1035 tests/icles/playback/Makefile
1036 docs/Makefile
1037 docs/design/Makefile
1038 docs/libs/Makefile
1039 docs/plugins/Makefile
1040 docs/version.entities
1041 po/Makefile.in
1042 common/Makefile
1043 common/m4/Makefile
1044 m4/Makefile
1045 )
1046
1047 dnl Create the config.h file for Visual Studio builds
1048 dnl Beware of spaces and /'s in some of the shell variable contents.
1049 sed \
1050     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1051     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1052     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1053     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1054     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1055     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1056     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1057     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1058     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1059     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1060     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1061     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1062     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1063     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1064     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1065     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1066     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1067     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1068     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1069     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1070     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1071     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1072     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1073     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1074     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1075     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1076     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1077     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1078     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1079     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1080     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1081     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1082     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1083     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1084     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1085     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1086     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1087     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1088     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1089     config.h.in >win32/common/config.h-new
1090
1091
1092
1093 AC_OUTPUT
1094
1095 AG_GST_OUTPUT_PLUGINS
1096 ORC_OUTPUT
1097