configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/rtp/gstasteriskh263.c
 153 AC_CHECK_HEADERS([netinet/in.h])
 154 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 155 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/time.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205 dnl GLib is required
 206 AG_GST_GLIB_CHECK([2.20])
 207
 208 dnl Orc
 209 ORC_CHECK([0.4.11])
 210
 211 dnl checks for gstreamer
 212 dnl uninstalled is selected preferentially -- see pkg-config(1)
 213 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK2_REQ=2.14.0
 243 GTK3_REQ=2.91.3
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 246   AC_ARG_WITH([gtk],
 247     AC_HELP_STRING([--with-gtk=3.0|2.0],
 248                    [which gtk+ version to compile against (default: 2.0)]),
 249     [case "$with_gtk" in
 250         2.0) GTK_REQ=$GTK2_REQ ;;
 251         3.0) GTK_REQ=$GTK3_REQ ;;
 252         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 253     esac],
 254     [with_gtk=2.0
 255      GTK_REQ=$GTK2_REQ])
 256   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 257   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 258   dnl some examples need gtk+-x11
 259   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 260   AC_SUBST(GTK_LIBS)
 261   AC_SUBST(GTK_CFLAGS)
 262 fi
 263 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 264 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 265
 266 dnl *** set variables based on configure arguments ***
 267
 268 dnl set license and copyright notice
 269 GST_LICENSE="LGPL"
 270 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 271 AC_SUBST(GST_LICENSE)
 272
 273 dnl set location of plugin directory
 274 AG_GST_SET_PLUGINDIR
 275
 276 dnl set release date/time
 277 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 278   ["${srcdir}/gst-plugins-good.doap"],
 279   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 280
 281 dnl define an ERROR_CFLAGS Makefile variable
 282 dnl -Wundef: too many broken headers
 283 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 284   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 285         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 286         -Wwrite-strings -Wold-style-definition -Waggregate-return
 287         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 288         -Wnested-externs ])
 289 else
 290   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 291   dnl doesn't understand all warning flags that the C compiler knows about
 292   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 293   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 294         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 295         -Wwrite-strings -Wold-style-definition
 296         -Winit-self -Wmissing-include-dirs -Wno-multichar
 297         -Wnested-externs ])
 298 fi
 299
 300 dnl define an ERROR_CXXFLAGS Makefile variable
 301 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 302         -Wmissing-declarations -Wredundant-decls
 303         -Wwrite-strings
 304         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 305
 306 dnl define correct level for debugging messages
 307 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 308
 309 dnl used in examples
 310 AG_GST_DEFAULT_ELEMENTS
 311
 312 dnl *** plug-ins to include ***
 313
 314 dnl Non ported plugins (non-dependant, then dependant)
 315 dnl Make sure you have a space before and after all plugins
 316 GST_PLUGINS_NONPORTED="deinterlace flx goom2k1 \
 317  imagefreeze interleave monoscope smpte \
 318  videobox videomixer \
 319  cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 320  oss oss4 shout2 \
 321  taglib wavpack \
 322  osx_video osx_audio "
 323 AC_SUBST(GST_PLUGINS_NONPORTED)
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(effectv)
 338 AG_GST_CHECK_PLUGIN(equalizer)
 339 AG_GST_CHECK_PLUGIN(flv)
 340 AG_GST_CHECK_PLUGIN(flx)
 341 AG_GST_CHECK_PLUGIN(goom)
 342 AG_GST_CHECK_PLUGIN(goom2k1)
 343 AG_GST_CHECK_PLUGIN(icydemux)
 344 AG_GST_CHECK_PLUGIN(id3demux)
 345 AG_GST_CHECK_PLUGIN(imagefreeze)
 346 AG_GST_CHECK_PLUGIN(interleave)
 347 AG_GST_CHECK_PLUGIN(isomp4)
 348 AG_GST_CHECK_PLUGIN(law)
 349 AG_GST_CHECK_PLUGIN(level)
 350 AG_GST_CHECK_PLUGIN(matroska)
 351 AG_GST_CHECK_PLUGIN(monoscope)
 352 AG_GST_CHECK_PLUGIN(multifile)
 353 AG_GST_CHECK_PLUGIN(multipart)
 354 AG_GST_CHECK_PLUGIN(replaygain)
 355 AG_GST_CHECK_PLUGIN(rtp)
 356 AG_GST_CHECK_PLUGIN(rtpmanager)
 357 AG_GST_CHECK_PLUGIN(rtsp)
 358 AG_GST_CHECK_PLUGIN(shapewipe)
 359 AG_GST_CHECK_PLUGIN(smpte)
 360 AG_GST_CHECK_PLUGIN(spectrum)
 361 AG_GST_CHECK_PLUGIN(udp)
 362 AG_GST_CHECK_PLUGIN(videobox)
 363 AG_GST_CHECK_PLUGIN(videocrop)
 364 AG_GST_CHECK_PLUGIN(videofilter)
 365 AG_GST_CHECK_PLUGIN(videomixer)
 366 AG_GST_CHECK_PLUGIN(wavenc)
 367 AG_GST_CHECK_PLUGIN(wavparse)
 368 AG_GST_CHECK_PLUGIN(y4m)
 369
 370 dnl *** checks for socket and nsl libraries ***
 371 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 372
 373 dnl disable gst plugins we might not be able to build on this
 374 dnl platform: udp and rtsp (ugly but minimally invasive)
 375 dnl FIXME: maybe move to sys
 376 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 377 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 378
 379 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 380   AG_GST_DISABLE_PLUGIN(udp)
 381   AG_GST_DISABLE_PLUGIN(rtsp)
 382 fi
 383
 384 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 385   WIN32_LIBS="-lws2_32"
 386   AC_SUBST(WIN32_LIBS)
 387 fi
 388
 389 dnl disable experimental plug-ins
 390 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 391   AG_GST_DISABLE_PLUGIN(monoscope)
 392 fi
 393
 394 dnl *** sys plug-ins ***
 395
 396 echo
 397 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 398 echo
 399
 400 dnl DirectSound
 401 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 402 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 403   HAVE_DIRECTSOUND="no"
 404   save_CFLAGS="$CFLAGS"
 405   save_LDFLAGS="$LDFLAGS"
 406   save_LIBS="$LIBS"
 407   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 408   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 409   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 410   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 411   AC_LINK_IFELSE([
 412 #include <windows.h>
 413 #include <dxerr9.h>
 414 #include <dsound.h>
 415
 416 int main ()
 417 {
 418   DXGetErrorString9 (0);
 419   DirectSoundCreate(NULL, NULL, NULL);
 420
 421   return 0;
 422 }
 423 ],
 424     [HAVE_DIRECTSOUND="yes"],
 425     [HAVE_DIRECTSOUND="no"])
 426   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 427   CFLAGS=$save_CFLAGS
 428   LDFLAGS=$save_LDFLAGS
 429   LIBS=$save_LIBS
 430
 431   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 432     dnl this is much more than we want
 433     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 434     AC_SUBST(DIRECTSOUND_CFLAGS)
 435     AC_SUBST(DIRECTSOUND_LDFLAGS)
 436     AC_SUBST(DIRECTSOUND_LIBS)
 437   fi
 438   AC_SUBST(HAVE_DIRECTSOUND)
 439 ])
 440
 441 dnl *** OSS audio *** (Linux, *BSD)
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 443 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 444  HAVE_OSS="yes"
 445 dnl Linux and newer BSD versions :
 446  AC_CHECK_HEADER(sys/soundcard.h, [
 447    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 448    ] , [
 449 dnl Some old BSD versions and also newer OpenBSD versions :
 450    AC_CHECK_HEADER(soundcard.h, [
 451      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 452      ], [
 453   dnl Some old BSD versions :
 454      AC_CHECK_HEADER(machine/soundcard.h, [
 455        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 456          [Define if OSS includes are in /machine/])
 457        ], [
 458        HAVE_OSS="no"
 459      ])
 460    ])
 461  ])
 462 ])
 463
 464 dnl *** oss4 ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 466 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 467   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 468   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 469       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 470       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 471 ])
 472
 473 dnl *** Sun Audio ***
 474 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 475 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 476   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 477 ])
 478
 479 dnl *** OSX Audio ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 481 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 482   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 483 ])
 484
 485 dnl *** OS X video ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 487 HAVE_OSX_VIDEO="no"
 488 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 489   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 490 ])
 491 dnl in case header OpenGL/gl.h is found on other platforms
 492 case "$host" in
 493   *-*darwin*)
 494     dnl do nothing
 495     ;;
 496   *)
 497     HAVE_OSX_VIDEO="no"
 498     ;;
 499 esac
 500
 501
 502 dnl *** Video 4 Linux 2 ***
 503 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 504 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 506 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 507   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 508   AC_TRY_COMPILE([
 509 #include <sys/types.h>
 510 #ifdef __sun /* Solaris */
 511 #include <sys/types.h>
 512 #include <sys/videodev2.h>
 513 #else /* Linux */
 514 #include <linux/types.h>
 515 #define _LINUX_TIME_H
 516 #define __user
 517 #include <linux/videodev2.h>
 518 #endif
 519 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 520 #error too early v4l2 version or no v4l2 at all
 521 #endif
 522     ], [
 523 return 0;
 524     ], [
 525       HAVE_GST_V4L2="yes"
 526       AC_MSG_RESULT(yes)
 527     ], [
 528       HAVE_GST_V4L2="no"
 529       AC_MSG_RESULT(no)
 530
 531       HAVE_VIDEODEV=no
 532       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 533       [
 534         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 535       ])
 536
 537       if test "x$HAVE_VIDEODEV" = "xyes"; then
 538         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 539         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 540       else
 541         AC_MSG_WARN([video4linux2 was not found])
 542       fi
 543     ])
 544
 545   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 546     dnl check for missing v4l2_buffer declaration (see #135919)
 547     MISSING_DECL=0
 548     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 549     AC_TRY_COMPILE([
 550 #include <sys/types.h>
 551 #ifdef __sun /* Solaris */
 552 #include <sys/types.h>
 553 #include <sys/videodev2.h>
 554 #else /* Linux */
 555 #include <linux/types.h>
 556 #define _LINUX_TIME_H
 557 #define __user
 558 #include <linux/videodev2.h>
 559 #endif
 560     ],[
 561 struct v4l2_buffer buf;
 562 buf.index = 0;
 563 return 0;
 564     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 565     if [ test x$MISSING_DECL = x1 ]; then
 566       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 567     fi
 568
 569     dnl check for XOverlay libraries
 570     AG_GST_CHECK_XV
 571   fi
 572 ])
 573
 574 # Optional gudev for device probing
 575 AC_ARG_WITH([gudev],
 576   AC_HELP_STRING([--with-gudev],
 577     [device detection with gudev]),
 578   [],
 579   [with_gudev=check])
 580 if test x$HAVE_GST_V4L2 = xyes; then
 581   if test x$with_gudev != xno; then
 582       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 583           [ have_gudev=yes
 584             AC_DEFINE(HAVE_GUDEV, 1,
 585                [Whether gudev is available for device detection])
 586             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 587           ], [
 588           have_gudev=no
 589           ])
 590   else
 591     have_gudev=no
 592   fi
 593 fi
 594 AC_SUBST(GUDEV_CFLAGS)
 595 AC_SUBST(GUDEV_LIBS)
 596
 597 # Make libv4l2 non-automagic
 598 AC_ARG_WITH([libv4l2],
 599   AC_HELP_STRING([--with-libv4l2],
 600     [support video buffer conversion using libv4l2]),
 601   [],
 602   [with_libv4l2=check])
 603 if test x$HAVE_GST_V4L2 = xyes; then
 604   if test x$with_libv4l2 != xno; then
 605       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 606           [ have_libv4l2=yes
 607             AC_DEFINE(HAVE_LIBV4L2, 1,
 608                 [Whether libv4l2 is available for video buffer conversion])
 609           ], [
 610           have_libv4l2=no
 611           ])
 612   else
 613     have_libv4l2=no
 614   fi
 615 fi
 616
 617 dnl Check for X11
 618 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 619 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 620                   [ximagesrc], [
 621   AC_PATH_XTRA
 622
 623   dnl now try to find the HEADER
 624   ac_cflags_save="$CFLAGS"
 625   ac_cppflags_save="$CPPFLAGS"
 626   CFLAGS="$CFLAGS $X_CFLAGS"
 627   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 628   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 629
 630   if test "x$HAVE_X" = "xno"
 631   then
 632     AC_MSG_NOTICE([cannot find X11 development files])
 633   else
 634     dnl this is much more than we want
 635     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 636     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 637     dnl it does not add the libs; therefore we add them here
 638     X_LIBS="$X_LIBS -lX11"
 639     AC_SUBST(X_CFLAGS)
 640     AC_SUBST(X_LIBS)
 641
 642     dnl check for Xfixes
 643     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 644     if test "x$HAVE_XFIXES" = "xyes"
 645     then
 646         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 647     fi
 648     AC_SUBST(XFIXES_LIBS)
 649     AC_SUBST(XFIXES_CFLAGS)
 650
 651     dnl check for Xdamage
 652     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 653     if test "x$HAVE_XDAMAGE" = "xyes"
 654     then
 655         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 656     fi
 657     AC_SUBST(XDAMAGE_LIBS)
 658     AC_SUBST(XDAMAGE_CFLAGS)
 659   fi
 660   AC_SUBST(HAVE_X)
 661   CFLAGS="$ac_cflags_save"
 662   CPPFLAGS="$ac_cppflags_save"
 663 ])
 664
 665 dnl FIXME: this should be rolled into the test above, it's just an additional
 666 dnl feature of the ximagesrc plug-in
 667 dnl This is the same as in gst-plugins-base
 668 dnl check for X Shm
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 670 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 671   if test x$HAVE_X = xyes; then
 672     AC_CHECK_LIB(Xext, XShmAttach,
 673                  HAVE_XSHM="yes", HAVE_XSHM="no",
 674                  $X_LIBS)
 675     if test "x$HAVE_XSHM" = "xyes"; then
 676       XSHM_LIBS="-lXext"
 677     else
 678       dnl On AIX, it is in XextSam instead, but we still need -lXext
 679       AC_CHECK_LIB(XextSam, XShmAttach,
 680                    HAVE_XSHM="yes", HAVE_XSHM="no",
 681                    $X_LIBS)
 682       if test "x$HAVE_XSHM" = "xyes"; then
 683         XSHM_LIBS="-lXext -lXextSam"
 684       fi
 685     fi
 686   fi
 687 ], ,[
 688   AC_SUBST(HAVE_XSHM)
 689   AC_SUBST(XSHM_LIBS)
 690 ])
 691
 692 dnl for V4L2, we also need to know if we have XVIDEO
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 694 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 695                   [], [
 696   AG_GST_CHECK_XV
 697 ])
 698
 699 dnl *** ext plug-ins ***
 700 dnl keep this list sorted alphabetically !
 701
 702 if test "x$BUILD_EXTERNAL" = "xyes"; then
 703
 704 echo
 705 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 706 echo
 707
 708 dnl *** aalib ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 710 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 711   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 712   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 713 ])
 714
 715 dnl *** annodex ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 717 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 718   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 719 ])
 720
 721 dnl *** cairo ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 723 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 724   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 725 ])
 726
 727 dnl *** cairo-gobject ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 729 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 730   [Cairo graphics rendering gobject bindings], cairooverlay, [
 731   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 732 ])
 733
 734 dnl *** FLAC ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 736 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 737   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 738 ])
 739
 740 dnl *** GDK pixbuf ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 742 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 743   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 744 ])
 745
 746 dnl *** Jack ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 748 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 749   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 750   AC_SUBST(JACK_CFLAGS)
 751   AC_SUBST(JACK_LIBS)
 752
 753   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 754   if test x$HAVE_JACK_0_120_1 = xyes; then
 755     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 756   fi
 757   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 758   if test x$HAVE_JACK_1_9_7 = xyes; then
 759     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 760   fi
 761
 762 ])
 763
 764 dnl *** jpeg ***
 765 dnl FIXME: we could use header checks here as well IMO
 766 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 767 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 768   AC_ARG_WITH(jpeg-mmx,
 769     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 770   OLD_LIBS="$LIBS"
 771   if test x$with_jpeg_mmx != x; then
 772     LIBS="$LIBS -L$with_jpeg_mmx"
 773   fi
 774   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 775   JPEG_LIBS="$LIBS -ljpeg-mmx"
 776   LIBS="$OLD_LIBS"
 777   if test x$HAVE_JPEG != xyes; then
 778     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 779     JPEG_LIBS="-ljpeg"
 780   fi
 781   AC_SUBST(JPEG_LIBS)
 782 ])
 783
 784 dnl *** libcaca ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 786 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 787   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 788 ])
 789
 790 dnl *** libdv ***
 791 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 792 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 793   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 794 ])
 795
 796 dnl *** libpng ***
 797 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 798 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 799   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 800 ])
 801
 802 dnl *** pulseaudio ***
 803 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 804 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 805
 806   dnl used in ext/pulse/pulseutil.c
 807   AC_CHECK_HEADERS([process.h])
 808
 809   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 810 ])
 811
 812 dnl *** dv1394 ***
 813 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 814 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 815   dnl first test for libraw1394 >= 2.0.0
 816   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 817   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 818   dnl now see how far we got
 819   if test x$HAVE_RAW1394 = xyes && \
 820      test x$HAVE_LIBIEC61883 = xyes; then
 821        AG_GST_CHECK_LIBHEADER(AVC1394,
 822         avc1394, avc1394_send_command, $RAW1394_LIBS,
 823         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 824        AG_GST_CHECK_LIBHEADER(ROM1394,
 825         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 826         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 827        if test x$HAVE_AVC1394 = xyes && \
 828           test x$HAVE_AVC1394 = xyes && \
 829           test x$HAVE_ROM1394 = xyes; then
 830           HAVE_DV1394=yes
 831           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 832           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 833           AC_SUBST(DV1394_CFLAGS)
 834           AC_SUBST(DV1394_LIBS)
 835         fi
 836   else
 837        if test x$HAVE_RAW1394 = xno; then
 838           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 839           AG_GST_CHECK_LIBHEADER(AVC1394,
 840            avc1394, avc1394_send_command, $RAW1394_LIBS,
 841            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 842           AG_GST_CHECK_LIBHEADER(ROM1394,
 843            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 844            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 845           if test x$HAVE_RAW1394 = xyes && \
 846              test x$HAVE_AVC1394 = xyes && \
 847              test x$HAVE_ROM1394 = xyes; then
 848              HAVE_DV1394=yes
 849              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 850              DV1394_CFLAGS="$RAW1394_CFLAGS"
 851              if test x$HAVE_LIBIEC61883 = xyes; then
 852                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 853                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 854              fi
 855              AC_SUBST(DV1394_CFLAGS)
 856              AC_SUBST(DV1394_LIBS)
 857            fi
 858          fi
 859   fi
 860 ])
 861 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 862
 863 dnl *** shout2 ***
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 865 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 866   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 867 ])
 868
 869 dnl *** soup ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 871 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 872   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 873     HAVE_SOUP="yes"
 874     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 875   ],[
 876     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 877       HAVE_SOUP="no"
 878     ])
 879   ])
 880   AC_SUBST(SOUP_CFLAGS)
 881   AC_SUBST(SOUP_LIBS)
 882 ])
 883
 884 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 885 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 886 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 887 dnl   speex_jitter.h is 1.1.x only
 888 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 889 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 890   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 891   if test $HAVE_SPEEX = no
 892   then
 893     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 894       AC_CHECK_HEADER(speex/speex_jitter.h, [
 895         dnl speex 1.1.x :
 896         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 897           dnl speex 1.1.5 or + :
 898           HAVE_SPEEX="yes"
 899           SPEEX_LIBS="-lspeex"
 900           AC_SUBST(SPEEX_CFLAGS)
 901           AC_SUBST(SPEEX_LIBS)
 902         ],[
 903           HAVE_SPEEX="no"
 904         ])
 905       ],[
 906         dnl speex 1.0.x :
 907           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 908             dnl speex 1.0.4
 909             HAVE_SPEEX="yes"
 910             SPEEX_LIBS="-lspeex"
 911             AC_SUBST(SPEEX_CFLAGS)
 912             AC_SUBST(SPEEX_LIBS)
 913
 914             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 915               [defined if speex 1.0.x API detected])
 916         ],[
 917             HAVE_SPEEX="no"
 918             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 919         ], [
 920 #include <speex/speex.h>
 921         ])
 922       ])
 923     ])
 924   fi
 925 ])
 926
 927 dnl *** taglib ***
 928 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 929 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 930   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 931   if test "x$HAVE_CXX" != "xyes"; then
 932     USE_TAGLIB=false
 933     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 934   else
 935     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 936     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 937         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 938       ], [
 939         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 940     ])
 941     AC_SUBST(TAGLIB_CXXFLAGS)
 942   fi
 943 ])
 944
 945 dnl *** wavpack ***
 946 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 947 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 948   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 949     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 950       HAVE_WAVPACK=yes
 951       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 952     ],[
 953       HAVE_WAVPACK=no
 954     ])
 955   ])
 956   AC_SUBST(WAVPACK_CFLAGS)
 957   AC_SUBST(WAVPACK_LIBS)
 958 ])
 959
 960 dnl *** qtdemux & matroska prefer to have zlib ***
 961 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 962 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 963   AG_GST_CHECK_LIBHEADER(ZLIB,
 964     z, uncompress,, zlib.h, [
 965     HAVE_ZLIB="yes"
 966     ZLIB_LIBS="-lz"
 967     AC_SUBST(ZLIB_LIBS)
 968   ])
 969 ])
 970
 971 dnl *** matroska prefers to have bz2 ***
 972 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 973 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 974   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 975   AC_SUBST(BZ2_LIBS)
 976 ])
 977
 978 else
 979
 980 dnl not building plugins with external dependencies,
 981 dnl but we still need to set the conditionals
 982 AM_CONDITIONAL(USE_AALIB, false)
 983 AM_CONDITIONAL(USE_ANNODEX, false)
 984 AM_CONDITIONAL(USE_BZ2, false)
 985 AM_CONDITIONAL(USE_CAIRO, false)
 986 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 987 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 988 AM_CONDITIONAL(USE_DV1394, false)
 989 AM_CONDITIONAL(USE_FLAC, false)
 990 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 991 AM_CONDITIONAL(USE_GST_V4L2, false)
 992 AM_CONDITIONAL(USE_JACK, false)
 993 AM_CONDITIONAL(USE_JPEG, false)
 994 AM_CONDITIONAL(USE_LIBCACA, false)
 995 AM_CONDITIONAL(USE_LIBDV, false)
 996 AM_CONDITIONAL(USE_LIBIEC61883, false)
 997 AM_CONDITIONAL(USE_LIBPNG, false)
 998 AM_CONDITIONAL(USE_OSS, false)
 999 AM_CONDITIONAL(USE_OSS4, false)
