configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.23.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 16, 0, 16)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.23.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl *** checks for library functions ***
 221
 222 dnl check for fseeko()
 223 AC_FUNC_FSEEKO
 224
 225 dnl Check for fast float to int casting as defined in C99
 226 dnl used in gst-libs/gst/floatcast/floatcast.h
 227 save_libs=$LIBS
 228 LIBS="$LIBS $LIBM"
 229 AC_C99_FUNC_LRINT
 230 AC_C99_FUNC_LRINTF
 231 LIBS=$save_libs
 232
 233 dnl Check for a way to display the function name in debug output
 234 AG_GST_CHECK_FUNCTION
 235
 236 dnl *** checks for socket and nsl libraries ***
 237 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 238 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 239
 240 dnl *** checks for dependency libraries ***
 241
 242 dnl GLib is required
 243 AG_GST_GLIB_CHECK([2.16])
 244
 245 dnl liboil is required
 246 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 247 if test "x$HAVE_LIBOIL" != "xyes"; then
 248   AC_ERROR([liboil-0.3.14 or later is required])
 249 fi
 250
 251 dnl checks for gstreamer
 252 dnl uninstalled is selected preferentially -- see pkg-config(1)
 253 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 254 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 255 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 258 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 259
 260 dnl Check for documentation xrefs
 261 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 262 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 263 AC_SUBST(GLIB_PREFIX)
 264 AC_SUBST(GST_PREFIX)
 265
 266 dnl GTK is optional and only used in examples
 267 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 268 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 269
 270 dnl some examples need gtk+-x11
 271 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.12.0,
 272     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 273 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 274
 275 dnl *** set variables based on configure arguments ***
 276
 277 dnl set license and copyright notice
 278 GST_LICENSE="LGPL"
 279 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 280 AC_SUBST(GST_LICENSE)
 281
 282 dnl set location of plugin directory
 283 AG_GST_SET_PLUGINDIR
 284
 285 dnl define an ERROR_CFLAGS Makefile variable
 286 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 287
 288 dnl define correct level for debugging messages
 289 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 290
 291 dnl used in examples
 292 AG_GST_DEFAULT_ELEMENTS
 293
 294 dnl behaviour of speex based audio resampler
 295 AC_MSG_CHECKING(which audio resample format to use for integer)
 296 AC_ARG_WITH([audioresample_format],
 297         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 298         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 299 AC_MSG_RESULT($ac_cv_audioresample_format)
 300 case $ac_cv_audioresample_format in
 301   int)
 302     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 303     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 304   ;;
 305   float)
 306     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 307     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 308   ;;
 309   auto)
 310     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 311     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 312 esac
 313 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 314
 315 dnl *** plug-ins to include ***
 316
 317 dnl these are all the gst plug-ins, compilable without additional libs
 318 AG_GST_CHECK_PLUGIN(adder)
 319 AG_GST_CHECK_PLUGIN(app)
 320 AG_GST_CHECK_PLUGIN(audioconvert)
 321 AG_GST_CHECK_PLUGIN(audiorate)
 322 AG_GST_CHECK_PLUGIN(audiotestsrc)
 323 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 324 AG_GST_CHECK_PLUGIN(gdp)
 325 AG_GST_CHECK_PLUGIN(playback)
 326 AG_GST_CHECK_PLUGIN(audioresample)
 327 AG_GST_CHECK_PLUGIN(subparse)
 328 AG_GST_CHECK_PLUGIN(tcp)
 329 AG_GST_CHECK_PLUGIN(typefind)
 330 AG_GST_CHECK_PLUGIN(videotestsrc)
 331 AG_GST_CHECK_PLUGIN(videorate)
 332 AG_GST_CHECK_PLUGIN(videoscale)
 333 AG_GST_CHECK_PLUGIN(volume)
 334
 335 dnl check for gstreamer core features (subsystems)
 336 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 337 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 338 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 339
 340 dnl disable plug-ins that require libxml2's HTML support if it is not available
 341 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 342   AG_GST_DISABLE_PLUGIN(subparse)
 343 fi
 344
 345 dnl disable plug-ins that require sys/socket.h if it is not available
 346 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 347   AG_GST_DISABLE_PLUGIN(tcp)
 348 fi
 349
 350 dnl *** sys plug-ins ***
 351
 352 echo
 353 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 354 echo
 355
 356 dnl *** X11 ***
 357 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 358 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 359                   [ximagesink], [
 360   AC_PATH_XTRA
 361   ac_cflags_save="$CFLAGS"
 362   ac_cppflags_save="$CPPFLAGS"
 363   CFLAGS="$CFLAGS $X_CFLAGS"
 364   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 365
 366   dnl now try to find the HEADER
 367   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 368
 369   if test "x$HAVE_X" = "xno"
 370   then
 371     AC_MSG_NOTICE([cannot find X11 development files])
 372   else
 373     dnl this is much more than we want
 374     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 375     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 376     dnl it does not add the libs; therefore we add them here
 377     X_LIBS="$X_LIBS -lX11"
 378     AC_SUBST(X_CFLAGS)
 379     AC_SUBST(X_LIBS)
 380   fi
 381   AC_SUBST(HAVE_X)
 382   CFLAGS="$ac_cflags_save"
 383   CPPFLAGS="$ac_cppflags_save"
 384 ])
 385
 386 dnl Check for Xv extension
 387 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 388 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 389                   [xvimagesink], [
 390   AG_GST_CHECK_XV
 391 ])
 392
 393 dnl check for X Shm
 394 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 395 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 396   if test x$HAVE_X = xyes; then
 397     AC_CHECK_LIB(Xext, XShmAttach,
 398                  HAVE_XSHM="yes", HAVE_XSHM="no",
 399                  $X_LIBS)
 400     if test "x$HAVE_XSHM" = "xyes"; then
 401       XSHM_LIBS="-lXext"
 402     else
 403       dnl On AIX, it is in XextSam instead, but we still need -lXext
 404       AC_CHECK_LIB(XextSam, XShmAttach,
 405                    HAVE_XSHM="yes", HAVE_XSHM="no",
 406                    $X_LIBS)
 407       if test "x$HAVE_XSHM" = "xyes"; then
 408         XSHM_LIBS="-lXext -lXextSam"
 409       fi
 410     fi
 411   fi
 412 ], , [
 413   AC_SUBST(HAVE_XSHM)
 414   AC_SUBST(XSHM_LIBS)
 415 ])
 416
 417 dnl v4l/v4l2 checks have been moved down because they require X
 418
 419 dnl *** Video 4 Linux ***
 420 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 421 dnl renamed to GST_V4L in accordance with V4L2 below
 422 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 423 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 424   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 425 #include <sys/types.h>
 426 #define _LINUX_TIME_H
 427 #define __user
 428 #include <linux/videodev.h>
 429   ])
 430
 431   dnl we can build v4l without Xv, but then we won't have XOverlay support
 432   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 433   then
 434     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 435     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 436   fi
 437 ])
 438
 439 dnl *** ext plug-ins ***
 440 dnl keep this list sorted alphabetically !
 441
 442 if test "x$BUILD_EXTERNAL" = "xyes"; then
 443
 444 echo
 445 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 446 echo
 447
 448 dnl *** alsa ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 450 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 451   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 452     HAVE_ALSA="yes"
 453     AC_SUBST(ALSA_CFLAGS)
 454     AC_SUBST(ALSA_LIBS)
 455   ], [
 456     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 457   ])
 458 ])
 459
 460 dnl *** CDParanoia ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 462 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 463   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 464                       cdda_open, -lm,
 465                       cdda_interface.h,
 466                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 467                       HEADER_DIR="no"
 468                       FOUND_CDPARANOIA="yes")
 469   if test "x$FOUND_CDPARANOIA" != "xyes";
 470   then
 471     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 472                         cdda_open, -lm,
 473                         cdda/cdda_interface.h,
 474                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 475                         HEADER_DIR="yes"
 476                         FOUND_CDPARANOIA="yes")
 477   fi
 478   if test "x$HEADER_DIR" = "xyes";
 479   then
 480     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 481                        defined if cdda headers are in a cdda/ directory)
 482   fi
 483   if test "x$FOUND_CDPARANOIA" = "xyes";
 484   then
 485     AC_CHECK_LIB(cdda_paranoia,
 486                  paranoia_cachemodel_size,
 487                  : ,
 488                  HAVE_CDPARANOIA=no)
 489   fi
 490
 491   AC_SUBST(CDPARANOIA_LIBS)
 492 ])
 493 dnl FIXME : add second check somehow if that is necessary
 494 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 495 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 496
 497 dnl *** GNOME VFS ***
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 499 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 500   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 501       HAVE_GNOME_VFS="yes"
 502       AC_SUBST(GNOME_VFS_CFLAGS)
 503       AC_SUBST(GNOME_VFS_LIBS)
 504       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 505       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 506              [The GnomeVFS modules directory.])
 507     ],[
 508       HAVE_GNOME_VFS="no"
 509     ]
 510     )
 511 ])
 512
 513 dnl *** libgio ***
 514 USE_GIO=$BUILD_EXPERIMENTAL
 515 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 516 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 517   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, [
 518     HAVE_GIO="yes"
 519     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 520     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 521            [The GIO modules directory.])
 522     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 523     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 524            [The GIO library directory.])
 525   ], [
 526     HAVE_GIO="no"
 527     AC_MSG_RESULT(no)
 528   ])
 529   AC_SUBST(GIO_CFLAGS)
 530   AC_SUBST(GIO_LIBS)
 531   AC_SUBST(GIO_LDFLAGS)
 532 ])
 533
 534 dnl *** libvisual ***
 535 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 536 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 537   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 538   if test $HAVE_LIBVISUAL = no
 539   then
 540     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 541     if test x$HAVE_LIBVISUAL == xyes; then
 542       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 543     fi
 544   else
 545     if test x$HAVE_LIBVISUAL == xyes; then
 546       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 547     fi
 548   fi
 549   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 550   if test x$LIBVIS_PLUGINSDIR != x; then
 551     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 552         "$LIBVIS_PLUGINSDIR",
 553         [directory in which the detected libvisual's plugins are located])
 554   fi
 555 ])
 556
 557 dnl *** ogg ***
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 559 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 560   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 561   if test $HAVE_OGG = no
 562   then
 563     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 564     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 565   fi
 566 ])
 567
 568 dnl *** pango ***
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 570 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 571   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 572 ])
 573
 574 dnl *** schroedinger ***
 575 translit(dnm, m, l) AM_CONDITIONAL(USE_SCHRO, true)
 576 AG_GST_CHECK_FEATURE(SCHRO, [Schroedinger video codec], schro, [
 577   AG_GST_PKG_CHECK_MODULES(SCHRO, schroedinger-1.0 >= 1.0.7)
 578 ])
 579
 580 dnl *** theora ***
 581 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 582 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 583   dnl theora uses pkg-config version incorrectly, for pkg-config:
 584   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 585   dnl theoraenc and theoradec appeared in 1.0beta3
 586
 587   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 588   if test x$HAVE_THEORA = xno; then
 589     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 590   fi
 591 ])
 592
 593 dnl *** vorbis ***
 594 dnl AM_PATH_VORBIS only takes two options
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 596 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 597   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 598   if test $HAVE_VORBIS = no
 599   then
 600     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 601     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 602   fi
 603 ])
 604
 605 if test "x$HAVE_VORBIS" = "xyes"; then
 606   ac_cflags_save="$CFLAGS"
 607   AC_COMPILE_IFELSE(
 608     AC_LANG_PROGRAM([
 609 #include <vorbis/codec.h>
 610                      ],[
 611 vorbis_dsp_state *v;
 612
 613 vorbis_synthesis_restart (v);
 614                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 615   if test "x$HAVE_VSR" = "xyes"; then
 616     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 617                        [defined if vorbis_synthesis_restart is present])
 618   fi
 619   CFLAGS="$ac_cflags_save"
 620 fi
 621
 622 else
 623
 624 dnl not building plugins with external dependencies,
 625 dnl but we still need to set the conditionals
 626 AM_CONDITIONAL(USE_ALSA, false)
 627 AM_CONDITIONAL(USE_CDPARANOIA, false)
 628 AM_CONDITIONAL(USE_GNOME_VFS, false)
 629 AM_CONDITIONAL(USE_GIO, false)
 630 AM_CONDITIONAL(USE_LIBVISUAL, false)
 631 AM_CONDITIONAL(USE_OGG, false)
 632 AM_CONDITIONAL(USE_PANGO, false)
 633 AM_CONDITIONAL(USE_SCHRO, false)
 634 AM_CONDITIONAL(USE_THEORA, false)
 635 AM_CONDITIONAL(USE_VORBIS, false)
 636
 637 fi dnl of EXT plugins
 638
 639 dnl seeking needs freetype, so check for it here
 640 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 641   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 642 ])
 643 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 644 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 645 AC_SUBST(FT2_CFLAGS)
 646 AC_SUBST(FT2_LIBS)
 647
 648 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 649
 650 dnl Overview:
 651 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 652 dnl GST_*:              flags shared by built objects to link against GStreamer
 653 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 654 dnl                          (compare to other modules) or for i18n
 655 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 656 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 657 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 658 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 659
 660 dnl GST_OPTION_CFLAGS
 661 if test "x$USE_DEBUG" = xyes; then
 662    PROFILE_CFLAGS="-g"
 663 fi
 664 AC_SUBST(PROFILE_CFLAGS)
 665
 666 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 667   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 668   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 669 else
 670   DEPRECATED_CFLAGS=""
 671 fi
 672 AC_SUBST(DEPRECATED_CFLAGS)
 673
 674 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 675 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 676 AC_SUBST(GST_OPTION_CFLAGS)
 677
 678 dnl our libraries need to be versioned correctly
 679 AC_SUBST(GST_LT_LDFLAGS)
 680
 681 dnl GST_PLUGINS_BASE_CFLAGS
 682 dnl prefer internal headers to already installed ones
 683 dnl also add builddir include for enumtypes and marshal
 684 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 685 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 686
 687 dnl FIXME: do we want to rename to GST_ALL_* ?
 688 dnl add GST_OPTION_CFLAGS, but overridable
 689 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 690 AC_SUBST(GST_CFLAGS)
 691 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 692 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 693 AC_SUBST(GST_LIBS)
 694
 695 dnl LDFLAGS really should only contain flags, not libs - they get added before
 696 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 697 GST_ALL_LDFLAGS="-no-undefined"
 698 AC_SUBST(GST_ALL_LDFLAGS)
 699
 700 dnl GST_LIB_LDFLAGS
 701 dnl linker flags shared by all libraries
 702 dnl LDFLAGS modifier defining exported symbols from built libraries
 703 dnl (export _gst_foo but not __gst_foo)
 704 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 705 AC_SUBST(GST_LIB_LDFLAGS)
 706
 707 dnl this really should only contain flags, not libs - they get added before
 708 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 709 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 710 AC_SUBST(GST_PLUGIN_LDFLAGS)
 711
 712 SHAVE_INIT([common],[enable])
 713
 714 dnl *** output files ***
 715
 716 AC_CONFIG_FILES(
 717 Makefile
 718 common/shave
 719 common/shave-libtool
 720 gst-plugins-base.spec
 721 gst/Makefile
 722 gst/adder/Makefile
 723 gst/app/Makefile
 724 gst/audioconvert/Makefile
 725 gst/audiorate/Makefile
 726 gst/audiotestsrc/Makefile
 727 gst/ffmpegcolorspace/Makefile
 728 gst/gdp/Makefile
 729 gst/playback/Makefile
 730 gst/audioresample/Makefile
 731 gst/subparse/Makefile
 732 gst/tcp/Makefile
 733 gst/typefind/Makefile
 734 gst/videotestsrc/Makefile
 735 gst/videorate/Makefile
 736 gst/videoscale/Makefile
 737 gst/volume/Makefile
 738 sys/Makefile
 739 sys/ximage/Makefile
 740 sys/xvimage/Makefile
 741 sys/v4l/Makefile
 742 ext/Makefile
 743 ext/alsa/Makefile
 744 ext/cdparanoia/Makefile
 745 ext/gnomevfs/Makefile
 746 ext/gio/Makefile
 747 ext/libvisual/Makefile
 748 ext/ogg/Makefile
 749 ext/pango/Makefile
 750 ext/schroedinger/Makefile
 751 ext/theora/Makefile
 752 ext/vorbis/Makefile
 753 gst-libs/Makefile
 754 gst-libs/gst/Makefile
 755 gst-libs/gst/audio/Makefile
 756 gst-libs/gst/app/Makefile
 757 gst-libs/gst/cdda/Makefile
 758 gst-libs/gst/fft/Makefile
 759 gst-libs/gst/floatcast/Makefile
 760 gst-libs/gst/interfaces/Makefile
 761 gst-libs/gst/netbuffer/Makefile
 762 gst-libs/gst/riff/Makefile
 763 gst-libs/gst/rtp/Makefile
 764 gst-libs/gst/rtsp/Makefile
 765 gst-libs/gst/sdp/Makefile
 766 gst-libs/gst/tag/Makefile
 767 gst-libs/gst/pbutils/Makefile
 768 gst-libs/gst/video/Makefile
 769 tools/Makefile
 770 pkgconfig/Makefile
 771 pkgconfig/gstreamer-audio.pc
 772 pkgconfig/gstreamer-audio-uninstalled.pc
 773 pkgconfig/gstreamer-app.pc
 774 pkgconfig/gstreamer-app-uninstalled.pc
 775 pkgconfig/gstreamer-cdda.pc
 776 pkgconfig/gstreamer-cdda-uninstalled.pc
 777 pkgconfig/gstreamer-fft.pc
 778 pkgconfig/gstreamer-fft-uninstalled.pc
 779 pkgconfig/gstreamer-floatcast.pc
 780 pkgconfig/gstreamer-floatcast-uninstalled.pc
 781 pkgconfig/gstreamer-interfaces.pc
 782 pkgconfig/gstreamer-interfaces-uninstalled.pc
 783 pkgconfig/gstreamer-netbuffer.pc
 784 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 785 pkgconfig/gstreamer-pbutils.pc
 786 pkgconfig/gstreamer-pbutils-uninstalled.pc
 787 pkgconfig/gstreamer-riff.pc
 788 pkgconfig/gstreamer-riff-uninstalled.pc
 789 pkgconfig/gstreamer-rtp.pc
 790 pkgconfig/gstreamer-rtp-uninstalled.pc
 791 pkgconfig/gstreamer-rtsp.pc
 792 pkgconfig/gstreamer-rtsp-uninstalled.pc
 793 pkgconfig/gstreamer-sdp.pc
 794 pkgconfig/gstreamer-sdp-uninstalled.pc
 795 pkgconfig/gstreamer-tag.pc
 796 pkgconfig/gstreamer-tag-uninstalled.pc
 797 pkgconfig/gstreamer-video.pc
 798 pkgconfig/gstreamer-video-uninstalled.pc
 799 pkgconfig/gstreamer-plugins-base.pc
 800 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 801 tests/Makefile
 802 tests/check/Makefile
 803 tests/examples/Makefile
 804 tests/examples/app/Makefile
 805 tests/examples/dynamic/Makefile
 806 tests/examples/seek/Makefile
 807 tests/examples/volume/Makefile
 808 tests/examples/snapshot/Makefile
 809 tests/icles/Makefile
 810 docs/Makefile
 811 docs/design/Makefile
 812 docs/libs/Makefile
 813 docs/plugins/Makefile
 814 docs/version.entities
 815 po/Makefile.in
 816 common/Makefile
 817 common/m4/Makefile
 818 m4/Makefile
 819 )
 820
 821 dnl Create the config.h file for Visual Studio builds
 822 dnl Beware of spaces and /'s in some of the shell variable contents.
 823 sed \
 824     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 825     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 826     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 827     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 828     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 829     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 830     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 831     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 832     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 833     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 834     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 835     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 836     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 837     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 838     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 839     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 840     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 841     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 842     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 843     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 844     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 845     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 846     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 847     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 848     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 849     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 850     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 851     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 852     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 853     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 854     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 855     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 856     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 857     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 858     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 859     config.h.in >win32/common/config.h-new
 860
 861
 862
 863 AC_OUTPUT
 864
 865 AG_GST_OUTPUT_PLUGINS