build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2
   3 SET(CMAKE_C_STANDARD 99)
   4 SET(CMAKE_CXX_STANDARD 17)
   5 PROJECT(dali-demo C CXX)
   6
   7 SET(dali-demo_VERSION_MAJOR 1)
   8 SET(dali-demo_VERSION_MINOR 0)
   9
  10 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  11 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  13     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  14   endif()
  15 endif()
  16
  17 # Define options to CMake
  18 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  19 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  20 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  21 OPTION(INTERNATIONALIZATION      "Internationalization demo string names" ON)
  22
  23 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  24 SET(DEMO_SHARED ${CMAKE_SOURCE_DIR}/../../shared)
  25
  26 SET(PREFIX ${CMAKE_INSTALL_PREFIX})
  27
  28 IF (APPLE)
  29   SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  30 ENDIF()
  31
  32 IF(DEFINED DALI_APP_DIR)
  33   SET(BINDIR ${DALI_APP_DIR})
  34 ELSE()
  35   SET(BINDIR ${PREFIX}/bin)
  36 ENDIF()
  37
  38 IF(DEFINED DALI_APP_RES_DIR)
  39   SET(APP_DATA_RES_DIR ${DALI_APP_RES_DIR})
  40 ELSE()
  41   SET(APP_DATA_RES_DIR ${PREFIX}/share/com.samsung.dali-demo/res)
  42 ENDIF()
  43
  44 MESSAGE( STATUS "CMAKE_BUILD_TYPE: " ${CMAKE_BUILD_TYPE} )
  45
  46 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  47   SET( ENABLE_DEBUG ON )
  48 ENDIF()
  49
  50 IF( ENABLE_DEBUG )
  51   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  52   SET( ENABLE_EXPORTALL ON )
  53 ELSE()
  54   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  55 ENDIF()
  56
  57 SET(RESOURCE_DIR ${ROOT_SRC_DIR}/resources)
  58 SET(LOCAL_IMAGES_DIR ${RESOURCE_DIR}/images)
  59 SET(LOCAL_GAME_DIR ${RESOURCE_DIR}/game)
  60 SET(LOCAL_VIDEOS_DIR ${RESOURCE_DIR}/videos)
  61 SET(LOCAL_MODELS_DIR ${RESOURCE_DIR}/models)
  62 SET(LOCAL_SCRIPTS_DIR ${RESOURCE_DIR}/scripts)
  63 SET(LOCAL_SHADERS_DIR ${RESOURCE_DIR}/shaders)
  64 IF(NOT DEFINED LOCAL_STYLE_DIR)
  65   SET(LOCAL_STYLE_DIR ${RESOURCE_DIR}/style)
  66 ENDIF()
  67
  68 IF(ANDROID)
  69   SET(LOCAL_STYLE_ANDROID_DIR ${RESOURCE_DIR}/style/android)
  70 ENDIF()
  71
  72 SET(IMAGES_DIR ${APP_DATA_RES_DIR}/images/)
  73 SET(GAME_DIR ${APP_DATA_RES_DIR}/game/)
  74 SET(VIDEOS_DIR ${APP_DATA_RES_DIR}/videos/)
  75 SET(MODELS_DIR ${APP_DATA_RES_DIR}/models/)
  76 SET(SCRIPTS_DIR ${APP_DATA_RES_DIR}/scripts/)
  77 SET(SHADERS_DIR ${APP_DATA_RES_DIR}/shaders/)
  78 SET(STYLE_DIR ${APP_DATA_RES_DIR}/style/)
  79
  80 IF(NOT DEFINED LOCALE_DIR)
  81    SET(LOCALE_DIR ${PREFIX}/share/locale)
  82 ENDIF()
  83
  84 IF(DEFINED DALI_DEMO_RES_DIR)
  85   SET(DEMO_IMAGE_DIR \\"${DALI_DEMO_RES_DIR}/images/\\")
  86   SET(DEMO_GAME_DIR \\"${DALI_DEMO_RES_DIR}/game/\\")
  87   SET(DEMO_VIDEO_DIR \\"${DALI_DEMO_RES_DIR}/videos/\\")
  88   SET(DEMO_MODEL_DIR \\"${DALI_DEMO_RES_DIR}/models/\\")
  89   SET(DEMO_SCRIPT_DIR \\"${DALI_DEMO_RES_DIR}/scripts/\\")
  90   SET(DEMO_SHADER_DIR \\"${DALI_DEMO_RES_DIR}/shaders/\\")
  91   SET(DEMO_STYLE_DIR \\"${DALI_DEMO_RES_DIR}/style/\\")
  92   SET(DEMO_THEME_PATH \\"${DALI_DEMO_RES_DIR}/style/demo-theme.json\\")
  93   SET(DEMO_LOCALE_DIR \\"${DALI_DEMO_RES_DIR}/locale/\\")
  94   SET(DEMO_STYLE_IMAGE_DIR \\"${DALI_DEMO_RES_DIR}/style/images\\")
  95 ELSE()
  96   SET(DEMO_GAME_DIR \\"${GAME_DIR}\\")
  97   SET(DEMO_IMAGE_DIR \\"${IMAGES_DIR}\\")
  98   SET(DEMO_VIDEO_DIR \\"${VIDEOS_DIR}\\")
  99   SET(DEMO_MODEL_DIR \\"${MODELS_DIR}\\")
 100   SET(DEMO_SCRIPT_DIR \\"${SCRIPTS_DIR}\\")
 101   SET(DEMO_SHADER_DIR \\"${SHADERS_DIR}\\")
 102   SET(DEMO_STYLE_DIR \\"${STYLE_DIR}\\")
 103   SET(DEMO_THEME_PATH \\"${STYLE_DIR}demo-theme.json\\")
 104   SET(DEMO_LOCALE_DIR \\"${LOCALE_DIR}\\")
 105   SET(DEMO_STYLE_IMAGE_DIR ${STYLE_DIR}/images)
 106 ENDIF()
 107
 108 SET(DEMO_EXAMPLE_BIN \\"${BINDIR}/\\")
 109 SET(DEMO_LANG \\"${LANG}\\")
 110
 111 #For run-time read/write directory
 112 IF(ANDROID)
 113   SET(DEMO_DATA_RW_DIR \\"/data/data/${DALI_DEMO_APP_ID}/\\")
 114   SET(DEMO_DATA_PUBLIC_RW_DIR \\"/sdcard/\\")
 115 ELSE()
 116   SET(DEMO_DATA_RW_DIR \\"/tmp/\\")
 117   SET(DEMO_DATA_PUBLIC_RW_DIR \\"/tmp/\\")
 118 ENDIF()
 119
 120 # Gets all sub-directories of SRC_DIR into the list RESULT, which will first be reset to empty.
 121 MACRO(GET_TREE RESULT SRC_DIR)
 122         FILE(GLOB_RECURSE LOCAL_LIST RELATIVE ${SRC_DIR} "${SRC_DIR}/*")
 123         SET(${RESULT} "/") # N.B. we need the contents of the root directory as well, and we can't have an empty string in a list in CMake.
 124         FOREACH(LOCAL_ENTRY ${LOCAL_LIST})
 125                 GET_FILENAME_COMPONENT(DIR ${LOCAL_ENTRY} DIRECTORY)
 126                 LIST(APPEND ${RESULT} ${DIR})
 127         ENDFOREACH()
 128         LIST(REMOVE_DUPLICATES ${RESULT})
 129 ENDMACRO()
 130
 131 # Installs files from each subdirectory of ROOT specified in TREE, matching FILTER, to DESTINATION,
 132 # while keeping the structure, up to (excluding) ROOT.
 133 MACRO(INSTALL_TREE_FILES ROOT TREE FILTER DESTINATION)
 134         FOREACH(LOCAL_DIR ${TREE})
 135                 SET(SRC_DIR "${ROOT}/${LOCAL_DIR}")
 136                 FILE(GLOB FILES
 137                         LIST_DIRECTORIES false
 138                         RELATIVE ${SRC_DIR} "${SRC_DIR}/${FILTER}")
 139                 FOREACH(LOCAL_FILE ${FILES})
 140                         INSTALL(FILES "${SRC_DIR}/${LOCAL_FILE}" DESTINATION "${DESTINATION}/${LOCAL_DIR}")
 141                 ENDFOREACH()
 142         ENDFOREACH()
 143 ENDMACRO()
 144
 145 GET_TREE(LOCAL_IMAGES_TREE "${LOCAL_IMAGES_DIR}")
 146 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.png" ${IMAGES_DIR})
 147 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.jpg" ${IMAGES_DIR})
 148 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.gif" ${IMAGES_DIR})
 149 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.webp" ${IMAGES_DIR})
 150 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.bmp" ${IMAGES_DIR})
 151 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.ico" ${IMAGES_DIR})
 152 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.wbmp" ${IMAGES_DIR})
 153 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.ktx" ${IMAGES_DIR})
 154 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.astc" ${IMAGES_DIR})
 155 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.svg" ${IMAGES_DIR})
 156 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.json" ${IMAGES_DIR})
 157
 158 FILE(GLOB LOCAL_VIDEOS_LIST RELATIVE "${LOCAL_VIDEOS_DIR}" "${LOCAL_VIDEOS_DIR}/*")
 159 FOREACH(flag ${LOCAL_VIDEOS_LIST})
 160         INSTALL(FILES ${LOCAL_VIDEOS_DIR}/${flag} DESTINATION ${VIDEOS_DIR})
 161 ENDFOREACH(flag)
 162
 163 GET_TREE(LOCAL_MODELS_TREE "${LOCAL_MODELS_DIR}")
 164 INSTALL_TREE_FILES(${LOCAL_MODELS_DIR} "${LOCAL_MODELS_TREE}" "*" ${MODELS_DIR})
 165
 166 FILE(GLOB LOCAL_SCRIPTS_LIST RELATIVE "${LOCAL_SCRIPTS_DIR}" "${LOCAL_SCRIPTS_DIR}/*.json")
 167 FOREACH(flag ${LOCAL_SCRIPTS_LIST})
 168         INSTALL(FILES ${LOCAL_SCRIPTS_DIR}/${flag} DESTINATION ${SCRIPTS_DIR})
 169 ENDFOREACH(flag)
 170
 171 FILE(GLOB LOCAL_SHADERS_LIST RELATIVE "${LOCAL_SHADERS_DIR}" "${LOCAL_SHADERS_DIR}/*")
 172 FOREACH(flag ${LOCAL_SHADERS_LIST})
 173         INSTALL(FILES ${LOCAL_SHADERS_DIR}/${flag} DESTINATION ${SHADERS_DIR})
 174 ENDFOREACH(flag)
 175
 176 FILE(GLOB LOCAL_GAME_LIST RELATIVE "${LOCAL_GAME_DIR}" "${LOCAL_GAME_DIR}/*.*")
 177 FOREACH(flag ${LOCAL_GAME_LIST})
 178         INSTALL(FILES ${LOCAL_GAME_DIR}/${flag} DESTINATION ${GAME_DIR})
 179 ENDFOREACH(flag)
 180
 181 #Create resources location file
 182 CONFIGURE_FILE( resources-location.in ${DEMO_SHARED}/resources-location.cpp )
 183
 184 MESSAGE("Installing from: ${LOCAL_STYLE_DIR}")
 185 FILE(GLOB LOCAL_STYLES_LIST "${LOCAL_STYLE_DIR}/*.json")
 186 FOREACH(flag ${LOCAL_STYLES_LIST})
 187   INSTALL(FILES ${flag} DESTINATION ${STYLE_DIR})
 188 ENDFOREACH(flag)
 189 MESSAGE("Installed ${LOCAL_STYLES_LIST} to ${STYLE_DIR}")
 190
 191 IF(ANDROID)
 192 FILE(GLOB LOCAL_STYLES_ANDROID_LIST "${LOCAL_STYLE_ANDROID_DIR}/*.json")
 193 FOREACH(flag ${LOCAL_STYLES_ANDROID_LIST})
 194   INSTALL(FILES ${flag} DESTINATION ${STYLE_DIR})
 195 ENDFOREACH(flag)
 196 MESSAGE("Installed ${LOCAL_STYLES_ANDROID_LIST} to ${STYLE_DIR}")
 197 ENDIF()
 198
 199 FILE(GLOB LOCAL_STYLE_IMAGES_LIST "${LOCAL_STYLE_DIR}/images/*.png")
 200 FOREACH(flag ${LOCAL_STYLE_IMAGES_LIST})
 201   INSTALL(FILES ${flag} DESTINATION ${STYLE_DIR}/images)
 202 ENDFOREACH(flag)
 203 MESSAGE("Installed style resources ${LOCAL_STYLE_IMAGES_LIST} to ${STYLE_DIR}/images")
 204
 205 IF( ENABLE_PKG_CONFIGURE )
 206   SET(PKG_LIST dali2-core
 207                dali2-adaptor
 208                dali2-toolkit)
 209
 210   INCLUDE(FindPkgConfig)
 211   pkg_check_modules(REQUIRED_PKGS REQUIRED ${PKG_LIST})
 212
 213   FOREACH(flag ${REQUIRED_PKGS_CFLAGS})
 214         SET(REQUIRED_CFLAGS "${REQUIRED_CFLAGS} ${flag}")
 215   ENDFOREACH(flag)
 216
 217   pkg_check_modules(DALI_SCENE_LOADER dali2-scene-loader)
 218   IF( DALI_SCENE_LOADER_FOUND )
 219     FOREACH(flag ${DALI_SCENE_LOADER_CFLAGS})
 220       SET(REQUIRED_CFLAGS "${REQUIRED_CFLAGS} ${flag}")
 221     ENDFOREACH(flag)
 222
 223     SET( REQUIRED_CFLAGS "${REQUIRED_CFLAGS} -DDALI_SCENE_LOADER_AVAILABLE" )
 224
 225     FOREACH(flag ${DALI_SCENE_LOADER_LDFLAGS})
 226       SET(REQUIRED_PKGS_LDFLAGS "${REQUIRED_PKGS_LDFLAGS} ${flag}")
 227     ENDFOREACH(flag)
 228
 229     SET( ENABLE_SCENE_LOADER "ON" )
 230   ENDIF()
 231
 232   # if build as tizen platform, use capi-appfw-app-control
 233   IF( TIZEN )
 234     pkg_check_modules(CAPI_APPFW_APP_CONTROL capi-appfw-app-control)
 235     IF( CAPI_APPFW_APP_CONTROL_FOUND)
 236       FOREACH(flag ${CAPI_APPFW_APP_CONTROL_CFLAGS})
 237         SET(REQUIRED_CFLAGS "${REQUIRED_CFLAGS} ${flag}")
 238       ENDFOREACH(flag)
 239       FOREACH(flag ${CAPI_APPFW_APP_CONTROL_LDFLAGS})
 240         SET(REQUIRED_PKGS_LDFLAGS "${REQUIRED_PKGS_LDFLAGS} ${flag}")
 241       ENDFOREACH(flag)
 242     ENDIF()
 243   ENDIF()
 244 ENDIF()
 245
 246 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
 247
 248 IF( WIN32 OR APPLE ) # WIN32 includes x64 as well according to the cmake doc.
 249   IF ( WIN32 )
 250     FIND_PACKAGE( pthreads REQUIRED )
 251   ENDIF()
 252   FIND_PACKAGE( curl REQUIRED )
 253   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 254
 255   FIND_PACKAGE( png REQUIRED )
 256   FIND_PACKAGE( gif REQUIRED )
 257   FIND_PACKAGE( jpeg REQUIRED )
 258   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 259
 260   FIND_PACKAGE( freetype REQUIRED )
 261   FIND_PACKAGE( harfbuzz REQUIRED )
 262   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 263
 264   FIND_PACKAGE( unofficial-angle REQUIRED )
 265   FIND_PACKAGE( unofficial-cairo REQUIRED )
 266
 267   FIND_PACKAGE( WebP REQUIRED )
 268
 269   IF ( WIN32 )
 270     FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 271     FIND_PACKAGE( dali-windows-dependencies REQUIRED )
 272     FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 273   ENDIF()
 274
 275   FIND_PACKAGE( dali2-core REQUIRED )
 276   FIND_PACKAGE( dali2-adaptor REQUIRED )
 277   FIND_PACKAGE( dali2-toolkit REQUIRED )
 278
 279   FIND_PACKAGE( dali2-scene-loader )
 280
 281   # Set up the include dir
 282   SET( INCLUDE_DIR $ENV{includedir} )
 283   IF( NOT INCLUDE_DIR )
 284     SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 285   ENDIF()
 286   IF( NOT INCLUDE_DIR )
 287     SET( INCLUDE_DIR ${PREFIX}/include )
 288   ENDIF()
 289
 290   SET( LIB_DIR $ENV{libdir} )
 291   IF( NOT LIB_DIR )
 292     SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 293   ENDIF()
 294   IF( NOT LIB_DIR )
 295     SET( LIB_DIR ${PREFIX}/lib )
 296   ENDIF()
 297
 298   SET( REQUIRED_LIBS
 299     CURL::libcurl
 300     ${EXIF_LIBRARY}
 301     ${PNG_LIBRARIES}
 302     ${GIF_LIBRARIES}
 303     JPEG::JPEG
 304     ${TURBO_JPEG_LIBRARY}
 305     Freetype::Freetype
 306     harfbuzz::harfbuzz
 307     ${FRIBIDI_LIBRARY}
 308     unofficial::angle::libEGL
 309     unofficial::angle::libGLESv2
 310     WebP::webp
 311     WebP::webpdemux
 312     dali2-core::dali2-core
 313     dali2-adaptor::dali2-adaptor
 314     dali2-toolkit::dali2-toolkit
 315   )
 316
 317   IF ( WIN32 )
 318     SET( REQUIRED_LIBS
 319       ${REQUIRED_LIBS}
 320       ${GETOPT_LIBRARY}
 321       unofficial::fontconfig::fontconfig
 322       unofficial::cairo::cairo
 323       PThreads4W::PThreads4W
 324       dali-windows-dependencies::dali-windows-dependencies
 325     )
 326   ENDIF()
 327
 328   IF (dali2-scene-loader_FOUND)
 329     SET(REQUIRED_LIBS
 330       ${REQUIRED_LIBS}
 331       dali2-scene-loader::dali2-scene-loader
 332     )
 333     SET( ENABLE_SCENE_LOADER "ON" )
 334   ENDIF()
 335 ELSEIF( UNIX )
 336   SET( REQUIRED_LIBS
 337     ${REQUIRED_PKGS_LDFLAGS}
 338     -pie
 339   )
 340
 341   IF( ANDROID )
 342     SET( REQUIRED_LIBS ${REQUIRED_LIBS} -lGLESv3 )
 343   ELSE()
 344     PKG_CHECK_MODULES( GLESV2 REQUIRED glesv2 )
 345     SET( REQUIRED_LIBS ${REQUIRED_LIBS} ${GLESV2_LIBRARIES} )
 346   ENDIF()
 347 ENDIF()
 348
 349 SET(DALI_DEMO_CFLAGS "-DDEMO_GAME_DIR=${DEMO_GAME_DIR} -DDEMO_IMAGE_DIR=${DEMO_IMAGE_DIR} -DDEMO_VIDEO_DIR=${DEMO_VIDEO_DIR} -DDEMO_MODEL_DIR=${DEMO_MODEL_DIR} -DDEMO_SCRIPT_DIR=${DEMO_SCRIPT_DIR} -DDEMO_SHADER_DIR=${DEMO_SHADER_DIR}  -DDEMO_STYLE_DIR=${DEMO_STYLE_DIR} -DDEMO_THEME_PATH=${DEMO_THEME_PATH} -DDEMO_EXAMPLE_BIN=${DEMO_EXAMPLE_BIN} -DDEMO_LOCALE_DIR=${DEMO_LOCALE_DIR} -DDEMO_LANG=${DEMO_LANG} -DDEMO_DATA_RW_DIR=${DEMO_DATA_RW_DIR} -DDEMO_DATA_PUBLIC_RW_DIR=${DEMO_DATA_PUBLIC_RW_DIR} ")
 350
 351 IF( ENABLE_DEBUG )
 352   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DDEBUG_ENABLED")
 353 ENDIF()
 354
 355 IF( ENABLE_SCENE_LOADER )
 356   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DDALI_SCENE_LOADER_AVAILABLE")
 357 ENDIF()
 358
 359 IF( UNIX )
 360   IF( NOT ${ENABLE_EXPORTALL} )
 361     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 362   ENDIF()
 363 ENDIF()
 364
 365 ###########################################################################
 366 # Internationalization
 367
 368 IF (UNIX)
 369   SET(PO_DIR ${RESOURCE_DIR}/po)
 370
 371   FILE(GLOB PO_FILES RELATIVE "${PO_DIR}" "${PO_DIR}/*.po")
 372
 373   SET(MSGFMT "msgfmt")
 374   SET(MO_FILES_DIR ${CMAKE_BINARY_DIR}/mo)
 375   FILE(MAKE_DIRECTORY ${MO_FILES_DIR})
 376
 377   FOREACH(PO_FILE ${PO_FILES})
 378         SET(PO_FILE ${PO_DIR}/${PO_FILE})
 379         MESSAGE("PO: ${PO_FILE}")
 380         GET_FILENAME_COMPONENT(ABS_PO_FILE ${PO_FILE} ABSOLUTE)
 381         GET_FILENAME_COMPONENT(lang ${ABS_PO_FILE} NAME_WE)
 382         SET(MO_FILE ${MO_FILES_DIR}/${lang}.mo)
 383         ADD_CUSTOM_COMMAND(OUTPUT ${MO_FILE}
 384                            COMMAND ${MSGFMT} -o ${MO_FILE} ${ABS_PO_FILE}
 385                            DEPENDS ${ABS_PO_FILE})
 386         INSTALL(FILES ${MO_FILE} DESTINATION ${LOCALE_DIR}/${lang}/LC_MESSAGES RENAME ${PROJECT_NAME}.mo)
 387         SET(MO_FILES ${MO_FILES} ${MO_FILE})
 388   ENDFOREACH(PO_FILE)
 389
 390   MESSAGE(".mo files: ${MO_FILES}")
 391   ADD_CUSTOM_TARGET(po ALL DEPENDS ${MO_FILES})
 392 ENDIF()
 393
 394 IF (INTERNATIONALIZATION)
 395   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DINTERNATIONALIZATION_ENABLED")
 396 ENDIF(INTERNATIONALIZATION)
 397
 398 ###########################################################################
 399
 400 IF( WIN32 )
 401   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 402   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 403   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 404 ELSE()
 405   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -Wall -fPIE")
 406   # -Werror is disable for clang in dali-adaptor
 407   IF ( NOT ${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" )
 408     SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -Werror")
 409   ENDIF()
 410
 411   IF( NOT ${ENABLE_EXPORTALL} )
 412     SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -fvisibility=hidden")
 413   ENDIF()
 414 ENDIF()
 415
 416 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${REQUIRED_CFLAGS} ${DALI_DEMO_CFLAGS}")
 417 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_C_FLAGS}")
 418
 419 INCLUDE_DIRECTORIES(
 420   ${SYSTEM_INCLUDE_DIR}
 421   ${ROOT_SRC_DIR}
 422   ${VCPKG_INCLUDE_DIR}
 423   ${INCLUDE_DIR}
 424 )
 425
 426 IF(ANDROID)
 427   INCLUDE_DIRECTORIES( ${ANDROID_NDK}/sources/android/native_app_glue )
 428   INCLUDE_DIRECTORIES( ${ANDROID_NDK}/sysroot/usr )
 429   INCLUDE_DIRECTORIES( ${ANDROID_NDK}/sysroot/usr/include/android )
 430   INCLUDE_DIRECTORIES( ${ROOT_SRC_DIR}/build/android/app/src/main/cpp )
 431 ENDIF()
 432
 433 LINK_DIRECTORIES(${LIB_DIR})
 434
 435 ADD_SUBDIRECTORY(demo)
 436 ADD_SUBDIRECTORY(examples)
 437 ADD_SUBDIRECTORY(examples-reel)
 438 ADD_SUBDIRECTORY(tests-reel)
 439 ADD_SUBDIRECTORY(builder)
 440
 441 # Setup CURRENT_BUILD_PLATFORM to use at message
 442 IF(ANDROID)
 443   SET(CURRENT_BUILD_PLATFORM "Android")
 444 ELSEIF(WIN32)
 445   SET(CURRENT_BUILD_PLATFORM "Windows")
 446 ELSEIF(APPLE)
 447   SET(CURRENT_BUILD_PLATFORM "MacOS")
 448 ELSEIF(TIZEN)
 449   SET(CURRENT_BUILD_PLATFORM "Tizen")
 450 ELSE()
 451   SET(CURRENT_BUILD_PLATFORM "Ubuntu")
 452 ENDIF()
 453
 454 MESSAGE( " Folder   DEMO_IMAGE_DIR : [" ${DEMO_IMAGE_DIR} "]" )
 455 MESSAGE( " Folder   DEMO_STYLE_DIR : [" ${DEMO_STYLE_DIR} "]" )
 456 MESSAGE( " Folder  DEMO_SHADER_DIR : [" ${DEMO_SHADER_DIR} "]" )
 457 MESSAGE( " Folder  DEMO_THEME_PATH : [" ${DEMO_THEME_PATH} "]" )
 458 MESSAGE( " Folder    DEMO_GAME_DIR : [" ${DEMO_GAME_DIR} "]" )
 459 MESSAGE( " Folder   DEMO_VIDEO_DIR : [" ${DEMO_VIDEO_DIR} "]" )
 460 MESSAGE( " Folder   DEMO_MODEL_DIR : [" ${DEMO_MODEL_DIR} "]" )
 461 MESSAGE( " Folder  DEMO_SCRIPT_DIR : [" ${DEMO_SCRIPT_DIR} "]" )
 462 MESSAGE( " Folder  DEMO_LOCALE_DIR : [" ${DEMO_LOCALE_DIR} "]" )
 463 MESSAGE( " Folder DEMO_EXAMPLE_BIN : [" ${DEMO_EXAMPLE_BIN} "]" )
 464 MESSAGE( " Folder        DEMO_LANG : [" ${DEMO_LANG} "]" )
 465 MESSAGE( " Current Build Platform  : [" ${CURRENT_BUILD_PLATFORM} "]" )
 466 MESSAGE( " Scene Loader Enabled    : [" ${ENABLE_SCENE_LOADER} "]" )