configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.17.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 12, 0, 12)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.17.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127 AG_GST_ARG_WITH_PLUGINS
 128 AC_SUBST(GST_PLUGINS_SELECTED)
 129
 130 AG_GST_ARG_ENABLE_EXTERNAL
 131
 132 AG_GST_ARG_ENABLE_EXPERIMENTAL
 133 dnl *** checks for platform ***
 134
 135 dnl * hardware/architecture *
 136
 137 dnl common/m4/gst-arch.m4
 138 dnl check CPU type
 139 AG_GST_ARCH
 140
 141 dnl check for large file support
 142 dnl affected plugins must include config.h
 143 AC_SYS_LARGEFILE
 144
 145 dnl *** checks for programs ***
 146
 147 dnl find a compiler
 148 AC_PROG_CC
 149
 150 dnl check if the compiler supports '-c' and '-o' options
 151 AM_PROG_CC_C_O
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for documentation tools
 157 GTK_DOC_CHECK([1.3])
 158 AS_PATH_PYTHON([2.1])
 159 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 160
 161 dnl *** checks for libraries ***
 162
 163 dnl For interactive UNIX (a Sun thing)
 164 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 165 AC_ISC_POSIX
 166
 167 dnl libm, for sin() etc.
 168 AC_CHECK_LIBM
 169 AC_SUBST(LIBM)
 170
 171 dnl *** checks for header files ***
 172
 173 dnl check if we have ANSI C header files
 174 AC_HEADER_STDC
 175
 176 dnl used in gst/ffmpegcolorspace/mem.c
 177 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 178 AC_CHECK_HEADERS([malloc.h])
 179
 180 dnl used in gst/subparse/gstsubparse.c
 181 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 182 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 183
 184 if test "x$HAVE_REGEX_H" = "xyes"; then
 185   ac_cppflags_save="$CPPFLAGS"
 186   CPPFLAGS="-Wall -Werror `$PKG_CONFIG --cflags libxml-2.0`"
 187   AC_COMPILE_IFELSE(
 188     AC_LANG_PROGRAM([
 189 #include <libxml/HTMLparser.h>
 190                      ],[
 191 #ifndef LIBXML_HTML_ENABLED
 192 #error libxml2 has no HTML support
 193 #endif /* LIBXML_HTML_ENABLED */
 194                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 195   CPPFLAGS="$ac_cppflags_save"
 196
 197   if test "x$HAVE_LIBXML_HTML" = "xyes"; then
 198     GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED subparse"
 199   else
 200     GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 201   fi
 202 else
 203   GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 204   HAVE_LIBXML_HTML="no"
 205 fi
 206 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 207
 208 dnl used in gst/tcp
 209 AC_CHECK_HEADERS([sys/socket.h],
 210   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 211 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 212 if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 213   GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED tcp"
 214 else
 215   GST_PLUGINS_NO="\t[tcp]\n$GST_PLUGINS_NO"
 216 fi
 217
 218 dnl used in gst-libs/gst/rtsp
 219 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 220 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 221   WIN32_LIBS="-lws2_32"
 222   AC_SUBST(WIN32_LIBS)
 223 fi
 224
 225 dnl check for hstrerror, for gst-libs/gst/rtsp
 226 save_libs="$LIBS"
 227 AC_CHECK_FUNC(hstrerror, ,
 228     AC_CHECK_LIB(resolv, hstrerror, ,
 229         [AC_DEFINE(NO_HSTRERROR, 1,
 230              [Define if you have no native hstrerror() function.])]))
 231 HSTRERROR_LIBS=$LIBS
 232 AC_SUBST(HSTRERROR_LIBS)
 233 LIBS="$save_libs"
 234
 235 dnl used in gst-libs/gst/pbutils and associated unit test
 236 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 237
 238 dnl ffmpegcolorspace includes _stdint.h
 239 dnl also, Windows does not have long long
 240 AX_CREATE_STDINT_H
 241
 242 dnl *** checks for functions ***
 243 AC_CHECK_FUNCS([localtime_r gmtime_r])
 244
 245 dnl *** checks for types/defines ***
 246
 247 dnl Check for FIONREAD ioctl declaration
 248 dnl used in gst/tcp
 249 GST_CHECK_FIONREAD
 250
 251 dnl *** checks for structures ***
 252
 253 dnl *** checks for compiler characteristics ***
 254
 255 dnl make sure we can use "inline" from C code
 256 AC_C_INLINE
 257
 258 dnl *** checks for library functions ***
 259
 260 dnl check for fseeko()
 261 AC_FUNC_FSEEKO
 262
 263 dnl Check for fast float to int casting as defined in C99
 264 dnl used in gst-libs/gst/floatcast/floatcast.h
 265 AC_C99_FUNC_LRINT
 266 AC_C99_FUNC_LRINTF
 267
 268 dnl Check for a way to display the function name in debug output
 269 AG_GST_CHECK_FUNCTION
 270
 271 dnl *** checks for dependency libraries ***
 272
 273 dnl GLib is required
 274 AG_GST_GLIB_CHECK([2.6])
 275
 276 dnl liboil is required
 277 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 278 if test "x$HAVE_LIBOIL" != "xyes"
 279 then
 280   AC_ERROR([liboil-0.3.8 or later is required])
 281 fi
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 286 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 287 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 288 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 289 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 dnl GTK is optional and used in examples
 299 HAVE_GTK=NO
 300 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 301 if test "x$HAVE_GTK_22" = "xyes"; then
 302   HAVE_GTK=yes
 303   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 304   AC_SUBST(GTK_VERSION)
 305   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 306   AC_SUBST(GTK_BASE_DIR)
 307 else
 308   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 309 fi
 310 if test "x$HAVE_GTK_20" = "xyes"; then
 311   HAVE_GTK=yes
 312 fi
 313 GTK_CFLAGS=$GTK2_CFLAGS
 314 GTK_LIBS=$GTK2_LIBS
 315 AC_SUBST(GTK_LIBS)
 316 AC_SUBST(GTK_CFLAGS)
 317 AC_SUBST(HAVE_GTK)
 318 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 319
 320 dnl *** set variables based on configure arguments ***
 321
 322 dnl set license and copyright notice
 323 GST_LICENSE="LGPL"
 324 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 325 AC_SUBST(GST_LICENSE)
 326
 327 dnl set location of plugin directory
 328 AG_GST_SET_PLUGINDIR
 329
 330 dnl define an ERROR_CFLAGS Makefile variable
 331 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 332
 333 dnl define correct level for debugging messages
 334 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 335
 336 dnl used in examples
 337 AG_GST_DEFAULT_ELEMENTS
 338
 339 dnl *** sys plug-ins ***
 340
 341 echo
 342 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 343 echo
 344
 345 dnl *** X11 ***
 346 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 347 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 348                   [ximagesink], [
 349   AC_PATH_XTRA
 350   ac_cflags_save="$CFLAGS"
 351   ac_cppflags_save="$CPPFLAGS"
 352   CFLAGS="$CFLAGS $X_CFLAGS"
 353   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 354
 355   dnl now try to find the HEADER
 356   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 357
 358   if test "x$HAVE_X" = "xno"
 359   then
 360     AC_MSG_NOTICE([cannot find X11 development files])
 361   else
 362     dnl this is much more than we want
 363     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 364     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 365     dnl it does not add the libs; therefore we add them here
 366     X_LIBS="$X_LIBS -lX11"
 367     AC_SUBST(X_CFLAGS)
 368     AC_SUBST(X_LIBS)
 369   fi
 370   AC_SUBST(HAVE_X)
 371   CFLAGS="$ac_cflags_save"
 372   CPPFLAGS="$ac_cppflags_save"
 373 ])
 374
 375 dnl Check for Xv extension
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 377 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 378                   [xvimagesink], [
 379   AG_GST_CHECK_XV
 380 ])
 381
 382 dnl check for X Shm
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 384 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 385   if test x$HAVE_X = xyes; then
 386     AC_CHECK_LIB(Xext, XShmAttach,
 387                  HAVE_XSHM="yes", HAVE_XSHM="no",
 388                  $X_LIBS)
 389     if test "x$HAVE_XSHM" = "xyes"; then
 390       XSHM_LIBS="-lXext"
 391     else
 392       dnl On AIX, it is in XextSam instead, but we still need -lXext
 393       AC_CHECK_LIB(XextSam, XShmAttach,
 394                    HAVE_XSHM="yes", HAVE_XSHM="no",
 395                    $X_LIBS)
 396       if test "x$HAVE_XSHM" = "xyes"; then
 397         XSHM_LIBS="-lXext -lXextSam"
 398       fi
 399     fi
 400   fi
 401 ], , [
 402   AC_SUBST(HAVE_XSHM)
 403   AC_SUBST(XSHM_LIBS)
 404 ])
 405
 406 dnl v4l/v4l2 checks have been moved down because they require X
 407
 408 dnl *** Video 4 Linux ***
 409 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 410 dnl renamed to GST_V4L in accordance with V4L2 below
 411 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 412 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 413   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 414 #include <sys/types.h>
 415 #define _LINUX_TIME_H
 416 #define __user
 417 #include <linux/videodev.h>
 418   ])
 419
 420   dnl we can build v4l without Xv, but then we won't have XOverlay support
 421   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 422   then
 423     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 424     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 425   fi
 426 ])
 427
 428 dnl *** ext plug-ins ***
 429 dnl keep this list sorted alphabetically !
 430
 431 if test "x$BUILD_EXTERNAL" = "xyes"; then
 432
 433 echo
 434 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 435 echo
 436
 437 dnl *** alsa ***
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 439 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 440   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 441     HAVE_ALSA="yes"
 442     AC_SUBST(ALSA_CFLAGS)
 443     AC_SUBST(ALSA_LIBS)
 444   ], [
 445     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 446   ])
 447 ])
 448
 449 dnl *** CDParanoia ***
 450 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 451 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 452   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 453                       cdda_open, -lm,
 454                       cdda_interface.h,
 455                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 456                       HEADER_DIR="no"
 457                       FOUND_CDPARANOIA="yes")
 458   if test "x$FOUND_CDPARANOIA" != "xyes";
 459   then
 460     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 461                         cdda_open, -lm,
 462                         cdda/cdda_interface.h,
 463                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 464                         HEADER_DIR="yes"
 465                         FOUND_CDPARANOIA="yes")
 466   fi
 467   if test "x$HEADER_DIR" = "xyes";
 468   then
 469     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 470                        defined if cdda headers are in a cdda/ directory)
 471   fi
 472   AC_SUBST(CDPARANOIA_LIBS)
 473 ])
 474 dnl FIXME : add second check somehow if that is necessary
 475 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 476 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 477
 478 dnl *** GNOME VFS ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 480 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 481   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 482 ])
 483
 484 dnl *** libgio ***
 485 USE_GIO=$BUILD_EXPERIMENTAL
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 487 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 488   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 489     HAVE_GIO="no"
 490     AC_MSG_RESULT(no)
 491   ])
 492   AC_SUBST(GIO_CFLAGS)
 493   AC_SUBST(GIO_LIBS)
 494   AC_SUBST(GIO_LDFLAGS)
 495 ])
 496
 497 dnl *** libvisual ***
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 499 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 500   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 501   if test $HAVE_LIBVISUAL = no
 502   then
 503     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 504   fi
 505 ])
 506
 507 dnl *** ogg ***
 508 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 509 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 510   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 511   if test $HAVE_OGG = no
 512   then
 513     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 514     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 515   fi
 516 ])
 517
 518 dnl *** pango ***
 519 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 520 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 521   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 522 ])
 523
 524 dnl *** theora ***
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 526 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 527   dnl this check will work as long as theora uses 1.0.x or similar for the
 528   dnl first post-alpha release and not just 1.0
 529   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 530 ])
 531
 532 dnl *** vorbis ***
 533 dnl AM_PATH_VORBIS only takes two options
 534 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 535 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 536   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 537   if test $HAVE_VORBIS = no
 538   then
 539     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 540     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 541   fi
 542 ])
 543
 544 if test "x$HAVE_VORBIS" = "xyes"; then
 545   ac_cflags_save="$CFLAGS"
 546   dnl FIXME: does this work on non-gcc? -- Company
 547   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 548   CFLAGS="-Wall -Werror"
 549   AC_COMPILE_IFELSE(
 550     AC_LANG_PROGRAM([
 551 #include <vorbis/codec.h>
 552                      ],[
 553 vorbis_dsp_state *v;
 554
 555 vorbis_synthesis_restart (v);
 556                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 557   if test "x$HAVE_VSR" = "xyes"; then
 558     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 559                        [defined if vorbis_synthesis_restart is present])
 560   fi
 561   CFLAGS="$ac_cflags_save"
 562 fi
 563
 564 else
 565
 566 dnl not building plugins with external dependencies,
 567 dnl but we still need to set the conditionals
 568 AM_CONDITIONAL(USE_ALSA, false)
 569 AM_CONDITIONAL(USE_CDPARANOIA, false)
 570 AM_CONDITIONAL(USE_GNOME_VFS, false)
 571 AM_CONDITIONAL(USE_GIO, false)
 572 AM_CONDITIONAL(USE_LIBVISUAL, false)
 573 AM_CONDITIONAL(USE_OGG, false)
 574 AM_CONDITIONAL(USE_PANGO, false)
 575 AM_CONDITIONAL(USE_THEORA, false)
 576 AM_CONDITIONAL(USE_VORBIS, false)
 577
 578 fi dnl of EXT plugins
 579
 580 dnl seeking needs freetype, so check for it here
 581 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 582   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 583 ])
 584 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 585 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 586 AC_SUBST(FT2_CFLAGS)
 587 AC_SUBST(FT2_LIBS)
 588
 589 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 590
 591 dnl Overview:
 592 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 593 dnl GST_*:              flags shared by built objects to link against GStreamer
 594 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 595 dnl                          (compare to other modules) or for i18n
 596 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 597 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 598 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 599 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 600
 601 dnl GST_OPTION_CFLAGS
 602 if test "x$USE_DEBUG" = xyes; then
 603    PROFILE_CFLAGS="-g"
 604 fi
 605 AC_SUBST(PROFILE_CFLAGS)
 606
 607 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 608   dnl Define _only_ during CVS (not pre-releases or releases)
 609   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 610 else
 611   DEPRECATED_CFLAGS=""
 612 fi
 613 AC_SUBST(DEPRECATED_CFLAGS)
 614
 615 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 616 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 617 AC_SUBST(GST_OPTION_CFLAGS)
 618
 619 dnl our libraries need to be versioned correctly
 620 AC_SUBST(GST_LT_LDFLAGS)
 621
 622 dnl GST_PLUGINS_BASE_CFLAGS
 623 dnl prefer internal headers to already installed ones
 624 dnl also add builddir include for enumtypes and marshal
 625 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 626 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 627
 628 dnl FIXME: do we want to rename to GST_ALL_* ?
 629 dnl add GST_OPTION_CFLAGS, but overridable
 630 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 631 AC_SUBST(GST_CFLAGS)
 632 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 633 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 634 AC_SUBST(GST_LIBS)
 635
 636 dnl LDFLAGS really should only contain flags, not libs - they get added before
 637 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 638 GST_ALL_LDFLAGS="-no-undefined"
 639 AC_SUBST(GST_ALL_LDFLAGS)
 640
 641 dnl GST_LIB_LDFLAGS
 642 dnl linker flags shared by all libraries
 643 dnl LDFLAGS modifier defining exported symbols from built libraries
 644 dnl (export _gst_foo but not __gst_foo)
 645 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 646 AC_SUBST(GST_LIB_LDFLAGS)
 647
 648 dnl this really should only contain flags, not libs - they get added before
 649 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 650 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 651 AC_SUBST(GST_PLUGIN_LDFLAGS)
 652
 653 dnl *** output files ***
 654
 655 AC_CONFIG_FILES(
 656 Makefile
 657 gst-plugins-base.spec
 658 gst/Makefile
 659 gst/adder/Makefile
 660 gst/audioconvert/Makefile
 661 gst/audiorate/Makefile
 662 gst/audioresample/Makefile
 663 gst/audiotestsrc/Makefile
 664 gst/ffmpegcolorspace/Makefile
 665 gst/gdp/Makefile
 666 gst/playback/Makefile
 667 gst/subparse/Makefile
 668 gst/tcp/Makefile
 669 gst/typefind/Makefile
 670 gst/videotestsrc/Makefile
 671 gst/videorate/Makefile
 672 gst/videoscale/Makefile
 673 gst/volume/Makefile
 674 sys/Makefile
 675 sys/ximage/Makefile
 676 sys/xvimage/Makefile
 677 sys/v4l/Makefile
 678 ext/Makefile
 679 ext/alsa/Makefile
 680 ext/cdparanoia/Makefile
 681 ext/gnomevfs/Makefile
 682 ext/gio/Makefile
 683 ext/libvisual/Makefile
 684 ext/ogg/Makefile
 685 ext/pango/Makefile
 686 ext/theora/Makefile
 687 ext/vorbis/Makefile
 688 gst-libs/Makefile
 689 gst-libs/gst/Makefile
 690 gst-libs/gst/audio/Makefile
 691 gst-libs/gst/cdda/Makefile
 692 gst-libs/gst/fft/Makefile
 693 gst-libs/gst/floatcast/Makefile
 694 gst-libs/gst/interfaces/Makefile
 695 gst-libs/gst/netbuffer/Makefile
 696 gst-libs/gst/riff/Makefile
 697 gst-libs/gst/rtp/Makefile
 698 gst-libs/gst/rtsp/Makefile
 699 gst-libs/gst/sdp/Makefile
 700 gst-libs/gst/tag/Makefile
 701 gst-libs/gst/pbutils/Makefile
 702 gst-libs/gst/video/Makefile
 703 tools/Makefile
 704 win32/common/config.h
 705 pkgconfig/Makefile
 706 pkgconfig/gstreamer-audio.pc
 707 pkgconfig/gstreamer-audio-uninstalled.pc
 708 pkgconfig/gstreamer-cdda.pc
 709 pkgconfig/gstreamer-cdda-uninstalled.pc
 710 pkgconfig/gstreamer-fft.pc
 711 pkgconfig/gstreamer-fft-uninstalled.pc
 712 pkgconfig/gstreamer-floatcast.pc
 713 pkgconfig/gstreamer-floatcast-uninstalled.pc
 714 pkgconfig/gstreamer-interfaces.pc
 715 pkgconfig/gstreamer-interfaces-uninstalled.pc
 716 pkgconfig/gstreamer-netbuffer.pc
 717 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 718 pkgconfig/gstreamer-pbutils.pc
 719 pkgconfig/gstreamer-pbutils-uninstalled.pc
 720 pkgconfig/gstreamer-riff.pc
 721 pkgconfig/gstreamer-riff-uninstalled.pc
 722 pkgconfig/gstreamer-rtp.pc
 723 pkgconfig/gstreamer-rtp-uninstalled.pc
 724 pkgconfig/gstreamer-rtsp.pc
 725 pkgconfig/gstreamer-rtsp-uninstalled.pc
 726 pkgconfig/gstreamer-sdp.pc
 727 pkgconfig/gstreamer-sdp-uninstalled.pc
 728 pkgconfig/gstreamer-tag.pc
 729 pkgconfig/gstreamer-tag-uninstalled.pc
 730 pkgconfig/gstreamer-video.pc
 731 pkgconfig/gstreamer-video-uninstalled.pc
 732 pkgconfig/gstreamer-plugins-base.pc
 733 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 734 tests/Makefile
 735 tests/check/Makefile
 736 tests/examples/Makefile
 737 tests/examples/dynamic/Makefile
 738 tests/examples/seek/Makefile
 739 tests/examples/volume/Makefile
 740 tests/examples/snapshot/Makefile
 741 tests/icles/Makefile
 742 docs/Makefile
 743 docs/design/Makefile
 744 docs/libs/Makefile
 745 docs/plugins/Makefile
 746 docs/version.entities
 747 po/Makefile.in
 748 common/Makefile
 749 common/m4/Makefile
 750 m4/Makefile
 751 )
 752 AC_OUTPUT
 753
 754 AG_GST_OUTPUT_PLUGINS