configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 101, 0, 101)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE([
 181   AC_LANG_PROGRAM([[
 182 #include <libxml/HTMLparser.h>
 183 ]],[[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187 ]])], [
 188   HAVE_LIBXML_HTML="yes"
 189 ], [
 190   HAVE_LIBXML_HTML="no"
 191 ])
 192 CPPFLAGS="$ac_cppflags_save"
 193 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 194
 195 dnl used in gst/tcp
 196 AC_CHECK_HEADERS([sys/socket.h],
 197   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 198 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 202
 203 dnl checks for ARM NEON support
 204 dnl this instruction set is used by the speex resampler code
 205 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 206 AC_LINK_IFELSE([
 207 AC_LANG_PROGRAM([[
 208   #include <arm_neon.h>
 209   int32x4_t testfunc(int16_t *a, int16_t *b) {
 210       return vmull_s16(vld1_s16(a), vld1_s16(b));
 211   }
 212 ]])],
 213 [
 214   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 215   AC_MSG_RESULT(yes)
 216 ],
 217 [
 218   AC_MSG_RESULT(no)
 219 ])
 220
 221 dnl also, Windows does not have long long
 222 AX_CREATE_STDINT_H
 223
 224 dnl *** checks for functions ***
 225 AC_CHECK_FUNCS([localtime_r gmtime_r])
 226
 227 dnl *** checks for math functions ***
 228 LIBS_SAVE=$LIBS
 229 LIBS="$LIBS $LIBM"
 230 AC_CHECK_FUNCS(log2)
 231 LIBS=$LIBS_SAVE
 232
 233 dnl *** checks for types/defines ***
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl *** checks for library functions ***
 240
 241 dnl check for fseeko()
 242 AC_FUNC_FSEEKO
 243
 244 dnl Check for fast float to int casting as defined in C99
 245 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 246 save_libs=$LIBS
 247 LIBS="$LIBS $LIBM"
 248 AC_C99_FUNC_LRINT
 249 AC_C99_FUNC_LRINTF
 250 LIBS=$save_libs
 251
 252 dnl Check for a way to display the function name in debug output
 253 AG_GST_CHECK_FUNCTION
 254
 255 dnl *** checks for dependency libraries ***
 256
 257 dnl GLib
 258 GLIB_REQ=2.32
 259 AG_GST_GLIB_CHECK([$GLIB_REQ])
 260
 261 ORC_CHECK([0.4.17])
 262
 263 dnl checks for gstreamer
 264 dnl uninstalled is selected preferentially -- see pkg-config(1)
 265 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 269 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 270
 271 dnl Check for documentation xrefs
 272 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 273 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 274 AC_SUBST(GLIB_PREFIX)
 275 AC_SUBST(GST_PREFIX)
 276
 277 dnl GTK is optional and only used in examples
 278 HAVE_GTK=no
 279 HAVE_GTK_X11=no
 280 GTK_REQ=3.0.0
 281 if test "x$BUILD_EXAMPLES" = "xyes"; then
 282   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 283   dnl some examples need gtk+-x11
 284   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 285   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 286   AC_SUBST(GTK_LIBS)
 287   AC_SUBST(GTK_CFLAGS)
 288 fi
 289 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 290 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 291 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 292
 293 dnl QT is optional and only used in examples
 294 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 295   HAVE_QT_GV=yes
 296   HAVE_QT=yes
 297 ], [
 298   HAVE_QT_GV=no
 299   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 300 ])
 301 if test "x$HAVE_QT" = "xyes"; then
 302   AC_MSG_CHECKING([Qt moc])
 303   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 304   AC_MSG_RESULT($QT4_MOC)
 305   AC_SUBST(QT4_MOC)
 306 fi
 307 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 308 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 309
 310 dnl chck for linux headers needed by the joystick seek example
 311 AC_COMPILE_IFELSE(
 312 [
 313   AC_LANG_PROGRAM([
 314     #include <linux/input.h>
 315     #include <linux/joystick.h>
 316   ],[
 317     struct js_event js;
 318     js.type = JS_EVENT_AXIS;
 319   ])
 320 ], [
 321   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 322 ], [
 323   HAVE_LINUX_JOYSTICK_HEADERS="no"
 324 ])
 325 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 326
 327 dnl Check for -Bsymbolic-functions linker flag used to avoid
 328 dnl intra-library PLT jumps, if available.
 329 AC_ARG_ENABLE(Bsymbolic,
 330               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 331               [SAVED_LDFLAGS="${LDFLAGS}"
 332                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 333                LDFLAGS=-Wl,-Bsymbolic-functions
 334                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 335                            AC_MSG_RESULT(yes)
 336                            enable_Bsymbolic=yes],[
 337                            AC_MSG_RESULT(no)
 338                            enable_Bsymbolic=no])
 339                LDFLAGS="${SAVED_LDFLAGS}"])
 340
 341
 342 dnl *** set variables based on configure arguments ***
 343
 344 dnl set license and copyright notice
 345 GST_LICENSE="LGPL"
 346 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 347 AC_SUBST(GST_LICENSE)
 348
 349 dnl set location of plugin directory
 350 AG_GST_SET_PLUGINDIR
 351
 352 dnl set release date/time
 353 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 354   ["${srcdir}/gst-plugins-base.doap"],
 355   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 356
 357 dnl build static plugins or not
 358 AC_MSG_CHECKING([whether to build static plugins or not])
 359 AC_ARG_ENABLE(
 360   static-plugins,
 361   AC_HELP_STRING(
 362     [--enable-static-plugins],
 363     [build static plugins @<:@default=no@:>@]),
 364   [AS_CASE(
 365     [$enableval], [no], [], [yes], [],
 366     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 367   [enable_static_plugins=no])
 368 AC_MSG_RESULT([$enable_static_plugins])
 369 if test "x$enable_static_plugins" = xyes; then
 370   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 371     [Define if static plugins should be built])
 372   GST_PLUGIN_LIBTOOLFLAGS=""
 373 else
 374   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 375 fi
 376 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 377 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 378
 379 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 380 dnl make sure it doesn't complain about unused variables if debugging is disabled
 381 NO_WARNINGS=""
 382 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 383
 384 dnl define an ERROR_CFLAGS Makefile variable
 385 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 386 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 387     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 388     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 389     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 390     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 391
 392 dnl define an ERROR_CXXFLAGS Makefile variable
 393 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 394     -Wmissing-declarations -Wredundant-decls -Wundef
 395     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 396     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 397     -Wno-multichar $NO_WARNINGS])
 398
 399 dnl define correct level for debugging messages
 400 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 401
 402 dnl used in examples
 403 AG_GST_DEFAULT_ELEMENTS
 404
 405 dnl needed for encoding-target
 406 GST_DATADIR="$GST_PREFIX/share"
 407 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 408 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 409
 410 dnl behaviour of speex based audio resampler
 411 AC_MSG_CHECKING(which audio resample format to use for integer)
 412 AC_ARG_WITH([audioresample_format],
 413         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 414         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 415 AC_MSG_RESULT($ac_cv_audioresample_format)
 416 case $ac_cv_audioresample_format in
 417   int)
 418     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 419     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 420   ;;
 421   float)
 422     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 423     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 424   ;;
 425   auto)
 426     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 427     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 428 esac
 429
 430 dnl Check for mmap (needed by allocators library)
 431 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 432
 433 dnl *** plug-ins to include ***
 434
 435 dnl these are all the gst plug-ins, compilable without additional libs
 436 AG_GST_CHECK_PLUGIN(adder)
 437 AG_GST_CHECK_PLUGIN(app)
 438 AG_GST_CHECK_PLUGIN(audioconvert)
 439 AG_GST_CHECK_PLUGIN(audiorate)
 440 AG_GST_CHECK_PLUGIN(audiotestsrc)
 441 AG_GST_CHECK_PLUGIN(encoding)
 442 AG_GST_CHECK_PLUGIN(videoconvert)
 443 AG_GST_CHECK_PLUGIN(gio)
 444 AG_GST_CHECK_PLUGIN(playback)
 445 AG_GST_CHECK_PLUGIN(audioresample)
 446 AG_GST_CHECK_PLUGIN(subparse)
 447 AG_GST_CHECK_PLUGIN(tcp)
 448 AG_GST_CHECK_PLUGIN(typefind)
 449 AG_GST_CHECK_PLUGIN(videotestsrc)
 450 AG_GST_CHECK_PLUGIN(videorate)
 451 AG_GST_CHECK_PLUGIN(videoscale)
 452 AG_GST_CHECK_PLUGIN(volume)
 453
 454 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 455 AM_CONDITIONAL(USE_XML, false)
 456 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 457
 458 dnl disable plug-ins that require libxml2's HTML support if it is not available
 459 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 460   AG_GST_DISABLE_PLUGIN(subparse)
 461 fi
 462
 463 dnl iso-codes is optional, used by libgsttag
 464 AC_ARG_ENABLE(iso-codes,
 465 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 466 [case "${enableval}" in
 467   yes) enable_iso_codes=yes ;;
 468   no)  enable_iso_codes=no ;;
 469   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 470 esac
 471 ],
 472 [enable_iso_codes=yes]) dnl Default value
 473
 474 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 475 if test "x$enable_iso_codes" = "xyes"; then
 476   AC_MSG_RESULT([yes])
 477   have_iso_codes=no
 478   AC_MSG_CHECKING([whether iso-codes are available on this system])
 479   if $PKG_CONFIG iso-codes; then
 480     AC_MSG_RESULT([yes])
 481     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 482     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 483       AC_MSG_RESULT([yes])
 484       AC_MSG_CHECKING([for iso-codes prefix])
 485       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 486       if test -d "$ISO_CODES_PREFIX"; then
 487         AC_MSG_RESULT([yes])
 488         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 489         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 490         ISO_639_DOMAIN="iso_639"
 491         AC_MSG_CHECKING([ISO_639_DOMAIN])
 492         AC_MSG_RESULT([$ISO_639_DOMAIN])
 493         have_iso_codes=yes
 494         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 495         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 496         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 497         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 498       else
 499         AC_MSG_RESULT([no])
 500       fi
 501     else
 502       AC_MSG_RESULT([no])
 503     fi
 504   else
 505     AC_MSG_RESULT([no])
 506   fi
 507   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 508 else
 509   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 510   AM_CONDITIONAL(USE_ISO_CODES, false)
 511 fi
 512
 513 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 514 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 515 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 516   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 517       HAVE_ZLIB="yes"
 518     ], [
 519       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 520         HAVE_ZLIB="yes"
 521         ZLIB_LIBS="-lz"
 522         AC_SUBST(ZLIB_LIBS)
 523       ])
 524     ])
 525 ])
 526
 527 dnl *** sys plug-ins ***
 528
 529 echo
 530 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 531 echo
 532
 533 dnl *** X11 ***
 534 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 535 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 536                   [ximagesink], [
 537   AC_PATH_XTRA
 538   ac_cflags_save="$CFLAGS"
 539   ac_cppflags_save="$CPPFLAGS"
 540   CFLAGS="$CFLAGS $X_CFLAGS"
 541   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 542
 543   dnl now try to find the HEADER
 544   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 545
 546   if test "x$HAVE_X" = "xno"
 547   then
 548     AC_MSG_NOTICE([cannot find X11 development files])
 549   else
 550     dnl this is much more than we want
 551     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 552     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 553     dnl it does not add the libs; therefore we add them here
 554     X_LIBS="$X_LIBS -lX11"
 555     AC_SUBST(X_CFLAGS)
 556     AC_SUBST(X_LIBS)
 557   fi
 558   AC_SUBST(HAVE_X)
 559   CFLAGS="$ac_cflags_save"
 560   CPPFLAGS="$ac_cppflags_save"
 561 ])
 562
 563 dnl Check for Xv extension
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 565 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 566                   [xvimagesink], [
 567   AG_GST_CHECK_XV
 568 ])
 569
 570 dnl check for X Shm
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 572 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 573   if test x$HAVE_X = xyes; then
 574     AC_CHECK_LIB(Xext, XShmAttach,
 575                  HAVE_XSHM="yes", HAVE_XSHM="no",
 576                  $X_LIBS)
 577     if test "x$HAVE_XSHM" = "xyes"; then
 578       XSHM_LIBS="-lXext"
 579     else
 580       dnl On AIX, it is in XextSam instead, but we still need -lXext
 581       AC_CHECK_LIB(XextSam, XShmAttach,
 582                    HAVE_XSHM="yes", HAVE_XSHM="no",
 583                    $X_LIBS)
 584       if test "x$HAVE_XSHM" = "xyes"; then
 585         XSHM_LIBS="-lXext -lXextSam"
 586       fi
 587     fi
 588   fi
 589 ], , [
 590   AC_SUBST(HAVE_XSHM)
 591   AC_SUBST(XSHM_LIBS)
 592 ])
 593
 594 dnl *** ext plug-ins ***
 595 dnl keep this list sorted alphabetically !
 596
 597 if test "x$BUILD_EXTERNAL" = "xyes"; then
 598
 599 echo
 600 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 601 echo
 602
 603 dnl *** alsa ***
 604 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 605 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 606   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 607     HAVE_ALSA="yes"
 608     AC_SUBST(ALSA_CFLAGS)
 609     AC_SUBST(ALSA_LIBS)
 610   ], [
 611     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 612   ])
 613 ])
 614
 615 dnl *** CDParanoia ***
 616 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 618 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 619   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 620     HAVE_CDPARANOIA="yes"
 621   ], [
 622     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 623                         cdda_open, -lm,
 624                         cdda_interface.h,
 625                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 626                         HEADER_DIR="no"
 627                         FOUND_CDPARANOIA="yes")
 628     if test "x$FOUND_CDPARANOIA" != "xyes";
 629     then
 630       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 631                           cdda_open, -lm,
 632                           cdda/cdda_interface.h,
 633                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 634                           HEADER_DIR="yes"
 635                           FOUND_CDPARANOIA="yes")
 636     fi
 637     if test "x$HEADER_DIR" = "xyes";
 638     then
 639       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 640                          defined if cdda headers are in a cdda/ directory)
 641     fi
 642     if test "x$FOUND_CDPARANOIA" = "xyes";
 643     then
 644       AC_CHECK_LIB(cdda_paranoia,
 645                    paranoia_cachemodel_size,
 646                    : ,
 647                    HAVE_CDPARANOIA=no,
 648                  [-lcdda_interface])
 649     fi
 650
 651     AC_SUBST(CDPARANOIA_LIBS)
 652   ])
 653 ])
 654 dnl FIXME : add second check somehow if that is necessary
 655 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 656 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 657
 658 dnl *** ivorbis ***
 659 dnl AM_PATH_IVORBIS only takes two options
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 661 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 662   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 663   if test $HAVE_IVORBIS = no
 664   then
 665     IVORBIS_LIBS=
 666     IVORBIS_CFLAGS=
 667     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 668       [IVORBIS_LIBS=-lvorbisidec
 669       HAVE_IVORBIS=yes
 670       case $host in
 671       arm-*-*)
 672         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 673       esac
 674       ],
 675       HAVE_IVORBIS=no)
 676     AC_SUBST(IVORBIS_LIBS)
 677     AC_SUBST(IVORBIS_CFLAGS)
 678   else
 679     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 680       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 681       USE_TREMOLO=no)
 682   fi
 683 ])
 684
 685 dnl *** libvisual ***
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 687 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 688   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 689   if test $HAVE_LIBVISUAL = no
 690   then
 691     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 692     if test x$HAVE_LIBVISUAL = xyes; then
 693       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 694     fi
 695   else
 696     if test x$HAVE_LIBVISUAL = xyes; then
 697       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 698     fi
 699   fi
 700   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 701   if test x$LIBVIS_PLUGINSDIR != x; then
 702     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 703         "$LIBVIS_PLUGINSDIR",
 704         [directory in which the detected libvisual's plugins are located])
 705   fi
 706 ])
 707
 708 dnl *** ogg ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 710 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 711   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 712   if test $HAVE_OGG = no
 713   then
 714     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 715     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 716   fi
 717 ])
 718
 719 dnl *** pango ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 721 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 722   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 723 ])
 724
 725 dnl *** theora ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 727 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 728   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 729 ])
 730
 731 dnl *** vorbis ***
 732 dnl AM_PATH_VORBIS only takes two options
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 734 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 735   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 736   if test $HAVE_VORBIS = no
 737   then
 738     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 739     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 740   fi
 741 ])
 742
 743 if test "x$HAVE_VORBIS" = "xyes"; then
 744   ac_cflags_save="$CFLAGS"
 745   AC_COMPILE_IFELSE([
 746     AC_LANG_PROGRAM([[
 747 #include <vorbis/codec.h>
 748                      ]],[[
 749 vorbis_dsp_state *v;
 750
 751 vorbis_synthesis_restart (v);
 752                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 753   if test "x$HAVE_VSR" = "xyes"; then
 754     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 755                        [defined if vorbis_synthesis_restart is present])
 756   fi
 757   CFLAGS="$ac_cflags_save"
 758 fi
 759
 760 else
 761
 762 dnl not building plugins with external dependencies,
 763 dnl but we still need to set the conditionals
 764 AM_CONDITIONAL(USE_ALSA, false)
 765 AM_CONDITIONAL(USE_CDPARANOIA, false)
 766 AM_CONDITIONAL(USE_IVORBIS, false)
 767 AM_CONDITIONAL(USE_LIBVISUAL, false)
 768 AM_CONDITIONAL(USE_OGG, false)
 769 AM_CONDITIONAL(USE_PANGO, false)
 770 AM_CONDITIONAL(USE_THEORA, false)
 771 AM_CONDITIONAL(USE_VORBIS, false)
 772
 773 fi dnl of EXT plugins
 774
 775 dnl seeking needs freetype, so check for it here
 776 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 777   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 778 ])
 779 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 780 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 781 AC_SUBST(FT2_CFLAGS)
 782 AC_SUBST(FT2_LIBS)
 783
 784 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 785
 786 dnl Overview:
 787 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 788 dnl GST_*:              flags shared by built objects to link against GStreamer
 789 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 790 dnl                          (compare to other modules) or for i18n
 791 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 792 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 793 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 794 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 795
 796 dnl GST_OPTION_CFLAGS
 797 if test "x$USE_DEBUG" = xyes; then
 798    PROFILE_CFLAGS="-g"
 799 fi
 800 AC_SUBST(PROFILE_CFLAGS)
 801
 802 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 803   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 804   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 805 else
 806   DEPRECATED_CFLAGS=""
 807 fi
 808 AC_SUBST(DEPRECATED_CFLAGS)
 809
 810 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 811 dnl at make time with e.g. make ERROR_CFLAGS=""
 812 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 813 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 814 AC_SUBST(GST_OPTION_CFLAGS)
 815 AC_SUBST(GST_OPTION_CXXFLAGS)
 816
 817 dnl our libraries need to be versioned correctly
 818 AC_SUBST(GST_LT_LDFLAGS)
 819
 820 dnl GST_PLUGINS_BASE_CFLAGS
 821 dnl prefer internal headers to already installed ones
 822 dnl also add builddir include for enumtypes and marshal
 823 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 824 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 825
 826 dnl FIXME: do we want to rename to GST_ALL_* ?
 827 dnl add GST_OPTION_CFLAGS, but overridable
 828 GST_CFLAGS="$GST_CFLAGS"
 829 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 830 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 831 AC_SUBST(GST_CFLAGS)
 832 AC_SUBST(GST_CXXFLAGS)
 833 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 834 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 835 AC_SUBST(GST_LIBS)
 836
 837 dnl LDFLAGS really should only contain flags, not libs - they get added before
 838 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 839 GST_ALL_LDFLAGS="-no-undefined"
 840 if test "x${enable_Bsymbolic}" = "xyes"; then
 841   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 842 fi
 843 AC_SUBST(GST_ALL_LDFLAGS)
 844
 845 dnl GST_LIB_LDFLAGS
 846 dnl linker flags shared by all libraries
 847 dnl LDFLAGS modifier defining exported symbols from built libraries
 848 dnl (export _gst_foo but not __gst_foo)
 849 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 850 AC_SUBST(GST_LIB_LDFLAGS)
 851
 852 dnl this really should only contain flags, not libs - they get added before
 853 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 854 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 855 AC_SUBST(GST_PLUGIN_LDFLAGS)
 856
 857 dnl *** output files ***
 858
 859 AC_CONFIG_FILES(
 860 Makefile
 861 gst-plugins-base.spec
 862 gst/Makefile
 863 gst/adder/Makefile
 864 gst/app/Makefile
 865 gst/audioconvert/Makefile
 866 gst/audiorate/Makefile
 867 gst/audiotestsrc/Makefile
 868 gst/encoding/Makefile
 869 gst/videoconvert/Makefile
 870 gst/gio/Makefile
 871 gst/playback/Makefile
 872 gst/audioresample/Makefile
 873 gst/subparse/Makefile
 874 gst/tcp/Makefile
 875 gst/typefind/Makefile
 876 gst/videotestsrc/Makefile
 877 gst/videorate/Makefile
 878 gst/videoscale/Makefile
 879 gst/volume/Makefile
 880 sys/Makefile
 881 sys/ximage/Makefile
 882 sys/xvimage/Makefile
 883 ext/Makefile
 884 ext/alsa/Makefile
 885 ext/cdparanoia/Makefile
 886 ext/libvisual/Makefile
 887 ext/ogg/Makefile
 888 ext/pango/Makefile
 889 ext/theora/Makefile
 890 ext/vorbis/Makefile
 891 gst-libs/Makefile
 892 gst-libs/gst/Makefile
 893 gst-libs/gst/allocators/Makefile
 894 gst-libs/gst/audio/Makefile
 895 gst-libs/gst/app/Makefile
 896 gst-libs/gst/fft/Makefile
 897 gst-libs/gst/riff/Makefile
 898 gst-libs/gst/rtp/Makefile
 899 gst-libs/gst/rtsp/Makefile
 900 gst-libs/gst/sdp/Makefile
 901 gst-libs/gst/tag/Makefile
 902 gst-libs/gst/pbutils/Makefile
 903 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 904 gst-libs/gst/video/Makefile
 905 tools/Makefile
 906 pkgconfig/Makefile
 907 pkgconfig/gstreamer-allocators.pc
 908 pkgconfig/gstreamer-allocators-uninstalled.pc
 909 pkgconfig/gstreamer-audio.pc
 910 pkgconfig/gstreamer-audio-uninstalled.pc
 911 pkgconfig/gstreamer-app.pc
 912 pkgconfig/gstreamer-app-uninstalled.pc
 913 pkgconfig/gstreamer-fft.pc
 914 pkgconfig/gstreamer-fft-uninstalled.pc
 915 pkgconfig/gstreamer-pbutils.pc
 916 pkgconfig/gstreamer-pbutils-uninstalled.pc
 917 pkgconfig/gstreamer-riff.pc
 918 pkgconfig/gstreamer-riff-uninstalled.pc
 919 pkgconfig/gstreamer-rtp.pc
 920 pkgconfig/gstreamer-rtp-uninstalled.pc
 921 pkgconfig/gstreamer-rtsp.pc
 922 pkgconfig/gstreamer-rtsp-uninstalled.pc
 923 pkgconfig/gstreamer-sdp.pc
 924 pkgconfig/gstreamer-sdp-uninstalled.pc
 925 pkgconfig/gstreamer-tag.pc
 926 pkgconfig/gstreamer-tag-uninstalled.pc
 927 pkgconfig/gstreamer-video.pc
 928 pkgconfig/gstreamer-video-uninstalled.pc
 929 pkgconfig/gstreamer-plugins-base.pc
 930 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 931 tests/Makefile
 932 tests/check/Makefile
 933 tests/examples/Makefile
 934 tests/examples/app/Makefile
 935 tests/examples/audio/Makefile
 936 tests/examples/dynamic/Makefile
 937 tests/examples/encoding/Makefile
 938 tests/examples/fft/Makefile
 939 tests/examples/gio/Makefile
 940 tests/examples/overlay/Makefile
 941 tests/examples/seek/Makefile
 942 tests/examples/snapshot/Makefile
 943 tests/examples/playback/Makefile
 944 tests/examples/playrec/Makefile
 945 tests/files/Makefile
 946 tests/icles/Makefile
 947 tests/icles/playback/Makefile
 948 docs/Makefile
 949 docs/design/Makefile
 950 docs/libs/Makefile
 951 docs/plugins/Makefile
 952 docs/version.entities
 953 po/Makefile.in
 954 common/Makefile
 955 common/m4/Makefile
 956 m4/Makefile
 957 )
 958
 959 dnl Create the config.h file for Visual Studio builds
 960 dnl Beware of spaces and /'s in some of the shell variable contents.
 961 sed \
 962     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 963     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 964     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 965     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 966     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 967     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 968     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 969     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 970     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 971     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 972     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 973     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 974     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 975     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 976     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 977     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 978     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 979     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 980     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 981     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 982     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 983     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 984     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 985     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 986     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 987     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 988     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 989     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 990     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 991     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 992     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 993     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 994     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 995     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 996     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 997     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 998     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 999     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1000     config.h.in >win32/common/config.h-new
1001
1002
1003
1004 AC_OUTPUT
1005
1006 AG_GST_OUTPUT_PLUGINS
1007 ORC_OUTPUT
1008