configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer OpenMAX Plug-ins, 1.15.2.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-omx)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([omx/gstomx.c])
  25
  26 dnl define the output header for config
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48 AS_LIBTOOL(GST, 1502, 0, 1502)
  49
  50 dnl *** required versions of GStreamer stuff ***
  51 GST_REQ=1.15.2.1
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl *** check for arguments to configure ***
  62
  63 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  64
  65 AG_GST_ARG_DEBUG
  66 AG_GST_ARG_PROFILING
  67 AG_GST_ARG_VALGRIND
  68 AG_GST_ARG_GCOV
  69
  70 AG_GST_ARG_EXAMPLES
  71
  72 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  73 AG_GST_ARG_WITH_PACKAGE_NAME
  74 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  75
  76 AG_GST_PKG_CONFIG_PATH
  77
  78 AG_GST_ARG_WITH_PLUGINS
  79
  80 AG_GST_ARG_ENABLE_EXPERIMENTAL
  81
  82 dnl *** checks for platform ***
  83
  84 dnl * hardware/architecture *
  85
  86 dnl common/m4/gst-arch.m4
  87 dnl check CPU type
  88 AG_GST_ARCH
  89
  90 dnl check for large file support
  91 dnl affected plugins must include config.h
  92 AC_SYS_LARGEFILE
  93
  94 dnl *** checks for programs ***
  95
  96 dnl find a compiler
  97 AC_PROG_CC
  98 AC_PROG_CC_STDC
  99
 100 dnl check if the compiler supports '-c' and '-o' options
 101 AM_PROG_CC_C_O
 102
 103 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 104 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 105
 106 dnl check for documentation tools
 107 GTK_DOC_CHECK([1.3])
 108 AS_PATH_PYTHON([2.1])
 109 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 110
 111 dnl *** checks for libraries ***
 112
 113 dnl libm, for sin() etc.
 114 LT_LIB_M
 115 AC_SUBST(LIBM)
 116
 117 dnl *** checks for header files ***
 118
 119 dnl check if we have ANSI C header files
 120 AC_HEADER_STDC
 121
 122 AX_CREATE_STDINT_H
 123
 124 dnl *** checks for functions ***
 125
 126 dnl *** checks for types/defines ***
 127
 128 dnl *** checks for structures ***
 129
 130 dnl *** checks for compiler characteristics ***
 131
 132 dnl *** checks for library functions ***
 133
 134 dnl Check for a way to display the function name in debug output
 135 AG_GST_CHECK_FUNCTION
 136
 137 dnl *** checks for dependency libraries ***
 138
 139 dnl GLib is required
 140 AG_GST_GLIB_CHECK([2.40.0])
 141
 142 dnl Needed by plugins that use g_module_*() API
 143 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 144
 145 dnl checks for gstreamer
 146 dnl uninstalled is selected preferentially -- see pkg-config(1)
 147 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 148 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 149 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 150 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 151 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_REQ], yes)
 152 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 153 PKG_CHECK_MODULES([GST_GL], [gstreamer-gl-1.0 >= $GST_REQ], [
 154   AC_DEFINE(HAVE_GST_GL, 1, [Have gstreamer-gl])
 155   GST_GL=yes
 156 ], [GST_GL=no])
 157 AM_CONDITIONAL(HAVE_GST_GL, test "x$GST_GL" = "xyes")
 158 PKG_CHECK_MODULES([GST_ALLOCATORS], [gstreamer-allocators-1.0])
 159
 160 dnl Check for documentation xrefs
 161 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 162 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 163 AC_SUBST(GLIB_PREFIX)
 164 AC_SUBST(GST_PREFIX)
 165
 166 dnl *** EGL ***
 167 PKG_CHECK_MODULES([EGL], [egl], [
 168   AC_DEFINE(HAVE_EGL, 1, [Have egl])
 169   HAVE_EGL=yes
 170 ], [HAVE_EGL=no])
 171 AM_CONDITIONAL(HAVE_EGL, test "x$HAVE_EGL" = "xyes")
 172
 173 dnl *** GLESv2 ***
 174 PKG_CHECK_MODULES([GLES2], [glesv2], [
 175   AC_DEFINE(HAVE_EGL, 1, [Have glesv2])
 176   HAVE_GLES2=yes
 177 ], [HAVE_GLES2=no])
 178 AM_CONDITIONAL(HAVE_GLES2, test "x$HAVE_GLES2" = "xyes")
 179
 180 dnl *** X11 ***
 181 PKG_CHECK_MODULES([X11], [x11], [
 182   AC_DEFINE(HAVE_X11, 1, [Have x11])
 183   HAVE_X11=yes
 184 ], [HAVE_X11=no])
 185 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "xyes")
 186
 187 dnl Check for -Bsymbolic-functions linker flag used to avoid
 188 dnl intra-library PLT jumps, if available.
 189 AC_ARG_ENABLE(Bsymbolic,
 190               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 191               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 192                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 193                LDFLAGS=-Wl,-Bsymbolic-functions
 194                LIBS=
 195                AC_TRY_LINK([], [return 0],
 196                            AC_MSG_RESULT(yes)
 197                            enable_Bsymbolic=yes,
 198                            AC_MSG_RESULT(no)
 199                            enable_Bsymbolic=no)
 200                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 201
 202 AC_ARG_WITH([omx-target],
 203         AS_HELP_STRING([--with-omx-target],[Use this OpenMAX IL target (generic, bellagio, rpi, tizonia, zynqultrascaleplus)]),
 204         [ac_cv_omx_target="$withval"], [ac_cv_omx_target="none"])
 205
 206 ac_cv_omx_target_struct_packing="none"
 207 AC_MSG_NOTICE([Using $ac_cv_omx_target as OpenMAX IL target])
 208 case "${ac_cv_omx_target}" in
 209   generic)
 210     AC_DEFINE(USE_OMX_TARGET_GENERIC, 1, [Use generic OpenMAX IL target])
 211     ;;
 212   rpi)
 213     AC_DEFINE(USE_OMX_TARGET_RPI, 1, [Use RPi OpenMAX IL target])
 214     AC_DEFINE(OMX_SKIP64BIT, 1, [Required by the RPi implementation])
 215     ac_cv_omx_target_struct_packing=4
 216     ;;
 217   bellagio)
 218     AC_DEFINE(USE_OMX_TARGET_BELLAGIO, 1, [Use Bellagio OpenMAX IL target])
 219     ;;
 220   zynqultrascaleplus)
 221     AC_DEFINE(USE_OMX_TARGET_ZYNQ_USCALE_PLUS, 1, [Use Zynq UltraScale+ OpenMAX IL target])
 222     ;;
 223   tizonia)
 224     AC_DEFINE(USE_OMX_TARGET_TIZONIA, 1, [Use Tizonia OpenMAX IL target])
 225     ;;
 226   none|*)
 227     AC_ERROR([invalid OpenMAX IL target, you must specify one of --with-omx-target={generic,rpi,bellagio,tizonia,zynqultrascaleplus}])
 228     ;;
 229 esac
 230 AM_CONDITIONAL(USE_OMX_TARGET_GENERIC, test "x$ac_cv_omx_target" = "xgeneric")
 231 AM_CONDITIONAL(USE_OMX_TARGET_BELLAGIO, test "x$ac_cv_omx_target" = "xbellagio")
 232 AM_CONDITIONAL(USE_OMX_TARGET_TIZONIA, test "x$ac_cv_omx_target" = "xtizonia")
 233 AM_CONDITIONAL(USE_OMX_TARGET_RPI, test "x$ac_cv_omx_target" = "xrpi")
 234 AM_CONDITIONAL(USE_OMX_TARGET_ZYNQ_USCALE_PLUS, test "x$ac_cv_omx_target" = "xzynqultrascaleplus")
 235
 236 AC_ARG_WITH([omx-struct-packing],
 237         AS_HELP_STRING([--with-omx-struct-packing],[Force OpenMAX struct packing, (default is none)]),
 238         [ac_cv_omx_struct_packing="$withval"], [ac_cv_omx_struct_packing="none"])
 239
 240 if test x"$ac_cv_omx_struct_packing" != x"none"; then
 241   AC_MSG_NOTICE([Using $ac_cv_omx_struct_packing as OpenMAX struct packing])
 242   AC_DEFINE_UNQUOTED(GST_OMX_STRUCT_PACKING, $ac_cv_omx_struct_packing, [The struct packing used for OpenMAX structures])
 243 elif test x"$ac_cv_omx_target_struct_packing" != x"none"; then
 244   AC_MSG_NOTICE([Using $ac_cv_omx_target_struct_packing as OpenMAX struct packing])
 245   AC_DEFINE_UNQUOTED(GST_OMX_STRUCT_PACKING, $ac_cv_omx_target_struct_packing, [The struct packing used for OpenMAX structures])
 246 fi
 247
 248 dnl settings for tizonia target
 249 if test "x$ac_cv_omx_target" = "xtizonia"; then
 250     PKG_CHECK_MODULES([TIZONIA], [tizilheaders])
 251     CPPFLAGS="$CPPFLAGS $TIZONIA_CFLAGS"
 252     TIZONIA_LIBDIR="`$PKG_CONFIG --variable=libdir tizilheaders`"
 253     AC_SUBST(TIZONIA_LIBDIR)
 254 fi
 255
 256 AC_ARG_WITH([omx-header-path],
 257             AS_HELP_STRING([--with-omx-header-path],[path of external OpenMAX IL header files]),
 258         [omx_header_path="$withval"], [omx_header_path="none"])
 259
 260 if test x"$omx_header_path" != x"none"; then
 261     CPPFLAGS="$CPPFLAGS -I$omx_header_path"
 262 fi
 263 dnl Check for external OpenMAX IL headers
 264 AC_CHECK_HEADER([OMX_Core.h], [HAVE_EXTERNAL_OMX=yes], [HAVE_EXTERNAL_OMX=no], [AC_INCLUDES_DEFAULT])
 265 AM_CONDITIONAL(HAVE_EXTERNAL_OMX, test "x$HAVE_EXTERNAL_OMX" = "xyes")
 266
 267 dnl OMX defines 8 header files to contain extensions:
 268 dnl OMX_VideoExt.h, OMX_IndexExt.h, OMX_ComponentExt.h, OMX_CoreExt.h
 269 dnl OMX_AudioExt.h, OMX_IVCommonExt.h, OMX_ImageExt.h, OMX_OtherExt.h
 270 dnl The first 4 are present in our internal OpenMAX IL, the latter are not
 271 HAVE_VIDEO_EXT=yes
 272 HAVE_INDEX_EXT=yes
 273 HAVE_COMPONENT_EXT=yes
 274 HAVE_CORE_EXT=yes
 275 HAVE_AUDIO_EXT=no
 276 HAVE_IV_COMMON_EXT=no
 277 HAVE_IMAGE_EXT=no
 278 HAVE_OTHER_EXT=no
 279 if test "x$HAVE_EXTERNAL_OMX" = "xyes"; then
 280     AC_CHECK_HEADER([OMX_VideoExt.h], [HAVE_VIDEO_EXT=yes], [HAVE_VIDEO_EXT=no], [AC_INCLUDES_DEFAULT])
 281     AC_CHECK_HEADER([OMX_IndexExt.h], [HAVE_INDEX_EXT=yes], [HAVE_INDEX_EXT=no], [AC_INCLUDES_DEFAULT])
 282     AC_CHECK_HEADER([OMX_ComponentExt.h], [HAVE_COMPONENT_EXT=yes], [HAVE_COMPONENT_EXT=no], [AC_INCLUDES_DEFAULT])
 283     AC_CHECK_HEADER([OMX_CoreExt.h], [HAVE_CORE_EXT=yes], [HAVE_CORE_EXT=no], [AC_INCLUDES_DEFAULT])
 284     AC_CHECK_HEADER([OMX_AudioExt.h], [HAVE_AUDIO_EXT=yes], [HAVE_AUDIO_EXT=no], [AC_INCLUDES_DEFAULT])
 285     AC_CHECK_HEADER([OMX_IVCommonExt.h], [HAVE_IV_COMMON_EXT=yes], [HAVE_IV_COMMON_EXT=no], [AC_INCLUDES_DEFAULT])
 286     AC_CHECK_HEADER([OMX_ImageExt.h], [HAVE_IMAGE_EXT=yes], [HAVE_IMAGE_EXT=no], [AC_INCLUDES_DEFAULT])
 287     AC_CHECK_HEADER([OMX_OtherExt.h], [HAVE_OTHER_EXT=yes], [HAVE_OTHER_EXT=no], [AC_INCLUDES_DEFAULT])
 288 fi
 289
 290 VIDEO_HEADERS="#include <OMX_Video.h>"
 291 if test "x$HAVE_VIDEO_EXT" = "xyes"; then
 292     AC_DEFINE(HAVE_VIDEO_EXT, 1, [OpenMAX IL has OMX_VideoExt.h header])
 293     VIDEO_HEADERS="$VIDEO_HEADERS
 294 #include <OMX_VideoExt.h>
 295 "
 296 fi
 297
 298 if test "x$HAVE_INDEX_EXT" = "xyes"; then
 299     AC_DEFINE(HAVE_INDEX_EXT, 1, [OpenMAX IL has OMX_IndexExt.h header])
 300 fi
 301
 302 if test "x$HAVE_COMPONENT_EXT" = "xyes"; then
 303     AC_DEFINE(HAVE_COMPONENT_EXT, 1, [OpenMAX IL has OMX_ComponentExt.h header])
 304 fi
 305
 306 if test "x$HAVE_CORE_EXT" = "xyes"; then
 307     AC_DEFINE(HAVE_CORE_EXT, 1, [OpenMAX IL has OMX_CoreExt.h header])
 308 fi
 309
 310 if test "x$HAVE_AUDIO_EXT" = "xyes"; then
 311     AC_DEFINE(HAVE_AUDIO_EXT, 1, [OpenMAX IL has OMX_AudioExt.h header])
 312 fi
 313
 314 if test "x$HAVE_IV_COMMON_EXT" = "xyes"; then
 315     AC_DEFINE(HAVE_IV_COMMON_EXT, 1, [OpenMAX IL has OMX_IVCommonExt.h header])
 316 fi
 317
 318 if test "x$HAVE_IMAGE_EXT" = "xyes"; then
 319     AC_DEFINE(HAVE_IMAGE_EXT, 1, [OpenMAX IL has OMX_ImageExt.h header])
 320 fi
 321
 322 if test "x$HAVE_OTHER_EXT" = "xyes"; then
 323     AC_DEFINE(HAVE_OTHER_EXT, 1, [OpenMAX IL has OMX_OtherExt.h header])
 324 fi
 325
 326 AC_CHECK_DECLS([OMX_VIDEO_CodingVP8],
 327   [
 328     AC_DEFINE(HAVE_VP8, 1, [OpenMAX IL has VP8 support])
 329     HAVE_VP8=yes
 330   ], [
 331     HAVE_VP8=no
 332   ], [[$VIDEO_HEADERS]])
 333 AM_CONDITIONAL(HAVE_VP8, test "x$HAVE_VP8" = "xyes")
 334
 335 AC_CHECK_DECLS([OMX_VIDEO_CodingTheora],
 336   [
 337     AC_DEFINE(HAVE_THEORA, 1, [OpenMAX IL has Theora support])
 338     HAVE_THEORA=yes
 339   ], [
 340     HAVE_THEORA=no
 341   ], [[$VIDEO_HEADERS]])
 342 AM_CONDITIONAL(HAVE_THEORA, test "x$HAVE_THEORA" = "xyes")
 343
 344 AC_CHECK_DECLS([OMX_VIDEO_CodingHEVC],
 345   [
 346     AC_DEFINE(HAVE_HEVC, 1, [OpenMAX IL has HEVC support])
 347     HAVE_HEVC=yes
 348   ], [
 349     HAVE_HEVC=no
 350   ], [[$VIDEO_HEADERS]])
 351 AM_CONDITIONAL(HAVE_HEVC, test "x$HAVE_HEVC" = "xyes")
 352
 353 if test "x$ac_cv_omx_target" = "xzynqultrascaleplus"; then
 354     AC_CHECK_HEADER([OMX_Allegro.h], [], [AC_ERROR([Need Allegro OMX headers to build for Zynq UltraScale+. Use --with-omx-header-path= argument to specify the path of those headers.])], [AC_INCLUDES_DEFAULT])
 355 fi
 356
 357 dnl *** set variables based on configure arguments ***
 358
 359 dnl set license and copyright notice
 360 GST_LICENSE="LGPL"
 361 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 362 AC_SUBST(GST_LICENSE)
 363
 364 dnl set location of plugin directory
 365 AG_GST_SET_PLUGINDIR
 366
 367 dnl set release date/time
 368 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 369   ["${srcdir}/gst-omx.doap"],
 370   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 371
 372 dnl define an ERROR_CFLAGS Makefile variable
 373 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 374     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 375     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wformat-nonliteral
 376     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 377     -Wno-multichar -Wnested-externs ])
 378
 379 dnl define correct level for debugging messages
 380 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 381
 382 dnl used in examples
 383 AG_GST_DEFAULT_ELEMENTS
 384
 385 dnl *** plug-ins to include ***
 386
 387 dnl these are all the gst plug-ins, compilable without additional libs
 388 AG_GST_CHECK_PLUGIN(omx)
 389
 390 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 391
 392 dnl Overview:
 393 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 394 dnl GST_*:              flags shared by built objects to link against GStreamer
 395 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 396 dnl                          (compare to other modules) or for i18n
 397 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 398 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 399 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 400 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 401
 402 dnl GST_OPTION_CFLAGS
 403 if test "x$USE_DEBUG" = xyes; then
 404    PROFILE_CFLAGS="-g"
 405 fi
 406 AC_SUBST(PROFILE_CFLAGS)
 407
 408 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 409   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 410   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 411 else
 412   DEPRECATED_CFLAGS=""
 413 fi
 414 AC_SUBST(DEPRECATED_CFLAGS)
 415
 416 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 417 dnl at make time with e.g. make ERROR_CFLAGS=""
 418 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 419 AC_SUBST(GST_OPTION_CFLAGS)
 420
 421 dnl GST_PLUGINS_BASE_CFLAGS
 422 dnl prefer internal headers to already installed ones
 423 dnl also add builddir include for enumtypes and marshal
 424 GST_OMX_CFLAGS=""
 425 AC_SUBST(GST_OMX_CFLAGS)
 426
 427 dnl FIXME: do we want to rename to GST_ALL_* ?
 428 dnl add GST_OPTION_CFLAGS, but overridable
 429 GST_CFLAGS="$GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 430 AC_SUBST(GST_CFLAGS)
 431 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 432 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 433 AC_SUBST(GST_LIBS)
 434
 435 dnl LDFLAGS really should only contain flags, not libs - they get added before
 436 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 437 GST_ALL_LDFLAGS="-no-undefined"
 438 if test "x${enable_Bsymbolic}" = "xyes"; then
 439   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 440 fi
 441 AC_SUBST(GST_ALL_LDFLAGS)
 442
 443 dnl this really should only contain flags, not libs - they get added before
 444 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 445 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 446 AC_SUBST(GST_PLUGIN_LDFLAGS)
 447
 448 AS_AC_EXPAND(GST_OMX_CONFIG_DIR, ${sysconfdir}/xdg)
 449 AC_DEFINE_UNQUOTED(GST_OMX_CONFIG_DIR, "$GST_OMX_CONFIG_DIR", [gst-omx configuration directory])
 450
 451 dnl *** output files ***
 452
 453 AC_CONFIG_FILES(
 454 Makefile
 455 omx/Makefile
 456 common/Makefile
 457 common/m4/Makefile
 458 tools/Makefile
 459 config/Makefile
 460 config/bellagio/Makefile
 461 config/rpi/Makefile
 462 config/tizonia/gstomx.conf
 463 config/tizonia/Makefile
 464 config/zynqultrascaleplus/Makefile
 465 examples/Makefile
 466 examples/egl/Makefile
 467 m4/Makefile
 468 tests/Makefile
 469 tests/check/Makefile
 470 )
 471
 472 AC_OUTPUT
 473