configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Editing Services, 1.14.0,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer-editing-services)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ges/ges-timeline.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35  [AM_DEFAULT_VERBOSITY=1
  36  AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl GES versioning, this is mostly informational
  39 GES_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  40 GES_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  41 GES_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  42 GES_VERSION_NANO=$PACKAGE_VERSION_NANO
  43 AC_SUBST(GES_VERSION_MAJOR)
  44 AC_SUBST(GES_VERSION_MINOR)
  45 AC_SUBST(GES_VERSION_MICRO)
  46 AC_SUBST(GES_VERSION_NANO)
  47
  48 dnl our libraries and install dirs use major.minor as a version
  49 GST_API_VERSION=$GST_EDITING_SERVICES_VERSION_MAJOR.$GST_EDITING_SERVICES_VERSION_MINOR
  50 dnl we override it here if we need to for the release candidate of new series
  51 GST_API_VERSION=1.0
  52 AC_SUBST(GST_API_VERSION)
  53
  54 AS_LIBTOOL(GST, 1400, 0, 1400)
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=1.14.0
  58 GSTPB_REQ=1.14.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67 AC_CONFIG_MACRO_DIR([m4])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  72 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_PKG_CONFIG_PATH
  86
  87 AG_GST_FLEX_CHECK
  88
  89 dnl *** checks for platform ***
  90
  91 dnl * hardware/architecture *
  92
  93 dnl common/m4/gst-arch.m4
  94 dnl check CPU type
  95 AG_GST_ARCH
  96
  97 dnl Determine endianness
  98 AC_C_BIGENDIAN
  99
 100 dnl *** checks for programs ***
 101
 102 dnl find a compiler
 103 AC_PROG_CC
 104
 105 dnl check if the compiler supports '-c' and '-o' options
 106 AM_PROG_CC_C_O
 107
 108 dnl check if the compiler supports do while(0) macros
 109 AG_GST_CHECK_DOWHILE_MACROS
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check for gobject-introspection
 115 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 116
 117 dnl check for documentation tools
 118 AG_GST_DOCBOOK_CHECK
 119 GTK_DOC_CHECK([1.3])
 120 AS_PATH_PYTHON([2.1])
 121 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 122
 123 dnl check for pygobject
 124 AC_SUBST(PYGOBJECT_REQ, 3.0)
 125 PKG_CHECK_MODULES(PYGOBJECT, pygobject-3.0 >= $PYGOBJECT_REQ,
 126   [
 127     HAVE_PYGOBJECT=yes
 128   ], HAVE_PYGOBJECT=no)
 129
 130 AM_CONDITIONAL(WITH_PYTHON, [test "x$HAVE_PYGOBJECT" = "xyes"])
 131
 132 dnl check for gst-validate
 133 PKG_CHECK_MODULES(GST_VALIDATE, gst-validate-1.0 >= 1.12.1,
 134   [
 135     HAVE_GST_VALIDATE=yes
 136     AC_DEFINE(HAVE_GST_VALIDATE, 1, [Define if build with gst-validate support])
 137   ], HAVE_GST_VALIDATE=no)
 138
 139 AC_SUBST(GST_VALIDATE_CFLAGS)
 140 AC_SUBST(GST_VALIDATE_LIBS)
 141 AM_CONDITIONAL(HAVE_GST_VALIDATE, [test "x$HAVE_GST_VALIDATE" = "xyes"])
 142
 143 dnl needed for scenarios definition files
 144 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 145 AC_SUBST(GST_PREFIX)
 146 GST_DATADIR="$GST_PREFIX/share"
 147 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 148
 149 dnl check for bash completion
 150 AC_ARG_WITH([bash-completion-dir],
 151     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 152         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 153     [],
 154     [with_bash_completion_dir=yes])
 155
 156 if test "x$with_bash_completion_dir" = "xyes"; then
 157     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 158         [BASH_COMPLETION_DIR="`pkg-config --variable=completionsdir bash-completion`"],
 159         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 160 else
 161     BASH_COMPLETION_DIR="$with_bash_completion_dir"
 162 fi
 163
 164 AC_SUBST([BASH_COMPLETION_DIR])
 165 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 166
 167 dnl *** checks for libraries ***
 168
 169 dnl check for libm, for sin() etc.
 170 # LT_LIB_M
 171 # AC_SUBST(LIBM)
 172
 173 dnl *** checks for header files ***
 174
 175 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 176 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 177
 178 if test "x$HAVE_UNISTD_H" != "xyes"; then
 179   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 180 fi
 181
 182 dnl *** checks for nose2 ***
 183
 184 AC_MSG_CHECKING(for nose2)
 185 NOSE2=nose2
 186 if $NOSE2 1>&AC_FD_CC 2>&AC_FD_CC
 187 then
 188   HAVE_NOSE2=yes
 189   AC_MSG_RESULT(yes)
 190 else
 191   HAVE_NOSE2=no
 192   AC_MSG_RESULT(no nose2)
 193 fi
 194 AC_SUBST([NOSE2])
 195 AM_CONDITIONAL(HAVE_NOSE2, test "x$HAVE_NOSE2" = "xyes")
 196
 197 dnl *** checks for types/defines ***
 198
 199 dnl *** checks for structures ***
 200
 201 dnl *** checks for compiler characteristics ***
 202
 203 dnl *** checks for library functions ***
 204
 205 dnl *** checks for headers ***
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.40.0])
 211
 212 PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, HAVE_GIO=yes, HAVE_GIO=no)
 213 AC_SUBST(GIO_CFLAGS)
 214 AC_SUBST(GIO_LIBS)
 215
 216 dnl checks for gstreamer
 217 dnl uninstalled is selected preferentially -- see pkg-config(1)
 218 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 220 #AG_GST_CHECK_GST_GDP($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 224 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GST_REQ], yes)
 225 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GST_REQ], yes)
 226 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 227
 228 AG_GST_ARG_WITH_PLUGINS
 229 AG_GST_CHECK_PLUGIN(plugins)
 230
 231 dnl set location of plugin directory
 232 AG_GST_SET_PLUGINDIR
 233
 234 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 235 AC_SUBST(GSTPB_PLUGINS_DIR)
 236 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 237
 238 dnl check for gstreamer-pbutils
 239 PKG_CHECK_MODULES(GST_PBUTILS, gstreamer-pbutils-$GST_API_VERSION, HAVE_GST_PBUTILS="yes", HAVE_GST_PBUTILS="no")
 240 if test "x$HAVE_GST_PBUTILS" != "xyes"; then
 241   AC_ERROR([gst-pbutils is required for rendering support])
 242 fi
 243 AC_SUBST(GST_PBUTILS_LIBS)
 244 AC_SUBST(GST_PBUTILS_CFLAGS)
 245
 246 dnl check for gst-controller
 247 PKG_CHECK_MODULES(GST_CONTROLLER, gstreamer-controller-$GST_API_VERSION, HAVE_GST_CONTROLLER="yes", HAVE_GST_CONROLLER="no")
 248 if test "x$HAVE_GST_CONTROLLER" != "xyes"; then
 249   AC_ERROR([gst-controller is required for transition support])
 250 fi
 251 AC_SUBST(GST_CONTROLLER_LIBS)
 252 AC_SUBST(GST_CONTROLLER_CFLAGS)
 253
 254 dnl check for gstvideo
 255 PKG_CHECK_MODULES(GST_VIDEO, gstreamer-video-$GST_API_VERSION, HAVE_GST_VIDEO="yes", HAVE_GST_CONROLLER="no")
 256 if test "x$HAVE_GST_VIDEO" != "xyes"; then
 257   AC_ERROR([gst-video is required for transition support])
 258 fi
 259 AC_SUBST(GST_VIDEO_LIBS)
 260 AC_SUBST(GST_VIDEO_CFLAGS)
 261
 262 dnl Check for documentation xrefs
 263 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 264 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 265 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268 AC_SUBST(GSTPB_PREFIX)
 269
 270 dnl pitivi formatter needs libxml
 271 PKG_CHECK_MODULES(XML, libxml-2.0, HAVE_LIBXML="yes", HAVE_LIBXML="no")
 272 if test "x$HAVE_LIBXML" != "xyes"; then
 273   AC_ERROR([libxml2 is required])
 274 fi
 275 AC_SUBST(XML_LIBS)
 276 AC_SUBST(XML_CFLAGS)
 277
 278 dnl GTK is optional and only used in examples
 279 HAVE_GTK=no
 280 HAVE_GTK_X11=no
 281 GTK2_REQ=2.14.0
 282 GTK3_REQ=2.91.3
 283 if test "x$BUILD_EXAMPLES" = "xyes"; then
 284   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 285   AC_ARG_WITH([gtk],
 286     AC_HELP_STRING([--with-gtk=3.0|2.0],
 287                    [which gtk+ version to compile against (default: 2.0)]),
 288     [case "$with_gtk" in
 289         2.0) GTK_REQ=$GTK2_REQ ;;
 290         3.0) GTK_REQ=$GTK3_REQ ;;
 291         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 292     esac],
 293     [with_gtk=2.0
 294      GTK_REQ=$GTK2_REQ])
 295   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 296   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 297   dnl some examples need gtk+-x11
 298   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 299   AC_SUBST(GTK_LIBS)
 300   AC_SUBST(GTK_CFLAGS)
 301 fi
 302 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 303 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 304
 305 dnl Check for -Bsymbolic-functions linker flag used to avoid
 306 dnl intra-library PLT jumps, if available.
 307 AC_ARG_ENABLE(Bsymbolic,
 308               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 309               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 310                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 311                LDFLAGS=-Wl,-Bsymbolic-functions
 312                LIBS=
 313                AC_TRY_LINK([], [return 0],
 314                            AC_MSG_RESULT(yes)
 315                            enable_Bsymbolic=yes,
 316                            AC_MSG_RESULT(no)
 317                            enable_Bsymbolic=no)
 318                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 319
 320 dnl building of benchmarks
 321 AC_ARG_ENABLE(benchmarks,
 322   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 323   [
 324     case "${enableval}" in
 325       yes) BUILD_BENCHMARKS=yes ;;
 326       no)  BUILD_BENCHMARKS=no ;;
 327       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 328     esac
 329   ],
 330 [BUILD_BENCHMARKS=yes]) dnl Default value
 331 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 332
 333 dnl set license and copyright notice
 334 GST_LICENSE="LGPL"
 335 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 336 AC_SUBST(GST_LICENSE)
 337
 338 dnl define LIBDIR so we can inform people where we live
 339 AS_AC_EXPAND(LIBDIR, $libdir)
 340 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 341
 342 dnl set location of plugin directory
 343 AG_GST_SET_PLUGINDIR
 344
 345 dnl define an ERROR_CFLAGS Makefile variable
 346 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef \
 347                                    -Wwrite-strings -Wformat-security -Wold-style-definition \
 348                                    -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar \
 349                                    -Wnested-externs])
 350
 351 dnl define correct level for debugging messages
 352 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 353
 354 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 355
 356 dnl Overview:
 357 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 358 dnl GST_*:              flags shared by built objects to link against GStreamer
 359 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 360 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 361 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 362 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 363
 364 dnl GST_OPTION_CFLAGS
 365 if test "x$USE_DEBUG" = xyes; then
 366    PROFILE_CFLAGS="-g"
 367 fi
 368 AC_SUBST(PROFILE_CFLAGS)
 369
 370 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 371   dnl Define _only_ during CVS (not pre-releases or releases)
 372   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 373 else
 374   DEPRECATED_CFLAGS=""
 375 fi
 376 AC_SUBST(DEPRECATED_CFLAGS)
 377
 378 VISIBILITY_CFLAGS=""
 379 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 380 AC_SUBST(VISIBILITY_CFLAGS)
 381
 382 dnl disable strict aliasing
 383 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 384 AC_SUBST(EXTRA_CFLAGS)
 385
 386 dnl every flag in GST_OPTION_CFLAGS can be overridden
 387 dnl at make time with e.g. make ERROR_CFLAGS=""
 388 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 389 AC_SUBST(GST_OPTION_CFLAGS)
 390
 391 dnl FIXME: do we want to rename to GST_ALL_* ?
 392 dnl prefer internal headers to already installed ones
 393 dnl also add builddir include for enumtypes and marshal
 394 dnl add GST_OPTION_CFLAGS, but overridable
 395 GST_CFLAGS="$GST_CFLAGS $EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) \$(VISIBILITY_CFLAGS) -DGST_USE_UNSTABLE_API"
 396 AC_SUBST(GST_CFLAGS)
 397 AC_SUBST(GST_LIBS)
 398
 399 dnl LDFLAGS really should only contain flags, not libs - they get added before
 400 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 401 GST_ALL_LDFLAGS="-no-undefined"
 402 if test "x${enable_Bsymbolic}" = "xyes"; then
 403   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 404 fi
 405 AC_SUBST(GST_ALL_LDFLAGS)
 406
 407 dnl GST_LIB_LDFLAGS
 408 dnl linker flags shared by all libraries
 409 dnl LDFLAGS modifier defining exported symbols from built libraries
 410 GST_LIB_LDFLAGS=""
 411 AC_SUBST(GST_LIB_LDFLAGS)
 412
 413 dnl GST_PLUGIN_LDFLAGS must only contain flags, not libs - they get added before
 414 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 415 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 416 AC_SUBST(GST_PLUGIN_LDFLAGS)
 417
 418 dnl *** output files ***
 419
 420 dnl po/Makefile.in
 421
 422 AC_CONFIG_FILES(
 423 Makefile
 424 ges/ges-version.h
 425 common/Makefile
 426 common/m4/Makefile
 427 m4/Makefile
 428 ges/Makefile
 429 tests/Makefile
 430 tests/check/Makefile
 431 tests/benchmarks/Makefile
 432 examples/Makefile
 433 examples/c/Makefile
 434 tests/validate/Makefile
 435 tests/validate/scenarios/Makefile
 436 tools/Makefile
 437 docs/Makefile
 438 docs/version.entities
 439 docs/libs/Makefile
 440 pkgconfig/Makefile
 441 pkgconfig/gst-editing-services.pc
 442 pkgconfig/gst-editing-services-uninstalled.pc
 443 plugins/Makefile
 444 plugins/nle/Makefile
 445 bindings/Makefile
 446 bindings/python/Makefile
 447 bindings/python/gi/Makefile
 448 bindings/python/gi/overrides/Makefile
 449 )
 450 AC_OUTPUT