configure.ac

   1 AC_PREREQ(2.52)
   2
   3 AC_INIT
   4 AC_CANONICAL_TARGET
   5
   6 dnl when going to/from release please set the nano (fourth number) right !
   7 dnl releases only do Wall, cvs and prerelease does Werror too
   8 AS_VERSION(gstreamer, GST_VERSION, 0, 9, 3, 1,
   9     GST_CVS="no", GST_CVS="yes")
  10
  11 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  12 AM_MAINTAINER_MODE
  13 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  14
  15 dnl our libraries and install dirs use major.minor as a version
  16 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  17 dnl we override it here for release candidates for a new series
  18 # GST_MAJORMINOR=0.9
  19 AC_SUBST(GST_MAJORMINOR)
  20
  21 AC_PROG_CC
  22 dnl For interactive UNIX (a Sun thing)
  23 AC_ISC_POSIX
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 AS_LIBTOOL(GST, 7, 0, 0)
  31 AS_LIBTOOL_TAGS([])
  32 AM_PROG_LIBTOOL
  33
  34 AC_CONFIG_SRCDIR([gst/gst.c])
  35 AM_CONFIG_HEADER(config.h)
  36
  37 dnl Add parameters for aclocal
  38 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  39
  40 AM_PROG_CC_STDC
  41 AM_PROG_AS
  42 AS="${CC}"
  43
  44 dnl the gettext stuff needed
  45 AM_GNU_GETTEXT_VERSION(0.11.5)
  46 AM_GNU_GETTEXT([external])
  47
  48 GETTEXT_PACKAGE=gstreamer-$GST_MAJORMINOR
  49 AC_SUBST(GETTEXT_PACKAGE)
  50 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  51                    [gettext package name])
  52
  53 dnl define LOCALEDIR in config.h
  54 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  55 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  56                    [gettext locale dir])
  57
  58 dnl define LIBDIR so we can inform people where we live
  59 AS_AC_EXPAND(LIBDIR, $libdir)
  60 AC_DEFINE_UNQUOTED([LIBDIR], "$LIBDIR",
  61                    [library dir])
  62
  63 GST_SET_ERROR_CFLAGS($GST_CVS)
  64
  65 dnl We disable static building for development, for time savings
  66 dnl *NOTE*: dnl this line before release, so release does static too
  67 dnl AM_DISABLE_STATIC
  68
  69 AC_HEADER_STDC([])
  70 AC_C_INLINE
  71
  72 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  73 dnl messages printed when running cvs builds
  74 if test "x$GST_CVS" = "xyes"; then
  75   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  76 fi
  77
  78 dnl subsystems - can influence other decisions so needs to be high up
  79 dnl we need to do AM_CONDITIONAL them here for automake 1.6.x compatibility
  80 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  81 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  82 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  83 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  87 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  88 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  89 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  90 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  91 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  93 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  95 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  96 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  97 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  98 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
  99 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 100
 101 dnl ##############################
 102 dnl # Do automated configuration #
 103 dnl ##############################
 104
 105 dnl Check for tools:
 106 dnl ================
 107
 108 dnl allow for different autotools
 109 AS_AUTOTOOLS_ALTERNATE()
 110
 111 dnl modify pkg-config path
 112 AC_ARG_WITH(pkg-config-path,
 113    AC_HELP_STRING([--with-pkg-config-path],
 114                   [colon-separated list of pkg-config(1) dirs]),
 115    [export PKG_CONFIG_PATH=${withval}])
 116
 117 GST_ARCH()
 118
 119 dnl ### Documentation checks
 120
 121 dnl Perl is used in building documentation
 122 AC_PATH_PROG(PERL_PATH, perl, no)
 123 if test x$PERL_PATH = xno; then
 124   AC_MSG_ERROR(Could not find perl)
 125 fi
 126
 127 GST_DOCBOOK_CHECK
 128 GTK_DOC_CHECK([1.3])
 129
 130 AC_PROG_AWK
 131
 132 dnl we require bison for building the parser
 133 dnl FIXME: check if AC_PROG_YACC is suitable here
 134 AC_PATH_PROG(BISON_PATH, bison, no)
 135 if test x$BISON_PATH = xno; then
 136   AC_MSG_ERROR(Could not find bison)
 137 fi
 138
 139 dnl check bison version
 140 AC_MSG_CHECKING([bison version])
 141
 142 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 143 then
 144   AC_MSG_RESULT([ok])
 145 else
 146   AC_MSG_RESULT([too old.])
 147   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 148 fi
 149
 150 dnl we require flex for building the parser
 151 dnl FIXME: check if AC_PROG_LEX is suitable here
 152 AC_PATH_PROG(FLEX_PATH, flex, no)
 153 if test x$FLEX_PATH = xno; then
 154   AC_MSG_ERROR(Could not find flex)
 155 fi
 156
 157 dnl check for large file support (affected
 158 dnl plugins must include config.h for this)
 159 AC_SYS_LARGEFILE
 160
 161 dnl check for mmap
 162 AC_FUNC_MMAP()
 163
 164 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 165 AC_CHECK_MCSC()
 166 if test "$ac_cv_check_mcsc" = "yes"; then
 167   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 168                      [defined if we have makecontext ()])
 169 fi
 170
 171 dnl Check for a way to display the function name in debug output
 172 GST_CHECK_FUNCTION()
 173
 174 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 175 dnl symbolic register names in inline asm
 176 if test x$HAVE_CPU_PPC = xyes ; then
 177   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 178     [GST_INT_CFLAGS="$GST_INT_CFLAGS -Wa,-mregnames"],
 179     true)
 180 fi
 181
 182 AC_ARG_ENABLE(gcov,
 183   AC_HELP_STRING([--enable-gcov],[compile with coverage profiling instrumentation (gcc only)]),
 184   enable_gcov=$enableval,enable_gcov=no)
 185 if test x$enable_gcov = xyes ; then
 186   AS_COMPILER_FLAG(["-fprofile-arcs"],
 187     [GST_INT_CFLAGS="$GST_INT_CFLAGS -fprofile-arcs"],
 188     true)
 189   AS_COMPILER_FLAG(["-ftest-coverage"],
 190     [GST_INT_CFLAGS="$GST_INT_CFLAGS -ftest-coverage"],
 191     true)
 192   GST_INT_CFLAGS=`echo "$GST_INT_CFLAGS" | sed -e 's/-O[0-9]*//g'`
 193
 194   AC_DEFINE_UNQUOTED(GST_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 195 fi
 196 AM_CONDITIONAL(GST_GCOV_ENABLED, test x$enable_gcov = xyes)
 197
 198 dnl Check for some compiler flags that optimize our code.
 199 if test "x$GCC" = xyes; then
 200   AS_COMPILER_FLAG(-fno-common,GST_INT_CFLAGS="$GST_INT_CFLAGS -fno-common",)
 201 fi
 202
 203 dnl HAVE_WIN32 currently means "disable POSIXisms".
 204 case "$host" in
 205   *-*-mingw*)
 206     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 207     ;;
 208   *)
 209     ;;
 210 esac
 211
 212 GST_UNALIGNED_ACCESS()
 213 if test x${as_cv_unaligned_access} = xyes ; then
 214   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 215 else
 216   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 217 fi
 218 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 219
 220 dnl Check for essential libraries first:
 221 dnl ====================================
 222
 223 dnl === GLib 2 ===
 224 dnl Minimum required version of GLib2
 225 dnl required for compilation without warnings
 226 GLIB2_REQ="2.4"
 227 AC_SUBST(GLIB2_REQ)
 228
 229 dnl Check for glib2 with sugar on top
 230 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 231 dnl for the poor souls who for example have glib in /usr/local
 232 AS_SCRUB_INCLUDE(GLIB2_CFLAGS)
 233 GLIB_LIBS=$GLIB2_LIBS
 234 GLIB_CFLAGS=$GLIB2_CFLAGS
 235 AC_SUBST(GLIB_LIBS)
 236 AC_SUBST(GLIB_CFLAGS)
 237
 238 AC_MSG_CHECKING([glib version >= 2.8])
 239 if pkg-config --atleast-version=2.8 glib-2.0; then
 240   AC_MSG_RESULT(yes)
 241   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 242 else
 243   AC_MSG_RESULT(no)
 244   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 245 fi
 246 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 247
 248 if test "x$HAVE_GLIB2" = "xno"; then
 249   AC_MSG_ERROR([GStreamer requires GLib $GLIB2_REQ to compile.])
 250 fi
 251
 252 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 253 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB2_REQ)
 254 AC_SUBST(GLIB_ONLY_CFLAGS)
 255 AC_SUBST(GLIB_ONLY_LIBS)
 256
 257 dnl === libxml 2 ===
 258 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && test "x$GST_DISABLE_REGISTRY" = "xyes"
 259 then
 260   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 261 else
 262   dnl check for libxml2 with minimum req version
 263   GST_LIBXML2_CHECK(2.4.9)
 264 fi
 265
 266 dnl popt checks
 267 dnl FIXME: This test passes on popt 1.6.2, maybe earlier, but popt 1.6.2
 268 dnl        causes segfaults on gst_init. Write a working test if possible.
 269 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 270   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 271                 download the latest version from
 272                 ftp://ftp.rpm.org/pub/rpm/dist/])
 273 )
 274 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 275 AC_COMPILE_IFELSE([
 276 #include <popt.h>
 277 int main ()
 278 {
 279 #ifndef POPT_TABLEEND
 280 #error
 281 #else
 282   return 0;
 283 #endif
 284 }
 285 ],, [
 286   dnl it failed
 287   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 288                 download the latest version from
 289                 ftp://ftp.rpm.org/pub/rpm/dist/])
 290 ])
 291 AC_SUBST(POPT_CFLAGS)
 292 AC_SUBST(POPT_LIBS)
 293
 294 dnl Check for ucontext.h
 295 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 296
 297 dnl check for "check", unit testing library/header
 298 AM_PATH_CHECK(0.9.2,
 299     [
 300         HAVE_CHECK=yes
 301         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 302         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 303     ],
 304     HAVE_CHECK=no)
 305 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 306
 307 dnl ######################################################################
 308 dnl # Check command line parameters, and set shell variables accordingly #
 309 dnl ######################################################################
 310
 311 dnl FIXME: simplify all this down using a few m4 macros
 312
 313 AC_ARG_ENABLE(fast-stack-trash,
 314 AC_HELP_STRING([--enable-fast-stack-trash],[use fast memory allocator (i586 or above)]),
 315 [case "${enableval}" in
 316   yes) USE_FAST_STACK_TRASH=yes;;
 317   noset) USE_FAST_STACK_TRASH=no;;
 318   no)  USE_FAST_STACK_TRASH=no;;
 319   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 320 esac],
 321 [USE_FAST_STACK_TRASH=yes]) dnl Default value
 322
 323 AC_ARG_ENABLE(profiling,
 324 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 325 [case "${enableval}" in
 326   yes) USE_PROFILING=yes ;;
 327   no)  USE_PROFILING=no ;;
 328   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 329 esac],
 330 [USE_PROFILING=no]) dnl Default value
 331
 332 dnl use a cache dir for storing element registry info.
 333 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 334
 335 AC_ARG_WITH(cachedir,
 336 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 337 [case "${withval}" in
 338   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 339   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 340   *) GST_CACHE_DIR="${withval}" ;;
 341 esac],
 342 [:]) dnl Default value
 343
 344 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 345 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 346 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 347
 348 dnl building of tests
 349 AC_ARG_ENABLE(tests,
 350 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 351 [case "${enableval}" in
 352   yes) BUILD_TESTS=yes ;;
 353   no)  BUILD_TESTS=no ;;
 354   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 355 esac],
 356 [BUILD_TESTS=yes]) dnl Default value
 357 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 358
 359 dnl tests known to fail
 360 AC_ARG_ENABLE(failing-tests,
 361 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 362 [case "${enableval}" in
 363   yes) BUILD_FAILING_TESTS=yes ;;
 364   no)  BUILD_FAILING_TESTS=no ;;
 365   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 366 esac],
 367 [BUILD_FAILING_TESTS=no]) dnl Default value
 368 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 369 if test x$BUILD_FAILING_TESTS = xyes; then
 370   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 371 else
 372   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 373 fi
 374
 375 AC_ARG_ENABLE(examples,
 376 AC_HELP_STRING([--disable-examples],[disable building examples]),
 377 [case "${enableval}" in
 378   yes) BUILD_EXAMPLES=yes ;;
 379   no)  BUILD_EXAMPLES=no ;;
 380   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 381 esac],
 382 [BUILD_EXAMPLES=yes]) dnl Default value
 383 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 384
 385 dnl poison destroyed objects
 386 AC_ARG_ENABLE(poisoning,
 387 AC_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 388 [case "${enableval}" in
 389   yes) USE_POISONING=yes ;;
 390   no)  USE_POISONING=no ;;
 391   *) AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 392 esac],
 393 [USE_POISONING=no]) dnl Default value
 394
 395 dnl Next, check for the optional components:
 396 dnl ========================================
 397
 398 dnl debugging stuff
 399 AC_ARG_ENABLE(debug,
 400 AC_HELP_STRING([--disable-debug],[disable addition of -g debugging info]),
 401 [case "${enableval}" in
 402   yes) USE_DEBUG=yes ;;
 403   no)  USE_DEBUG=no ;;
 404   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 405 esac],
 406 [USE_DEBUG=yes]) dnl Default value
 407
 408 dnl valgrind inclusion
 409 AC_ARG_ENABLE(valgrind,
 410 AC_HELP_STRING([--disable-valgrind],[disable run-time valgrind detection]),
 411 [case "${enableval}" in
 412   yes) USE_VALGRIND="$USE_DEBUG" ;;
 413   no)  USE_VALGRIND=no ;;
 414   *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind) ;;
 415 esac],
 416 [USE_VALGRIND="$USE_DEBUG"]) dnl Default value
 417 VALGRIND_REQ="2.1"
 418 if test "x$USE_VALGRIND" = xyes; then
 419
 420   PKG_CHECK_MODULES(VALGRIND, valgrind > $VALGRIND_REQ, USE_VALGRIND="yes", USE_VALGRIND="no")
 421 fi
 422 if test "x$USE_VALGRIND" = xyes; then
 423   AC_DEFINE(HAVE_VALGRIND, 1, [Define if valgrind should be used])
 424   AC_MSG_NOTICE(Using extra code paths for valgrind)
 425 fi
 426 AC_SUBST(VALGRIND_CFLAGS)
 427 AC_SUBST(VALGRIND_LIBS)
 428
 429 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 430 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 431
 432 dnl ################################################
 433 dnl # Set defines according to variables set above #
 434 dnl ################################################
 435
 436
 437 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 438 dnl HAVE_ and it is likely to be easier to stick with the old name
 439 if test "x$USE_FAST_STACK_TRASH" = xyes; then
 440   AC_DEFINE(USE_FAST_STACK_TRASH, 1, [Define if we should use i586 optimized stack functions])
 441 fi
 442
 443 if test "x$USE_POISONING" = xyes; then
 444   AC_DEFINE(USE_POISONING, 1, [Define if we should poison deallocated memory])
 445 fi
 446
 447 dnl test for sigaction()
 448 AC_CHECK_FUNC(sigaction,
 449    AC_DEFINE(HAVE_SIGACTION, 1,
 450              [Defined if we have sigaction ()]))
 451
 452 dnl test for register_printf_function
 453 AC_CHECK_FUNC(register_printf_function,
 454   [
 455     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 456     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 457              [Defined if we have register_printf_function ()])
 458   ],
 459   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 460 )
 461 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 462
 463 dnl test if we have dladdr(); we use it for debugging
 464 save_cflags="$CFLAGS"
 465 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 466 AC_CHECK_LIB(dl, dladdr,
 467    AC_DEFINE(HAVE_DLADDR, 1,
 468              [Defined if we have dladdr ()]))
 469 CFLAGS="$save_cflags"
 470
 471 if test "x$USE_DEBUG" = xyes; then
 472    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 473 fi
 474
 475 dnl #############################
 476 dnl # Set automake conditionals #
 477 dnl #############################
 478
 479 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 480 dnl HAVE_ and it is likely to be easier to stick with the old name
 481 AM_CONDITIONAL(EXPERIMENTAL,        test "x$EXPERIMENTAL" = "xyes")
 482 AM_CONDITIONAL(BROKEN,              test "x$BROKEN" = "xyes")
 483
 484 dnl ############################
 485 dnl # Set up some more defines #
 486 dnl ############################
 487
 488 dnl set license and copyright notice
 489 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 490
 491 dnl package name in plugins
 492 AC_ARG_WITH(package-name,
 493 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 494 [case "${withval}" in
 495   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 496   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 497   *) GST_PACKAGE="${withval}" ;;
 498 esac],
 499 [
 500 dnl default value
 501 if test "x$GST_CVS" = "xyes"
 502 then
 503   dnl nano >= 1
 504   GST_PACKAGE="GStreamer CVS/prerelease"
 505 else
 506   GST_PACKAGE="GStreamer source release"
 507 fi
 508 ]
 509 )
 510 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 511 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 512
 513 dnl package origin URL
 514 AC_ARG_WITH(package-origin,
 515 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 516 [case "${withval}" in
 517   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 518   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 519   *) GST_ORIGIN="${withval}" ;;
 520 esac],
 521 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 522 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 523 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 524
 525 dnl Set location of plugin directory
 526 AS_AC_EXPAND(PLUGINS_DIR, ${libdir}/gstreamer-$GST_MAJORMINOR)
 527 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 528 AC_SUBST(PLUGINS_DIR)
 529 AC_MSG_NOTICE([Using $PLUGINS_DIR as the plugin install location])
 530
 531 dnl LDFLAGS modifier defining exported symbols from built objects
 532 EXPORT_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 533
 534 dnl GST_PKG_*:    the flags we use that are also used
 535 dnl               for external applications/.pc file
 536 dnl GST_LIB_*:    used for the main library
 537 dnl GST_OBJ_*:    the flags we use for all the objects internal to the core
 538 dnl GST_PLUGIN_*: additional flags we use for all plugins
 539
 540 dnl finalize _CFLAGS and _LIBS
 541 dnl flags exported for external applications and use in our pkg-config .pc files
 542 dnl since glib and xml are package deps, there's no need to include their cflags
 543 dnl in the pkg-config file
 544
 545 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 546 AC_SUBST(GST_PKG_CFLAGS)
 547 AC_SUBST(GST_PKG_LIBS)
 548 AC_SUBST(GST_PKG_DEPS)
 549
 550 dnl flags shared for all internal objects (core libs, elements, applications)
 551 dnl we disable deprecated internally
 552 dnl XML, GLib, popt, GST_INT, VALGRIND, and the right include for CFLAGS
 553 dnl no need to add XML, GLib, popt explicitly since libgstreamer pulls them in
 554 GST_INT_CFLAGS="$GLIB_CFLAGS $XML_CFLAGS $GST_PKG_CFLAGS \
 555  $GST_INT_CFLAGS \$(ERROR_CFLAGS) -DGST_DISABLE_DEPRECATED"
 556
 557 dnl Private vars for libgst only
 558 GST_LIB_CFLAGS="$GST_PKG_CFLAGS $GST_INT_CFLAGS \
 559   $VALGRIND_CFLAGS -I\$(top_srcdir)"
 560 GST_LIB_LIBS="$XML_LIBS $GLIB_LIBS -lpopt $GST_PKG_LIBS $LTLIBINTL $VALGRIND_LIBS"
 561 GST_LIB_LDFLAGS="$GST_LT_LDFLAGS -version-info $GST_LIBVERSION -no-undefined $EXPORT_LDFLAGS"
 562 AC_SUBST(GST_LIB_CFLAGS)
 563 AC_SUBST(GST_LIB_LIBS)
 564 AC_SUBST(GST_LIB_LDFLAGS)
 565
 566 dnl Vars for all internal objects built on libgstreamer
 567 GST_OBJ_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)"
 568 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 569
 570 AC_SUBST(GST_OBJ_CFLAGS, "$GST_OBJ_CFLAGS")
 571 AC_SUBST(GST_OBJ_LIBS, "$GST_OBJ_LIBS")
 572
 573 dnl specific additional LDFLAGS for plugins
 574 GST_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined $EXPORT_LDFLAGS"
 575 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 576
 577 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 578 AC_SUBST(plugindir)
 579
 580 dnl ##################################################
 581 dnl # deps for examples from manual                  #
 582 dnl ##################################################
 583
 584 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 585                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 586 AC_SUBST(LIBGNOMEUI_CFLAGS)
 587 AC_SUBST(LIBGNOMEUI_LIBS)
 588 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 589
 590 dnl ##################################################
 591 dnl # Prepare informative messages to display at end #
 592 dnl ##################################################
 593
 594 infomessages=
 595
 596 dnl #########################
 597 dnl # Make the output files #
 598 dnl #########################
 599
 600 dnl libs/ext/Makefile
 601 dnl nothing there yet !
 602 AC_OUTPUT(
 603 Makefile
 604 gst/Makefile
 605 gst/gstconfig.h
 606 gst/gstversion.h
 607 gst/base/Makefile
 608 gst/check/Makefile
 609 gst/indexers/Makefile
 610 gst/elements/Makefile
 611 gst/parse/Makefile
 612 libs/Makefile
 613 libs/gst/Makefile
 614 libs/gst/controller/Makefile
 615 libs/gst/dataprotocol/Makefile
 616 po/Makefile.in
 617 check/Makefile
 618 tests/Makefile
 619 tests/instantiate/Makefile
 620 tests/muxing/Makefile
 621 tests/seeking/Makefile
 622 tests/sched/Makefile
 623 tests/threadstate/Makefile
 624 testsuite/Makefile
 625 testsuite/bytestream/Makefile
 626 testsuite/caps/Makefile
 627 testsuite/cleanup/Makefile
 628 testsuite/controller/Makefile
 629 testsuite/debug/Makefile
 630 testsuite/dlopen/Makefile
 631 testsuite/elements/Makefile
 632 testsuite/indexers/Makefile
 633 testsuite/negotiation/Makefile
 634 testsuite/pad/Makefile
 635 testsuite/parse/Makefile
 636 testsuite/plugin/Makefile
 637 testsuite/refcounting/Makefile
 638 testsuite/schedulers/Makefile
 639 testsuite/states/Makefile
 640 testsuite/threads/Makefile
 641 testsuite/trigger/Makefile
 642 examples/Makefile
 643 examples/controller/Makefile
 644 examples/cutter/Makefile
 645 examples/helloworld/Makefile
 646 examples/launch/Makefile
 647 examples/manual/Makefile
 648 examples/mixer/Makefile
 649 examples/metadata/Makefile
 650 examples/pingpong/Makefile
 651 examples/plugins/Makefile
 652 examples/pwg/Makefile
 653 examples/queue/Makefile
 654 examples/retag/Makefile
 655 examples/thread/Makefile
 656 examples/typefind/Makefile
 657 examples/xml/Makefile
 658 tools/Makefile
 659 common/Makefile
 660 common/m4/Makefile
 661 docs/Makefile
 662 docs/faq/Makefile
 663 docs/gst/Makefile
 664 docs/libs/Makefile
 665 docs/manual/Makefile
 666 docs/pwg/Makefile
 667 docs/xsl/Makefile
 668 docs/version.entities
 669 pkgconfig/Makefile
 670 stamp.h
 671 pkgconfig/gstreamer.pc
 672 pkgconfig/gstreamer-uninstalled.pc
 673 pkgconfig/gstreamer-base.pc
 674 pkgconfig/gstreamer-base-uninstalled.pc
 675 pkgconfig/gstreamer-check.pc
 676 pkgconfig/gstreamer-check-uninstalled.pc
 677 pkgconfig/gstreamer-controller.pc
 678 pkgconfig/gstreamer-controller-uninstalled.pc
 679 pkgconfig/gstreamer-dataprotocol.pc
 680 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 681 gstreamer.spec,
 682 echo "$infomessages", infomessages="$infomessages"
 683 )