1000 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1001 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1002 AM_CONDITIONAL(USE_PULSE, false)
1003 AM_CONDITIONAL(USE_SHOUT2, false)
1004 AM_CONDITIONAL(USE_SOUP, false)
1005 AM_CONDITIONAL(USE_SPEEX, false)
1006 AM_CONDITIONAL(USE_SUNAUDIO, false)
1007 AM_CONDITIONAL(USE_TAGLIB, false)
1008 AM_CONDITIONAL(USE_WAVPACK, false)
1009 AM_CONDITIONAL(USE_X, false)
1010 AM_CONDITIONAL(USE_XSHM, false)
1011 AM_CONDITIONAL(USE_XVIDEO, false)
1012 AM_CONDITIONAL(USE_ZLIB, false)
1013
1014 fi dnl of EXT plugins
1015
1016 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1017
1018 dnl Overview:
1019 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1020 dnl GST_*:              flags shared by all built objects
1021 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1022 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1023 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1024 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1025
1026 dnl GST_OPTION_CFLAGS
1027 if test "x$USE_DEBUG" = xyes; then
1028    PROFILE_CFLAGS="-g"
1029 fi
1030 AC_SUBST(PROFILE_CFLAGS)
1031
1032 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1033   dnl Define _only_ for git (not pre-releases or releases)
1034   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1035 else
1036   DEPRECATED_CFLAGS=""
1037 fi
1038 AC_SUBST(DEPRECATED_CFLAGS)
1039
1040 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1041 dnl at make time with e.g. make ERROR_CFLAGS=""
1042 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1043 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1044 AC_SUBST(GST_OPTION_CFLAGS)
1045 AC_SUBST(GST_OPTION_CXXFLAGS)
1046
1047 dnl our libraries need to be versioned correctly
1048 AC_SUBST(GST_LT_LDFLAGS)
1049
1050 dnl FIXME: do we want to rename to GST_ALL_* ?
1051 dnl prefer internal headers to already installed ones
1052 dnl also add builddir include for enumtypes and marshal
1053 dnl add ERROR_CFLAGS, but overridable
1054 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1055 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1056 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1057 AC_SUBST(GST_CFLAGS)
1058 AC_SUBST(GST_CXXFLAGS)
1059 AC_SUBST(GST_LIBS)
1060
1061 dnl LDFLAGS really should only contain flags, not libs - they get added before
1062 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1063 GST_ALL_LDFLAGS="-no-undefined"
1064 AC_SUBST(GST_ALL_LDFLAGS)
1065
1066 dnl this really should only contain flags, not libs - they get added before
1067 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1068 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1069 AC_SUBST(GST_PLUGIN_LDFLAGS)
1070
1071 dnl *** output files ***
1072
1073 dnl keep this alphabetic per directory, please
1074 AC_CONFIG_FILES(
1075 Makefile
1076 gst/Makefile
1077 gst/alpha/Makefile
1078 gst/apetag/Makefile
1079 gst/audiofx/Makefile
1080 gst/audioparsers/Makefile
1081 gst/auparse/Makefile
1082 gst/autodetect/Makefile
1083 gst/avi/Makefile
1084 gst/cutter/Makefile
1085 gst/deinterlace/Makefile
1086 gst/debugutils/Makefile
1087 gst/effectv/Makefile
1088 gst/equalizer/Makefile
1089 gst/flv/Makefile
1090 gst/goom/Makefile
1091 gst/goom2k1/Makefile
1092 gst/id3demux/Makefile
1093 gst/icydemux/Makefile
1094 gst/imagefreeze/Makefile
1095 gst/interleave/Makefile
1096 gst/isomp4/Makefile
1097 gst/law/Makefile
1098 gst/level/Makefile
1099 gst/matroska/Makefile
1100 gst/monoscope/Makefile
1101 gst/multifile/Makefile
1102 gst/multipart/Makefile
1103 gst/replaygain/Makefile
1104 gst/rtp/Makefile
1105 gst/rtpmanager/Makefile
1106 gst/rtsp/Makefile
1107 gst/shapewipe/Makefile
1108 gst/smpte/Makefile
1109 gst/spectrum/Makefile
1110 gst/udp/Makefile
1111 gst/videobox/Makefile
1112 gst/videocrop/Makefile
1113 gst/videofilter/Makefile
1114 gst/videomixer/Makefile
1115 gst/wavenc/Makefile
1116 gst/wavparse/Makefile
1117 gst/flx/Makefile
1118 gst/y4m/Makefile
1119 ext/Makefile
1120 ext/aalib/Makefile
1121 ext/annodex/Makefile
1122 ext/cairo/Makefile
1123 ext/dv/Makefile
1124 ext/flac/Makefile
1125 ext/gdk_pixbuf/Makefile
1126 ext/jack/Makefile
1127 ext/jpeg/Makefile
1128 ext/libcaca/Makefile
1129 ext/libpng/Makefile
1130 ext/pulse/Makefile
1131 ext/raw1394/Makefile
1132 ext/shout2/Makefile
1133 ext/soup/Makefile
1134 ext/speex/Makefile
1135 ext/taglib/Makefile
1136 ext/wavpack/Makefile
1137 sys/Makefile
1138 sys/directsound/Makefile
1139 sys/oss/Makefile
1140 sys/oss4/Makefile
1141 sys/osxaudio/Makefile
1142 sys/osxvideo/Makefile
1143 sys/sunaudio/Makefile
1144 sys/v4l2/Makefile
1145 sys/waveform/Makefile
1146 sys/ximage/Makefile
1147 po/Makefile.in
1148 tests/Makefile
1149 tests/check/Makefile
1150 tests/examples/Makefile
1151 tests/examples/audiofx/Makefile
1152 tests/examples/cairo/Makefile
1153 tests/examples/equalizer/Makefile
1154 tests/examples/jack/Makefile
1155 tests/examples/level/Makefile
1156 tests/examples/pulse/Makefile
1157 tests/examples/rtp/Makefile
1158 tests/examples/shapewipe/Makefile
1159 tests/examples/spectrum/Makefile
1160 tests/examples/v4l2/Makefile
1161 tests/files/Makefile
1162 tests/icles/Makefile
1163 common/Makefile
1164 common/m4/Makefile
1165 m4/Makefile
1166 docs/Makefile
1167 docs/plugins/Makefile
1168 docs/version.entities
1169 pkgconfig/Makefile
1170 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1171 gst-plugins-good.spec
1172 )
1173
1174 dnl Create the config.h file for Visual Studio builds
1175 dnl Beware of spaces and /'s in some of the shell variable contents.
1176 sed \
1177     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1178     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1179     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1180     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1181     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1182     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1183     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1184     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1185     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1186     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1187     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1188     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1189     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1190     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1191     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1192     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1193     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1194     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1195     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1196     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1197     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1198     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1199     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1200     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1201     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1202     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1203     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1204     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1205     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1206     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1207     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1208     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1209     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1210     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1211     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1212     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1213     config.h.in >win32/common/config.h-new
1214
1215 AC_OUTPUT
1216
1217 AG_GST_OUTPUT_PLUGINS
1218 ORC_OUTPUT
1219