configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.21.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 18, 0, 18)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl Use binary registry
 178 AC_ARG_ENABLE(binary-registry,
 179   AC_HELP_STRING([--disable-binary-registry],
 180     [disable binary registry]),
 181   [
 182     case "${enableval}" in
 183       yes) USE_BINARY_REGISTRY=yes ;;
 184       no)  USE_BINARY_REGISTRY=no ;;
 185       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-binary-registry) ;;
 186     esac
 187   ],
 188   [USE_BINARY_REGISTRY=yes]) dnl Default value
 189
 190 if test "x$USE_BINARY_REGISTRY" = xyes; then
 191   dnl for config.h:
 192   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 193     [Define if we should use binary registry instead xml registry])
 194 fi
 195 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 196
 197 dnl *** checks for platform ***
 198
 199 dnl * hardware/architecture *
 200
 201 dnl common/m4/gst-arch.m4
 202 dnl check CPU type
 203 AG_GST_ARCH
 204 dnl substitution for win32/common/config.h
 205 HOST_CPU=$host_cpu
 206 AC_SUBST(HOST_CPU)
 207
 208 dnl common/m4/gst-arch.m4
 209 dnl check for unaligned access
 210 AG_GST_UNALIGNED_ACCESS
 211 dnl create a configure variable for gst/gstconfig.h
 212 if test x${as_cv_unaligned_access} = xyes ; then
 213   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 214 else
 215   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 216 fi
 217 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 218
 219 dnl check for platform specific settings
 220 case $host_os in
 221      rhapsody*)
 222         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 223         ;;
 224      darwin*)
 225         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 226         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 227         ;;
 228      cygwin* | mingw* | msvc* | mks*)
 229         dnl HAVE_WIN32 currently means "disable POSIXisms".
 230         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 231         ;;
 232      *)
 233         ;;
 234 esac
 235
 236 dnl * software *
 237
 238 dnl check for large file support
 239 dnl affected plugins must include config.h
 240 AC_SYS_LARGEFILE
 241
 242 dnl *** checks for programs ***
 243
 244 dnl find a compiler
 245 AC_PROG_CC
 246
 247 dnl check if the compiler supports '-c' and '-o' options
 248 AM_PROG_CC_C_O
 249
 250 dnl find an assembler
 251 AM_PROG_AS
 252
 253 dnl Perl is used in building documentation and in the version checks
 254 AC_PATH_PROG(PERL_PATH, perl, no)
 255 if test x$PERL_PATH = xno; then
 256   AC_MSG_ERROR(Could not find perl)
 257 fi
 258
 259 dnl we require flex and bison for building the parser
 260 if test "x$GST_DISABLE_PARSE" != xyes; then
 261   AG_GST_BISON_CHECK
 262   AG_GST_FLEX_CHECK
 263 fi
 264
 265 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 266 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 267
 268 dnl check for documentation tools
 269 AG_GST_DOCBOOK_CHECK
 270 GTK_DOC_CHECK([1.3])
 271 AS_PATH_PYTHON([2.1])
 272 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 273
 274 dnl *** checks for libraries ***
 275
 276 dnl check for libm, for sin()
 277 AC_CHECK_LIBM
 278 AC_SUBST(LIBM)
 279
 280 dnl *** checks for header files ***
 281
 282 dnl check if we have ANSI C header files
 283 AC_HEADER_STDC
 284
 285 dnl Check for ucontext.h
 286 AC_CHECK_HEADERS([ucontext.h])
 287
 288 dnl Check for sys/socket.h
 289 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 290 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 291
 292 dnl check for sys/times.h for tests/examples/adapter/
 293 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 294 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 295 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 296
 297 dnl Check for process.h for getpid() on win32
 298 AC_CHECK_HEADERS([process.h])
 299
 300 dnl Check for sys/utsname.h for uname
 301 AC_CHECK_HEADERS([sys/utsname.h])
 302
 303 dnl Check for stdio_ext.f for __fbufsize
 304 AC_CHECK_HEADERS([stdio_ext.h])
 305
 306 dnl Check for valgrind.h
 307 dnl separate from HAVE_VALGRIND because you can have the program, but not
 308 dnl the dev package
 309 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 310
 311 dnl used in gst/gstpoll.c
 312 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 313 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 314 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 315   WIN32_LIBS="-lws2_32"
 316   AC_SUBST(WIN32_LIBS)
 317 fi
 318
 319 dnl *** checks for types/defines ***
 320
 321 dnl *** checks for structures ***
 322
 323 dnl *** checks for compiler characteristics ***
 324
 325 dnl make sure we can use "inline" from C code
 326 AC_C_INLINE
 327
 328 OPT_CFLAGS=
 329 dnl Check for some compiler flags that optimize our code.
 330 if test "x$GCC" = xyes; then
 331   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 332 fi
 333
 334 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 335 dnl flag
 336 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 337 dnl symbolic register names in inline asm
 338 if test x$HAVE_CPU_PPC = xyes ; then
 339   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 340     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 341 fi
 342
 343 dnl *** checks for library functions ***
 344
 345 AC_CHECK_FUNCS([sigaction])
 346
 347 dnl we use fork in the registry code
 348 AC_CHECK_FUNCS([fork])
 349
 350 dnl check for fseeko()
 351 AC_FUNC_FSEEKO
 352 dnl check for ftello()
 353 AC_CHECK_FUNCS([ftello])
 354
 355 AC_CHECK_FUNCS([fgetpos])
 356 AC_CHECK_FUNCS([fsetpos])
 357
 358 dnl check for poll(), ppoll() and pselect()
 359 AC_CHECK_FUNCS([poll])
 360 AC_CHECK_FUNCS([ppoll])
 361 AC_CHECK_FUNCS([pselect])
 362
 363 dnl check for mmap()
 364 AC_FUNC_MMAP
 365 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 366
 367 dnl Check for POSIX timers
 368 AC_CHECK_FUNCS(clock_gettime, [], [
 369   AC_CHECK_LIB(rt, clock_gettime, [
 370     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 371     LIBS="$LIBS -lrt"
 372   ])
 373 ])
 374
 375 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 376     AC_TRY_COMPILE([
 377 #include <time.h>
 378 #ifdef HAVE_UNISTD_H
 379 #include <unistd.h>
 380 #endif
 381     ], [
 382 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 383 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 384 #endif
 385       return 0;
 386     ], [
 387       gst_cv_posix_timers=yes
 388     ], [
 389       gst_cv_posix_timers=no
 390     ])
 391 )
 392
 393 if test "$gst_cv_posix_timers" = "yes"; then
 394   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 395   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 396 else
 397   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 398 fi
 399 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 400 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 401
 402 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 403     AC_TRY_COMPILE([
 404 #include <time.h>
 405 #ifdef HAVE_UNISTD_H
 406 #include <unistd.h>
 407 #endif
 408     ], [
 409 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 410 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 411 #endif
 412       return 0;
 413     ], [
 414       gst_cv_monotonic_clock=yes
 415     ], [
 416       gst_cv_monotonic_clock=no
 417     ])
 418 )
 419
 420 if test "$gst_cv_monotonic_clock" = "yes"; then
 421   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 422   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 423 else
 424   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 425 fi
 426 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 427 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 428
 429 dnl Check for a way to display the function name in debug output
 430 AG_GST_CHECK_FUNCTION
 431
 432 dnl test for register_printf_function
 433 AC_CHECK_FUNC(register_printf_function,
 434   [
 435     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 436     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 437     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 438     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 439       [Defined if we have register_printf_function ()])
 440   ], [
 441     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 442     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 443     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 444   ]
 445 )
 446 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 447 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 448 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 449
 450 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 451 save_cflags="$CFLAGS"
 452 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 453 AC_CHECK_LIB(dl, dladdr,
 454    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 455    LIBS="$LIBS -ldl")
 456 CFLAGS="$save_cflags"
 457
 458 dnl check for inet_aton()
 459 save_libs="$LIBS"
 460 AC_CHECK_FUNC(inet_aton, ,
 461    AC_CHECK_LIB(nsl, inet_aton, ,
 462       AC_CHECK_LIB(socket, inet_aton, ,
 463          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 464 INET_ATON_LIBS=$LIBS
 465 AC_SUBST(INET_ATON_LIBS)
 466 LIBS="$save_libs"
 467
 468 dnl *** checks for dependency libraries ***
 469
 470 dnl GLib
 471 GLIB_REQ=2.12
 472
 473 AG_GST_GLIB_CHECK([$GLIB_REQ])
 474
 475 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 476 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 477 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 478
 479 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 480 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 481
 482 dnl Check for documentation xrefs
 483 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 484 AC_SUBST(GLIB_PREFIX)
 485
 486 dnl libxml 2 is optional in some cases
 487 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 488    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 489    test "x$USE_BINARY_REGISTRY" = "xyes" )
 490 then
 491   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 492   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 493 else
 494   dnl check for libxml2 with minimum req version
 495   AG_GST_LIBXML2_CHECK(2.4.9)
 496   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 497 fi
 498 AC_SUBST(GST_DISABLE_XML_DEFINE)
 499
 500 dnl check for "check", unit testing library/header
 501 if test "$cross_compiling" != yes; then
 502   AM_PATH_CHECK(0.9.2,
 503       HAVE_CHECK=yes,
 504       HAVE_CHECK=no)
 505 else
 506   HAVE_CHECK=no
 507 fi
 508 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 509
 510 dnl pkg-config check that for libcheck that works for cross-compiling
 511 dnl but not normal compilation on Fedora & Ubuntu:
 512 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 513 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 514 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 515 dnl )
 516
 517 dnl *** set variables based on configure arguments
 518
 519 dnl set license and copyright notice
 520 GST_LICENSE="LGPL"
 521 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 522 AC_SUBST(GST_LICENSE)
 523
 524 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 525 AS_AC_EXPAND(LIBDIR, $libdir)
 526 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 527 AS_AC_EXPAND(DATADIR, $datadir)
 528 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 529
 530 dnl set location of plugin directory
 531 AG_GST_SET_PLUGINDIR
 532
 533 dnl FIXME: add LIBXML_PKG here if we use it
 534 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 535 AC_SUBST(GST_PKG_DEPS)
 536
 537 dnl define an ERROR_CFLAGS Makefile variable
 538 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 539
 540 dnl define correct level for debugging messages
 541 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 542
 543 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 544
 545 dnl Overview:
 546 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 547 dnl GST_ALL_*:          vars shared by all built objects
 548 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 549 dnl GST_OBJ_*:          additional vars to link to the core library
 550 dnl                     include GST_ALL_*
 551 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 552 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 553
 554 dnl GST_OPTION_CFLAGS
 555 if test "x$USE_DEBUG" = xyes; then
 556    PROFILE_CFLAGS="-g"
 557 fi
 558 AC_SUBST(PROFILE_CFLAGS)
 559
 560 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 561 # functionality from the API that gstreamer uses
 562 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 563 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 564   dnl Define _only_ during CVS (not pre-releases or releases)
 565   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 566 else
 567   DEPRECATED_CFLAGS=""
 568 fi
 569 AC_SUBST(DEPRECATED_CFLAGS)
 570
 571 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 572 dnl make DEPRECATED_CFLAGS=''
 573 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 574 AC_SUBST(GST_OPTION_CFLAGS)
 575
 576 dnl GST_ALL_*
 577 dnl vars common to for all internal objects (core libs, elements, applications)
 578 dnl CFLAGS:
 579 dnl - XML needs to be added because xmlPtr is used in core
 580 dnl - src and build dirs need to be added because every piece that gets built
 581 dnl   will need the GStreamer source and generated headers
 582 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 583 dnl       from LibXML except for in the core library
 584 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 585
 586 dnl FIXME: check if LTLIBINTL is needed everywhere
 587 dnl I presume it is given that it contains the symbols that _() stuff maps to
 588 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 589
 590 dnl LDFLAGS really should only contain flags, not libs - they get added before
 591 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 592 GST_ALL_LDFLAGS="-no-undefined"
 593
 594 AC_SUBST(GST_ALL_CFLAGS)
 595 AC_SUBST(GST_ALL_LIBS)
 596 AC_SUBST(GST_ALL_LDFLAGS)
 597
 598 dnl GST_LIB_LDFLAGS
 599 dnl linker flags shared by all libraries
 600 dnl LDFLAGS modifier defining exported symbols from built libraries
 601 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 602 AC_SUBST(GST_LIB_LDFLAGS)
 603 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 604 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 605 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 606 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 607   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 608 fi
 609 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 610
 611 dnl GST_OBJ_*
 612 dnl default vars for all internal objects built on libgstreamer
 613 dnl includes GST_ALL_*
 614 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 615 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 616 AC_SUBST(GST_OBJ_CFLAGS)
 617 AC_SUBST(GST_OBJ_LIBS)
 618
 619 dnl GST_PLUGIN_LDFLAGS
 620 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 621 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 622 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 623
 624 AC_CONFIG_FILES(
 625 Makefile
 626 gst/Makefile
 627 gst/gstconfig.h
 628 gst/gstversion.h
 629 gst/parse/Makefile
 630 libs/Makefile
 631 libs/gst/Makefile
 632 libs/gst/base/Makefile
 633 libs/gst/check/Makefile
 634 libs/gst/controller/Makefile
 635 libs/gst/dataprotocol/Makefile
 636 libs/gst/net/Makefile
 637 plugins/Makefile
 638 plugins/indexers/Makefile
 639 plugins/elements/Makefile
 640 po/Makefile.in
 641 tests/Makefile
 642 tests/benchmarks/Makefile
 643 tests/check/Makefile
 644 tests/misc/Makefile
 645 tests/examples/Makefile
 646 tests/examples/adapter/Makefile
 647 tests/examples/controller/Makefile
 648 tests/examples/helloworld/Makefile
 649 tests/examples/launch/Makefile
 650 tests/examples/manual/Makefile
 651 tests/examples/metadata/Makefile
 652 tests/examples/queue/Makefile
 653 tests/examples/typefind/Makefile
 654 tests/examples/xml/Makefile
 655 tools/Makefile
 656 common/Makefile
 657 common/m4/Makefile
 658 docs/Makefile
 659 docs/design/Makefile
 660 docs/faq/Makefile
 661 docs/gst/Makefile
 662 docs/gst/gstreamer.types
 663 docs/libs/Makefile
 664 docs/plugins/Makefile
 665 docs/manual/Makefile
 666 docs/pwg/Makefile
 667 docs/slides/Makefile
 668 docs/xsl/Makefile
 669 docs/version.entities
 670 win32/common/config.h
 671 pkgconfig/Makefile
 672 stamp.h
 673 pkgconfig/gstreamer.pc
 674 pkgconfig/gstreamer-uninstalled.pc
 675 pkgconfig/gstreamer-base.pc
 676 pkgconfig/gstreamer-base-uninstalled.pc
 677 pkgconfig/gstreamer-check.pc
 678 pkgconfig/gstreamer-check-uninstalled.pc
 679 pkgconfig/gstreamer-controller.pc
 680 pkgconfig/gstreamer-controller-uninstalled.pc
 681 pkgconfig/gstreamer-dataprotocol.pc
 682 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 683 pkgconfig/gstreamer-net.pc
 684 pkgconfig/gstreamer-net-uninstalled.pc
 685 gst-element-check.m4
 686 gstreamer.spec
 687 )
 688
 689 AC_OUTPUT
 690
 691 dnl negate for output
 692 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 693 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 694 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 695 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 696 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 697 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 698 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 699 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 700
 701 echo "
 702
 703 Configuration
 704         Version                    : ${VERSION}
 705         Source code location       : ${srcdir}
 706         Prefix                     : ${prefix}
 707         Compiler                   : ${CC}
 708         Package name               : ${GST_PACKAGE_NAME}
 709         Package origin             : ${GST_PACKAGE_ORIGIN}
 710
 711         Documentation (manuals)    : ${enable_docbook}
 712         Documentation (API)        : ${enable_gtk_doc}
 713
 714         Pipeline XML load/save     : ${enable_loadsave}
 715         Command-line parser        : ${enable_parse}
 716         Option parsing in gst_init : ${enable_option_parsing}
 717         Tracing subsystem          : ${enable_trace}
 718         Allocation tracing         : ${enable_alloc_trace}
 719         Plugin registry            : ${enable_registry}
 720         Plugin support             : ${enable_plugin}
 721         Network support            : ${enable_net}
 722
 723         Debug                      : ${USE_DEBUG}
 724         Profiling                  : ${USE_PROFILING}
 725
 726         Building examples          : ${BUILD_EXAMPLES}
 727         Building test apps         : ${BUILD_TESTS}
 728         Building tests that fail   : ${BUILD_FAILING_TESTS}
 729 "