configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.9.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 901, 0, 901)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.9.1.1
  50 GSTPB_REQ=1.9.1.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/time.h])
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/socket.h])
 161
 162 dnl *** checks for types/defines ***
 163
 164 dnl Check for FIONREAD ioctl declaration.  This check is needed
 165 dnl for the UDP plugin to build on Solaris
 166 GST_CHECK_FIONREAD
 167
 168 dnl *** checks for structures ***
 169
 170 dnl *** checks for compiler characteristics ***
 171
 172 dnl check if we have GCC inline-asm
 173 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 174 if test x$HAVE_GCC_ASM = xyes ; then
 175   AC_DEFINE(HAVE_GCC_ASM, 1,
 176     [Define if compiler supports gcc inline assembly])
 177 fi
 178 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 179
 180 dnl *** checks for library functions ***
 181
 182 LIBS_SAVE=$LIBS
 183 LIBS="$LIBS $LIBM"
 184 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 185 LIBS=$LIBS_SAVE
 186
 187 dnl Check whether isinf() is defined by math.h
 188 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 190 if test "$ac_cv_have_isinf" = "yes"
 191 then
 192     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 193 fi
 194
 195 dnl Check for mmap (needed by electricfence plugin)
 196 AC_FUNC_MMAP
 197 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 198
 199 dnl Check for mmap (needed by electricfence plugin)
 200
 201 AC_CHECK_TYPE([struct ip_mreqn], [
 202               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 203               [#include <netinet/in.h>])
 204
 205 dnl *** checks for dependency libraries ***
 206
 207
 208 dnl GLib
 209 GLIB_REQ=2.40.0
 210 AG_GST_GLIB_CHECK([$GLIB_REQ])
 211
 212 dnl Orc
 213 ORC_CHECK([0.4.17])
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 HAVE_GTK=no
 245 GTK_REQ=3.0.0
 246 if test "x$BUILD_EXAMPLES" = "xyes"; then
 247   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 248   dnl some examples need gtk+-x11
 249   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 250   AC_SUBST(GTK_LIBS)
 251   AC_SUBST(GTK_CFLAGS)
 252 fi
 253 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 254 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 255
 256 dnl Check for -Bsymbolic-functions linker flag used to avoid
 257 dnl intra-library PLT jumps, if available.
 258 AC_ARG_ENABLE(Bsymbolic,
 259               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 260               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 261                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 262                LDFLAGS=-Wl,-Bsymbolic-functions
 263                LIBS=
 264                AC_TRY_LINK([], [return 0],
 265                            AC_MSG_RESULT(yes)
 266                            enable_Bsymbolic=yes,
 267                            AC_MSG_RESULT(no)
 268                            enable_Bsymbolic=no)
 269                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 270
 271 dnl *** set variables based on configure arguments ***
 272
 273 dnl set license and copyright notice
 274 GST_LICENSE="LGPL"
 275 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 276 AC_SUBST(GST_LICENSE)
 277
 278 dnl set location of plugin directory
 279 AG_GST_SET_PLUGINDIR
 280
 281 dnl set release date/time
 282 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 283   ["${srcdir}/gst-plugins-good.doap"],
 284   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 285
 286 dnl build static plugins or not
 287 AC_MSG_CHECKING([whether to build static plugins or not])
 288 AC_ARG_ENABLE(
 289   static-plugins,
 290   AC_HELP_STRING(
 291     [--enable-static-plugins],
 292     [build static plugins @<:@default=no@:>@]),
 293   [AS_CASE(
 294     [$enableval], [no], [], [yes], [],
 295     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 296   [enable_static_plugins=no])
 297 AC_MSG_RESULT([$enable_static_plugins])
 298 if test "x$enable_static_plugins" = xyes; then
 299   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 300     [Define if static plugins should be built])
 301   GST_PLUGIN_LIBTOOLFLAGS=""
 302 else
 303   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 304 fi
 305 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 306 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 307
 308 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 309 dnl make sure it doesn't complain about unused variables if debugging is disabled
 310 NO_WARNINGS=""
 311 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 312
 313 dnl define an ERROR_CFLAGS Makefile variable
 314 dnl -Wundef: too many broken headers
 315 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 316       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 317       -Wwrite-strings -Wold-style-definition -Waggregate-return
 318       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 319       -Wnested-externs $NO_WARNINGS])
 320
 321 dnl define an ERROR_CXXFLAGS Makefile variable
 322 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 323         -Wmissing-declarations -Wredundant-decls
 324         -Wwrite-strings
 325         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 326         $NO_WARNINGS])
 327
 328 dnl define an ERROR_OBJCFLAGS Makefile variable
 329 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 330       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 331       -Wwrite-strings -Wold-style-definition
 332       -Winit-self -Wmissing-include-dirs -Wno-multichar
 333       -Wnested-externs $NO_WARNINGS])
 334
 335 dnl define correct level for debugging messages
 336 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 337
 338 dnl used in examples
 339 AG_GST_DEFAULT_ELEMENTS
 340
 341 dnl *** plug-ins to include ***
 342
 343 dnl these are all the gst plug-ins, compilable without additional libs
 344 dnl videofilter is at the top because others depend on it
 345 AG_GST_CHECK_PLUGIN(alpha)
 346 AG_GST_CHECK_PLUGIN(apetag)
 347 AG_GST_CHECK_PLUGIN(audiofx)
 348 AG_GST_CHECK_PLUGIN(audioparsers)
 349 AG_GST_CHECK_PLUGIN(auparse)
 350 AG_GST_CHECK_PLUGIN(autodetect)
 351 AG_GST_CHECK_PLUGIN(avi)
 352 AG_GST_CHECK_PLUGIN(cutter)
 353 AG_GST_CHECK_PLUGIN(debugutils)
 354 AG_GST_CHECK_PLUGIN(deinterlace)
 355 AG_GST_CHECK_PLUGIN(dtmf)
 356 AG_GST_CHECK_PLUGIN(effectv)
 357 AG_GST_CHECK_PLUGIN(equalizer)
 358 AG_GST_CHECK_PLUGIN(flv)
 359 AG_GST_CHECK_PLUGIN(flx)
 360 AG_GST_CHECK_PLUGIN(goom)
 361 AG_GST_CHECK_PLUGIN(goom2k1)
 362 AG_GST_CHECK_PLUGIN(icydemux)
 363 AG_GST_CHECK_PLUGIN(id3demux)
 364 AG_GST_CHECK_PLUGIN(imagefreeze)
 365 AG_GST_CHECK_PLUGIN(interleave)
 366 AG_GST_CHECK_PLUGIN(isomp4)
 367 AG_GST_CHECK_PLUGIN(law)
 368 AG_GST_CHECK_PLUGIN(level)
 369 AG_GST_CHECK_PLUGIN(matroska)
 370 AG_GST_CHECK_PLUGIN(monoscope)
 371 AG_GST_CHECK_PLUGIN(multifile)
 372 AG_GST_CHECK_PLUGIN(multipart)
 373 AG_GST_CHECK_PLUGIN(replaygain)
 374 AG_GST_CHECK_PLUGIN(rtp)
 375 AG_GST_CHECK_PLUGIN(rtpmanager)
 376 AG_GST_CHECK_PLUGIN(rtsp)
 377 AG_GST_CHECK_PLUGIN(shapewipe)
 378 AG_GST_CHECK_PLUGIN(smpte)
 379 AG_GST_CHECK_PLUGIN(spectrum)
 380 AG_GST_CHECK_PLUGIN(udp)
 381 AG_GST_CHECK_PLUGIN(videobox)
 382 AG_GST_CHECK_PLUGIN(videocrop)
 383 AG_GST_CHECK_PLUGIN(videofilter)
 384 AG_GST_CHECK_PLUGIN(videomixer)
 385 AG_GST_CHECK_PLUGIN(wavenc)
 386 AG_GST_CHECK_PLUGIN(wavparse)
 387 AG_GST_CHECK_PLUGIN(y4m)
 388
 389 dnl disable experimental plug-ins
 390 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 391   AG_GST_DISABLE_PLUGIN(monoscope)
 392 fi
 393
 394 dnl *** sys plug-ins ***
 395
 396 echo
 397 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 398 echo
 399
 400 dnl DirectSound
 401 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 402 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 403   HAVE_DIRECTSOUND="no"
 404   save_CFLAGS="$CFLAGS"
 405   save_LDFLAGS="$LDFLAGS"
 406   save_LIBS="$LIBS"
 407   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 408   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 409   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 410   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 411   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 412 #include <windows.h>
 413 #include <dxerr9.h>
 414 #include <dsound.h>
 415 ]], [[
 416   DXGetErrorString9 (0);
 417   DirectSoundCreate(NULL, NULL, NULL);
 418   CLSIDFromString(NULL, NULL);
 419 ]])
 420 ],
 421     [HAVE_DIRECTSOUND="yes"],
 422     [HAVE_DIRECTSOUND="no"])
 423   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 424   CFLAGS=$save_CFLAGS
 425   LDFLAGS=$save_LDFLAGS
 426   LIBS=$save_LIBS
 427
 428   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 429     dnl this is much more than we want
 430     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 431     AC_SUBST(DIRECTSOUND_CFLAGS)
 432     AC_SUBST(DIRECTSOUND_LDFLAGS)
 433     AC_SUBST(DIRECTSOUND_LIBS)
 434   fi
 435   AC_SUBST(HAVE_DIRECTSOUND)
 436 ])
 437
 438 dnl *** Win32 WaveOut ***
 439 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 440 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 441   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 442 ])
 443
 444 dnl *** OSS audio *** (Linux, *BSD)
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 446 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 447  HAVE_OSS="yes"
 448 dnl Linux and newer BSD versions :
 449  AC_CHECK_HEADER(sys/soundcard.h, [
 450    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 451    ] , [
 452 dnl Some old BSD versions and also newer OpenBSD versions :
 453    AC_CHECK_HEADER(soundcard.h, [
 454      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 455      ], [
 456   dnl Some old BSD versions :
 457      AC_CHECK_HEADER(machine/soundcard.h, [
 458        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 459          [Define if OSS includes are in /machine/])
 460        ], [
 461        HAVE_OSS="no"
 462      ])
 463    ])
 464  ])
 465 ])
 466
 467 dnl *** oss4 ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 469 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 470   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 471   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 472       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 473       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 474 ])
 475
 476 dnl *** Sun Audio ***
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 478 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 479   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 480 ])
 481
 482 dnl *** OSX Audio ***
 483 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 484 HAVE_IOS="no"
 485 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 486   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 487     [HAVE_OSX_AUDIO="yes"],
 488     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 489     [
 490       HAVE_OSX_AUDIO="yes"
 491       HAVE_IOS="yes"
 492     ], [
 493       HAVE_OSX_AUDIO="no"
 494       HAVE_IOS="no"
 495     ])]
 496   )
 497 ])
 498 if test "x$HAVE_IOS" = "xyes"; then
 499   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 500 fi
 501 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 502
 503 dnl *** OS X video ***
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 505 HAVE_OSX_VIDEO="no"
 506 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 507   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 508
 509   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 510   dnl also require Snow Leopard or newer
 511
 512   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 513         #include <AvailabilityMacros.h>
 514         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 515         #error Too old OSX version
 516         #endif
 517       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 518 ])
 519
 520 dnl *** Video 4 Linux 2 ***
 521 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 523 HAVE_GST_V4L2=no
 524 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 525   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 526   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 527   [
 528     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 529     [
 530       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 531     ])
 532   ])
 533   if test "x$HAVE_VIDEODEV" = "xno"; then
 534      AC_MSG_WARN([video4linux2 was not found])
 535   fi
 536 ])
 537
 538 # Optional gudev for device probing
 539 AC_ARG_WITH([gudev],
 540   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 541   [],
 542   [with_gudev=check])
 543 if test x$HAVE_GST_V4L2 = xyes; then
 544   if test x$with_gudev != xno; then
 545     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 546       [ AC_DEFINE(HAVE_GUDEV, 1,
 547           [Whether gudev is available for device detection])
 548       ],
 549       [true])
 550   fi
 551 fi
 552
 553 AC_SUBST(GUDEV_CFLAGS)
 554 AC_SUBST(GUDEV_LIBS)
 555
 556 # Make libv4l2 non-automagic
 557 AC_ARG_WITH([libv4l2],
 558   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 559   [],
 560   [with_libv4l2=check])
 561 if test x$HAVE_GST_V4L2 = xyes; then
 562   if test x$with_libv4l2 != xno; then
 563       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 564           [ have_libv4l2=yes
 565             AC_DEFINE(HAVE_LIBV4L2, 1,
 566                 [Whether libv4l2 is available for video buffer conversion])
 567           ], [
 568           have_libv4l2=no
 569           ])
 570   else
 571     have_libv4l2=no
 572   fi
 573 fi
 574
 575 dnl Allow enabling v4l2 device probing
 576 AS_CASE([$host],
 577     [*-*linux*],
 578       [AS_CASE([$host_cpu],
 579         [arm*], [
 580           enable_v4l2_probe="yes"],
 581         [aarch64*], [
 582           enable_v4l2_probe="yes"])])
 583 AC_ARG_ENABLE(
 584   v4l2-probe,
 585   AC_HELP_STRING(
 586     [--enable-v4l2-probe],
 587     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 588 if test "x$enable_v4l2_probe" = "xyes"; then
 589   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 590     [Define if Video4Linux probe shall be run at plugin load])
 591 fi
 592
 593 dnl Check for X11
 594 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 595 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 596                   [ximagesrc], [
 597   PKG_CHECK_MODULES([X], [x11], [
 598     HAVE_X="yes"
 599     dnl check for Xfixes
 600     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 601       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 602     ], [ HAVE_XFIXES="no" ])
 603
 604     dnl check for Xdamage
 605     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 606       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 607     ], [ HAVE_XDAMAGE="no" ])
 608
 609     dnl check for X Shm
 610     PKG_CHECK_MODULES([XEXT], [ xext ], [
 611       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 612         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 613         XSHM_LIBS="$XEXT_LIBS"
 614         XSHM_CFLAGS="$XEXT_CFLAGS"
 615       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 616     ])
 617     AC_SUBST(XSHM_LIBS)
 618     AC_SUBST(XSHM_CFLAGS)
 619   ], [ HAVE_X="no" ])
 620 ])
 621
 622 dnl *** ext plug-ins ***
 623 dnl keep this list sorted alphabetically !
 624
 625 if test "x$BUILD_EXTERNAL" = "xyes"; then
 626
 627 echo
 628 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 629 echo
 630
 631 dnl *** aalib ***
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 633 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 634   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 635 ])
 636
 637 dnl *** cairo ***
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 639 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 640   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 641 ])
 642
 643 dnl *** FLAC ***
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 645 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 646   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 647 ])
 648
 649 dnl *** GDK pixbuf ***
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 651 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 652   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 653 ])
 654
 655 dnl *** Jack ***
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 657 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 658   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 659   AC_SUBST(JACK_CFLAGS)
 660   AC_SUBST(JACK_LIBS)
 661
 662   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 663   if test x$HAVE_JACK_0_120_1 = xyes; then
 664     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 665   fi
 666   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 667   if test x$HAVE_JACK_1_9_7 = xyes; then
 668     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 669   fi
 670
 671 ])
 672
 673 dnl *** jpeg ***
 674 dnl FIXME: we could use header checks here as well IMO
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 676 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 677   AC_ARG_WITH(jpeg-mmx,
 678     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 679   OLD_LIBS="$LIBS"
 680   if test x$with_jpeg_mmx != x; then
 681     LIBS="$LIBS -L$with_jpeg_mmx"
 682   fi
 683   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 684   JPEG_LIBS="$LIBS -ljpeg-mmx"
 685   LIBS="$OLD_LIBS"
 686   if test x$HAVE_JPEG != xyes; then
 687     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 688     JPEG_LIBS="-ljpeg"
 689   fi
 690   AC_SUBST(JPEG_LIBS)
 691 ])
 692
 693 dnl *** libcaca ***
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 695 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 696   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 697 ])
 698
 699 dnl *** libdv ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 701 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 702   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 703 ])
 704
 705 dnl *** libpng ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 707 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 708   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 709 ])
 710
 711 dnl *** pulseaudio ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 713 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 714
 715   dnl used in ext/pulse/pulseutil.c
 716   AC_CHECK_HEADERS([process.h])
 717
 718   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 719 ])
 720
 721 dnl *** dv1394 ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 723 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 724   dnl first test for libraw1394 >= 2.0.0
 725   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 726   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 727   dnl now see how far we got
 728   if test x$HAVE_RAW1394 = xyes && \
 729      test x$HAVE_LIBIEC61883 = xyes; then
 730        AG_GST_CHECK_LIBHEADER(AVC1394,
 731         avc1394, avc1394_send_command, $RAW1394_LIBS,
 732         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 733        AG_GST_CHECK_LIBHEADER(ROM1394,
 734         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 735         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 736        if test x$HAVE_AVC1394 = xyes && \
 737           test x$HAVE_AVC1394 = xyes && \
 738           test x$HAVE_ROM1394 = xyes; then
 739           HAVE_DV1394=yes
 740           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 741           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 742           AC_SUBST(DV1394_CFLAGS)
 743           AC_SUBST(DV1394_LIBS)
 744         fi
 745   else
 746        if test x$HAVE_RAW1394 = xno; then
 747           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 748           AG_GST_CHECK_LIBHEADER(AVC1394,
 749            avc1394, avc1394_send_command, $RAW1394_LIBS,
 750            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 751           AG_GST_CHECK_LIBHEADER(ROM1394,
 752            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 753            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 754           if test x$HAVE_RAW1394 = xyes && \
 755              test x$HAVE_AVC1394 = xyes && \
 756              test x$HAVE_ROM1394 = xyes; then
 757              HAVE_DV1394=yes
 758              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 759              DV1394_CFLAGS="$RAW1394_CFLAGS"
 760              if test x$HAVE_LIBIEC61883 = xyes; then
 761                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 762                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 763              fi
 764              AC_SUBST(DV1394_CFLAGS)
 765              AC_SUBST(DV1394_LIBS)
 766            fi
 767          fi
 768   fi
 769 ])
 770 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 771
 772 dnl *** shout2 ***
 773 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 774 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 775   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 776 ])
 777
 778 dnl *** soup ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 780 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 781   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 782   AC_SUBST(SOUP_CFLAGS)
 783   AC_SUBST(SOUP_LIBS)
 784 ])
 785
 786 dnl *** speex ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 788 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 789   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 790 ])
 791
 792 dnl *** taglib ***
 793 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 794 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 795   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 796   if test "x$HAVE_CXX" != "xyes"; then
 797     USE_TAGLIB=false
 798     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 799   else
 800     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 801     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 802         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 803       ], [
 804         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 805     ])
 806     AC_SUBST(TAGLIB_CXXFLAGS)
 807   fi
 808 ])
 809
 810 dnl *** vpx ***
 811 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 812 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 813   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 814   HAVE_VP8=no
 815   HAVE_VP9=no
 816
 817   if test $HAVE_VPX = "yes"; then
 818     OLD_LIBS="$LIBS"
 819     OLD_CFLAGS="$CFLAGS"
 820     CFLAGS="$CFLAGS $VPX_CFLAGS"
 821     LIBS="$LIBS $VPX_LIBS"
 822     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 823       HAVE_VP8=yes
 824       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 825     ])
 826     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 827       HAVE_VP8=yes
 828       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 829     ])
 830
 831     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 832       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 833         HAVE_VP9=yes
 834         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 835       ])
 836       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 837         HAVE_VP9=yes
 838         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 839       ])
 840     ], [true])
 841
 842     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 843       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 844     ], [true])
 845
 846     LIBS="$OLD_LIBS"
 847     CFLAGS="$OLD_CFLAGS"
 848   fi
 849   AC_SUBST(VPX_LIBS)
 850   AC_SUBST(VPX_CFLAGS)
 851 ])
 852
 853 dnl *** wavpack ***
 854 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 855 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 856   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 857 ])
 858
 859 dnl *** qtdemux & matroska prefer to have zlib ***
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 861 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 862   AG_GST_CHECK_LIBHEADER(ZLIB,
 863     z, uncompress,, zlib.h, [
 864     HAVE_ZLIB="yes"
 865     ZLIB_LIBS="-lz"
 866     AC_SUBST(ZLIB_LIBS)
 867   ])
 868 ])
 869
 870 dnl *** matroska prefers to have bz2 ***
 871 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 872 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 873   save_LIBS=$LIBS
 874   LIBS="$LIBS -lbz2"
 875   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 876   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 877   AC_MSG_RESULT($HAVE_BZ2)
 878   LIBS=$save_LIBS
 879   if test "x$HAVE_BZ2" = "xyes"; then
 880     BZ2_LIBS="-lbz2"
 881   fi
 882   AC_SUBST(BZ2_LIBS)
 883 ])
 884
 885 else
 886
 887 dnl not building plugins with external dependencies,
 888 dnl but we still need to set the conditionals
 889 AM_CONDITIONAL(USE_AALIB, false)
 890 AM_CONDITIONAL(USE_BZ2, false)
 891 AM_CONDITIONAL(USE_CAIRO, false)
 892 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 893 AM_CONDITIONAL(USE_DV1394, false)
 894 AM_CONDITIONAL(USE_FLAC, false)
 895 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 896 AM_CONDITIONAL(USE_JACK, false)
 897 AM_CONDITIONAL(USE_JPEG, false)
 898 AM_CONDITIONAL(USE_LIBCACA, false)
 899 AM_CONDITIONAL(USE_LIBDV, false)
 900 AM_CONDITIONAL(USE_LIBIEC61883, false)
 901 AM_CONDITIONAL(USE_LIBPNG, false)
 902 AM_CONDITIONAL(USE_OSS, false)
 903 AM_CONDITIONAL(USE_OSS4, false)
 904 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 905 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 906 AM_CONDITIONAL(USE_PULSE, false)
 907 AM_CONDITIONAL(USE_SHOUT2, false)
 908 AM_CONDITIONAL(USE_SOUP, false)
 909 AM_CONDITIONAL(USE_SPEEX, false)
 910 AM_CONDITIONAL(USE_SUNAUDIO, false)
 911 AM_CONDITIONAL(USE_TAGLIB, false)
 912 AM_CONDITIONAL(USE_VPX, false)
 913 AM_CONDITIONAL(USE_WAVEFORM, false)
 914 AM_CONDITIONAL(USE_WAVPACK, false)
 915 AM_CONDITIONAL(USE_X, false)
 916 AM_CONDITIONAL(USE_ZLIB, false)
 917
 918 fi dnl of EXT plugins
 919
 920 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 921
 922 dnl Overview:
 923 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 924 dnl GST_*:              flags shared by all built objects
 925 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 926 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 927 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 928 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 929
 930 dnl GST_OPTION_CFLAGS
 931 if test "x$USE_DEBUG" = xyes; then
 932    PROFILE_CFLAGS="-g"
 933 fi
 934 AC_SUBST(PROFILE_CFLAGS)
 935
 936 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 937   dnl Define _only_ for git (not pre-releases or releases)
 938   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 939 else
 940   DEPRECATED_CFLAGS=""
 941 fi
 942 AC_SUBST(DEPRECATED_CFLAGS)
 943
 944 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 945 dnl at make time with e.g. make ERROR_CFLAGS=""
 946 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 947 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 948 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 949 AC_SUBST(GST_OPTION_CFLAGS)
 950 AC_SUBST(GST_OPTION_CXXFLAGS)
 951 AC_SUBST(GST_OPTION_OBJCFLAGS)
 952
 953 dnl our libraries need to be versioned correctly
 954 AC_SUBST(GST_LT_LDFLAGS)
 955
 956 dnl FIXME: do we want to rename to GST_ALL_* ?
 957 dnl prefer internal headers to already installed ones
 958 dnl also add builddir include for enumtypes and marshal
 959 dnl add ERROR_CFLAGS, but overridable
 960 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 961 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 962 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 963 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 964 AC_SUBST(GST_CFLAGS)
 965 AC_SUBST(GST_CXXFLAGS)
 966 AC_SUBST(GST_OBJCFLAGS)
 967 AC_SUBST(GST_LIBS)
 968
 969 dnl LDFLAGS really should only contain flags, not libs - they get added before
 970 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 971 GST_ALL_LDFLAGS="-no-undefined"
 972 if test "x${enable_Bsymbolic}" = "xyes"; then
 973   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 974 fi
 975 AC_SUBST(GST_ALL_LDFLAGS)
 976
 977 dnl this really should only contain flags, not libs - they get added before
 978 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 979 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 980 AC_SUBST(GST_PLUGIN_LDFLAGS)
 981
 982 dnl *** output files ***
 983
 984 $MKDIR_P tests/check/orc
 985
 986 dnl keep this alphabetic per directory, please
 987 AC_CONFIG_FILES(
 988 Makefile
 989 gst/Makefile
 990 gst/alpha/Makefile
 991 gst/apetag/Makefile
 992 gst/audiofx/Makefile
 993 gst/audioparsers/Makefile
 994 gst/auparse/Makefile
 995 gst/autodetect/Makefile
 996 gst/avi/Makefile
 997 gst/cutter/Makefile
 998 gst/deinterlace/Makefile
 999 gst/dtmf/Makefile
1000 gst/debugutils/Makefile
1001 gst/effectv/Makefile
1002 gst/equalizer/Makefile
1003 gst/flv/Makefile
1004 gst/goom/Makefile
1005 gst/goom2k1/Makefile
1006 gst/id3demux/Makefile
1007 gst/icydemux/Makefile
1008 gst/imagefreeze/Makefile
1009 gst/interleave/Makefile
1010 gst/isomp4/Makefile
1011 gst/law/Makefile
1012 gst/level/Makefile
1013 gst/matroska/Makefile
1014 gst/monoscope/Makefile
1015 gst/multifile/Makefile
1016 gst/multipart/Makefile
1017 gst/replaygain/Makefile
1018 gst/rtp/Makefile
1019 gst/rtpmanager/Makefile
1020 gst/rtsp/Makefile
1021 gst/shapewipe/Makefile
1022 gst/smpte/Makefile
1023 gst/spectrum/Makefile
1024 gst/udp/Makefile
1025 gst/videobox/Makefile
1026 gst/videocrop/Makefile
1027 gst/videofilter/Makefile
1028 gst/videomixer/Makefile
1029 gst/wavenc/Makefile
1030 gst/wavparse/Makefile
1031 gst/flx/Makefile
1032 gst/y4m/Makefile
1033 ext/Makefile
1034 ext/aalib/Makefile
1035 ext/cairo/Makefile
1036 ext/dv/Makefile
1037 ext/flac/Makefile
1038 ext/gdk_pixbuf/Makefile
1039 ext/jack/Makefile
1040 ext/jpeg/Makefile
1041 ext/libcaca/Makefile
1042 ext/libpng/Makefile
1043 ext/pulse/Makefile
1044 ext/raw1394/Makefile
1045 ext/shout2/Makefile
1046 ext/soup/Makefile
1047 ext/speex/Makefile
1048 ext/taglib/Makefile
1049 ext/vpx/Makefile
1050 ext/wavpack/Makefile
1051 sys/Makefile
1052 sys/directsound/Makefile
1053 sys/oss/Makefile
1054 sys/oss4/Makefile
1055 sys/osxaudio/Makefile
1056 sys/osxvideo/Makefile
1057 sys/sunaudio/Makefile
1058 sys/v4l2/Makefile
1059 sys/waveform/Makefile
1060 sys/ximage/Makefile
1061 po/Makefile.in
1062 tests/Makefile
1063 tests/check/Makefile
1064 tests/examples/Makefile
1065 tests/examples/audiofx/Makefile
1066 tests/examples/cairo/Makefile
1067 tests/examples/equalizer/Makefile
1068 tests/examples/jack/Makefile
1069 tests/examples/level/Makefile
1070 tests/examples/pulse/Makefile
1071 tests/examples/rtp/Makefile
1072 tests/examples/shapewipe/Makefile
1073 tests/examples/spectrum/Makefile
1074 tests/examples/v4l2/Makefile
1075 tests/files/Makefile
1076 tests/icles/Makefile
1077 common/Makefile
1078 common/m4/Makefile
1079 m4/Makefile
1080 docs/Makefile
1081 docs/plugins/Makefile
1082 docs/version.entities
1083 pkgconfig/Makefile
1084 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1085 gst-plugins-good.spec
1086 )
1087
1088 dnl Create the config.h file for Visual Studio builds
1089 dnl Beware of spaces and /'s in some of the shell variable contents.
1090 sed \
1091     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1092     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1093     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1094     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1095     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1096     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1097     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1098     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1099     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1100     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1101     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1102     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1103     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1104     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1105     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1106     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1107     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1108     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1109     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1110     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1111     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1112     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1113     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1114     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1115     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1116     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1117     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1118     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1119     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1120     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1121     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1122     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1123     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1124     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1125     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1126     config.h.in >win32/common/config.h-new
1127
1128 AC_OUTPUT
1129
1130 AG_GST_OUTPUT_PLUGINS
1131 ORC_OUTPUT
1132