build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_C_STANDARD 99)
   5 SET(CMAKE_CXX_STANDARD 17)
   6 PROJECT(${name} CXX)
   7 SET(PKG_NAME ${name})
   8
   9 SET(name "dali2-adaptor")
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 OPTION(ENABLE_PKG_CONFIGURE     "Use pkgconfig" ON)
  19 OPTION(ENABLE_LINK_TEST         "Enable the link test" ON)
  20 OPTION(ENABLE_ATSPI             "Enable AT-SPI accessibility" ON)
  21 OPTION(ENABLE_APPMODEL          "Enable AppModel" OFF)
  22 OPTION(ENABLE_TRACE             "Enable Trace" OFF)
  23 OPTION(ENABLE_TRACE_STREAMLINE  "Enable Trace (Streamline)" OFF)
  24
  25 # Include additional macros
  26 INCLUDE( common.cmake )
  27
  28 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  29   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  30   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  31   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  32 ELSE()
  33   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  34 ENDIF()
  35
  36 # from root/build/tizen, get back to root.
  37 # set the variable only if it's not set yet. it allows to access build script
  38 # from top-level directory
  39 IF( NOT ROOT_SRC_DIR )
  40   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  41 ENDIF()
  42 # Make sure the path is absolute
  43 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  44
  45 # API VERSION (Not DALi release version)
  46 SET(${name}_VERSION_MAJOR 2)
  47 SET(${name}_VERSION_MINOR 0)
  48 SET(${name}_VERSION_PATCH 0)
  49 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  50
  51 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  52
  53 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  54   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  55   FIND_PACKAGE( dali2-core REQUIRED)
  56 ENDIF()
  57
  58 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  59
  60 IF( UNIX )
  61   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  62   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  63
  64   IF("${ARCH}" STREQUAL "arm")
  65     ADD_DEFINITIONS("-DTARGET")
  66   ENDIF("${ARCH}" STREQUAL "arm")
  67 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  68   IF(NOT DEFINED STATIC)
  69     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  70   ENDIF()
  71
  72   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  73   ADD_DEFINITIONS( "-D_NSIG=65" )
  74 ENDIF()
  75
  76 # Deployment folder should come from spec file or command line:
  77 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  78 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  79
  80 # Set up the include dir
  81 SET( INCLUDE_DIR $ENV{includedir} )
  82 IF( NOT INCLUDE_DIR )
  83   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  84 ENDIF()
  85 IF( NOT INCLUDE_DIR )
  86   SET( INCLUDE_DIR ${PREFIX}/include )
  87 ENDIF()
  88
  89 # Set up the lib dir
  90 SET( LIB_DIR $ENV{libdir} )
  91 IF( NOT LIB_DIR )
  92   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  93 ENDIF()
  94 IF( NOT LIB_DIR )
  95   SET( LIB_DIR ${PREFIX}/lib )
  96 ENDIF()
  97
  98 # Set up the bin dir
  99 SET( BIN_DIR $ENV{bindir} )
 100 IF( NOT BIN_DIR )
 101   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 102 ENDIF()
 103 IF( NOT BIN_DIR )
 104   SET( BIN_DIR ${PREFIX}/bin )
 105 ENDIF()
 106
 107 IF( UNIX )
 108   INCLUDE( deps-check.cmake )
 109 ENDIF()
 110
 111 IF( UBUNTU_PROFILE OR ANDROID_PROFILE OR WIN32 OR APPLE OR LIBUV_X11_PROFILE OR GLIB_X11_PROFILE)
 112   SET( ENABLE_VCONF OFF )
 113 ELSE()
 114   SET( ENABLE_VCONF ON )
 115 ENDIF()
 116
 117 IF( NOT DALI_ELDBUS_AVAILABLE OR LIBUV_X11_PROFILE OR GLIB_X11_PROFILE)
 118   SET( ENABLE_ATSPI OFF )
 119 ENDIF()
 120
 121 IF( ENABLE_VCONF )
 122   ADD_DEFINITIONS("-DVCONF_ENABLED")
 123 ENDIF()
 124
 125 IF( ENABLE_TRACE OR ENABLE_TRACE_STREAMLINE )
 126   ADD_DEFINITIONS("-DTRACE_ENABLED")
 127   SET(ENABLE_TRACE_STRING ON)
 128   IF( ENABLE_TRACE_STREAMLINE )
 129     SET(ENABLE_TRACE_STRING "ON (Streamline)")
 130   ENDIF()
 131 ELSE()
 132   SET(ENABLE_TRACE_STRING OFF)
 133 ENDIF()
 134
 135 # Set up compiler flags and warnings
 136 IF( UNIX )
 137   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 138 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 139   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 140   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 141   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 142   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 143   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 144 ENDIF()
 145
 146 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES ${DEFINITIONS} )
 147
 148
 149 # from root/build/tizen, get back to root
 150 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 151
 152 # Make sure the path is absolute
 153 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 154
 155 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 156 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 157 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 158 SET(SOURCES "")
 159
 160 # Include list of modules
 161 INCLUDE( module-list.cmake )
 162
 163 # Include profile specific setup
 164 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 165
 166 IF ( ENABLE_ATSPI )
 167   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_bridge_src_files} )
 168 ELSE()
 169   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_dummy_src_files} )
 170 ENDIF()
 171
 172 IF( ENABLE_PKG_CONFIGURE )
 173   # Configure the pkg-config file
 174   # Requires the following variables to be setup:
 175   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 176   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 177   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor.pc )
 178   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor-integration.pc )
 179   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 180   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 181 ENDIF()
 182
 183 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 184
 185 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 186 IF( WIN32 )
 187   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 188 ENDIF()
 189
 190 SET( THIRD_PARTY_MACOS_PLATFORM "" )
 191 IF( APPLE )
 192   SET( THIRD_PARTY_MACOS_PLATFORM ${ROOT_SRC_DIR}/third-party/macos-platform )
 193 ENDIF()
 194
 195 INCLUDE_DIRECTORIES(
 196   ${ROOT_SRC_DIR}
 197   ${PROFILE_INCLUDE_DIRECTORIES}
 198   ${THIRD_PARTY_WINDOWS_PLATFORM}
 199   ${THIRD_PARTY_MACOS_PLATFORM}
 200   ${VCPKG_INCLUDE_DIR}
 201   ${INCLUDE_DIR}
 202 )
 203
 204 SET(LIBTYPE SHARED)
 205 IF(DEFINED STATIC)
 206   SET(LIBTYPE STATIC)
 207 ENDIF()
 208
 209 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 210
 211 IF( UNIX )
 212   # pthread required due to gcc issue
 213   FIND_LIBRARY( PTHREAD pthread )
 214   IF( PTHREAD AND NOT ANDROID_PROFILE )
 215     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 216   ENDIF()
 217 ENDIF()
 218
 219 TARGET_LINK_LIBRARIES( ${name}
 220                        ${DALI_LDFLAGS}
 221                        ${REQUIRED_LIBS}
 222                        ${OPTIONAL_LIBS}
 223                        ${COVERAGE}
 224 )
 225
 226 SET_TARGET_PROPERTIES( ${name}
 227   PROPERTIES
 228   VERSION ${DALI_ADAPTOR_VERSION}
 229   SOVERSION ${${name}_VERSION_MAJOR}
 230   CLEAN_DIRECT_OUPUT 1
 231 )
 232
 233 IF( INSTALL_CMAKE_MODULES )
 234   IF( ENABLE_DEBUG )
 235     SET( BIN_DIR "${BIN_DIR}/debug" )
 236     SET( LIB_DIR "${LIB_DIR}/debug" )
 237   ENDIF()
 238
 239   # Install the library files.
 240   INSTALL( TARGETS ${name}
 241     EXPORT ${name}-targets
 242     LIBRARY DESTINATION ${LIB_DIR}
 243     ARCHIVE DESTINATION ${LIB_DIR}
 244     RUNTIME DESTINATION ${BIN_DIR}
 245   )
 246
 247   # Install the cmake modules.
 248   INSTALL(
 249     EXPORT ${name}-targets
 250     NAMESPACE ${name}::
 251     FILE ${name}-targets.cmake
 252     DESTINATION share/${name}
 253   )
 254
 255   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 256     include(CMakeFindDependencyMacro)
 257     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 258   ")
 259   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 260
 261   # Install the pdb file.
 262   IF( ENABLE_DEBUG AND WIN32 )
 263     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 264   ENDIF()
 265 ELSE()
 266   # Install the library so file and symlinks
 267   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 268 ENDIF()
 269
 270 IF( ENABLE_PKG_CONFIGURE )
 271   # Install the pkg-config file
 272   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 273   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 274 ENDIF()
 275
 276 # macro for installing headers by replacing prefix. (TODO, investigate
 277 # if there is a CMAKE way of doing this automatically)
 278 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 279   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 280   FOREACH(HEADER ${${HEADER_LIST}})
 281     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 282     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 283     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 284   ENDFOREACH(HEADER)
 285 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 286
 287
 288 ########################################################################################
 289 # INSTALL:
 290 # Set deployment directories
 291 # Due to complicated adaptor deployment the install section is pretty much converted from
 292 # the automake counterpart.
 293 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 294 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 295 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 296 SET( tizenadaptorapplicationapidir ${INCLUDE_DIR}/dali/internal/application-model )
 297 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 298 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 299 SET( tizencanvasrendererdevelapidir ${tizenadaptorframeworkdevelapidir}/canvas-renderer )
 300 SET( tizenwebenginedevelapidir ${tizenadaptorframeworkdevelapidir}/web-engine )
 301 SET( tizenatspiinterfacesdevelapidir ${tizenadaptordevelapidir}/atspi-interfaces )
 302 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 303 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 304 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 305 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 306
 307 # Android framework headers for Android build
 308 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 309
 310 # Install headers
 311 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 312 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 313 INSTALL( FILES ${adaptor_application_api_header_files} DESTINATION ${tizenadaptorapplicationapidir} )
 314 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 315 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 316 INSTALL( FILES ${devel_api_adaptor_framework_canvas_renderer_header_files} DESTINATION ${tizencanvasrendererdevelapidir} )
 317 INSTALL( FILES ${devel_api_adaptor_framework_web_engine_header_files} DESTINATION ${tizenwebenginedevelapidir} )
 318 INSTALL( FILES ${devel_api_atspi_interfaces_header_files} DESTINATION ${tizenatspiinterfacesdevelapidir} )
 319 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 320
 321 # Install Android framework headers for Android build
 322 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 323
 324 # Install DOXY
 325 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 326 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 327 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 328 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 329
 330 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE AND NOT MACOS_PROFILE )
 331   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 332   IF( NOT WAYLAND )
 333     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 334   ENDIF()
 335 ENDIF()
 336
 337 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 338 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 339 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 340 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 341
 342 IF( ANDROID_PROFILE )
 343   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 344   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 345 ELSEIF( UNIX )
 346   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 347   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 348 ENDIF()
 349
 350 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 351
 352 ########################################################################################
 353
 354 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 355 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 356 # target names duplication with other DALi modules.
 357 IF( ENABLE_COVERAGE )
 358   FIND_PROGRAM( LCOV_BIN "lcov" )
 359   IF( LCOV_BIN )
 360
 361     # Define custom rules for coverage
 362     SET(COVERAGE_DIR .cov)
 363     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 364
 365     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 366     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 367     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 368     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 369     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 370       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 371     ENDIF()
 372
 373     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 374
 375     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 376       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"*/third-party/*\" \"/usr/local/include/*\" -o dali.info )
 377
 378     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 379       DEPENDS cov_data )
 380
 381     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 382
 383     # Define custom rule for distclean
 384     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 385     ADD_CUSTOM_COMMAND(
 386           DEPENDS clean
 387           COMMENT "distribution clean"
 388           COMMAND find
 389           ARGS    .
 390           -not -name config.cmake -and \(
 391           -name tester.c -or
 392           -name Testing -or
 393           -name CMakeFiles -or
 394           -name doc -or
 395           -name cmake.depends -or
 396           -name cmake.check_depends -or
 397           -name CMakeCache.txt -or
 398           -name cmake.check_cache -or
 399           -name *.cmake -or
 400           -name Makefile -or
 401           -name core -or
 402           -name core.* -or
 403           -name gmon.out -or
 404           -name install_manifest.txt -or
 405           -name *.pc -or
 406           -name *.gcov -or
 407           -name *.gcno -or
 408           -name *.gcda -or
 409           -name *~ -or
 410           -name libdali*.so* \)
 411           | grep -v TC | xargs rm -rf
 412           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 413           VERBATIM
 414           )
 415
 416   ENDIF( LCOV_BIN )
 417 ENDIF()
 418
 419 IF( ENABLE_LINK_TEST )
 420   # Linker Test
 421   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 422   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 423   SET( LINKER_TEST_SOURCES
 424     linker-test.cpp
 425   )
 426   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 427   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 428   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 429   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 430   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 431 ENDIF()
 432
 433 # Configuration Messages
 434 MESSAGE( STATUS "Configuration:\n" )
 435 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 436 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 437 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 438 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 439 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 440 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 441 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 442 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 443 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 444 MESSAGE( STATUS "WebP:                             ${webp_available_ENABLED}")
 445 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 446 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORK_LOGGING}")
 447 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 448 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 449 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 450 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 451 MESSAGE( STATUS "Enable AT-SPI:                    ${ENABLE_ATSPI}" )
 452 MESSAGE( STATUS "Enable AppModel:                  ${ENABLE_APPMODEL}" )
 453 MESSAGE( STATUS "Enable Trace:                     ${ENABLE_TRACE_STRING}" )
 454 MESSAGE( STATUS "Enable VConf:                     ${ENABLE_VCONF}" )
 455 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 456 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 457 MESSAGE( STATUS "Compile flags:                    ${CMAKE_C_FLAGS}")
 458 MESSAGE( STATUS "CMAKE_SYSROOT:                    ${CMAKE_SYSROOT}")
 459 MESSAGE( STATUS "CMAKE_SYSTEM_INCLUDE_PATH:        ${CMAKE_SYSTEM_INCLUDE_PATH}")
 460 MESSAGE( STATUS "CMAKE_SYSTEM_LIBRARY_PATH:        ${CMAKE_SYSTEM_LIBRARY_PATH}")
 461 IF( enable_feedback )
 462   ADD_SUBDIRECTORY( plugins )
 463 ENDIF()
 464
 465 IF( ENABLE_APPMODEL )
 466   ADD_SUBDIRECTORY( application-model )
 467 ENDIF()
 468
 469 CLEAN_ARG_CACHE()