configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.36.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 26)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.36
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AC_HELP_STRING([--with-install-plugins-helper],
  99     [specify path of helper script to call to install plugins]),
 100   [
 101     case "${withval}" in
 102       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 104       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 105     esac
 106   ],
 107   [
 108     dnl Default value
 109     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 110   ]
 111 )
 112 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 113 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 114     [plugin install helper script])
 115 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 116
 117 AG_GST_ARG_WITH_PLUGINS
 118
 119 AG_GST_ARG_ENABLE_EXTERNAL
 120
 121 AG_GST_ARG_ENABLE_EXPERIMENTAL
 122
 123 dnl *** checks for platform ***
 124 AG_GST_PLATFORM
 125
 126 dnl * hardware/architecture *
 127
 128 dnl common/m4/gst-arch.m4
 129 dnl check CPU type
 130 AG_GST_ARCH
 131
 132 dnl check for large file support
 133 dnl affected plugins must include config.h
 134 AC_SYS_LARGEFILE
 135
 136 dnl *** checks for programs ***
 137
 138 dnl find a compiler
 139 AC_PROG_CC
 140 AC_PROG_CC_STDC
 141
 142 dnl check if the compiler supports '-c' and '-o' options
 143 AM_PROG_CC_C_O
 144
 145 dnl determine if c++ is available on this system
 146 AC_PROG_CXX
 147 dnl CXX may be set to some default even if no c++ compiler is available
 148 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 149 AC_LANG_PUSH([C++])
 150 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 151 AC_LANG_POP([C++])
 152 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 153 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 154
 155 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 156 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 157
 158 dnl check for gobject-introspection
 159 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 160
 161 dnl check for documentation tools
 162 GTK_DOC_CHECK([1.3])
 163 AS_PATH_PYTHON([2.1])
 164 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 165
 166 dnl *** checks for libraries ***
 167
 168 dnl libm, for sin() etc.
 169 AC_CHECK_LIBM
 170 AC_SUBST(LIBM)
 171
 172 dnl *** checks for header files ***
 173
 174 dnl check if we have ANSI C header files
 175 AC_HEADER_STDC
 176
 177 dnl used in gst/ffmpegcolorspace/mem.c
 178 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 179 AC_CHECK_HEADERS([malloc.h])
 180
 181 ac_cppflags_save="$CPPFLAGS"
 182 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 183 AC_COMPILE_IFELSE([
 184   AC_LANG_PROGRAM([[
 185 #include <libxml/HTMLparser.h>
 186 ]],[[
 187 #ifndef LIBXML_HTML_ENABLED
 188 #error libxml2 has no HTML support
 189 #endif /* LIBXML_HTML_ENABLED */
 190 ]])], [
 191   HAVE_LIBXML_HTML="yes"
 192 ], [
 193   HAVE_LIBXML_HTML="no"
 194 ])
 195 CPPFLAGS="$ac_cppflags_save"
 196 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 197
 198 dnl used in gst/tcp
 199 AC_CHECK_HEADERS([sys/socket.h],
 200   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 201 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 202
 203 dnl used in gst-libs/gst/rtsp
 204 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 205 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 206   WIN32_LIBS="-lws2_32"
 207   AC_SUBST(WIN32_LIBS)
 208 fi
 209
 210 dnl check for hstrerror, for gst-libs/gst/rtsp
 211 save_libs="$LIBS"
 212 AC_CHECK_FUNC(hstrerror, ,
 213     AC_CHECK_LIB(resolv, hstrerror, ,
 214         [AC_DEFINE(NO_HSTRERROR, 1,
 215              [Define if you have no native hstrerror() function.])]))
 216 HSTRERROR_LIBS=$LIBS
 217 AC_SUBST(HSTRERROR_LIBS)
 218 LIBS="$save_libs"
 219
 220 dnl used in gst-libs/gst/pbutils and associated unit test
 221 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 222
 223 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 224
 225 dnl ffmpegcolorspace includes _stdint.h
 226 dnl also, Windows does not have long long
 227 AX_CREATE_STDINT_H
 228
 229 dnl *** checks for functions ***
 230 AC_CHECK_FUNCS([localtime_r gmtime_r])
 231
 232 dnl *** checks for math functions ***
 233 LIBS_SAVE=$LIBS
 234 LIBS="$LIBS $LIBM"
 235 AC_CHECK_FUNCS(log2)
 236 LIBS=$LIBS_SAVE
 237
 238 dnl *** checks for types/defines ***
 239
 240 dnl Check for FIONREAD ioctl declaration
 241 dnl used in gst/tcp
 242 GST_CHECK_FIONREAD
 243
 244 dnl *** checks for structures ***
 245
 246 dnl *** checks for compiler characteristics ***
 247
 248 dnl *** checks for library functions ***
 249
 250 dnl check for fseeko()
 251 AC_FUNC_FSEEKO
 252
 253 dnl Check for fast float to int casting as defined in C99
 254 dnl used in gst-libs/gst/floatcast/floatcast.h
 255 save_libs=$LIBS
 256 LIBS="$LIBS $LIBM"
 257 AC_C99_FUNC_LRINT
 258 AC_C99_FUNC_LRINTF
 259 LIBS=$save_libs
 260
 261 dnl Check for a way to display the function name in debug output
 262 AG_GST_CHECK_FUNCTION
 263
 264 dnl *** checks for socket and nsl libraries ***
 265 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 266 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 267
 268 dnl *** checks for dependency libraries ***
 269
 270 dnl GLib is required
 271 AG_GST_GLIB_CHECK([2.24])
 272
 273 ORC_CHECK([0.4.11])
 274
 275 dnl checks for gstreamer
 276 dnl uninstalled is selected preferentially -- see pkg-config(1)
 277 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 278 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 279 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 280 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 281 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 282 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 283
 284 dnl Check for documentation xrefs
 285 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 286 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 287 AC_SUBST(GLIB_PREFIX)
 288 AC_SUBST(GST_PREFIX)
 289
 290 dnl GTK is optional and only used in examples
 291 HAVE_GTK=no
 292 HAVE_GTK_X11=no
 293 GTK_REQ=3.0.0
 294 if test "x$BUILD_EXAMPLES" = "xyes"; then
 295   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 296   dnl some examples need gtk+-x11
 297   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 298   AC_SUBST(GTK_LIBS)
 299   AC_SUBST(GTK_CFLAGS)
 300 fi
 301 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 302 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 303
 304 dnl QT is optional and only used in examples
 305 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 306   HAVE_QT_GV=yes
 307   HAVE_QT=yes
 308 ], [
 309   HAVE_QT_GV=no
 310   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 311 ])
 312 if test "x$HAVE_QT" = "xyes"; then
 313   AC_MSG_CHECKING([Qt moc])
 314   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 315   AC_MSG_RESULT($QT4_MOC)
 316   AC_SUBST(QT4_MOC)
 317 fi
 318 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 319 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 320
 321 dnl chck for linux headers needed by the joystick seek example
 322 AC_COMPILE_IFELSE(
 323 [
 324   AC_LANG_PROGRAM([
 325     #include <linux/input.h>
 326     #include <linux/joystick.h>
 327   ],[
 328     struct js_event js;
 329     js.type = JS_EVENT_AXIS;
 330   ])
 331 ], [
 332   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 333 ], [
 334   HAVE_LINUX_JOYSTICK_HEADERS="no"
 335 ])
 336 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 337
 338 dnl Check for -Bsymbolic-functions linker flag used to avoid
 339 dnl intra-library PLT jumps, if available.
 340 AC_ARG_ENABLE(Bsymbolic,
 341               [AC_HELP_STRING([--disable-Bsymbolic],
 342                               [avoid linking with -Bsymbolic])],,
 343               [SAVED_LDFLAGS="${LDFLAGS}"
 344                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 345                LDFLAGS=-Wl,-Bsymbolic-functions
 346                AC_TRY_LINK([], [int main (void) { return 0; }],
 347                            AC_MSG_RESULT(yes)
 348                            enable_Bsymbolic=yes,
 349                            AC_MSG_RESULT(no)
 350                            enable_Bsymbolic=no)
 351                LDFLAGS="${SAVED_LDFLAGS}"])
 352
 353
 354 dnl *** set variables based on configure arguments ***
 355
 356 dnl set license and copyright notice
 357 GST_LICENSE="LGPL"
 358 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 359 AC_SUBST(GST_LICENSE)
 360
 361 dnl set location of plugin directory
 362 AG_GST_SET_PLUGINDIR
 363
 364 dnl set release date/time
 365 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 366   ["${srcdir}/gst-plugins-base.doap"],
 367   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 368
 369 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 370 dnl make sure it doesn't complain about unused variables if debugging is disabled
 371 NO_WARNINGS=""
 372 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 373
 374 dnl define an ERROR_CFLAGS Makefile variable
 375 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 376 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 377     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 378     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 379     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 380     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 381
 382 dnl define an ERROR_CXXFLAGS Makefile variable
 383 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 384     -Wmissing-declarations -Wredundant-decls -Wundef
 385     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 386     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 387     -Wno-multichar $NO_WARNINGS])
 388
 389 dnl define correct level for debugging messages
 390 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 391
 392 dnl used in examples
 393 AG_GST_DEFAULT_ELEMENTS
 394
 395 dnl needed for encoding-target
 396 GST_DATADIR="$GST_PREFIX/share"
 397 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 398 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 399
 400 dnl behaviour of speex based audio resampler
 401 AC_MSG_CHECKING(which audio resample format to use for integer)
 402 AC_ARG_WITH([audioresample_format],
 403         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 404         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 405 AC_MSG_RESULT($ac_cv_audioresample_format)
 406 case $ac_cv_audioresample_format in
 407   int)
 408     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 409     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 410   ;;
 411   float)
 412     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 413     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 414   ;;
 415   auto)
 416     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 417     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 418 esac
 419
 420 dnl *** plug-ins to include ***
 421
 422 dnl these are all the gst plug-ins, compilable without additional libs
 423 AG_GST_CHECK_PLUGIN(adder)
 424 AG_GST_CHECK_PLUGIN(app)
 425 AG_GST_CHECK_PLUGIN(audioconvert)
 426 AG_GST_CHECK_PLUGIN(audiorate)
 427 AG_GST_CHECK_PLUGIN(audiotestsrc)
 428 AG_GST_CHECK_PLUGIN(encoding)
 429 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 430 AG_GST_CHECK_PLUGIN(gdp)
 431 AG_GST_CHECK_PLUGIN(playback)
 432 AG_GST_CHECK_PLUGIN(audioresample)
 433 AG_GST_CHECK_PLUGIN(subparse)
 434 AG_GST_CHECK_PLUGIN(tcp)
 435 AG_GST_CHECK_PLUGIN(typefind)
 436 AG_GST_CHECK_PLUGIN(videotestsrc)
 437 AG_GST_CHECK_PLUGIN(videorate)
 438 AG_GST_CHECK_PLUGIN(videoscale)
 439 AG_GST_CHECK_PLUGIN(volume)
 440
 441 dnl check for gstreamer core features (subsystems)
 442 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 443 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 444 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 445 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 446
 447 dnl disable plug-ins that require libxml2's HTML support if it is not available
 448 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 449   AG_GST_DISABLE_PLUGIN(subparse)
 450 fi
 451
 452 dnl disable plug-ins that require sys/socket.h if it is not available
 453 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 454   AG_GST_DISABLE_PLUGIN(tcp)
 455 fi
 456
 457 dnl iso-codes is optional, used by libgsttag
 458 AC_ARG_ENABLE(iso-codes,
 459 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 460 [case "${enableval}" in
 461   yes) enable_iso_codes=yes ;;
 462   no)  enable_iso_codes=no ;;
 463   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 464 esac
 465 ],
 466 [enable_iso_codes=yes]) dnl Default value
 467
 468 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 469 if test "x$enable_iso_codes" = "xyes"; then
 470   AC_MSG_RESULT([yes])
 471   have_iso_codes=no
 472   AC_MSG_CHECKING([whether iso-codes are available on this system])
 473   if $PKG_CONFIG iso-codes; then
 474     AC_MSG_RESULT([yes])
 475     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 476     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 477       AC_MSG_RESULT([yes])
 478       AC_MSG_CHECKING([for iso-codes prefix])
 479       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 480       if test -d "$ISO_CODES_PREFIX"; then
 481         AC_MSG_RESULT([yes])
 482         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 483         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 484         ISO_639_DOMAIN="iso_639"
 485         AC_MSG_CHECKING([ISO_639_DOMAIN])
 486         AC_MSG_RESULT([$ISO_639_DOMAIN])
 487         have_iso_codes=yes
 488         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 489         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 490         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 491         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 492       else
 493         AC_MSG_RESULT([no])
 494       fi
 495     else
 496       AC_MSG_RESULT([no])
 497     fi
 498   else
 499     AC_MSG_RESULT([no])
 500   fi
 501   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 502 else
 503   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 504   AM_CONDITIONAL(USE_ISO_CODES, false)
 505 fi
 506
 507 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 508 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 509 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 510   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 511       HAVE_ZLIB="yes"
 512     ], [
 513       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 514         HAVE_ZLIB="yes"
 515         ZLIB_LIBS="-lz"
 516         AC_SUBST(ZLIB_LIBS)
 517       ])
 518     ])
 519 ])
 520
 521 dnl *** sys plug-ins ***
 522
 523 echo
 524 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 525 echo
 526
 527 dnl *** X11 ***
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 529 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 530                   [ximagesink], [
 531   AC_PATH_XTRA
 532   ac_cflags_save="$CFLAGS"
 533   ac_cppflags_save="$CPPFLAGS"
 534   CFLAGS="$CFLAGS $X_CFLAGS"
 535   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 536
 537   dnl now try to find the HEADER
 538   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 539
 540   if test "x$HAVE_X" = "xno"
 541   then
 542     AC_MSG_NOTICE([cannot find X11 development files])
 543   else
 544     dnl this is much more than we want
 545     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 546     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 547     dnl it does not add the libs; therefore we add them here
 548     X_LIBS="$X_LIBS -lX11"
 549     AC_SUBST(X_CFLAGS)
 550     AC_SUBST(X_LIBS)
 551   fi
 552   AC_SUBST(HAVE_X)
 553   CFLAGS="$ac_cflags_save"
 554   CPPFLAGS="$ac_cppflags_save"
 555 ])
 556
 557 dnl Check for Xv extension
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 559 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 560                   [xvimagesink], [
 561   AG_GST_CHECK_XV
 562 ])
 563
 564 dnl check for X Shm
 565 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 566 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 567   if test x$HAVE_X = xyes; then
 568     AC_CHECK_LIB(Xext, XShmAttach,
 569                  HAVE_XSHM="yes", HAVE_XSHM="no",
 570                  $X_LIBS)
 571     if test "x$HAVE_XSHM" = "xyes"; then
 572       XSHM_LIBS="-lXext"
 573     else
 574       dnl On AIX, it is in XextSam instead, but we still need -lXext
 575       AC_CHECK_LIB(XextSam, XShmAttach,
 576                    HAVE_XSHM="yes", HAVE_XSHM="no",
 577                    $X_LIBS)
 578       if test "x$HAVE_XSHM" = "xyes"; then
 579         XSHM_LIBS="-lXext -lXextSam"
 580       fi
 581     fi
 582   fi
 583 ], , [
 584   AC_SUBST(HAVE_XSHM)
 585   AC_SUBST(XSHM_LIBS)
 586 ])
 587
 588 dnl v4l/v4l2 checks have been moved down because they require X
 589
 590 dnl *** Video 4 Linux ***
 591 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 592 dnl renamed to GST_V4L in accordance with V4L2 below
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 594 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 595   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 596 #include <sys/types.h>
 597 #define _LINUX_TIME_H
 598 #define __user
 599 #include <linux/videodev.h>
 600   ])
 601
 602   dnl we can build v4l without Xv, but then we won't have XOverlay support
 603   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 604   then
 605     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 606     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 607   fi
 608 ])
 609
 610 # Optional gudev for device probing
 611 AC_ARG_WITH([gudev],
 612   AC_HELP_STRING([--with-gudev],
 613     [device detection with gudev]),
 614   [],
 615   [with_gudev=check])
 616 if test x$HAVE_GST_V4L = xyes; then
 617   if test x$with_gudev != xno; then
 618       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 619           [ have_gudev=yes
 620             AC_DEFINE(HAVE_GUDEV, 1,
 621                [Whether gudev is available for device detection])
 622             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 623           ], [
 624           have_gudev=no
 625           ])
 626   else
 627     have_gudev=no
 628   fi
 629 fi
 630 AC_SUBST(GUDEV_CFLAGS)
 631 AC_SUBST(GUDEV_LIBS)
 632
 633 dnl *** ext plug-ins ***
 634 dnl keep this list sorted alphabetically !
 635
 636 if test "x$BUILD_EXTERNAL" = "xyes"; then
 637
 638 echo
 639 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 640 echo
 641
 642 dnl *** alsa ***
 643 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 644 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 645   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 646     HAVE_ALSA="yes"
 647     AC_SUBST(ALSA_CFLAGS)
 648     AC_SUBST(ALSA_LIBS)
 649   ], [
 650     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 651   ])
 652 ])
 653
 654 dnl *** CDParanoia ***
 655 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 657 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 658   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 659     HAVE_CDPARANOIA="yes"
 660   ], [
 661     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 662                         cdda_open, -lm,
 663                         cdda_interface.h,
 664                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 665                         HEADER_DIR="no"
 666                         FOUND_CDPARANOIA="yes")
 667     if test "x$FOUND_CDPARANOIA" != "xyes";
 668     then
 669       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 670                           cdda_open, -lm,
 671                           cdda/cdda_interface.h,
 672                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 673                           HEADER_DIR="yes"
 674                           FOUND_CDPARANOIA="yes")
 675     fi
 676     if test "x$HEADER_DIR" = "xyes";
 677     then
 678       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 679                          defined if cdda headers are in a cdda/ directory)
 680     fi
 681     if test "x$FOUND_CDPARANOIA" = "xyes";
 682     then
 683       AC_CHECK_LIB(cdda_paranoia,
 684                    paranoia_cachemodel_size,
 685                    : ,
 686                    HAVE_CDPARANOIA=no,
 687                  [-lcdda_interface])
 688     fi
 689
 690     AC_SUBST(CDPARANOIA_LIBS)
 691   ])
 692 ])
 693 dnl FIXME : add second check somehow if that is necessary
 694 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 695 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 696
 697 dnl *** GNOME VFS ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 699 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 700   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 701       HAVE_GNOME_VFS="yes"
 702       AC_SUBST(GNOME_VFS_CFLAGS)
 703       AC_SUBST(GNOME_VFS_LIBS)
 704       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 705       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 706              [The GnomeVFS modules directory.])
 707     ],[
 708       HAVE_GNOME_VFS="no"
 709     ]
 710     )
 711 ])
 712
 713 dnl *** ivorbis ***
 714 dnl AM_PATH_IVORBIS only takes two options
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 716 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 717   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 718   if test $HAVE_IVORBIS = no
 719   then
 720     IVORBIS_LIBS=
 721     IVORBIS_CFLAGS=
 722     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 723       [IVORBIS_LIBS=-lvorbisidec
 724       HAVE_IVORBIS=yes
 725       case $host in
 726       arm-*-*)
 727         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 728       esac
 729       ],
 730       HAVE_IVORBIS=no)
 731     AC_SUBST(IVORBIS_LIBS)
 732     AC_SUBST(IVORBIS_CFLAGS)
 733   else
 734     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 735       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 736       USE_TREMOLO=no)
 737   fi
 738 ])
 739
 740 dnl *** libgio ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 742 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 743   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 744     HAVE_GIO="yes"
 745     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 746     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 747            [The GIO modules directory.])
 748     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 749     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 750            [The GIO library directory.])
 751   ], [
 752     HAVE_GIO="no"
 753   ])
 754   AC_SUBST(GIO_CFLAGS)
 755   AC_SUBST(GIO_LIBS)
 756   AC_SUBST(GIO_LDFLAGS)
 757 ])
 758
 759 dnl *** libvisual ***
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 761 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 762   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 763   if test $HAVE_LIBVISUAL = no
 764   then
 765     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 766     if test x$HAVE_LIBVISUAL = xyes; then
 767       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 768     fi
 769   else
 770     if test x$HAVE_LIBVISUAL = xyes; then
 771       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 772     fi
 773   fi
 774   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 775   if test x$LIBVIS_PLUGINSDIR != x; then
 776     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 777         "$LIBVIS_PLUGINSDIR",
 778         [directory in which the detected libvisual's plugins are located])
 779   fi
 780 ])
 781
 782 dnl *** ogg ***
 783 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 784 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 785   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 786   if test $HAVE_OGG = no
 787   then
 788     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 789     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 790   fi
 791 ])
 792
 793 dnl *** pango ***
 794 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 795 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 796   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 797 ])
 798
 799 dnl *** theora ***
 800 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 801 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 802   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 803 ])
 804
 805 dnl *** vorbis ***
 806 dnl AM_PATH_VORBIS only takes two options
 807 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 808 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 809   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 810   if test $HAVE_VORBIS = no
 811   then
 812     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 813     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 814   fi
 815 ])
 816
 817 if test "x$HAVE_VORBIS" = "xyes"; then
 818   ac_cflags_save="$CFLAGS"
 819   AC_COMPILE_IFELSE([
 820     AC_LANG_PROGRAM([[
 821 #include <vorbis/codec.h>
 822                      ]],[[
 823 vorbis_dsp_state *v;
 824
 825 vorbis_synthesis_restart (v);
 826                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 827   if test "x$HAVE_VSR" = "xyes"; then
 828     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 829                        [defined if vorbis_synthesis_restart is present])
 830   fi
 831   CFLAGS="$ac_cflags_save"
 832 fi
 833
 834 else
 835
 836 dnl not building plugins with external dependencies,
 837 dnl but we still need to set the conditionals
 838 AM_CONDITIONAL(USE_ALSA, false)
 839 AM_CONDITIONAL(USE_CDPARANOIA, false)
 840 AM_CONDITIONAL(USE_GIO, false)
 841 AM_CONDITIONAL(USE_GNOME_VFS, false)
 842 AM_CONDITIONAL(USE_IVORBIS, false)
 843 AM_CONDITIONAL(USE_LIBVISUAL, false)
 844 AM_CONDITIONAL(USE_OGG, false)
 845 AM_CONDITIONAL(USE_PANGO, false)
 846 AM_CONDITIONAL(USE_THEORA, false)
 847 AM_CONDITIONAL(USE_VORBIS, false)
 848
 849 fi dnl of EXT plugins
 850
 851 dnl seeking needs freetype, so check for it here
 852 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 853   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 854 ])
 855 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 856 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 857 AC_SUBST(FT2_CFLAGS)
 858 AC_SUBST(FT2_LIBS)
 859
 860 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 861
 862 dnl Overview:
 863 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 864 dnl GST_*:              flags shared by built objects to link against GStreamer
 865 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 866 dnl                          (compare to other modules) or for i18n
 867 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 868 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 869 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 870 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 871
 872 dnl GST_OPTION_CFLAGS
 873 if test "x$USE_DEBUG" = xyes; then
 874    PROFILE_CFLAGS="-g"
 875 fi
 876 AC_SUBST(PROFILE_CFLAGS)
 877
 878 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 879   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 880   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 881 else
 882   DEPRECATED_CFLAGS=""
 883 fi
 884 AC_SUBST(DEPRECATED_CFLAGS)
 885
 886 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 887 dnl at make time with e.g. make ERROR_CFLAGS=""
 888 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 889 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 890 AC_SUBST(GST_OPTION_CFLAGS)
 891 AC_SUBST(GST_OPTION_CXXFLAGS)
 892
 893 dnl our libraries need to be versioned correctly
 894 AC_SUBST(GST_LT_LDFLAGS)
 895
 896 dnl GST_PLUGINS_BASE_CFLAGS
 897 dnl prefer internal headers to already installed ones
 898 dnl also add builddir include for enumtypes and marshal
 899 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 900 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 901
 902 dnl FIXME: do we want to rename to GST_ALL_* ?
 903 dnl add GST_OPTION_CFLAGS, but overridable
 904 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 905 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 906 AC_SUBST(GST_CFLAGS)
 907 AC_SUBST(GST_CXXFLAGS)
 908 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 909 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 910 AC_SUBST(GST_LIBS)
 911
 912 dnl LDFLAGS really should only contain flags, not libs - they get added before
 913 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 914 GST_ALL_LDFLAGS="-no-undefined"
 915 if test "x${enable_Bsymbolic}" = "xyes"; then
 916   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 917 fi
 918 AC_SUBST(GST_ALL_LDFLAGS)
 919
 920 dnl GST_LIB_LDFLAGS
 921 dnl linker flags shared by all libraries
 922 dnl LDFLAGS modifier defining exported symbols from built libraries
 923 dnl (export _gst_foo but not __gst_foo)
 924 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 925 AC_SUBST(GST_LIB_LDFLAGS)
 926
 927 dnl this really should only contain flags, not libs - they get added before
 928 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 929 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 930 AC_SUBST(GST_PLUGIN_LDFLAGS)
 931
 932 dnl *** output files ***
 933
 934 AC_CONFIG_FILES(
 935 Makefile
 936 gst-plugins-base.spec
 937 gst/Makefile
 938 gst/adder/Makefile
 939 gst/app/Makefile
 940 gst/audioconvert/Makefile
 941 gst/audiorate/Makefile
 942 gst/audiotestsrc/Makefile
 943 gst/encoding/Makefile
 944 gst/ffmpegcolorspace/Makefile
 945 gst/gdp/Makefile
 946 gst/playback/Makefile
 947 gst/audioresample/Makefile
 948 gst/subparse/Makefile
 949 gst/tcp/Makefile
 950 gst/typefind/Makefile
 951 gst/videotestsrc/Makefile
 952 gst/videorate/Makefile
 953 gst/videoscale/Makefile
 954 gst/volume/Makefile
 955 sys/Makefile
 956 sys/ximage/Makefile
 957 sys/xvimage/Makefile
 958 sys/v4l/Makefile
 959 ext/Makefile
 960 ext/alsa/Makefile
 961 ext/cdparanoia/Makefile
 962 ext/gnomevfs/Makefile
 963 ext/gio/Makefile
 964 ext/libvisual/Makefile
 965 ext/ogg/Makefile
 966 ext/pango/Makefile
 967 ext/theora/Makefile
 968 ext/vorbis/Makefile
 969 gst-libs/Makefile
 970 gst-libs/gst/Makefile
 971 gst-libs/gst/audio/Makefile
 972 gst-libs/gst/app/Makefile
 973 gst-libs/gst/cdda/Makefile
 974 gst-libs/gst/fft/Makefile
 975 gst-libs/gst/floatcast/Makefile
 976 gst-libs/gst/interfaces/Makefile
 977 gst-libs/gst/netbuffer/Makefile
 978 gst-libs/gst/riff/Makefile
 979 gst-libs/gst/rtp/Makefile
 980 gst-libs/gst/rtsp/Makefile
 981 gst-libs/gst/sdp/Makefile
 982 gst-libs/gst/tag/Makefile
 983 gst-libs/gst/pbutils/Makefile
 984 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 985 gst-libs/gst/video/Makefile
 986 tools/Makefile
 987 pkgconfig/Makefile
 988 pkgconfig/gstreamer-audio.pc
 989 pkgconfig/gstreamer-audio-uninstalled.pc
 990 pkgconfig/gstreamer-app.pc
 991 pkgconfig/gstreamer-app-uninstalled.pc
 992 pkgconfig/gstreamer-cdda.pc
 993 pkgconfig/gstreamer-cdda-uninstalled.pc
 994 pkgconfig/gstreamer-fft.pc
 995 pkgconfig/gstreamer-fft-uninstalled.pc
 996 pkgconfig/gstreamer-floatcast.pc
 997 pkgconfig/gstreamer-floatcast-uninstalled.pc
 998 pkgconfig/gstreamer-interfaces.pc
 999 pkgconfig/gstreamer-interfaces-uninstalled.pc
1000 pkgconfig/gstreamer-netbuffer.pc
1001 pkgconfig/gstreamer-netbuffer-uninstalled.pc
1002 pkgconfig/gstreamer-pbutils.pc
1003 pkgconfig/gstreamer-pbutils-uninstalled.pc
1004 pkgconfig/gstreamer-riff.pc
1005 pkgconfig/gstreamer-riff-uninstalled.pc
1006 pkgconfig/gstreamer-rtp.pc
1007 pkgconfig/gstreamer-rtp-uninstalled.pc
1008 pkgconfig/gstreamer-rtsp.pc
1009 pkgconfig/gstreamer-rtsp-uninstalled.pc
1010 pkgconfig/gstreamer-sdp.pc
1011 pkgconfig/gstreamer-sdp-uninstalled.pc
1012 pkgconfig/gstreamer-tag.pc
1013 pkgconfig/gstreamer-tag-uninstalled.pc
1014 pkgconfig/gstreamer-video.pc
1015 pkgconfig/gstreamer-video-uninstalled.pc
1016 pkgconfig/gstreamer-plugins-base.pc
1017 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1018 tests/Makefile
1019 tests/check/Makefile
1020 tests/examples/Makefile
1021 tests/examples/app/Makefile
1022 tests/examples/audio/Makefile
1023 tests/examples/dynamic/Makefile
1024 tests/examples/encoding/Makefile
1025 tests/examples/fft/Makefile
1026 tests/examples/gio/Makefile
1027 tests/examples/overlay/Makefile
1028 tests/examples/seek/Makefile
1029 tests/examples/snapshot/Makefile
1030 tests/examples/playback/Makefile
1031 tests/examples/playrec/Makefile
1032 tests/examples/v4l/Makefile
1033 tests/files/Makefile
1034 tests/icles/Makefile
1035 tests/icles/playback/Makefile
1036 docs/Makefile
1037 docs/design/Makefile
1038 docs/libs/Makefile
1039 docs/plugins/Makefile
1040 docs/version.entities
1041 po/Makefile.in
1042 common/Makefile
1043 common/m4/Makefile
1044 m4/Makefile
1045 )
1046
1047 dnl Create the config.h file for Visual Studio builds
1048 dnl Beware of spaces and /'s in some of the shell variable contents.
1049 sed \
1050     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1051     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1052     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1053     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1054     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1055     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1056     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1057     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1058     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1059     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1060     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1061     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1062     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1063     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1064     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1065     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1066     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1067     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1068     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1069     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1070     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1071     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1072     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1073     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1074     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1075     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1076     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1077     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1078     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1079     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1080     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1081     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1082     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1083     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1084     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1085     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1086     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1087     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1088     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1089     config.h.in >win32/common/config.h-new
1090
1091
1092
1093 AC_OUTPUT
1094
1095 AG_GST_OUTPUT_PLUGINS
1096 ORC_OUTPUT
1097