configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gstreamer, GST_VERSION, 0, 10, 3, 1,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/gst.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  31 dnl we override it here for release candidates for a new series
  32 GST_MAJORMINOR=0.10
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 3, 0, 3)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 dnl subsystems - can influence other decisions so needs to be high up
  62 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  63 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  64 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  65 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  66 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  67 dnl define a substitution to use in docs/gst/gstreamer.types
  68 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  69 then
  70   GST_LOADSAVE_DOC_TYPES="%"
  71 else
  72   GST_LOADSAVE_DOC_TYPES=
  73 fi
  74 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  75 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  76 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  77 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  78 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  79 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  80 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  81 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  82 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  85 then
  86   GST_REGISTRY_DOC_TYPES="%"
  87 else
  88   GST_REGISTRY_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_REGISTRY_DOC_TYPES)
  91 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  92 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  93 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  94 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  95 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
  96 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
  97 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  98 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  99 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 100 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 101
 102 GST_ARG_DEBUG
 103 GST_ARG_PROFILING
 104 GST_ARG_VALGRIND
 105 GST_ARG_GCOV
 106
 107 GST_ARG_EXAMPLES
 108
 109 GST_ARG_WITH_PKG_CONFIG_PATH
 110 GST_ARG_WITH_PACKAGE_NAME([GStreamer])
 111 GST_ARG_WITH_PACKAGE_ORIGIN
 112
 113 dnl use a cache dir for storing element registry info.
 114 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 115
 116 AC_ARG_WITH(cachedir,
 117   AC_HELP_STRING([--with-cachedir],
 118     [specify path to use for plugin and command completion registries]),
 119   [
 120     case "${withval}" in
 121       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 122       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 123       *)   GST_CACHE_DIR="${withval}" ;;
 124     esac
 125   ],
 126   [:]) dnl Default value
 127
 128 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 129 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 130 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 131
 132 dnl building of tests
 133 AC_ARG_ENABLE(tests,
 134   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 135   [
 136     case "${enableval}" in
 137       yes) BUILD_TESTS=yes ;;
 138       no)  BUILD_TESTS=no ;;
 139       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 140     esac
 141   ],
 142 [BUILD_TESTS=yes]) dnl Default value
 143 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 144
 145 dnl tests known to fail
 146 AC_ARG_ENABLE(failing-tests,
 147   AC_HELP_STRING([--disable-failing-tests],
 148     [disable building tests known to fail]),
 149   [
 150     case "${enableval}" in
 151       yes) BUILD_FAILING_TESTS=yes ;;
 152       no)  BUILD_FAILING_TESTS=no ;;
 153       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 154     esac
 155   ],
 156   [BUILD_FAILING_TESTS=no]) dnl Default value
 157 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 158 if test x$BUILD_FAILING_TESTS = xyes; then
 159   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 160 else
 161   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 162 fi
 163
 164 dnl poison destroyed objects
 165 AC_ARG_ENABLE(poisoning,
 166   AC_HELP_STRING([--enable-poisoning],
 167     [enable poisoning of deallocated objects]),
 168   [
 169     case "${enableval}" in
 170       yes) USE_POISONING=yes ;;
 171       no)  USE_POISONING=no ;;
 172       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 173     esac
 174   ],
 175   [USE_POISONING=no]) dnl Default value
 176 if test "x$USE_POISONING" = xyes; then
 177   AC_DEFINE(USE_POISONING, 1,
 178     [Define if we should poison deallocated memory])
 179 fi
 180
 181 dnl *** checks for platform ***
 182
 183 dnl * hardware/architecture *
 184
 185 dnl common/m4/gst-arch.m4
 186 dnl check CPU type
 187 GST_ARCH
 188 dnl substitution for win32/common/config.h
 189 HOST_CPU=$host_cpu
 190 AC_SUBST(HOST_CPU)
 191
 192 dnl common/m4/gst-arch.m4
 193 dnl check for unaligned access
 194 GST_UNALIGNED_ACCESS
 195 dnl create a configure variable for gst/gstconfig.h
 196 if test x${as_cv_unaligned_access} = xyes ; then
 197   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 198 else
 199   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 200 fi
 201 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 202
 203 dnl * software *
 204
 205 dnl check for large file support
 206 dnl affected plugins must include config.h
 207 AC_SYS_LARGEFILE
 208
 209 dnl HAVE_WIN32 currently means "disable POSIXisms".
 210 case "$host" in
 211   *-*-mingw*)
 212     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 213     ;;
 214   *)
 215     ;;
 216 esac
 217
 218 dnl *** checks for programs ***
 219
 220 dnl find a compiler
 221 AC_PROG_CC
 222
 223 dnl find an assembler
 224 AM_PROG_AS
 225
 226 dnl we use awk in the bison version check
 227 AC_PROG_AWK
 228
 229 dnl we require bison for building the parser
 230 dnl FIXME: check if AC_PROG_YACC is suitable here
 231 dnl FIXME: make precious
 232 AC_PATH_PROG(BISON_PATH, bison, no)
 233 if test x$BISON_PATH = xno; then
 234   AC_MSG_ERROR(Could not find bison)
 235 fi
 236
 237 dnl check bison version
 238 AC_MSG_CHECKING([bison version])
 239
 240 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 241 then
 242   AC_MSG_RESULT([ok])
 243 else
 244   AC_MSG_RESULT([too old.])
 245   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 246 fi
 247
 248 dnl we require flex for building the parser
 249 dnl FIXME: check if AC_PROG_LEX is suitable here
 250 AC_PATH_PROG(FLEX_PATH, flex, no)
 251 if test x$FLEX_PATH = xno; then
 252   AC_MSG_ERROR(Could not find flex)
 253 fi
 254
 255 dnl Perl is used in building documentation
 256 AC_PATH_PROG(PERL_PATH, perl, no)
 257 if test x$PERL_PATH = xno; then
 258   AC_MSG_ERROR(Could not find perl)
 259 fi
 260
 261 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 262 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 263
 264 dnl check for documentation tools
 265 GST_DOCBOOK_CHECK
 266 GTK_DOC_CHECK([1.3])
 267 AS_PATH_PYTHON([2.1])
 268
 269 dnl *** checks for libraries ***
 270
 271 dnl For interactive UNIX (a Sun thing)
 272 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 273 AC_ISC_POSIX
 274
 275 dnl *** checks for header files ***
 276
 277 dnl check if we have ANSI C header files
 278 AC_HEADER_STDC
 279
 280 dnl Check for ucontext.h
 281 AC_CHECK_HEADERS([ucontext.h])
 282 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 283 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 284 AC_CHECK_HEADERS([process.h])
 285
 286 dnl *** checks for types/defines ***
 287
 288 dnl *** checks for structures ***
 289
 290 dnl *** checks for compiler characteristics ***
 291
 292 dnl make sure we can use "inline" from C code
 293 AC_C_INLINE
 294
 295 OPT_CFLAGS=
 296 dnl Check for some compiler flags that optimize our code.
 297 if test "x$GCC" = xyes; then
 298   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 299 fi
 300
 301 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 302 dnl flag
 303 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 304 dnl symbolic register names in inline asm
 305 if test x$HAVE_CPU_PPC = xyes ; then
 306   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 307     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 308 fi
 309
 310 dnl *** checks for library functions ***
 311
 312 AC_CHECK_FUNCS([sigaction])
 313
 314 dnl check for fseeko()
 315 AC_FUNC_FSEEKO
 316 dnl check for ftello()
 317 AC_CHECK_FUNCS([ftello])
 318
 319 AC_CHECK_FUNCS([fgetpos])
 320 AC_CHECK_FUNCS([fsetpos])
 321
 322 dnl check for mmap()
 323 AC_FUNC_MMAP
 324 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 325
 326 dnl Check for a way to display the function name in debug output
 327 GST_CHECK_FUNCTION
 328
 329 dnl test for register_printf_function
 330 AC_CHECK_FUNC(register_printf_function,
 331   [
 332     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 333     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 334       [Defined if we have register_printf_function ()])
 335   ],
 336   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 337 )
 338 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 339
 340 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 341 save_cflags="$CFLAGS"
 342 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 343 AC_CHECK_LIB(dl, dladdr,
 344    AC_DEFINE(HAVE_DLADDR, 1,
 345              [Defined if we have dladdr ()]))
 346 CFLAGS="$save_cflags"
 347
 348 dnl *** checks for dependancy libraries ***
 349
 350 dnl GLib
 351
 352 GST_GLIB_CHECK([2.6])
 353
 354 dnl GLib 2.8 has some bug fixes that we like, so make sure our code knows
 355 AC_MSG_CHECKING([glib version >= 2.8])
 356 if pkg-config --atleast-version=2.8 glib-2.0; then
 357   AC_MSG_RESULT(yes)
 358   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 359 else
 360   AC_MSG_RESULT(no)
 361   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 362 fi
 363 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 364
 365 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 366 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 367
 368 dnl libxml 2, which is/should be optional (FIXME)
 369 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 370    test "x$GST_DISABLE_REGISTRY" = "xyes"
 371 then
 372   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 373 else
 374   dnl check for libxml2 with minimum req version
 375   GST_LIBXML2_CHECK(2.4.9)
 376 fi
 377
 378 dnl check for "check", unit testing library/header
 379 AM_PATH_CHECK(0.9.2,
 380     [
 381         HAVE_CHECK=yes
 382         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 383         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 384     ],
 385     HAVE_CHECK=no)
 386 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 387
 388 dnl *** set variables based on configure arguments
 389
 390 dnl set license and copyright notice
 391 GST_LICENSE="LGPL"
 392 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 393 AC_SUBST(GST_LICENSE)
 394
 395 dnl define LIBDIR so we can inform people where we live
 396 AS_AC_EXPAND(LIBDIR, $libdir)
 397 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 398
 399 dnl set location of plugin directory
 400 GST_SET_PLUGINDIR
 401
 402 dnl FIXME: add LIBXML_PKG here
 403 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 404 AC_SUBST(GST_PKG_DEPS)
 405
 406 dnl define an ERROR_CFLAGS Makefile variable
 407 GST_SET_ERROR_CFLAGS($GST_CVS)
 408
 409 dnl define correct level for debugging messages
 410 GST_SET_LEVEL_DEFAULT($GST_CVS)
 411
 412 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 413
 414 dnl Overview:
 415 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 416 dnl GST_ALL_*:          vars shared by all built objects
 417 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 418 dnl GST_OBJ_*:          additional vars to link to the core library
 419 dnl                     include GST_ALL_*
 420 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 421 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 422
 423 dnl GST_OPTION_CFLAGS
 424 if test "x$USE_DEBUG" = xyes; then
 425    PROFILE_CFLAGS="-g"
 426 fi
 427 AC_SUBST(PROFILE_CFLAGS)
 428
 429 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 430 AC_SUBST(DEPRECATED_CFLAGS)
 431
 432 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 433 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 434 AC_SUBST(GST_OPTION_CFLAGS)
 435
 436 dnl GST_ALL_*
 437 dnl vars common to for all internal objects (core libs, elements, applications)
 438 dnl CFLAGS:
 439 dnl - XML needs to be added because xmlPtr is used in core
 440 dnl - src and build dirs need to be added because every piece that gets built
 441 dnl   will need the GStreamer source and generated headers
 442 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 443 dnl       from LibXML except for in the core library
 444 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 445 dnl FIXME: check if LTLIBINTL is needed everywhere
 446 dnl I presume it is given that it contains the symbols that _() stuff maps to
 447 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL"
 448 dnl LDFLAGS really should only contain flags, not libs - they get added before
 449 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 450 GST_ALL_LDFLAGS="-no-undefined"
 451
 452 AC_SUBST(GST_ALL_CFLAGS)
 453 AC_SUBST(GST_ALL_LIBS)
 454 AC_SUBST(GST_ALL_LDFLAGS)
 455
 456 dnl GST_LIB_LDFLAGS
 457 dnl linker flags shared by all libraries
 458 dnl LDFLAGS modifier defining exported symbols from built libraries
 459 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 460 AC_SUBST(GST_LIB_LDFLAGS)
 461
 462 dnl GST_OBJ_*
 463 dnl default vars for all internal objects built on libgstreamer
 464 dnl includes GST_ALL_*
 465 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 466 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 467 AC_SUBST(GST_OBJ_CFLAGS)
 468 AC_SUBST(GST_OBJ_LIBS)
 469
 470 dnl GST_PLUGIN_LDFLAGS
 471 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 472 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 473 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 474
 475 dnl ##################################################
 476 dnl # deps for examples from manual                  #
 477 dnl ##################################################
 478
 479 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 480                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 481 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 482
 483 AC_CONFIG_FILES(
 484 Makefile
 485 gst/Makefile
 486 gst/gstconfig.h
 487 gst/gstversion.h
 488 gst/parse/Makefile
 489 libs/Makefile
 490 libs/gst/Makefile
 491 libs/gst/base/Makefile
 492 libs/gst/check/Makefile
 493 libs/gst/controller/Makefile
 494 libs/gst/dataprotocol/Makefile
 495 libs/gst/net/Makefile
 496 plugins/Makefile
 497 plugins/indexers/Makefile
 498 plugins/elements/Makefile
 499 po/Makefile.in
 500 tests/Makefile
 501 tests/benchmarks/Makefile
 502 tests/check/Makefile
 503 tests/misc/Makefile
 504 tests/examples/Makefile
 505 tests/examples/controller/Makefile
 506 tests/examples/helloworld/Makefile
 507 tests/examples/launch/Makefile
 508 tests/examples/metadata/Makefile
 509 tests/examples/queue/Makefile
 510 tests/examples/typefind/Makefile
 511 tests/examples/xml/Makefile
 512 tools/Makefile
 513 common/Makefile
 514 common/m4/Makefile
 515 docs/Makefile
 516 docs/design/Makefile
 517 docs/faq/Makefile
 518 docs/gst/Makefile
 519 docs/gst/gstreamer.types
 520 docs/libs/Makefile
 521 docs/plugins/Makefile
 522 docs/manual/Makefile
 523 docs/pwg/Makefile
 524 docs/xsl/Makefile
 525 docs/version.entities
 526 win32/common/config.h
 527 pkgconfig/Makefile
 528 stamp.h
 529 pkgconfig/gstreamer.pc
 530 pkgconfig/gstreamer-uninstalled.pc
 531 pkgconfig/gstreamer-base.pc
 532 pkgconfig/gstreamer-base-uninstalled.pc
 533 pkgconfig/gstreamer-check.pc
 534 pkgconfig/gstreamer-check-uninstalled.pc
 535 pkgconfig/gstreamer-controller.pc
 536 pkgconfig/gstreamer-controller-uninstalled.pc
 537 pkgconfig/gstreamer-dataprotocol.pc
 538 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 539 pkgconfig/gstreamer-net.pc
 540 pkgconfig/gstreamer-net-uninstalled.pc
 541 gstreamer.spec
 542 )
 543
 544 AC_OUTPUT