configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.90.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 dnl CURRENT, REVISION, AGE
  48 dnl - library source changed -> increment REVISION
  49 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  50 dnl - interfaces added -> increment AGE
  51 dnl - interfaces removed -> AGE = 0
  52 dnl sets GST_LT_LDFLAGS
  53 AS_LIBTOOL(GST, 0, 0, 0)
  54
  55 dnl *** required versions of GStreamer stuff ***
  56 GST_REQ=0.11.90
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_PKG_CONFIG_PATH
  88
  89 dnl let distro override plugin install helper path
  90 AC_ARG_WITH(install-plugins-helper,
  91   AC_HELP_STRING([--with-install-plugins-helper],
  92     [specify path of helper script to call to install plugins]),
  93   [
  94     case "${withval}" in
  95       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  96       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  97       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  98     esac
  99   ],
 100   [
 101     dnl Default value
 102     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 103   ]
 104 )
 105 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 106 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 107     [plugin install helper script])
 108 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 109
 110 AG_GST_ARG_WITH_PLUGINS
 111
 112 AG_GST_ARG_ENABLE_EXTERNAL
 113
 114 AG_GST_ARG_ENABLE_EXPERIMENTAL
 115
 116 dnl *** checks for platform ***
 117 AG_GST_PLATFORM
 118
 119 dnl * hardware/architecture *
 120
 121 dnl common/m4/gst-arch.m4
 122 dnl check CPU type
 123 AG_GST_ARCH
 124
 125 dnl check for large file support
 126 dnl affected plugins must include config.h
 127 AC_SYS_LARGEFILE
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133 AC_PROG_CC_STDC
 134
 135 dnl check if the compiler supports '-c' and '-o' options
 136 AM_PROG_CC_C_O
 137
 138 dnl determine if c++ is available on this system
 139 AC_PROG_CXX
 140 dnl CXX may be set to some default even if no c++ compiler is available
 141 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 142 AC_LANG_PUSH([C++])
 143 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 144 AC_LANG_POP([C++])
 145 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 146 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 147
 148 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 149 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 150
 151 dnl check for gobject-introspection
 152 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 153
 154 dnl check for documentation tools
 155 GTK_DOC_CHECK([1.3])
 156 AS_PATH_PYTHON([2.1])
 157 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 158
 159 dnl *** checks for libraries ***
 160
 161 dnl libm, for sin() etc.
 162 LT_LIB_M
 163 AC_SUBST(LIBM)
 164
 165 dnl *** checks for header files ***
 166
 167 dnl check if we have ANSI C header files
 168 AC_HEADER_STDC
 169
 170 ac_cppflags_save="$CPPFLAGS"
 171 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 172 AC_COMPILE_IFELSE([
 173   AC_LANG_PROGRAM([[
 174 #include <libxml/HTMLparser.h>
 175 ]],[[
 176 #ifndef LIBXML_HTML_ENABLED
 177 #error libxml2 has no HTML support
 178 #endif /* LIBXML_HTML_ENABLED */
 179 ]])], [
 180   HAVE_LIBXML_HTML="yes"
 181 ], [
 182   HAVE_LIBXML_HTML="no"
 183 ])
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/pbutils and associated unit test
 193 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 194
 195 dnl also, Windows does not have long long
 196 AX_CREATE_STDINT_H
 197
 198 dnl *** checks for functions ***
 199 AC_CHECK_FUNCS([localtime_r gmtime_r])
 200
 201 dnl *** checks for math functions ***
 202 LIBS_SAVE=$LIBS
 203 LIBS="$LIBS $LIBM"
 204 AC_CHECK_FUNCS(log2)
 205 LIBS=$LIBS_SAVE
 206
 207 dnl *** checks for types/defines ***
 208
 209 dnl *** checks for structures ***
 210
 211 dnl *** checks for compiler characteristics ***
 212
 213 dnl *** checks for library functions ***
 214
 215 dnl check for fseeko()
 216 AC_FUNC_FSEEKO
 217
 218 dnl Check for fast float to int casting as defined in C99
 219 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 220 save_libs=$LIBS
 221 LIBS="$LIBS $LIBM"
 222 AC_C99_FUNC_LRINT
 223 AC_C99_FUNC_LRINTF
 224 LIBS=$save_libs
 225
 226 dnl Check for a way to display the function name in debug output
 227 AG_GST_CHECK_FUNCTION
 228
 229 dnl *** checks for dependency libraries ***
 230
 231 dnl GLib
 232 GLIB_REQ=2.31.14
 233 AG_GST_GLIB_CHECK([$GLIB_REQ])
 234
 235 ORC_CHECK([0.4.11])
 236
 237 dnl checks for gstreamer
 238 dnl uninstalled is selected preferentially -- see pkg-config(1)
 239 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 240 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 241 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 242 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 243 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 244
 245 dnl Check for documentation xrefs
 246 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 247 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 248 AC_SUBST(GLIB_PREFIX)
 249 AC_SUBST(GST_PREFIX)
 250
 251 dnl GTK is optional and only used in examples
 252 HAVE_GTK=no
 253 HAVE_GTK_X11=no
 254 GTK_REQ=3.0.0
 255 if test "x$BUILD_EXAMPLES" = "xyes"; then
 256   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 257   dnl some examples need gtk+-x11
 258   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 259   AC_SUBST(GTK_LIBS)
 260   AC_SUBST(GTK_CFLAGS)
 261 fi
 262 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 263 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 264
 265 dnl QT is optional and only used in examples
 266 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 267   HAVE_QT_GV=yes
 268   HAVE_QT=yes
 269 ], [
 270   HAVE_QT_GV=no
 271   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 272 ])
 273 if test "x$HAVE_QT" = "xyes"; then
 274   AC_MSG_CHECKING([Qt moc])
 275   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 276   AC_MSG_RESULT($QT4_MOC)
 277   AC_SUBST(QT4_MOC)
 278 fi
 279 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 280 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 281
 282 dnl chck for linux headers needed by the joystick seek example
 283 AC_COMPILE_IFELSE(
 284 [
 285   AC_LANG_PROGRAM([
 286     #include <linux/input.h>
 287     #include <linux/joystick.h>
 288   ],[
 289     struct js_event js;
 290     js.type = JS_EVENT_AXIS;
 291   ])
 292 ], [
 293   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 294 ], [
 295   HAVE_LINUX_JOYSTICK_HEADERS="no"
 296 ])
 297 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 298
 299 dnl Check for -Bsymbolic-functions linker flag used to avoid
 300 dnl intra-library PLT jumps, if available.
 301 AC_ARG_ENABLE(Bsymbolic,
 302               [AC_HELP_STRING([--disable-Bsymbolic],
 303                               [avoid linking with -Bsymbolic])],,
 304               [SAVED_LDFLAGS="${LDFLAGS}"
 305                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 306                LDFLAGS=-Wl,-Bsymbolic-functions
 307                AC_TRY_LINK([], [int main (void) { return 0; }],
 308                            AC_MSG_RESULT(yes)
 309                            enable_Bsymbolic=yes,
 310                            AC_MSG_RESULT(no)
 311                            enable_Bsymbolic=no)
 312                LDFLAGS="${SAVED_LDFLAGS}"])
 313
 314
 315 dnl *** set variables based on configure arguments ***
 316
 317 dnl set license and copyright notice
 318 GST_LICENSE="LGPL"
 319 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 320 AC_SUBST(GST_LICENSE)
 321
 322 dnl set location of plugin directory
 323 AG_GST_SET_PLUGINDIR
 324
 325 dnl set release date/time
 326 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 327   ["${srcdir}/gst-plugins-base.doap"],
 328   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 329
 330 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 331 dnl make sure it doesn't complain about unused variables if debugging is disabled
 332 NO_WARNINGS=""
 333 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 334
 335 dnl define an ERROR_CFLAGS Makefile variable
 336 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 337 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 338     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 339     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 340     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 341     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 342
 343 dnl define an ERROR_CXXFLAGS Makefile variable
 344 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 345     -Wmissing-declarations -Wredundant-decls -Wundef
 346     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 347     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 348     -Wno-multichar $NO_WARNINGS])
 349
 350 dnl define correct level for debugging messages
 351 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 352
 353 dnl used in examples
 354 AG_GST_DEFAULT_ELEMENTS
 355
 356 dnl needed for encoding-target
 357 GST_DATADIR="$GST_PREFIX/share"
 358 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 359 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 360
 361 dnl behaviour of speex based audio resampler
 362 AC_MSG_CHECKING(which audio resample format to use for integer)
 363 AC_ARG_WITH([audioresample_format],
 364         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 365         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 366 AC_MSG_RESULT($ac_cv_audioresample_format)
 367 case $ac_cv_audioresample_format in
 368   int)
 369     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 370     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 371   ;;
 372   float)
 373     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 374     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 375   ;;
 376   auto)
 377     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 378     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 379 esac
 380
 381 dnl *** plug-ins to include ***
 382
 383 dnl these are all the gst plug-ins, compilable without additional libs
 384 AG_GST_CHECK_PLUGIN(adder)
 385 AG_GST_CHECK_PLUGIN(app)
 386 AG_GST_CHECK_PLUGIN(audioconvert)
 387 AG_GST_CHECK_PLUGIN(audiorate)
 388 AG_GST_CHECK_PLUGIN(audiotestsrc)
 389 AG_GST_CHECK_PLUGIN(encoding)
 390 AG_GST_CHECK_PLUGIN(videoconvert)
 391 AG_GST_CHECK_PLUGIN(gdp)
 392 AG_GST_CHECK_PLUGIN(gio)
 393 AG_GST_CHECK_PLUGIN(playback)
 394 AG_GST_CHECK_PLUGIN(audioresample)
 395 AG_GST_CHECK_PLUGIN(subparse)
 396 AG_GST_CHECK_PLUGIN(tcp)
 397 AG_GST_CHECK_PLUGIN(typefind)
 398 AG_GST_CHECK_PLUGIN(videotestsrc)
 399 AG_GST_CHECK_PLUGIN(videorate)
 400 AG_GST_CHECK_PLUGIN(videoscale)
 401 AG_GST_CHECK_PLUGIN(volume)
 402
 403 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 404 AM_CONDITIONAL(USE_XML, false)
 405 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 406
 407 dnl disable plug-ins that require libxml2's HTML support if it is not available
 408 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 409   AG_GST_DISABLE_PLUGIN(subparse)
 410 fi
 411
 412 dnl iso-codes is optional, used by libgsttag
 413 AC_ARG_ENABLE(iso-codes,
 414 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 415 [case "${enableval}" in
 416   yes) enable_iso_codes=yes ;;
 417   no)  enable_iso_codes=no ;;
 418   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 419 esac
 420 ],
 421 [enable_iso_codes=yes]) dnl Default value
 422
 423 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 424 if test "x$enable_iso_codes" = "xyes"; then
 425   AC_MSG_RESULT([yes])
 426   have_iso_codes=no
 427   AC_MSG_CHECKING([whether iso-codes are available on this system])
 428   if $PKG_CONFIG iso-codes; then
 429     AC_MSG_RESULT([yes])
 430     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 431     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 432       AC_MSG_RESULT([yes])
 433       AC_MSG_CHECKING([for iso-codes prefix])
 434       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 435       if test -d "$ISO_CODES_PREFIX"; then
 436         AC_MSG_RESULT([yes])
 437         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 438         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 439         ISO_639_DOMAIN="iso_639"
 440         AC_MSG_CHECKING([ISO_639_DOMAIN])
 441         AC_MSG_RESULT([$ISO_639_DOMAIN])
 442         have_iso_codes=yes
 443         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 444         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 445         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 446         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 447       else
 448         AC_MSG_RESULT([no])
 449       fi
 450     else
 451       AC_MSG_RESULT([no])
 452     fi
 453   else
 454     AC_MSG_RESULT([no])
 455   fi
 456   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 457 else
 458   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 459   AM_CONDITIONAL(USE_ISO_CODES, false)
 460 fi
 461
 462 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 464 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 465   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 466       HAVE_ZLIB="yes"
 467     ], [
 468       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 469         HAVE_ZLIB="yes"
 470         ZLIB_LIBS="-lz"
 471         AC_SUBST(ZLIB_LIBS)
 472       ])
 473     ])
 474 ])
 475
 476 dnl *** sys plug-ins ***
 477
 478 echo
 479 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 480 echo
 481
 482 dnl *** X11 ***
 483 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 484 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 485                   [ximagesink], [
 486   AC_PATH_XTRA
 487   ac_cflags_save="$CFLAGS"
 488   ac_cppflags_save="$CPPFLAGS"
 489   CFLAGS="$CFLAGS $X_CFLAGS"
 490   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 491
 492   dnl now try to find the HEADER
 493   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 494
 495   if test "x$HAVE_X" = "xno"
 496   then
 497     AC_MSG_NOTICE([cannot find X11 development files])
 498   else
 499     dnl this is much more than we want
 500     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 501     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 502     dnl it does not add the libs; therefore we add them here
 503     X_LIBS="$X_LIBS -lX11"
 504     AC_SUBST(X_CFLAGS)
 505     AC_SUBST(X_LIBS)
 506   fi
 507   AC_SUBST(HAVE_X)
 508   CFLAGS="$ac_cflags_save"
 509   CPPFLAGS="$ac_cppflags_save"
 510 ])
 511
 512 dnl Check for Xv extension
 513 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 514 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 515                   [xvimagesink], [
 516   AG_GST_CHECK_XV
 517 ])
 518
 519 dnl check for X Shm
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 521 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 522   if test x$HAVE_X = xyes; then
 523     AC_CHECK_LIB(Xext, XShmAttach,
 524                  HAVE_XSHM="yes", HAVE_XSHM="no",
 525                  $X_LIBS)
 526     if test "x$HAVE_XSHM" = "xyes"; then
 527       XSHM_LIBS="-lXext"
 528     else
 529       dnl On AIX, it is in XextSam instead, but we still need -lXext
 530       AC_CHECK_LIB(XextSam, XShmAttach,
 531                    HAVE_XSHM="yes", HAVE_XSHM="no",
 532                    $X_LIBS)
 533       if test "x$HAVE_XSHM" = "xyes"; then
 534         XSHM_LIBS="-lXext -lXextSam"
 535       fi
 536     fi
 537   fi
 538 ], , [
 539   AC_SUBST(HAVE_XSHM)
 540   AC_SUBST(XSHM_LIBS)
 541 ])
 542
 543 dnl *** ext plug-ins ***
 544 dnl keep this list sorted alphabetically !
 545
 546 if test "x$BUILD_EXTERNAL" = "xyes"; then
 547
 548 echo
 549 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 550 echo
 551
 552 dnl *** alsa ***
 553 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 554 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 555   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 556     HAVE_ALSA="yes"
 557     AC_SUBST(ALSA_CFLAGS)
 558     AC_SUBST(ALSA_LIBS)
 559   ], [
 560     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 561   ])
 562 ])
 563
 564 dnl *** CDParanoia ***
 565 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 566 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 567 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 568   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 569     HAVE_CDPARANOIA="yes"
 570   ], [
 571     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 572                         cdda_open, -lm,
 573                         cdda_interface.h,
 574                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 575                         HEADER_DIR="no"
 576                         FOUND_CDPARANOIA="yes")
 577     if test "x$FOUND_CDPARANOIA" != "xyes";
 578     then
 579       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 580                           cdda_open, -lm,
 581                           cdda/cdda_interface.h,
 582                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 583                           HEADER_DIR="yes"
 584                           FOUND_CDPARANOIA="yes")
 585     fi
 586     if test "x$HEADER_DIR" = "xyes";
 587     then
 588       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 589                          defined if cdda headers are in a cdda/ directory)
 590     fi
 591     if test "x$FOUND_CDPARANOIA" = "xyes";
 592     then
 593       AC_CHECK_LIB(cdda_paranoia,
 594                    paranoia_cachemodel_size,
 595                    : ,
 596                    HAVE_CDPARANOIA=no,
 597                  [-lcdda_interface])
 598     fi
 599
 600     AC_SUBST(CDPARANOIA_LIBS)
 601   ])
 602 ])
 603 dnl FIXME : add second check somehow if that is necessary
 604 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 605 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 606
 607 dnl *** ivorbis ***
 608 dnl AM_PATH_IVORBIS only takes two options
 609 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 610 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 611   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 612   if test $HAVE_IVORBIS = no
 613   then
 614     IVORBIS_LIBS=
 615     IVORBIS_CFLAGS=
 616     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 617       [IVORBIS_LIBS=-lvorbisidec
 618       HAVE_IVORBIS=yes
 619       case $host in
 620       arm-*-*)
 621         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 622       esac
 623       ],
 624       HAVE_IVORBIS=no)
 625     AC_SUBST(IVORBIS_LIBS)
 626     AC_SUBST(IVORBIS_CFLAGS)
 627   else
 628     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 629       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 630       USE_TREMOLO=no)
 631   fi
 632 ])
 633
 634 dnl *** libvisual ***
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 636 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 637   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 638   if test $HAVE_LIBVISUAL = no
 639   then
 640     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 641     if test x$HAVE_LIBVISUAL = xyes; then
 642       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 643     fi
 644   else
 645     if test x$HAVE_LIBVISUAL = xyes; then
 646       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 647     fi
 648   fi
 649   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 650   if test x$LIBVIS_PLUGINSDIR != x; then
 651     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 652         "$LIBVIS_PLUGINSDIR",
 653         [directory in which the detected libvisual's plugins are located])
 654   fi
 655 ])
 656
 657 dnl *** ogg ***
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 659 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 660   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 661   if test $HAVE_OGG = no
 662   then
 663     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 664     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 665   fi
 666 ])
 667
 668 dnl *** pango ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 670 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 671   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 672 ])
 673
 674 dnl *** theora ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 676 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 677   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 678 ])
 679
 680 dnl *** vorbis ***
 681 dnl AM_PATH_VORBIS only takes two options
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 683 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 684   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 685   if test $HAVE_VORBIS = no
 686   then
 687     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 688     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 689   fi
 690 ])
 691
 692 if test "x$HAVE_VORBIS" = "xyes"; then
 693   ac_cflags_save="$CFLAGS"
 694   AC_COMPILE_IFELSE([
 695     AC_LANG_PROGRAM([[
 696 #include <vorbis/codec.h>
 697                      ]],[[
 698 vorbis_dsp_state *v;
 699
 700 vorbis_synthesis_restart (v);
 701                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 702   if test "x$HAVE_VSR" = "xyes"; then
 703     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 704                        [defined if vorbis_synthesis_restart is present])
 705   fi
 706   CFLAGS="$ac_cflags_save"
 707 fi
 708
 709 else
 710
 711 dnl not building plugins with external dependencies,
 712 dnl but we still need to set the conditionals
 713 AM_CONDITIONAL(USE_ALSA, false)
 714 AM_CONDITIONAL(USE_CDPARANOIA, false)
 715 AM_CONDITIONAL(USE_IVORBIS, false)
 716 AM_CONDITIONAL(USE_LIBVISUAL, false)
 717 AM_CONDITIONAL(USE_OGG, false)
 718 AM_CONDITIONAL(USE_PANGO, false)
 719 AM_CONDITIONAL(USE_THEORA, false)
 720 AM_CONDITIONAL(USE_VORBIS, false)
 721
 722 fi dnl of EXT plugins
 723
 724 dnl seeking needs freetype, so check for it here
 725 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 726   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 727 ])
 728 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 729 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 730 AC_SUBST(FT2_CFLAGS)
 731 AC_SUBST(FT2_LIBS)
 732
 733 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 734
 735 dnl Overview:
 736 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 737 dnl GST_*:              flags shared by built objects to link against GStreamer
 738 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 739 dnl                          (compare to other modules) or for i18n
 740 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 741 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 742 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 743 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 744
 745 dnl GST_OPTION_CFLAGS
 746 if test "x$USE_DEBUG" = xyes; then
 747    PROFILE_CFLAGS="-g"
 748 fi
 749 AC_SUBST(PROFILE_CFLAGS)
 750
 751 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 752   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 753   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 754 else
 755   DEPRECATED_CFLAGS=""
 756 fi
 757 AC_SUBST(DEPRECATED_CFLAGS)
 758
 759 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 760 dnl at make time with e.g. make ERROR_CFLAGS=""
 761 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 762 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 763 AC_SUBST(GST_OPTION_CFLAGS)
 764 AC_SUBST(GST_OPTION_CXXFLAGS)
 765
 766 dnl our libraries need to be versioned correctly
 767 AC_SUBST(GST_LT_LDFLAGS)
 768
 769 dnl GST_PLUGINS_BASE_CFLAGS
 770 dnl prefer internal headers to already installed ones
 771 dnl also add builddir include for enumtypes and marshal
 772 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 773 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 774
 775 dnl FIXME: do we want to rename to GST_ALL_* ?
 776 dnl add GST_OPTION_CFLAGS, but overridable
 777 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 778 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 779 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 780 AC_SUBST(GST_CFLAGS)
 781 AC_SUBST(GST_CXXFLAGS)
 782 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 783 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 784 AC_SUBST(GST_LIBS)
 785
 786 dnl LDFLAGS really should only contain flags, not libs - they get added before
 787 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 788 GST_ALL_LDFLAGS="-no-undefined"
 789 if test "x${enable_Bsymbolic}" = "xyes"; then
 790   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 791 fi
 792 AC_SUBST(GST_ALL_LDFLAGS)
 793
 794 dnl GST_LIB_LDFLAGS
 795 dnl linker flags shared by all libraries
 796 dnl LDFLAGS modifier defining exported symbols from built libraries
 797 dnl (export _gst_foo but not __gst_foo)
 798 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 799 AC_SUBST(GST_LIB_LDFLAGS)
 800
 801 dnl this really should only contain flags, not libs - they get added before
 802 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 803 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 804 AC_SUBST(GST_PLUGIN_LDFLAGS)
 805
 806 dnl *** output files ***
 807
 808 AC_CONFIG_FILES(
 809 Makefile
 810 gst-plugins-base.spec
 811 gst/Makefile
 812 gst/adder/Makefile
 813 gst/app/Makefile
 814 gst/audioconvert/Makefile
 815 gst/audiorate/Makefile
 816 gst/audiotestsrc/Makefile
 817 gst/encoding/Makefile
 818 gst/videoconvert/Makefile
 819 gst/gdp/Makefile
 820 gst/gio/Makefile
 821 gst/playback/Makefile
 822 gst/audioresample/Makefile
 823 gst/subparse/Makefile
 824 gst/tcp/Makefile
 825 gst/typefind/Makefile
 826 gst/videotestsrc/Makefile
 827 gst/videorate/Makefile
 828 gst/videoscale/Makefile
 829 gst/volume/Makefile
 830 sys/Makefile
 831 sys/ximage/Makefile
 832 sys/xvimage/Makefile
 833 ext/Makefile
 834 ext/alsa/Makefile
 835 ext/cdparanoia/Makefile
 836 ext/libvisual/Makefile
 837 ext/ogg/Makefile
 838 ext/pango/Makefile
 839 ext/theora/Makefile
 840 ext/vorbis/Makefile
 841 gst-libs/Makefile
 842 gst-libs/gst/Makefile
 843 gst-libs/gst/audio/Makefile
 844 gst-libs/gst/app/Makefile
 845 gst-libs/gst/fft/Makefile
 846 gst-libs/gst/riff/Makefile
 847 gst-libs/gst/rtp/Makefile
 848 gst-libs/gst/rtsp/Makefile
 849 gst-libs/gst/sdp/Makefile
 850 gst-libs/gst/tag/Makefile
 851 gst-libs/gst/pbutils/Makefile
 852 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 853 gst-libs/gst/video/Makefile
 854 tools/Makefile
 855 pkgconfig/Makefile
 856 pkgconfig/gstreamer-audio.pc
 857 pkgconfig/gstreamer-audio-uninstalled.pc
 858 pkgconfig/gstreamer-app.pc
 859 pkgconfig/gstreamer-app-uninstalled.pc
 860 pkgconfig/gstreamer-fft.pc
 861 pkgconfig/gstreamer-fft-uninstalled.pc
 862 pkgconfig/gstreamer-pbutils.pc
 863 pkgconfig/gstreamer-pbutils-uninstalled.pc
 864 pkgconfig/gstreamer-riff.pc
 865 pkgconfig/gstreamer-riff-uninstalled.pc
 866 pkgconfig/gstreamer-rtp.pc
 867 pkgconfig/gstreamer-rtp-uninstalled.pc
 868 pkgconfig/gstreamer-rtsp.pc
 869 pkgconfig/gstreamer-rtsp-uninstalled.pc
 870 pkgconfig/gstreamer-sdp.pc
 871 pkgconfig/gstreamer-sdp-uninstalled.pc
 872 pkgconfig/gstreamer-tag.pc
 873 pkgconfig/gstreamer-tag-uninstalled.pc
 874 pkgconfig/gstreamer-video.pc
 875 pkgconfig/gstreamer-video-uninstalled.pc
 876 pkgconfig/gstreamer-plugins-base.pc
 877 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 878 tests/Makefile
 879 tests/check/Makefile
 880 tests/examples/Makefile
 881 tests/examples/app/Makefile
 882 tests/examples/audio/Makefile
 883 tests/examples/dynamic/Makefile
 884 tests/examples/encoding/Makefile
 885 tests/examples/fft/Makefile
 886 tests/examples/gio/Makefile
 887 tests/examples/overlay/Makefile
 888 tests/examples/seek/Makefile
 889 tests/examples/snapshot/Makefile
 890 tests/examples/playback/Makefile
 891 tests/examples/playrec/Makefile
 892 tests/files/Makefile
 893 tests/icles/Makefile
 894 tests/icles/playback/Makefile
 895 docs/Makefile
 896 docs/design/Makefile
 897 docs/libs/Makefile
 898 docs/plugins/Makefile
 899 docs/version.entities
 900 po/Makefile.in
 901 common/Makefile
 902 common/m4/Makefile
 903 m4/Makefile
 904 )
 905
 906 dnl Create the config.h file for Visual Studio builds
 907 dnl Beware of spaces and /'s in some of the shell variable contents.
 908 sed \
 909     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 910     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 911     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 912     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 913     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 914     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 915     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 916     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 917     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 918     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 919     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 920     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 921     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 922     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 923     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 924     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 925     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 926     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 927     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 928     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 929     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 930     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 931     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 932     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 933     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 934     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 935     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 936     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 937     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 938     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 939     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 940     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 941     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 942     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 943     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 944     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 945     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 946     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 947     config.h.in >win32/common/config.h-new
 948
 949
 950
 951 AC_OUTPUT
 952
 953 AG_GST_OUTPUT_PLUGINS
 954 ORC_OUTPUT
 955