configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 dnl
   8 dnl ==========> REMOVE GST_USE_UNSTABLE_API when doing 1.0.0 <=============
   9 dnl             (also check libtool version)
  10 dnl
  11 AC_INIT(GStreamer, 0.11.93.1,
  12     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  13     gstreamer)
  14 AG_GST_INIT
  15
  16 dnl initialize automake (we require GNU make)
  17 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  18
  19 dnl define PACKAGE_VERSION_* variables
  20 AS_VERSION
  21
  22 dnl check if this is a release version
  23 AS_NANO(GST_GIT="no", GST_GIT="yes")
  24
  25 dnl can autoconf find the source ?
  26 AC_CONFIG_SRCDIR([gst/gst.c])
  27
  28 dnl define the output header for config
  29 AM_CONFIG_HEADER([config.h])
  30
  31 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  32 AM_MAINTAINER_MODE([enable])
  33
  34 dnl sets host_* variables
  35 AC_CANONICAL_HOST
  36
  37 dnl use pretty build output with automake >= 1.11
  38 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  39   [AM_DEFAULT_VERBOSITY=1
  40    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41
  42 dnl GStreamer versioning, this is mostly informational
  43 dnl GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  44 dnl GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  45 dnl GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  46 dnl GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  47 dnl Change this to the above for non-pre
  48 GST_VERSION_MAJOR=1
  49 GST_VERSION_MINOR=0
  50 GST_VERSION_MICRO=0
  51 GST_VERSION_NANO=0
  52 AC_SUBST(GST_VERSION_MAJOR)
  53 AC_SUBST(GST_VERSION_MINOR)
  54 AC_SUBST(GST_VERSION_MICRO)
  55 AC_SUBST(GST_VERSION_NANO)
  56
  57 dnl our libraries and install dirs use GST_API_VERSION in the filename
  58 dnl to allow side-by-side installation of different API versions
  59 GST_API_VERSION=1.0
  60 AC_SUBST(GST_API_VERSION)
  61 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  62   [GStreamer API Version])
  63
  64 dnl CURRENT, REVISION, AGE
  65 dnl - library source changed -> increment REVISION
  66 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  67 dnl - interfaces added -> increment AGE
  68 dnl - interfaces removed -> AGE = 0
  69 dnl sets GST_LT_LDFLAGS
  70 AS_LIBTOOL(GST, 0, 0, 0)
  71
  72 dnl *** autotools stuff ****
  73
  74 dnl allow for different autotools
  75 AS_AUTOTOOLS_ALTERNATE
  76
  77 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  78 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  79
  80 dnl set up gettext
  81 dnl the version check needs to stay here because autopoint greps for it
  82 AM_GNU_GETTEXT_VERSION([0.17])
  83 AM_GNU_GETTEXT([external])
  84 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  85
  86 dnl *** check for arguments to configure ***
  87
  88 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  89
  90 dnl subsystems - can influence other decisions so needs to be high up
  91 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  93 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  94 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  95 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  96 if test "x$GST_DISABLE_PARSE" = xyes; then
  97   AC_DEFINE(GST_DISABLE_PARSE, 1,
  98     [Define if pipeline parsing code is disabled])
  99 fi
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
 101 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 102 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 103   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 104     [Define if option parsing is disabled])
 105 fi
 106 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 107 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 108 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 109 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 110 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 111 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 112 dnl define a substitution to use in docs/gst/gstreamer.types
 113 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 114 then
 115   GST_REGISTRY_DOC_TYPES="%"
 116 else
 117   GST_REGISTRY_DOC_TYPES=
 118 fi
 119 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 120 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 121 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 122
 123 AG_GST_ARG_DEBUG
 124 AG_GST_ARG_PROFILING
 125 AG_GST_ARG_VALGRIND
 126 AG_GST_ARG_GCOV
 127
 128 AG_GST_ARG_EXAMPLES
 129
 130 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 131 AG_GST_ARG_WITH_PACKAGE_NAME
 132 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 133
 134 AG_GST_PKG_CONFIG_PATH
 135
 136 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 137   ["${srcdir}/gstreamer.doap"],
 138   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 139
 140 dnl building of tests
 141 AC_ARG_ENABLE(tests,
 142   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 143   [
 144     case "${enableval}" in
 145       yes) BUILD_TESTS=yes ;;
 146       no)  BUILD_TESTS=no ;;
 147       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 148     esac
 149   ],
 150 [BUILD_TESTS=yes]) dnl Default value
 151 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 152
 153 dnl tests known to fail
 154 AC_ARG_ENABLE(failing-tests,
 155   AC_HELP_STRING([--disable-failing-tests],
 156     [disable building tests known to fail]),
 157   [
 158     case "${enableval}" in
 159       yes) BUILD_FAILING_TESTS=yes ;;
 160       no)  BUILD_FAILING_TESTS=no ;;
 161       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 162     esac
 163   ],
 164   [BUILD_FAILING_TESTS=no]) dnl Default value
 165 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 166 if test x$BUILD_FAILING_TESTS = xyes; then
 167   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 168 else
 169   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 170 fi
 171
 172 dnl building of benchmarks
 173 AC_ARG_ENABLE(benchmarks,
 174   AC_HELP_STRING([--disable-benchmarks], [disable building benchmarks apps]),
 175   [
 176     case "${enableval}" in
 177       yes) BUILD_BENCHMARKS=yes ;;
 178       no)  BUILD_BENCHMARKS=no ;;
 179       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 180     esac
 181   ],
 182 [BUILD_BENCHMARKS=yes]) dnl Default value
 183 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 184
 185 dnl building of tools
 186 AC_ARG_ENABLE(tools,
 187   AC_HELP_STRING([--disable-tools], [disable building tools]),
 188   [
 189     case "${enableval}" in
 190       yes) BUILD_TOOLS=yes ;;
 191       no)  BUILD_TOOLS=no ;;
 192       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 193     esac
 194   ],
 195 [BUILD_TOOLS=yes]) dnl Default value
 196 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 197
 198 dnl poison destroyed objects
 199 AC_ARG_ENABLE(poisoning,
 200   AC_HELP_STRING([--enable-poisoning],
 201     [enable poisoning of deallocated objects]),
 202   [
 203     case "${enableval}" in
 204       yes) USE_POISONING=yes ;;
 205       no)  USE_POISONING=no ;;
 206       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 207     esac
 208   ],
 209   [USE_POISONING=no]) dnl Default value
 210 if test "x$USE_POISONING" = xyes; then
 211   AC_DEFINE(USE_POISONING, 1,
 212     [Define if we should poison deallocated memory])
 213 fi
 214
 215 dnl *** checks for platform ***
 216
 217 dnl * hardware/architecture *
 218
 219 dnl common/m4/gst-arch.m4
 220 dnl check CPU type
 221 AG_GST_ARCH
 222 dnl substitution for win32/common/config.h
 223 HOST_CPU=$host_cpu
 224 AC_SUBST(HOST_CPU)
 225
 226 dnl common/m4/gst-arch.m4
 227 dnl check for unaligned access
 228 AG_GST_UNALIGNED_ACCESS
 229 dnl create a configure variable for gst/gstconfig.h
 230 if test x${as_cv_unaligned_access} = xyes ; then
 231   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 232 else
 233   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 234 fi
 235 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 236
 237 dnl check for platform specific settings
 238 AG_GST_PLATFORM
 239
 240 dnl * software *
 241
 242 dnl check for large file support
 243 dnl affected plugins must include config.h
 244 AC_SYS_LARGEFILE
 245
 246 dnl *** checks for programs ***
 247
 248 dnl find a compiler
 249 AC_PROG_CC
 250 AC_PROG_CC_STDC
 251
 252 dnl check if the compiler supports '-c' and '-o' options
 253 AM_PROG_CC_C_O
 254
 255 dnl find an assembler
 256 AM_PROG_AS
 257
 258 dnl determine if c++ is available on this system
 259 AC_PROG_CXX
 260 dnl CXX may be set to some default even if no c++ compiler is available
 261 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 262 AC_LANG_PUSH([C++])
 263 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 264 AC_LANG_POP([C++])
 265 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 266 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 267
 268 dnl Perl is used in building documentation and in the version checks
 269 AC_PATH_PROG(PERL_PATH, perl, no)
 270 if test x$PERL_PATH = xno; then
 271   AC_MSG_ERROR(Could not find perl)
 272 fi
 273
 274 dnl we require flex and bison for building the parser
 275 if test "x$GST_DISABLE_PARSE" != xyes; then
 276   AG_GST_BISON_CHECK
 277   AG_GST_FLEX_CHECK
 278 fi
 279
 280 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 281 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 282
 283 dnl check for gobject-introspection
 284 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 285
 286 dnl check for documentation tools
 287 AG_GST_DOCBOOK_CHECK
 288 GTK_DOC_CHECK([1.12])
 289 AS_PATH_PYTHON([2.1])
 290 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 291
 292 dnl *** checks for libraries ***
 293
 294 dnl check for libm, for sin()
 295 LT_LIB_M
 296 AC_SUBST(LIBM)
 297
 298 dnl *** checks for header files ***
 299
 300 dnl check if we have ANSI C header files
 301 AC_HEADER_STDC
 302
 303 dnl Check for ucontext.h
 304 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 305
 306 dnl Check for sys/socket.h
 307 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 308 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 309
 310 dnl check for sys/times.h for tests/examples/adapter/
 311 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 312 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 313 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 314
 315 dnl Check for process.h for getpid() on win32
 316 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 317
 318 dnl Check for sys/utsname.h for uname
 319 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 320
 321 dnl Check for stdio_ext.f for __fbufsize
 322 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 323
 324 dnl check for pthreads
 325 AC_CHECK_HEADERS([pthread.h], [HAVE_PTHREAD_H=yes], [HAVE_PTHREAD_H=no], [AC_INCLUDES_DEFAULT])
 326 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 327
 328 dnl check for sys/prctl for setting thread name on Linux
 329 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 330
 331 dnl Check for valgrind.h
 332 dnl separate from HAVE_VALGRIND because you can have the program, but not
 333 dnl the dev package
 334 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 335
 336 dnl used in gst/gstpoll.c
 337 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 338 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 339 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 340   WIN32_LIBS="-lws2_32"
 341   AC_SUBST(WIN32_LIBS)
 342 fi
 343
 344 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 345 if test "x$BUILD_TESTS" = "xyes"; then
 346   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 347                          __gmpz_init_set_d, ,
 348                          gmp.h,
 349                          GMP_LIBS="-lgmp"
 350                          AC_SUBST(GMP_LIBS)
 351                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 352   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 353                          gsl_rng_uniform_int, -lgslcblas,
 354                          gsl/gsl_rng.h,
 355                          GSL_LIBS="-lgsl -lgslcblas"
 356                          AC_SUBST(GSL_LIBS)
 357                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 358 fi
 359
 360 dnl *** checks for types/defines ***
 361
 362 dnl *** checks for structures ***
 363
 364 dnl *** checks for compiler characteristics ***
 365
 366 dnl check if the compiler supports __uint128_t (gcc)
 367 dnl Actually check for 128-bit division, since that's what we use
 368 dnl uint128_t for.
 369 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 370     AC_TRY_LINK([ ], [
 371       static __uint128_t v1 = 100;
 372       static __uint128_t v2 = 10;
 373       static __uint128_t u;
 374       u = v1 / v2;
 375     ], [
 376       gst_cv_uint128_t=yes
 377     ], [
 378       gst_cv_uint128_t=no
 379     ])
 380 )
 381 if test x$gst_cv_uint128_t = xyes; then
 382   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 383 fi
 384
 385 dnl *** checking for tm_gmtoff ***
 386 AC_MSG_CHECKING([for tm_gmtoff])
 387 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 388         #include <time.h>
 389         int main(void) {
 390           struct tm t;
 391           t.tm_gmtoff = 0;
 392           exit(0);
 393         }]])],
 394   [have_tm_gmtoff=yes
 395    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 396   [have_tm_gmtoff=no],
 397   [have_tm_gmtoff="no (cross compiling)"])
 398 AC_MSG_RESULT($have_tm_gmtoff)
 399
 400
 401 dnl *** checks for library functions ***
 402
 403 AC_CHECK_FUNCS([gmtime_r])
 404 AC_CHECK_FUNCS([localtime_r])
 405 AC_CHECK_FUNCS([sigaction])
 406
 407 dnl check for fseeko()
 408 AC_FUNC_FSEEKO
 409 dnl check for ftello()
 410 AC_CHECK_FUNCS([ftello])
 411
 412 AC_CHECK_FUNCS([fgetpos])
 413 AC_CHECK_FUNCS([fsetpos])
 414
 415 dnl check for poll(), ppoll() and pselect()
 416 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 417 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 418 AC_CHECK_FUNCS([poll])
 419 AC_CHECK_FUNCS([ppoll])
 420 AC_CHECK_FUNCS([pselect])
 421
 422 dnl ****************************************
 423 dnl *** GLib POLL* compatibility defines ***
 424 dnl ****************************************
 425
 426 AC_MSG_CHECKING([for broken poll])
 427 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 428         #include <stdlib.h>
 429         #include <fcntl.h>
 430         #ifdef HAVE_SYS_POLL_H
 431         #include <sys/poll.h>
 432         #endif
 433         #ifdef HAVE_POLL_H
 434         #include <poll.h>
 435         #endif
 436         int main(void) {
 437           struct pollfd fds[1];
 438           int fd;
 439           fd = open("/dev/null", 1);
 440           fds[0].fd = fd;
 441           fds[0].events = POLLIN;
 442           fds[0].revents = 0;
 443           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 444                 exit(1);  /* Does not work for devices -- fail */
 445           }
 446           exit(0);
 447         }]])],
 448   [broken_poll=no],
 449   [broken_poll=yes
 450    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 451   [broken_poll="no (cross compiling)"])
 452 AC_MSG_RESULT($broken_poll)
 453
 454 dnl check for mmap()
 455 AC_FUNC_MMAP
 456 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 457
 458 dnl check for posix_memalign(), getpagesize()
 459 AC_CHECK_FUNCS([posix_memalign])
 460 AC_CHECK_FUNCS([getpagesize])
 461
 462 dnl Check for POSIX timers
 463 AC_CHECK_FUNCS(clock_gettime, [], [
 464   AC_CHECK_LIB(rt, clock_gettime, [
 465     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 466     LIBS="$LIBS -lrt"
 467   ])
 468 ])
 469
 470 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 471     AC_TRY_COMPILE([
 472 #include <time.h>
 473 #ifdef HAVE_UNISTD_H
 474 #include <unistd.h>
 475 #endif
 476     ], [
 477 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 478 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 479 #endif
 480     ], [
 481       gst_cv_posix_timers=yes
 482     ], [
 483       gst_cv_posix_timers=no
 484     ])
 485 )
 486
 487 if test "$gst_cv_posix_timers" = "yes"; then
 488   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 489   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 490 else
 491   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 492 fi
 493 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 494 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 495
 496 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 497     AC_TRY_COMPILE([
 498 #include <time.h>
 499 #ifdef HAVE_UNISTD_H
 500 #include <unistd.h>
 501 #endif
 502     ], [
 503 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 504 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 505 #endif
 506     ], [
 507       gst_cv_monotonic_clock=yes
 508     ], [
 509       gst_cv_monotonic_clock=no
 510     ])
 511 )
 512
 513 if test "$gst_cv_monotonic_clock" = "yes"; then
 514   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 515   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 516 else
 517   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 518 fi
 519 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 520 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 521
 522 dnl Check for a way to display the function name in debug output
 523 AG_GST_CHECK_FUNCTION
 524
 525 dnl test for register_printf_specifier or register_printf_function
 526 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 527     [HAVE_PRINTF_EXTENSION=yes])
 528
 529 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 530   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 531   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 532   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 533   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 534       [Defined if we have printf specifier extensions available])
 535 else
 536     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 537     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 538     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 539 fi
 540 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 541 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 542 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 543
 544 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 545 save_cflags="$CFLAGS"
 546 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 547 AC_CHECK_LIB(dl, dladdr,
 548    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 549    LIBS="$LIBS -ldl")
 550 CFLAGS="$save_cflags"
 551
 552 dnl *** checks for dependency libraries ***
 553
 554 dnl GLib
 555 GLIB_REQ=2.32.0
 556 AG_GST_GLIB_CHECK([$GLIB_REQ])
 557
 558 dnl Check for documentation xrefs
 559 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 560 AC_SUBST(GLIB_PREFIX)
 561
 562 dnl building of unit test libraries
 563 AC_ARG_ENABLE(check,
 564   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 565   [
 566     case "${enableval}" in
 567       yes) BUILD_CHECK=yes ;;
 568       no)  BUILD_CHECK=no ;;
 569       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 570     esac
 571   ], [
 572     dnl Default value
 573     case $host_os in
 574       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 575       *) BUILD_CHECK=yes ;;
 576     esac
 577 ])
 578 dnl bit of a misnomer, but keep the conditional named like this so we don't
 579 dnl have to change too much elsewhere
 580 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 581
 582 dnl configure the desired memory alignment
 583 AC_ARG_WITH([memory-alignment],
 584   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 585   [
 586     if test "x$withval" = "xyes"
 587     then
 588       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 589     else
 590       case "${withval}" in
 591         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 592         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 593         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 594       esac
 595     fi
 596   ], [
 597     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 598   ]
 599 )
 600
 601 dnl Check for -Bsymbolic-functions linker flag used to avoid
 602 dnl intra-library PLT jumps, if available.
 603 AC_ARG_ENABLE(Bsymbolic,
 604               [AC_HELP_STRING([--disable-Bsymbolic],
 605                               [avoid linking with -Bsymbolic])],,
 606               [SAVED_LDFLAGS="${LDFLAGS}"
 607                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 608                LDFLAGS=-Wl,-Bsymbolic-functions
 609                AC_TRY_LINK([], [int main (void) { return 0; }],
 610                            AC_MSG_RESULT(yes)
 611                            enable_Bsymbolic=yes,
 612                            AC_MSG_RESULT(no)
 613                            enable_Bsymbolic=no)
 614                LDFLAGS="${SAVED_LDFLAGS}"])
 615
 616
 617 dnl *** set variables based on configure arguments
 618
 619 dnl set license and copyright notice
 620 GST_LICENSE="LGPL"
 621 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 622 AC_SUBST(GST_LICENSE)
 623
 624 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 625 AS_AC_EXPAND(LIBDIR, $libdir)
 626 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 627 AS_AC_EXPAND(DATADIR, $datadir)
 628 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 629
 630 dnl set location of plugin directory
 631 AG_GST_SET_PLUGINDIR
 632
 633 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 634 AC_SUBST(GST_PKG_DEPS)
 635
 636 dnl make sure it doesn't complain about unused variables if debugging is disabled
 637 NO_WARNINGS=""
 638 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 639   NO_WARNINGS="-Wno-unused"
 640 fi
 641
 642 dnl define an ERROR_CFLAGS Makefile variable
 643 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 644
 645 dnl define correct level for debugging messages
 646 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 647
 648 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 649
 650 dnl Overview:
 651 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 652 dnl GST_ALL_*:          vars shared by all built objects
 653 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 654 dnl GST_OBJ_*:          additional vars to link to the core library
 655 dnl                     include GST_ALL_*
 656 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 657 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 658
 659 dnl GST_OPTION_CFLAGS
 660 if test "x$USE_DEBUG" = xyes; then
 661    PROFILE_CFLAGS="-g"
 662 fi
 663 AC_SUBST(PROFILE_CFLAGS)
 664
 665 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 666 # functionality from the API that gstreamer uses
 667 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 668 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 669   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 670   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 671 else
 672   DEPRECATED_CFLAGS=""
 673 fi
 674 AC_SUBST(DEPRECATED_CFLAGS)
 675
 676 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 677 dnl make DEPRECATED_CFLAGS=''
 678 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 679 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 680 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS -DGST_USE_UNSTABLE_API"
 681 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS -DGST_USE_UNSTABLE_API"
 682 AC_SUBST(GST_OPTION_CFLAGS)
 683 AC_SUBST(GST_OPTION_CXXFLAGS)
 684
 685 dnl GST_ALL_*
 686 dnl vars common to for all internal objects (core libs, elements, applications)
 687 dnl CFLAGS:
 688 dnl - src and build dirs need to be added because every piece that gets built
 689 dnl   will need the GStreamer source and generated headers
 690 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 691 dnl       from LibXML except for in the core library
 692 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 693 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 694
 695 dnl FIXME: check if LTLIBINTL is needed everywhere
 696 dnl I presume it is given that it contains the symbols that _() stuff maps to
 697 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 698
 699 dnl LDFLAGS really should only contain flags, not libs - they get added before
 700 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 701 GST_ALL_LDFLAGS="-no-undefined"
 702 if test "x${enable_Bsymbolic}" = "xyes"; then
 703   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 704 fi
 705
 706 AC_SUBST(GST_ALL_CFLAGS)
 707 AC_SUBST(GST_ALL_CXXFLAGS)
 708 AC_SUBST(GST_ALL_LIBS)
 709 AC_SUBST(GST_ALL_LDFLAGS)
 710
 711 dnl GST_LIB_LDFLAGS
 712 dnl linker flags shared by all libraries
 713 dnl LDFLAGS modifier defining exported symbols from built libraries
 714 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 715 AC_SUBST(GST_LIB_LDFLAGS)
 716
 717 dnl GST_OBJ_*
 718 dnl default vars for all internal objects built on libgstreamer
 719 dnl includes GST_ALL_*
 720 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 721 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 722 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 723 AC_SUBST(GST_OBJ_CFLAGS)
 724 AC_SUBST(GST_OBJ_CXXFLAGS)
 725 AC_SUBST(GST_OBJ_LIBS)
 726
 727 dnl GST_PLUGIN_LDFLAGS
 728 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 729 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 730 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 731
 732 dnl plugin scanner locations
 733 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 734 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 735     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 736 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 737
 738 dnl things for our internal libcheck (must be called even if building
 739 dnl libcheck is disabled because it defines conditionals)
 740 AG_GST_CHECK_CHECKS()
 741
 742 AC_CONFIG_FILES(
 743 Makefile
 744 gst/Makefile
 745 gst/gstconfig.h
 746 gst/gstversion.h
 747 gst/parse/Makefile
 748 libs/Makefile
 749 libs/gst/Makefile
 750 libs/gst/base/Makefile
 751 libs/gst/check/Makefile
 752 libs/gst/check/libcheck/Makefile
 753 libs/gst/check/libcheck/check.h
 754 libs/gst/controller/Makefile
 755 libs/gst/helpers/Makefile
 756 libs/gst/net/Makefile
 757 plugins/Makefile
 758 plugins/elements/Makefile
 759 po/Makefile.in
 760 tests/Makefile
 761 tests/benchmarks/Makefile
 762 tests/check/Makefile
 763 tests/misc/Makefile
 764 tests/examples/Makefile
 765 tests/examples/adapter/Makefile
 766 tests/examples/controller/Makefile
 767 tests/examples/stepping/Makefile
 768 tests/examples/helloworld/Makefile
 769 tests/examples/launch/Makefile
 770 tests/examples/manual/Makefile
 771 tests/examples/memory/Makefile
 772 tests/examples/metadata/Makefile
 773 tests/examples/queue/Makefile
 774 tests/examples/streams/Makefile
 775 tests/examples/typefind/Makefile
 776 tools/Makefile
 777 common/Makefile
 778 common/m4/Makefile
 779 docs/Makefile
 780 docs/design/Makefile
 781 docs/faq/Makefile
 782 docs/gst/Makefile
 783 docs/gst/gstreamer.types
 784 docs/libs/Makefile
 785 docs/plugins/Makefile
 786 docs/manual/Makefile
 787 docs/pwg/Makefile
 788 docs/slides/Makefile
 789 docs/xsl/Makefile
 790 docs/version.entities
 791 m4/Makefile
 792 pkgconfig/Makefile
 793 stamp.h
 794 pkgconfig/gstreamer.pc
 795 pkgconfig/gstreamer-uninstalled.pc
 796 pkgconfig/gstreamer-base.pc
 797 pkgconfig/gstreamer-base-uninstalled.pc
 798 pkgconfig/gstreamer-check.pc
 799 pkgconfig/gstreamer-check-uninstalled.pc
 800 pkgconfig/gstreamer-controller.pc
 801 pkgconfig/gstreamer-controller-uninstalled.pc
 802 pkgconfig/gstreamer-net.pc
 803 pkgconfig/gstreamer-net-uninstalled.pc
 804 gstreamer.spec
 805 )
 806
 807 dnl Create the config.h file for Visual Studio builds
 808 dnl Beware of spaces and /'s in some of the shell variable contents.
 809 sed \
 810     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 811     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 812     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 813     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 814     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 815     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 816     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 817     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 818     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 819     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 820     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 821     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 822     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 823     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 824     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 825     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 826     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 827     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 828     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 829     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 830     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 831     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 832     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 833     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 834     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 835     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 836     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 837     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 838     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 839     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 840     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 841     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 842     config.h.in >win32/common/config.h-new
 843
 844 AC_OUTPUT
 845
 846 dnl negate for output
 847 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 848 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 849 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 850 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 851 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 852 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 853 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 854
 855 echo "
 856
 857 Configuration
 858         Version                    : ${VERSION}
 859         Source code location       : ${srcdir}
 860         Prefix                     : ${prefix}
 861         Compiler                   : ${CC}
 862         Package name               : ${GST_PACKAGE_NAME}
 863         Package origin             : ${GST_PACKAGE_ORIGIN}
 864
 865         Documentation (manuals)    : ${enable_docbook}
 866         Documentation (API)        : ${enable_gtk_doc}
 867
 868         Debug Logging              : ${enable_gst_debug}
 869         Command-line parser        : ${enable_parse}
 870         Option parsing in gst_init : ${enable_option_parsing}
 871         Tracing subsystem          : ${enable_trace}
 872         Allocation tracing         : ${enable_alloc_trace}
 873         Plugin registry            : ${enable_registry}
 874         Plugin support             : ${enable_plugin}
 875         Unit testing support       : ${BUILD_CHECK}
 876
 877         Debug                      : ${USE_DEBUG}
 878         Profiling                  : ${USE_PROFILING}
 879
 880         Building benchmarks        : ${BUILD_BENCHMARKS}
 881         Building examples          : ${BUILD_EXAMPLES}
 882         Building test apps         : ${BUILD_TESTS}
 883         Building tests that fail   : ${BUILD_FAILING_TESTS}
 884         Building tools             : ${BUILD_TOOLS}
 885 "