build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-core")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  23
  24 SET(DALI_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27
  28 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  29 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  30 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  31 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  32 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  33 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  34 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  35 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  36
  37 OPTION(ENABLE_LOW_SPEC_MEMORY_MANAGEMENT "Enable Memory management for low spec devices" OFF)
  38
  39 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  40   SET(dali-windows-dependencies_DIR "${CMAKE_INSTALL_PREFIX}/share/dali-windows-dependencies")
  41   FIND_PACKAGE( dali-windows-dependencies REQUIRED )
  42 ENDIF()
  43
  44 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  45
  46 # Set up compiler definitions
  47
  48 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  49   SET( ENABLE_DEBUG ON )
  50 ENDIF()
  51
  52 IF( ENABLE_DEBUG )
  53   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  54   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  55   SET( ENABLE_EXPORTALL ON )
  56 ELSE()
  57   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  58 ENDIF()
  59
  60 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  61
  62   IF(NOT DEFINED STATIC)
  63     ADD_DEFINITIONS( "-DBUILDING_DALI_CORE" )
  64   ENDIF()
  65
  66 ELSEIF( UNIX )
  67
  68   IF( NOT ${ENABLE_EXPORTALL} )
  69     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
  70   ENDIF()
  71
  72   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  73
  74   IF("${ARCH}" STREQUAL "arm")
  75     ADD_DEFINITIONS("-DTARGET")
  76   ENDIF()
  77
  78 ENDIF()
  79
  80 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  81   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  82 ENDIF()
  83
  84 IF( ENABLE_LOCK_BACKTRACE )
  85   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  86 ENDIF()
  87
  88 IF( ENABLE_TRACE )
  89   ADD_DEFINITIONS("-DTRACE_ENABLED")
  90 ENDIF()
  91
  92 IF( ENABLE_LOW_SPEC_MEMORY_MANAGEMENT )
  93   ADD_DEFINITIONS("-DLOW_SPEC_MEMORY_MANAGEMENT_ENABLED")
  94 ENDIF()
  95
  96 # Deployment folder should come from spec file or command line:
  97 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  98 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  99
 100 # from root/build/tizen, get back to root
 101 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
 102
 103 # Make sure the path is absolute
 104 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 105
 106 # Set up the include dir
 107 SET( INCLUDE_DIR $ENV{includedir} )
 108 IF( NOT INCLUDE_DIR )
 109   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 110 ENDIF()
 111 IF( NOT INCLUDE_DIR )
 112   SET( INCLUDE_DIR ${PREFIX}/include )
 113 ENDIF()
 114
 115 # Set up the lib dir
 116 SET( LIB_DIR $ENV{libdir} )
 117 IF( NOT LIB_DIR )
 118   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 119 ENDIF()
 120 IF( NOT LIB_DIR )
 121   SET( LIB_DIR ${PREFIX}/lib )
 122 ENDIF()
 123
 124 # Set up the bin dir
 125 SET( BIN_DIR $ENV{bindir} )
 126 IF( NOT BIN_DIR )
 127   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 128 ENDIF()
 129 IF( NOT BIN_DIR )
 130   SET( BIN_DIR ${PREFIX}/bin )
 131 ENDIF()
 132
 133 IF( ENABLE_PKG_CONFIGURE )
 134   # Configure the pkg-config file
 135   # Requires the following variables to be setup:
 136   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 137   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 138   SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-core.pc )
 139   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 140 ENDIF()
 141
 142 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 143
 144   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 145   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 146   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 147
 148 ELSEIF( UNIX )
 149
 150   INCLUDE(CheckCXXCompilerFlag)
 151
 152   # Set up compiler flags and warnings
 153   ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 154
 155   # TODO: Clang is a lot more strict with warnings, we should address
 156   # those issues at some point.
 157   IF( NOT ${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" )
 158     ADD_COMPILE_OPTIONS( -Werror )
 159   ENDIF()
 160
 161   ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
 162   CHECK_CXX_COMPILER_FLAG(-Wno-class-memaccess HAVE_NO_CLASS_MEMACCESS)
 163   IF (HAVE_NO_CLASS_MEMACCESS)
 164     ADD_COMPILE_OPTIONS( -Wno-class-memaccess )
 165   ENDIF()
 166
 167   CHECK_CXX_COMPILER_FLAG(-Wno-cast-function-type HAVE_NO_CAST_FUNCTION_TYPE)
 168   IF (HAVE_NO_CAST_FUNCTION_TYPE)
 169     ADD_COMPILE_OPTIONS( -Wno-cast-function-type )
 170   ENDIF()
 171
 172   CHECK_CXX_COMPILER_FLAG(-Wno-unused-result HAVE_NO_UNUSED_RESULT)
 173   IF (HAVE_NO_UNUSED_RESULT)
 174     ADD_COMPILE_OPTIONS( -Wno-unused-result )
 175   ENDIF()
 176
 177   CHECK_CXX_COMPILER_FLAG(-Wno-string-plus-int HAVE_NO_STRING_PLUS_INT)
 178   IF (HAVE_NO_STRING_PLUS_INT)
 179     ADD_COMPILE_OPTIONS( -Wno-string-plus-int )
 180   ENDIF()
 181   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 182     ADD_COMPILE_OPTIONS( --coverage )
 183     SET(ENABLE_COVERAGE ON)
 184     SET(COVERAGE --coverage)
 185   ENDIF()
 186
 187   IF( NOT ${ENABLE_EXPORTALL} )
 188     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 189   ENDIF()
 190
 191 ENDIF()
 192
 193 INCLUDE_DIRECTORIES(
 194   ${ROOT_SRC_DIR}
 195   ${VCPKG_INCLUDE_DIR}
 196   ${INCLUDE_DIR}
 197 )
 198
 199 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 200 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 201
 202 SET(SOURCES "")
 203
 204 # could use INCLUDE to get the source lists a different way;
 205 # would then need to specify a build folder somehow...
 206 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 207 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 208 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 209 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 210 INCLUDE( ${ROOT_SRC_DIR}/dali/graphics-api/file.list )
 211 IF( WIN32 )
 212   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 213 ELSEIF( UNIX )
 214   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 215 ENDIF()
 216 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 217
 218 SET(LIBTYPE SHARED)
 219 IF(DEFINED STATIC)
 220   SET(LIBTYPE STATIC)
 221 ENDIF()
 222
 223 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 224
 225 # pthread required due to gcc issue
 226 IF( WIN32 )
 227     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} dali-windows-dependencies::dali-windows-dependencies )
 228 ELSEIF( UNIX )
 229   FIND_LIBRARY(PTHREAD pthread)
 230   IF(PTHREAD)
 231     SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 232   ENDIF()
 233 ENDIF()
 234
 235 TARGET_LINK_LIBRARIES( ${name}
 236   ${OPTIONAL_LIBS}
 237   ${COVERAGE}
 238 )
 239
 240 SET_TARGET_PROPERTIES( ${name}
 241   PROPERTIES
 242   VERSION ${DALI_VERSION}
 243   SOVERSION ${${name}_VERSION_MAJOR}
 244   CLEAN_DIRECT_OUPUT 1
 245 )
 246
 247 IF( INSTALL_CMAKE_MODULES )
 248   IF( ENABLE_DEBUG )
 249     SET( BIN_DIR "${BIN_DIR}/debug" )
 250     SET( LIB_DIR "${LIB_DIR}/debug" )
 251   ENDIF()
 252
 253   # Install the library files.
 254   INSTALL( TARGETS ${name}
 255     EXPORT ${name}-targets
 256     LIBRARY DESTINATION ${LIB_DIR}
 257     ARCHIVE DESTINATION ${LIB_DIR}
 258     RUNTIME DESTINATION ${BIN_DIR}
 259   )
 260
 261   # Install the cmake modules.
 262   INSTALL(
 263     EXPORT ${name}-targets
 264     NAMESPACE ${name}::
 265     FILE ${name}-targets.cmake
 266     DESTINATION share/${name}
 267   )
 268
 269   FILE( WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 270     include(CMakeFindDependencyMacro)
 271     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 272   ")
 273   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name} )
 274
 275   # Install the pdb file.
 276   IF( ENABLE_DEBUG AND WIN32 )
 277     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 278   ENDIF()
 279 ELSE()
 280   # Install the library so file and symlinks.
 281   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 282 ENDIF()
 283
 284
 285 # Install the pkg-config file
 286 IF( ENABLE_PKG_CONFIGURE )
 287   INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 288 ENDIF()
 289
 290 # macro for installing headers by replacing prefix. (TODO, investigate
 291 # if there is a CMAKE way of doing this automatically)
 292 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 293   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 294   FOREACH(HEADER ${${HEADER_LIST}})
 295     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 296     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 297     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 298   ENDFOREACH(HEADER)
 299 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 300
 301 # Install headers using lists defined by ADD_SUBDIRECTORY
 302 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 303 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 304 INSTALL_HEADERS_WITH_DIRECTORY(GRAPHICS_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 305 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 306 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 307
 308 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 309 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 310 # target names duplication with other DALi modules.
 311 IF( ENABLE_COVERAGE )
 312   FIND_PROGRAM( LCOV_BIN "lcov" )
 313   IF( LCOV_BIN )
 314
 315     # Define custom rules for coverage
 316     SET(COVERAGE_DIR .cov)
 317     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 318
 319     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 320     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 321     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 322     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 323     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 324       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 325     ENDIF()
 326
 327     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 328
 329     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 330       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 331
 332     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 333       DEPENDS cov_data )
 334
 335     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 336
 337     # Define custom rule for distclean
 338     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 339     ADD_CUSTOM_COMMAND(
 340           DEPENDS ${DALI_CORE_PREFIX}clean
 341           COMMENT "distribution clean"
 342           COMMAND find
 343           ARGS    .
 344           -not -name config.cmake -and \(
 345           -name tester.c -or
 346           -name Testing -or
 347           -name CMakeFiles -or
 348           -name doc -or
 349           -name cmake.depends -or
 350           -name cmake.check_depends -or
 351           -name CMakeCache.txt -or
 352           -name cmake.check_cache -or
 353           -name *.cmake -or
 354           -name Makefile -or
 355           -name core -or
 356           -name core.* -or
 357           -name gmon.out -or
 358           -name install_manifest.txt -or
 359           -name *.pc -or
 360           -name *.gcov -or
 361           -name *.gcno -or
 362           -name *.gcda -or
 363           -name *~ -or
 364           -name libdali*.so* \)
 365           | grep -v TC | xargs rm -rf
 366           TARGET  ${DALI_CORE_PREFIX}distclean
 367 VERBATIM
 368           )
 369
 370   ENDIF( LCOV_BIN )
 371 ENDIF()
 372
 373 IF( ENABLE_LINK_TEST )
 374   # Linker Test
 375   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 376   SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 377   SET( LINKER_TEST_SOURCES
 378     linker-test.cpp
 379     ${DALI_TEST_SUITE_DIR}/test-application.cpp
 380     ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 381     ${DALI_TEST_SUITE_DIR}/test-graphics-sync-impl.cpp
 382     ${DALI_TEST_SUITE_DIR}/test-graphics-sync-object.cpp
 383     ${DALI_TEST_SUITE_DIR}/test-graphics-buffer.cpp
 384     ${DALI_TEST_SUITE_DIR}/test-graphics-command-buffer.cpp
 385     ${DALI_TEST_SUITE_DIR}/test-graphics-controller.cpp
 386     ${DALI_TEST_SUITE_DIR}/test-graphics-framebuffer.cpp
 387     ${DALI_TEST_SUITE_DIR}/test-graphics-pipeline.cpp
 388     ${DALI_TEST_SUITE_DIR}/test-graphics-program.cpp
 389     ${DALI_TEST_SUITE_DIR}/test-graphics-reflection.cpp
 390     ${DALI_TEST_SUITE_DIR}/test-graphics-sampler.cpp
 391     ${DALI_TEST_SUITE_DIR}/test-graphics-shader.cpp
 392     ${DALI_TEST_SUITE_DIR}/test-graphics-texture.cpp
 393     ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 394     ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 395     ${DALI_TEST_SUITE_DIR}/test-render-surface.cpp
 396     ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 397     ${DALI_TEST_SUITE_DIR}/test-render-surface-if.cpp
 398   )
 399   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 400   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name})
 401   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 402 ENDIF()
 403
 404 # Configuration Messages
 405 MESSAGE( STATUS "Configuration:\n" )
 406 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 407 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 408 MESSAGE( STATUS "Bin Dir:               " ${BIN_DIR} )
 409 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 410 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 411 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 412 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 413 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 414 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 415 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 416 MESSAGE( STATUS "Use pkg configure:     " ${ENABLE_PKG_CONFIGURE} )
 417 MESSAGE( STATUS "Enable link test:      " ${ENABLE_LINK_TEST} )
 418 MESSAGE( STATUS "Memory Management:     " ${ENABLE_LOW_SPEC_MEMORY_MANAGEMENT} )
 419 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 420 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )