configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.29.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 20, 0, 20)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.29
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 dnl let distro override plugin install helper path
  93 AC_ARG_WITH(install-plugins-helper,
  94   AC_HELP_STRING([--with-install-plugins-helper],
  95     [specify path of helper script to call to install plugins]),
  96   [
  97     case "${withval}" in
  98       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  99       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 100       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 101     esac
 102   ],
 103   [
 104     dnl Default value
 105     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 106   ]
 107 )
 108 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 109 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 110     [plugin install helper script])
 111 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 112
 113 AG_GST_ARG_WITH_PLUGINS
 114
 115 AG_GST_ARG_ENABLE_EXTERNAL
 116
 117 AG_GST_ARG_ENABLE_EXPERIMENTAL
 118
 119 dnl *** checks for platform ***
 120
 121 dnl * hardware/architecture *
 122
 123 dnl common/m4/gst-arch.m4
 124 dnl check CPU type
 125 AG_GST_ARCH
 126
 127 dnl check for large file support
 128 dnl affected plugins must include config.h
 129 AC_SYS_LARGEFILE
 130
 131 dnl *** checks for programs ***
 132
 133 dnl find a compiler
 134 AC_PROG_CC
 135 AC_PROG_CXX
 136
 137 dnl determine if c++ is available on this system
 138 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 139
 140 dnl determine c++ preprocessor
 141 dnl FIXME: do we need this ?
 142 AC_PROG_CXXCPP
 143
 144 dnl check if the compiler supports '-c' and '-o' options
 145 AM_PROG_CC_C_O
 146
 147 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 148 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 149
 150 dnl check for gobject-introspection
 151 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 152
 153 dnl check for documentation tools
 154 GTK_DOC_CHECK([1.3])
 155 AS_PATH_PYTHON([2.1])
 156 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 157
 158 dnl *** checks for libraries ***
 159
 160 dnl libm, for sin() etc.
 161 AC_CHECK_LIBM
 162 AC_SUBST(LIBM)
 163
 164 dnl *** checks for header files ***
 165
 166 dnl check if we have ANSI C header files
 167 AC_HEADER_STDC
 168
 169 dnl used in gst/ffmpegcolorspace/mem.c
 170 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 171 AC_CHECK_HEADERS([malloc.h])
 172
 173 ac_cppflags_save="$CPPFLAGS"
 174 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 175 AC_COMPILE_IFELSE(
 176   AC_LANG_PROGRAM([
 177 #include <libxml/HTMLparser.h>
 178                      ],[
 179 #ifndef LIBXML_HTML_ENABLED
 180 #error libxml2 has no HTML support
 181 #endif /* LIBXML_HTML_ENABLED */
 182                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 183 CPPFLAGS="$ac_cppflags_save"
 184 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 185
 186 dnl used in gst/tcp
 187 AC_CHECK_HEADERS([sys/socket.h],
 188   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 189 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 190
 191 dnl used in gst-libs/gst/rtsp
 192 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 193 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 194   WIN32_LIBS="-lws2_32"
 195   AC_SUBST(WIN32_LIBS)
 196 fi
 197
 198 dnl check for hstrerror, for gst-libs/gst/rtsp
 199 save_libs="$LIBS"
 200 AC_CHECK_FUNC(hstrerror, ,
 201     AC_CHECK_LIB(resolv, hstrerror, ,
 202         [AC_DEFINE(NO_HSTRERROR, 1,
 203              [Define if you have no native hstrerror() function.])]))
 204 HSTRERROR_LIBS=$LIBS
 205 AC_SUBST(HSTRERROR_LIBS)
 206 LIBS="$save_libs"
 207
 208 dnl used in gst-libs/gst/pbutils and associated unit test
 209 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 210
 211 dnl ffmpegcolorspace includes _stdint.h
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(cbrt)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used in gst-libs/gst/floatcast/floatcast.h
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.20])
 258
 259 dnl liboil is required
 260 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 261 if test "x$HAVE_LIBOIL" != "xyes"; then
 262   AC_ERROR([liboil-0.3.14 or later is required])
 263 fi
 264
 265 dnl checks for gstreamer
 266 dnl uninstalled is selected preferentially -- see pkg-config(1)
 267 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 269 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 270 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 271 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 272 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 273
 274 dnl Check for documentation xrefs
 275 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 276 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 277 AC_SUBST(GLIB_PREFIX)
 278 AC_SUBST(GST_PREFIX)
 279
 280 dnl GTK is optional and only used in examples
 281 PKG_CHECK_MODULES(GTK, gtk+-3.0, HAVE_GTK=yes,
 282     [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)])
 283 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 284
 285 dnl some examples need gtk+-x11
 286 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0, HAVE_GTK_X11=yes,
 287     [PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.14.0, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)])
 288 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 289
 290 dnl QT is optional and only used in examples
 291 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 292   HAVE_QT_GV=yes
 293   HAVE_QT=yes
 294 ], [
 295   HAVE_QT_GV=no
 296   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 297 ])
 298 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 299 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 300
 301 dnl chck for linux headers needed by the joystick seek example
 302 AC_COMPILE_IFELSE(
 303 [
 304   AC_LANG_PROGRAM([
 305     #include <linux/input.h>
 306     #include <linux/joystick.h>
 307   ],[
 308     struct js_event js;
 309     js.type = JS_EVENT_AXIS;
 310   ])
 311 ], [
 312   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 313 ], [
 314   HAVE_LINUX_JOYSTICK_HEADERS="no"
 315 ])
 316 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 317
 318 dnl *** set variables based on configure arguments ***
 319
 320 dnl set license and copyright notice
 321 GST_LICENSE="LGPL"
 322 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 323 AC_SUBST(GST_LICENSE)
 324
 325 dnl set location of plugin directory
 326 AG_GST_SET_PLUGINDIR
 327
 328 dnl define an ERROR_CFLAGS Makefile variable
 329 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 330 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 331     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 332     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 333     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 334     -Wno-multichar -Wnested-externs ])
 335
 336 dnl define an ERROR_CXXFLAGS Makefile variable
 337 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 338     -Wmissing-declarations -Wredundant-decls -Wundef
 339     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 340     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 341     -Wno-multichar])
 342
 343 dnl define correct level for debugging messages
 344 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 345
 346 dnl used in examples
 347 AG_GST_DEFAULT_ELEMENTS
 348
 349 dnl behaviour of speex based audio resampler
 350 AC_MSG_CHECKING(which audio resample format to use for integer)
 351 AC_ARG_WITH([audioresample_format],
 352         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 353         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 354 AC_MSG_RESULT($ac_cv_audioresample_format)
 355 case $ac_cv_audioresample_format in
 356   int)
 357     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 358     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 359   ;;
 360   float)
 361     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 362     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 363   ;;
 364   auto)
 365     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 366     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 367 esac
 368 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 369
 370 dnl *** plug-ins to include ***
 371
 372 dnl these are all the gst plug-ins, compilable without additional libs
 373 AG_GST_CHECK_PLUGIN(adder)
 374 AG_GST_CHECK_PLUGIN(app)
 375 AG_GST_CHECK_PLUGIN(audioconvert)
 376 AG_GST_CHECK_PLUGIN(audiorate)
 377 AG_GST_CHECK_PLUGIN(audiotestsrc)
 378 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 379 AG_GST_CHECK_PLUGIN(gdp)
 380 AG_GST_CHECK_PLUGIN(playback)
 381 AG_GST_CHECK_PLUGIN(audioresample)
 382 AG_GST_CHECK_PLUGIN(subparse)
 383 AG_GST_CHECK_PLUGIN(tcp)
 384 AG_GST_CHECK_PLUGIN(typefind)
 385 AG_GST_CHECK_PLUGIN(videotestsrc)
 386 AG_GST_CHECK_PLUGIN(videorate)
 387 AG_GST_CHECK_PLUGIN(videoscale)
 388 AG_GST_CHECK_PLUGIN(volume)
 389
 390 dnl check for gstreamer core features (subsystems)
 391 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 392 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 393 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 394 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 395
 396 dnl disable plug-ins that require libxml2's HTML support if it is not available
 397 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 398   AG_GST_DISABLE_PLUGIN(subparse)
 399 fi
 400
 401 dnl disable plug-ins that require sys/socket.h if it is not available
 402 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 403   AG_GST_DISABLE_PLUGIN(tcp)
 404 fi
 405
 406 dnl iso-codes is optional, used by libgsttag
 407 AC_ARG_ENABLE(iso-codes,
 408 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 409 [case "${enableval}" in
 410   yes) enable_iso_codes=yes ;;
 411   no)  enable_iso_codes=no ;;
 412   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 413 esac
 414 ],
 415 [enable_iso_codes=yes]) dnl Default value
 416
 417 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 418 if test "x$enable_iso_codes" = "xyes"; then
 419   AC_MSG_RESULT([yes])
 420   have_iso_codes=no
 421   AC_MSG_CHECKING([whether iso-codes are available on this system])
 422   if $PKG_CONFIG iso-codes; then
 423     AC_MSG_RESULT([yes])
 424     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 425     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 426       AC_MSG_RESULT([yes])
 427       AC_MSG_CHECKING([for iso-codes prefix])
 428       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 429       if test -d "$ISO_CODES_PREFIX"; then
 430         AC_MSG_RESULT([yes])
 431         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 432         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 433         ISO_639_DOMAIN="iso_639"
 434         AC_MSG_CHECKING([ISO_639_DOMAIN])
 435         AC_MSG_RESULT([$ISO_639_DOMAIN])
 436         have_iso_codes=yes
 437         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 438         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 439         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 440         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 441       else
 442         AC_MSG_RESULT([no])
 443       fi
 444     else
 445       AC_MSG_RESULT([no])
 446     fi
 447   else
 448     AC_MSG_RESULT([no])
 449   fi
 450   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 451 else
 452   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 453   AM_CONDITIONAL(USE_ISO_CODES, false)
 454 fi
 455
 456 dnl *** sys plug-ins ***
 457
 458 echo
 459 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 460 echo
 461
 462 dnl *** X11 ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 464 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 465                   [ximagesink], [
 466   AC_PATH_XTRA
 467   ac_cflags_save="$CFLAGS"
 468   ac_cppflags_save="$CPPFLAGS"
 469   CFLAGS="$CFLAGS $X_CFLAGS"
 470   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 471
 472   dnl now try to find the HEADER
 473   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 474
 475   if test "x$HAVE_X" = "xno"
 476   then
 477     AC_MSG_NOTICE([cannot find X11 development files])
 478   else
 479     dnl this is much more than we want
 480     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 481     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 482     dnl it does not add the libs; therefore we add them here
 483     X_LIBS="$X_LIBS -lX11"
 484     AC_SUBST(X_CFLAGS)
 485     AC_SUBST(X_LIBS)
 486   fi
 487   AC_SUBST(HAVE_X)
 488   CFLAGS="$ac_cflags_save"
 489   CPPFLAGS="$ac_cppflags_save"
 490 ])
 491
 492 dnl Check for Xv extension
 493 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 494 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 495                   [xvimagesink], [
 496   AG_GST_CHECK_XV
 497 ])
 498
 499 dnl check for X Shm
 500 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 501 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 502   if test x$HAVE_X = xyes; then
 503     AC_CHECK_LIB(Xext, XShmAttach,
 504                  HAVE_XSHM="yes", HAVE_XSHM="no",
 505                  $X_LIBS)
 506     if test "x$HAVE_XSHM" = "xyes"; then
 507       XSHM_LIBS="-lXext"
 508     else
 509       dnl On AIX, it is in XextSam instead, but we still need -lXext
 510       AC_CHECK_LIB(XextSam, XShmAttach,
 511                    HAVE_XSHM="yes", HAVE_XSHM="no",
 512                    $X_LIBS)
 513       if test "x$HAVE_XSHM" = "xyes"; then
 514         XSHM_LIBS="-lXext -lXextSam"
 515       fi
 516     fi
 517   fi
 518 ], , [
 519   AC_SUBST(HAVE_XSHM)
 520   AC_SUBST(XSHM_LIBS)
 521 ])
 522
 523 dnl v4l/v4l2 checks have been moved down because they require X
 524
 525 dnl *** Video 4 Linux ***
 526 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 527 dnl renamed to GST_V4L in accordance with V4L2 below
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 529 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 530   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 531 #include <sys/types.h>
 532 #define _LINUX_TIME_H
 533 #define __user
 534 #include <linux/videodev.h>
 535   ])
 536
 537   dnl we can build v4l without Xv, but then we won't have XOverlay support
 538   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 539   then
 540     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 541     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 542   fi
 543 ])
 544
 545 # Optional gudev for device probing
 546 AC_ARG_WITH([gudev],
 547   AC_HELP_STRING([--with-gudev],
 548     [device detection with gudev]),
 549   [],
 550   [with_gudev=check])
 551 if test x$HAVE_GST_V4L = xyes; then
 552   if test x$with_gudev != xno; then
 553       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 554           [ have_gudev=yes
 555             AC_DEFINE(HAVE_GUDEV, 1,
 556                [Whether gudev is available for device detection])
 557             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 558           ], [
 559           have_gudev=no
 560           ])
 561   else
 562     have_gudev=no
 563   fi
 564 fi
 565 AC_SUBST(GUDEV_CFLAGS)
 566 AC_SUBST(GUDEV_LIBS)
 567
 568 dnl *** ext plug-ins ***
 569 dnl keep this list sorted alphabetically !
 570
 571 if test "x$BUILD_EXTERNAL" = "xyes"; then
 572
 573 echo
 574 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 575 echo
 576
 577 dnl *** alsa ***
 578 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 579 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 580   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 581     HAVE_ALSA="yes"
 582     AC_SUBST(ALSA_CFLAGS)
 583     AC_SUBST(ALSA_LIBS)
 584   ], [
 585     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 586   ])
 587 ])
 588
 589 dnl *** CDParanoia ***
 590 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 591 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 592   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 593                       cdda_open, -lm,
 594                       cdda_interface.h,
 595                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 596                       HEADER_DIR="no"
 597                       FOUND_CDPARANOIA="yes")
 598   if test "x$FOUND_CDPARANOIA" != "xyes";
 599   then
 600     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 601                         cdda_open, -lm,
 602                         cdda/cdda_interface.h,
 603                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 604                         HEADER_DIR="yes"
 605                         FOUND_CDPARANOIA="yes")
 606   fi
 607   if test "x$HEADER_DIR" = "xyes";
 608   then
 609     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 610                        defined if cdda headers are in a cdda/ directory)
 611   fi
 612   if test "x$FOUND_CDPARANOIA" = "xyes";
 613   then
 614     AC_CHECK_LIB(cdda_paranoia,
 615                  paranoia_cachemodel_size,
 616                  : ,
 617                  HAVE_CDPARANOIA=no,
 618                  [-lcdda_interface])
 619   fi
 620
 621   AC_SUBST(CDPARANOIA_LIBS)
 622 ])
 623 dnl FIXME : add second check somehow if that is necessary
 624 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 625 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 626
 627 dnl *** GNOME VFS ***
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 629 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 630   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 631       HAVE_GNOME_VFS="yes"
 632       AC_SUBST(GNOME_VFS_CFLAGS)
 633       AC_SUBST(GNOME_VFS_LIBS)
 634       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 635       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 636              [The GnomeVFS modules directory.])
 637     ],[
 638       HAVE_GNOME_VFS="no"
 639     ]
 640     )
 641 ])
 642
 643 dnl *** ivorbis ***
 644 dnl AM_PATH_IVORBIS only takes two options
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 646 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 647   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 648   if test $HAVE_IVORBIS = no
 649   then
 650     IVORBIS_LIBS=
 651     IVORBIS_CFLAGS=
 652     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 653       [IVORBIS_LIBS=-lvorbisidec
 654       HAVE_IVORBIS=yes
 655       case $host in
 656       arm-*-*)
 657         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 658       esac
 659       ],
 660       HAVE_IVORBIS=no)
 661     AC_SUBST(IVORBIS_LIBS)
 662     AC_SUBST(IVORBIS_CFLAGS)
 663   fi
 664 ])
 665
 666 dnl *** libgio ***
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 668 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 669   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 670     HAVE_GIO="yes"
 671     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 672     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 673            [The GIO modules directory.])
 674     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 675     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 676            [The GIO library directory.])
 677   ], [
 678     HAVE_GIO="no"
 679     AC_MSG_RESULT(no)
 680   ])
 681   AC_SUBST(GIO_CFLAGS)
 682   AC_SUBST(GIO_LIBS)
 683   AC_SUBST(GIO_LDFLAGS)
 684 ])
 685
 686 dnl *** libvisual ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 688 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 689   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 690   if test $HAVE_LIBVISUAL = no
 691   then
 692     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 693     if test x$HAVE_LIBVISUAL = xyes; then
 694       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 695     fi
 696   else
 697     if test x$HAVE_LIBVISUAL = xyes; then
 698       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 699     fi
 700   fi
 701   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 702   if test x$LIBVIS_PLUGINSDIR != x; then
 703     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 704         "$LIBVIS_PLUGINSDIR",
 705         [directory in which the detected libvisual's plugins are located])
 706   fi
 707 ])
 708
 709 dnl *** ogg ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 711 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 712   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 713   if test $HAVE_OGG = no
 714   then
 715     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 716     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 717   fi
 718 ])
 719
 720 dnl *** pango ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 722 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 723   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 724 ])
 725
 726 dnl *** theora ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 728 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 729   dnl theora uses pkg-config version incorrectly, for pkg-config:
 730   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 731   dnl theoraenc and theoradec appeared in 1.0beta3
 732
 733   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 734 ])
 735
 736 dnl *** vorbis ***
 737 dnl AM_PATH_VORBIS only takes two options
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 739 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 740   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 741   if test $HAVE_VORBIS = no
 742   then
 743     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 744     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 745   fi
 746 ])
 747
 748 if test "x$HAVE_VORBIS" = "xyes"; then
 749   ac_cflags_save="$CFLAGS"
 750   AC_COMPILE_IFELSE(
 751     AC_LANG_PROGRAM([
 752 #include <vorbis/codec.h>
 753                      ],[
 754 vorbis_dsp_state *v;
 755
 756 vorbis_synthesis_restart (v);
 757                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 758   if test "x$HAVE_VSR" = "xyes"; then
 759     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 760                        [defined if vorbis_synthesis_restart is present])
 761   fi
 762   CFLAGS="$ac_cflags_save"
 763 fi
 764
 765 else
 766
 767 dnl not building plugins with external dependencies,
 768 dnl but we still need to set the conditionals
 769 AM_CONDITIONAL(USE_ALSA, false)
 770 AM_CONDITIONAL(USE_CDPARANOIA, false)
 771 AM_CONDITIONAL(USE_GNOME_VFS, false)
 772 AM_CONDITIONAL(USE_GIO, false)
 773 AM_CONDITIONAL(USE_LIBVISUAL, false)
 774 AM_CONDITIONAL(USE_OGG, false)
 775 AM_CONDITIONAL(USE_PANGO, false)
 776 AM_CONDITIONAL(USE_THEORA, false)
 777 AM_CONDITIONAL(USE_VORBIS, false)
 778
 779 fi dnl of EXT plugins
 780
 781 dnl seeking needs freetype, so check for it here
 782 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 783   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 784 ])
 785 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 786 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 787 AC_SUBST(FT2_CFLAGS)
 788 AC_SUBST(FT2_LIBS)
 789
 790 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 791
 792 dnl Overview:
 793 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 794 dnl GST_*:              flags shared by built objects to link against GStreamer
 795 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 796 dnl                          (compare to other modules) or for i18n
 797 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 798 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 799 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 800 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 801
 802 dnl GST_OPTION_CFLAGS
 803 if test "x$USE_DEBUG" = xyes; then
 804    PROFILE_CFLAGS="-g"
 805 fi
 806 AC_SUBST(PROFILE_CFLAGS)
 807
 808 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 809   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 810   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 811 else
 812   DEPRECATED_CFLAGS=""
 813 fi
 814 AC_SUBST(DEPRECATED_CFLAGS)
 815
 816 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 817 dnl at make time with e.g. make ERROR_CFLAGS=""
 818 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 819 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 820 AC_SUBST(GST_OPTION_CFLAGS)
 821 AC_SUBST(GST_OPTION_CXXFLAGS)
 822
 823 dnl our libraries need to be versioned correctly
 824 AC_SUBST(GST_LT_LDFLAGS)
 825
 826 dnl GST_PLUGINS_BASE_CFLAGS
 827 dnl prefer internal headers to already installed ones
 828 dnl also add builddir include for enumtypes and marshal
 829 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 830 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 831
 832 dnl FIXME: do we want to rename to GST_ALL_* ?
 833 dnl add GST_OPTION_CFLAGS, but overridable
 834 GST_CXXFLAGS="$GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 835 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 836 AC_SUBST(GST_CFLAGS)
 837 AC_SUBST(GST_CXXFLAGS)
 838 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 839 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 840 AC_SUBST(GST_LIBS)
 841
 842 dnl LDFLAGS really should only contain flags, not libs - they get added before
 843 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 844 GST_ALL_LDFLAGS="-no-undefined"
 845 AC_SUBST(GST_ALL_LDFLAGS)
 846
 847 dnl GST_LIB_LDFLAGS
 848 dnl linker flags shared by all libraries
 849 dnl LDFLAGS modifier defining exported symbols from built libraries
 850 dnl (export _gst_foo but not __gst_foo)
 851 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 852 AC_SUBST(GST_LIB_LDFLAGS)
 853
 854 dnl this really should only contain flags, not libs - they get added before
 855 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 856 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 857 AC_SUBST(GST_PLUGIN_LDFLAGS)
 858
 859 dnl *** output files ***
 860
 861 AC_CONFIG_FILES(
 862 Makefile
 863 gst-plugins-base.spec
 864 gst/Makefile
 865 gst/adder/Makefile
 866 gst/app/Makefile
 867 gst/audioconvert/Makefile
 868 gst/audiorate/Makefile
 869 gst/audiotestsrc/Makefile
 870 gst/ffmpegcolorspace/Makefile
 871 gst/gdp/Makefile
 872 gst/playback/Makefile
 873 gst/audioresample/Makefile
 874 gst/subparse/Makefile
 875 gst/tcp/Makefile
 876 gst/typefind/Makefile
 877 gst/videotestsrc/Makefile
 878 gst/videorate/Makefile
 879 gst/videoscale/Makefile
 880 gst/volume/Makefile
 881 sys/Makefile
 882 sys/ximage/Makefile
 883 sys/xvimage/Makefile
 884 sys/v4l/Makefile
 885 ext/Makefile
 886 ext/alsa/Makefile
 887 ext/cdparanoia/Makefile
 888 ext/gnomevfs/Makefile
 889 ext/gio/Makefile
 890 ext/libvisual/Makefile
 891 ext/ogg/Makefile
 892 ext/pango/Makefile
 893 ext/theora/Makefile
 894 ext/vorbis/Makefile
 895 gst-libs/Makefile
 896 gst-libs/gst/Makefile
 897 gst-libs/gst/audio/Makefile
 898 gst-libs/gst/app/Makefile
 899 gst-libs/gst/cdda/Makefile
 900 gst-libs/gst/fft/Makefile
 901 gst-libs/gst/floatcast/Makefile
 902 gst-libs/gst/interfaces/Makefile
 903 gst-libs/gst/netbuffer/Makefile
 904 gst-libs/gst/riff/Makefile
 905 gst-libs/gst/rtp/Makefile
 906 gst-libs/gst/rtsp/Makefile
 907 gst-libs/gst/sdp/Makefile
 908 gst-libs/gst/tag/Makefile
 909 gst-libs/gst/pbutils/Makefile
 910 gst-libs/gst/video/Makefile
 911 tools/Makefile
 912 pkgconfig/Makefile
 913 pkgconfig/gstreamer-audio.pc
 914 pkgconfig/gstreamer-audio-uninstalled.pc
 915 pkgconfig/gstreamer-app.pc
 916 pkgconfig/gstreamer-app-uninstalled.pc
 917 pkgconfig/gstreamer-cdda.pc
 918 pkgconfig/gstreamer-cdda-uninstalled.pc
 919 pkgconfig/gstreamer-fft.pc
 920 pkgconfig/gstreamer-fft-uninstalled.pc
 921 pkgconfig/gstreamer-floatcast.pc
 922 pkgconfig/gstreamer-floatcast-uninstalled.pc
 923 pkgconfig/gstreamer-interfaces.pc
 924 pkgconfig/gstreamer-interfaces-uninstalled.pc
 925 pkgconfig/gstreamer-netbuffer.pc
 926 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 927 pkgconfig/gstreamer-pbutils.pc
 928 pkgconfig/gstreamer-pbutils-uninstalled.pc
 929 pkgconfig/gstreamer-riff.pc
 930 pkgconfig/gstreamer-riff-uninstalled.pc
 931 pkgconfig/gstreamer-rtp.pc
 932 pkgconfig/gstreamer-rtp-uninstalled.pc
 933 pkgconfig/gstreamer-rtsp.pc
 934 pkgconfig/gstreamer-rtsp-uninstalled.pc
 935 pkgconfig/gstreamer-sdp.pc
 936 pkgconfig/gstreamer-sdp-uninstalled.pc
 937 pkgconfig/gstreamer-tag.pc
 938 pkgconfig/gstreamer-tag-uninstalled.pc
 939 pkgconfig/gstreamer-video.pc
 940 pkgconfig/gstreamer-video-uninstalled.pc
 941 pkgconfig/gstreamer-plugins-base.pc
 942 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 943 tests/Makefile
 944 tests/check/Makefile
 945 tests/examples/Makefile
 946 tests/examples/app/Makefile
 947 tests/examples/dynamic/Makefile
 948 tests/examples/overlay/Makefile
 949 tests/examples/seek/Makefile
 950 tests/examples/volume/Makefile
 951 tests/examples/snapshot/Makefile
 952 tests/examples/gio/Makefile
 953 tests/examples/v4l/Makefile
 954 tests/icles/Makefile
 955 docs/Makefile
 956 docs/design/Makefile
 957 docs/libs/Makefile
 958 docs/plugins/Makefile
 959 docs/version.entities
 960 po/Makefile.in
 961 common/Makefile
 962 common/m4/Makefile
 963 m4/Makefile
 964 )
 965
 966 dnl Create the config.h file for Visual Studio builds
 967 dnl Beware of spaces and /'s in some of the shell variable contents.
 968 sed \
 969     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 970     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 971     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 972     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 973     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 974     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 975     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 976     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 977     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 978     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 979     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 980     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 981     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 982     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 983     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 984     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 985     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 986     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 987     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 988     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 989     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 990     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 991     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 992     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 993     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 994     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 995     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 996     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 997     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 998     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 999     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1000     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1001     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1002     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1003     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1004     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1005     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1006     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1007     config.h.in >win32/common/config.h-new
1008
1009
1010
1011 AC_OUTPUT
1012
1013 AG_GST_OUTPUT_PLUGINS