0.10.17.2 prelease
[platform/upstream/gstreamer.git] / configure.ac
1 AC_PREREQ(2.52)
2
3 dnl initialize autoconf
4 dnl when going to/from release please set the nano (fourth number) right !
5 dnl releases only do Wall, cvs and prerelease does Werror too
6 AC_INIT(GStreamer, 0.10.17.2,
7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
8     gstreamer)
9 AG_GST_INIT
10
11 dnl initialize automake
12 AM_INIT_AUTOMAKE
13
14 dnl define PACKAGE_VERSION_* variables
15 AS_VERSION
16
17 dnl check if this is a release version
18 AS_NANO(GST_CVS="no", GST_CVS="yes")
19
20 dnl can autoconf find the source ?
21 AC_CONFIG_SRCDIR([gst/gst.c])
22
23 dnl define the output header for config
24 AM_CONFIG_HEADER([config.h])
25
26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
27 AM_MAINTAINER_MODE
28
29 dnl sets host_* variables
30 AC_CANONICAL_HOST
31
32 dnl our libraries and install dirs use major.minor as a version
33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
34 dnl we override it here for release candidates for a new series
35 GST_MAJORMINOR=0.10
36 AC_SUBST(GST_MAJORMINOR)
37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
38   [library major.minor version])
39
40 dnl CURRENT, REVISION, AGE
41 dnl - library source changed -> increment REVISION
42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
43 dnl - interfaces added -> increment AGE
44 dnl - interfaces removed -> AGE = 0
45 dnl sets GST_LT_LDFLAGS
46 AS_LIBTOOL(GST, 15, 0, 15)
47
48 dnl FIXME: this macro doesn't actually work;
49 dnl the generated libtool script has no support for the listed tags.
50 dnl So this needs to be fixed first if we want to use this
51 dnl AS_LIBTOOL_TAGS
52
53 AM_PROG_LIBTOOL
54
55 dnl *** autotools stuff ****
56
57 dnl allow for different autotools
58 AS_AUTOTOOLS_ALTERNATE
59
60 dnl Add parameters for aclocal
61 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
62
63 dnl set up gettext
64 dnl the version check needs to stay here because autopoint greps for it
65 AM_GNU_GETTEXT_VERSION([0.11.5])
66 AM_GNU_GETTEXT([external])
67 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
68
69 dnl *** check for arguments to configure ***
70
71 dnl subsystems - can influence other decisions so needs to be high up
72 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
73 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
74 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
75 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
76 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
77 dnl define a substitution to use in docs/gst/gstreamer.types
78 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
79 then
80   GST_LOADSAVE_DOC_TYPES="%"
81 else
82   GST_LOADSAVE_DOC_TYPES=
83 fi
84 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
85 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
86 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
87 if test "x$GST_DISABLE_PARSE" = xyes; then
88   AC_DEFINE(GST_DISABLE_PARSE, 1,
89     [Define if pipeline parsing code is disabled])
90 fi
91 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
92 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
93 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
94 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
95 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
96 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
97 dnl define a substitution to use in docs/gst/gstreamer.types
98 if test "x$GST_DISABLE_REGISTRY" = "xyes"
99 then
100   GST_REGISTRY_DOC_TYPES="%"
101 else
102   GST_REGISTRY_DOC_TYPES=
103 fi
104 AC_SUBST(GST_REGISTRY_DOC_TYPES)
105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
106 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
107 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
108 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
109 dnl define a substitution to use in docs/gst/gstreamer.types
110 if test "x$GST_DISABLE_INDEX" = "xyes"
111 then
112   GST_INDEX_DOC_TYPES="%"
113 else
114   GST_INDEX_DOC_TYPES=
115 fi
116 AC_SUBST(GST_INDEX_DOC_TYPES)
117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
121 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
122 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
123
124 AG_GST_ARG_DEBUG
125 AG_GST_ARG_PROFILING
126 AG_GST_ARG_VALGRIND
127 AG_GST_ARG_GCOV
128
129 AG_GST_ARG_EXAMPLES
130
131 AG_GST_ARG_WITH_PKG_CONFIG_PATH
132 AG_GST_ARG_WITH_PACKAGE_NAME
133 AG_GST_ARG_WITH_PACKAGE_ORIGIN
134
135 dnl building of tests
136 AC_ARG_ENABLE(tests,
137   AC_HELP_STRING([--disable-tests], [disable building test apps]),
138   [
139     case "${enableval}" in
140       yes) BUILD_TESTS=yes ;;
141       no)  BUILD_TESTS=no ;;
142       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
143     esac
144   ],
145 [BUILD_TESTS=yes]) dnl Default value
146 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
147
148 dnl tests known to fail
149 AC_ARG_ENABLE(failing-tests,
150   AC_HELP_STRING([--disable-failing-tests],
151     [disable building tests known to fail]),
152   [
153     case "${enableval}" in
154       yes) BUILD_FAILING_TESTS=yes ;;
155       no)  BUILD_FAILING_TESTS=no ;;
156       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
157     esac
158   ],
159   [BUILD_FAILING_TESTS=no]) dnl Default value
160 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
161 if test x$BUILD_FAILING_TESTS = xyes; then
162   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
163 else
164   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
165 fi
166
167 dnl poison destroyed objects
168 AC_ARG_ENABLE(poisoning,
169   AC_HELP_STRING([--enable-poisoning],
170     [enable poisoning of deallocated objects]),
171   [
172     case "${enableval}" in
173       yes) USE_POISONING=yes ;;
174       no)  USE_POISONING=no ;;
175       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
176     esac
177   ],
178   [USE_POISONING=no]) dnl Default value
179 if test "x$USE_POISONING" = xyes; then
180   AC_DEFINE(USE_POISONING, 1,
181     [Define if we should poison deallocated memory])
182 fi
183
184 dnl Use binary registry
185 AC_ARG_ENABLE(binary-registry,
186   AC_HELP_STRING([--enable-binary-registry],
187     [enable experimental binary registry]),
188   [
189     case "${enableval}" in
190       yes) USE_BINARY_REGISTRY=yes ;;
191       no)  USE_BINARY_REGISTRY=no ;;
192       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
193     esac
194   ],
195   [USE_BINARY_REGISTRY=no]) dnl Default value
196
197 if test "x$USE_BINARY_REGISTRY" = xyes; then
198   dnl for gstconfig.h:
199   GST_USING_BINARY_REGISTRY_DEFINE="#define GST_USING_BINARY_REGISTRY"
200   dnl for config.h:
201   AC_DEFINE(USE_BINARY_REGISTRY, 1,
202     [Define if we should use binary registry instead xml registry])
203 else
204   GST_USING_BINARY_REGISTRY_DEFINE="#undef GST_USING_BINARY_REGISTRY"
205 fi
206 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
207 AC_SUBST(GST_USING_BINARY_REGISTRY_DEFINE)
208
209 dnl *** checks for platform ***
210
211 dnl * hardware/architecture *
212
213 dnl common/m4/gst-arch.m4
214 dnl check CPU type
215 AG_GST_ARCH
216 dnl substitution for win32/common/config.h
217 HOST_CPU=$host_cpu
218 AC_SUBST(HOST_CPU)
219
220 dnl common/m4/gst-arch.m4
221 dnl check for unaligned access
222 AG_GST_UNALIGNED_ACCESS
223 dnl create a configure variable for gst/gstconfig.h
224 if test x${as_cv_unaligned_access} = xyes ; then
225   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
226 else
227   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
228 fi
229 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
230
231 dnl * software *
232
233 dnl check for large file support
234 dnl affected plugins must include config.h
235 AC_SYS_LARGEFILE
236
237 dnl HAVE_WIN32 currently means "disable POSIXisms".
238 case "$host" in
239   *-*-mingw*)
240     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
241     ;;
242   *)
243     ;;
244 esac
245
246 dnl *** checks for programs ***
247
248 dnl find a compiler
249 AC_PROG_CC
250
251 dnl check if the compiler supports '-c' and '-o' options
252 AM_PROG_CC_C_O
253
254 dnl find an assembler
255 AM_PROG_AS
256
257 dnl Perl is used in building documentation and in the version checks
258 AC_PATH_PROG(PERL_PATH, perl, no)
259 if test x$PERL_PATH = xno; then
260   AC_MSG_ERROR(Could not find perl)
261 fi
262
263 dnl we require flex and bison for building the parser
264 AG_GST_BISON_CHECK
265 AG_GST_FLEX_CHECK
266
267 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
268 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
269
270 dnl check for documentation tools
271 AG_GST_DOCBOOK_CHECK
272 GTK_DOC_CHECK([1.3])
273 AS_PATH_PYTHON([2.1])
274 AG_GST_PLUGIN_DOCS([1.3],[2.1])
275
276 dnl *** checks for libraries ***
277
278 dnl For interactive UNIX (a Sun thing)
279 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
280 AC_ISC_POSIX
281
282 dnl check for libm, for sin()
283 AC_CHECK_LIBM
284 AC_SUBST(LIBM)
285
286 dnl *** checks for header files ***
287
288 dnl check if we have ANSI C header files
289 AC_HEADER_STDC
290
291 dnl Check for ucontext.h
292 AC_CHECK_HEADERS([ucontext.h])
293
294 dnl Check for sys/socket.h
295 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
296 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
297
298 dnl check for sys/times.h for tests/examples/adapter/
299 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
300 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
301 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
302
303 dnl Check for process.h for getpid() on win32
304 AC_CHECK_HEADERS([process.h])
305
306 dnl Check for sys/utsname.h for uname
307 AC_CHECK_HEADERS([sys/utsname.h])
308
309 dnl Check for stdio_ext.f for __fbufsize
310 AC_CHECK_HEADERS([stdio_ext.h])
311
312 dnl *** checks for types/defines ***
313
314 dnl *** checks for structures ***
315
316 dnl *** checks for compiler characteristics ***
317
318 dnl make sure we can use "inline" from C code
319 AC_C_INLINE
320
321 OPT_CFLAGS=
322 dnl Check for some compiler flags that optimize our code.
323 if test "x$GCC" = xyes; then
324   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
325 fi
326
327 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
328 dnl flag
329 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
330 dnl symbolic register names in inline asm
331 if test x$HAVE_CPU_PPC = xyes ; then
332   AS_COMPILER_FLAG(["-Wa,-mregnames"],
333     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
334 fi
335
336 dnl *** checks for library functions ***
337
338 AC_CHECK_FUNCS([sigaction])
339
340 dnl we use fork in the registry code
341 AC_CHECK_FUNCS([fork])
342
343 dnl check for fseeko()
344 AC_FUNC_FSEEKO
345 dnl check for ftello()
346 AC_CHECK_FUNCS([ftello])
347
348 AC_CHECK_FUNCS([fgetpos])
349 AC_CHECK_FUNCS([fsetpos])
350
351 dnl check for poll(), ppoll() and pselect()
352 AC_CHECK_FUNCS([poll])
353 AC_CHECK_FUNCS([ppoll])
354 AC_CHECK_FUNCS([pselect])
355
356 dnl check for mmap()
357 AC_FUNC_MMAP
358 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
359
360 dnl Check for POSIX timers
361 AC_CHECK_FUNCS(clock_gettime, [], [
362   AC_CHECK_LIB(rt, clock_gettime, [
363     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
364     LIBS="$LIBS -lrt"
365   ])
366 ])
367
368 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
369     AC_TRY_COMPILE([
370 #include <time.h>
371 #ifdef HAVE_UNISTD_H
372 #include <unistd.h>
373 #endif
374     ], [
375 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
376 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
377 #endif
378       return 0;
379     ], [
380       gst_cv_posix_timers=yes
381     ], [
382       gst_cv_posix_timers=no
383     ])
384 )
385
386 if test "$gst_cv_posix_timers" = "yes"; then
387   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
388   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
389 else
390   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
391 fi
392 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
393 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
394
395 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
396     AC_TRY_COMPILE([
397 #include <time.h>
398 #ifdef HAVE_UNISTD_H
399 #include <unistd.h>
400 #endif
401     ], [
402 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
403 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
404 #endif
405       return 0;
406     ], [
407       gst_cv_monotonic_clock=yes
408     ], [
409       gst_cv_monotonic_clock=no
410     ])
411 )
412
413 if test "$gst_cv_monotonic_clock" = "yes"; then
414   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
415   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
416 else
417   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
418 fi
419 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
420 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
421
422 dnl Check for a way to display the function name in debug output
423 AG_GST_CHECK_FUNCTION
424
425 dnl test for register_printf_function
426 AC_CHECK_FUNC(register_printf_function,
427   [
428     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
429     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
430     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
431     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
432       [Defined if we have register_printf_function ()])
433   ], [
434     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
435     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
436     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
437   ]
438 )
439 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
440 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
441 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
442
443 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
444 save_cflags="$CFLAGS"
445 CFLAGS="$CFLAGS -D_GNU_SOURCE"
446 AC_CHECK_LIB(dl, dladdr,
447    AC_DEFINE(HAVE_DLADDR, 1,
448              [Defined if we have dladdr ()]))
449 CFLAGS="$save_cflags"
450
451 dnl check for inet_aton()
452 save_libs="$LIBS"
453 AC_CHECK_FUNC(inet_aton, ,
454    AC_CHECK_LIB(nsl, inet_aton, ,
455       AC_CHECK_LIB(socket, inet_aton, ,
456          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
457 INET_ATON_LIBS=$LIBS
458 AC_SUBST(INET_ATON_LIBS)
459 LIBS="$save_libs"
460
461 dnl *** checks for dependency libraries ***
462
463 dnl GLib
464
465 AG_GST_GLIB_CHECK([2.8])
466
467 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
468 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
469 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
470
471 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
472 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
473
474 dnl Check for documentation xrefs
475 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
476 AC_SUBST(GLIB_PREFIX)
477
478 dnl libxml 2 is optional in some cases
479 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
480    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
481    test "x$USE_BINARY_REGISTRY" = "xyes" )
482 then
483   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
484   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
485 else
486   dnl check for libxml2 with minimum req version
487   AG_GST_LIBXML2_CHECK(2.4.9)
488   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
489 fi
490 AC_SUBST(GST_DISABLE_XML_DEFINE)
491
492 dnl check for "check", unit testing library/header
493 AM_PATH_CHECK(0.9.2,
494     [
495         HAVE_CHECK=yes
496         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
497         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
498     ],
499     HAVE_CHECK=no)
500 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
501
502 dnl pkg-config check that for libcheck that works for cross-compiling
503 dnl but not normal compilation on Fedora & Ubuntu:
504 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
505 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
506 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
507 dnl )
508
509 dnl *** set variables based on configure arguments
510
511 dnl set license and copyright notice
512 GST_LICENSE="LGPL"
513 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
514 AC_SUBST(GST_LICENSE)
515
516 dnl define LIBDIR so we can inform people where we live
517 AS_AC_EXPAND(LIBDIR, $libdir)
518 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
519
520 dnl set location of plugin directory
521 AG_GST_SET_PLUGINDIR
522
523 dnl FIXME: add LIBXML_PKG here if we use it
524 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
525 AC_SUBST(GST_PKG_DEPS)
526
527 dnl define an ERROR_CFLAGS Makefile variable
528 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
529
530 dnl define correct level for debugging messages
531 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
532
533 dnl *** finalize CFLAGS, LDFLAGS, LIBS
534
535 dnl Overview:
536 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
537 dnl GST_ALL_*:          vars shared by all built objects
538 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
539 dnl GST_OBJ_*:          additional vars to link to the core library
540 dnl                     include GST_ALL_*
541 dnl GST_LT_LDFLAGS:     library versioning of our libraries
542 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
543
544 dnl GST_OPTION_CFLAGS
545 if test "x$USE_DEBUG" = xyes; then
546    PROFILE_CFLAGS="-g"
547 fi
548 AC_SUBST(PROFILE_CFLAGS)
549
550 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
551 # functionality from the API that gstreamer uses
552 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
553 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
554   dnl Define _only_ during CVS (not pre-releases or releases)
555   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
556 else
557   DEPRECATED_CFLAGS=""
558 fi
559 AC_SUBST(DEPRECATED_CFLAGS)
560
561 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
562 dnl make DEPRECATED_CFLAGS=''
563 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
564 AC_SUBST(GST_OPTION_CFLAGS)
565
566 dnl GST_ALL_*
567 dnl vars common to for all internal objects (core libs, elements, applications)
568 dnl CFLAGS:
569 dnl - XML needs to be added because xmlPtr is used in core
570 dnl - src and build dirs need to be added because every piece that gets built
571 dnl   will need the GStreamer source and generated headers
572 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
573 dnl       from LibXML except for in the core library
574 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
575
576 dnl FIXME: check if LTLIBINTL is needed everywhere
577 dnl I presume it is given that it contains the symbols that _() stuff maps to
578 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
579
580 dnl LDFLAGS really should only contain flags, not libs - they get added before
581 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
582 GST_ALL_LDFLAGS="-no-undefined"
583
584 AC_SUBST(GST_ALL_CFLAGS)
585 AC_SUBST(GST_ALL_LIBS)
586 AC_SUBST(GST_ALL_LDFLAGS)
587
588 dnl GST_LIB_LDFLAGS
589 dnl linker flags shared by all libraries
590 dnl LDFLAGS modifier defining exported symbols from built libraries
591 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
592 AC_SUBST(GST_LIB_LDFLAGS)
593 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
594 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
595 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
596 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
597   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
598 fi
599 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
600
601 dnl GST_OBJ_*
602 dnl default vars for all internal objects built on libgstreamer
603 dnl includes GST_ALL_*
604 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
605 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
606 AC_SUBST(GST_OBJ_CFLAGS)
607 AC_SUBST(GST_OBJ_LIBS)
608
609 dnl GST_PLUGIN_LDFLAGS
610 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
611 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
612 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
613
614 AC_CONFIG_FILES(
615 Makefile
616 gst/Makefile
617 gst/gstconfig.h
618 gst/gstversion.h
619 gst/parse/Makefile
620 libs/Makefile
621 libs/gst/Makefile
622 libs/gst/base/Makefile
623 libs/gst/check/Makefile
624 libs/gst/controller/Makefile
625 libs/gst/dataprotocol/Makefile
626 libs/gst/net/Makefile
627 plugins/Makefile
628 plugins/indexers/Makefile
629 plugins/elements/Makefile
630 po/Makefile.in
631 tests/Makefile
632 tests/benchmarks/Makefile
633 tests/check/Makefile
634 tests/misc/Makefile
635 tests/examples/Makefile
636 tests/examples/adapter/Makefile
637 tests/examples/controller/Makefile
638 tests/examples/helloworld/Makefile
639 tests/examples/launch/Makefile
640 tests/examples/manual/Makefile
641 tests/examples/metadata/Makefile
642 tests/examples/queue/Makefile
643 tests/examples/typefind/Makefile
644 tests/examples/xml/Makefile
645 tools/Makefile
646 common/Makefile
647 common/m4/Makefile
648 docs/Makefile
649 docs/design/Makefile
650 docs/faq/Makefile
651 docs/gst/Makefile
652 docs/gst/gstreamer.types
653 docs/libs/Makefile
654 docs/plugins/Makefile
655 docs/manual/Makefile
656 docs/pwg/Makefile
657 docs/slides/Makefile
658 docs/xsl/Makefile
659 docs/version.entities
660 win32/common/config.h
661 pkgconfig/Makefile
662 stamp.h
663 pkgconfig/gstreamer.pc
664 pkgconfig/gstreamer-uninstalled.pc
665 pkgconfig/gstreamer-base.pc
666 pkgconfig/gstreamer-base-uninstalled.pc
667 pkgconfig/gstreamer-check.pc
668 pkgconfig/gstreamer-check-uninstalled.pc
669 pkgconfig/gstreamer-controller.pc
670 pkgconfig/gstreamer-controller-uninstalled.pc
671 pkgconfig/gstreamer-dataprotocol.pc
672 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
673 pkgconfig/gstreamer-net.pc
674 pkgconfig/gstreamer-net-uninstalled.pc
675 gst-element-check.m4
676 gstreamer.spec
677 )
678
679 AC_OUTPUT