configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2016 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.165],[https://bugzilla.redhat.com/],[elfutils])
  21
  22 AC_CONFIG_AUX_DIR([config])
  23 AC_CONFIG_FILES([config/Makefile])
  24
  25 AC_COPYRIGHT([Copyright (C) 1996-2016 Red Hat, Inc.])
  26 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  27
  28 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  29 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  30 AM_MAINTAINER_MODE
  31
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CONFIG_SRCDIR([libelf/libelf.h])
  35 AC_CONFIG_FILES([Makefile])
  36 AC_CONFIG_HEADERS([config.h])
  37
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_FILES([m4/Makefile])
  40
  41 dnl The RPM spec file.  We substitute a few values in the file.
  42 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  43
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_ARG_ENABLE(deterministic-archives,
  48 [AS_HELP_STRING([--enable-deterministic-archives],
  49                 [ar and ranlib default to -D behavior])], [
  50 if test "${enableval}" = no; then
  51   default_ar_deterministic=false
  52 else
  53   default_ar_deterministic=true
  54 fi], [default_ar_deterministic=false])
  55 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  56                    [Should ar and ranlib use -D behavior by default?])
  57
  58 AC_ARG_ENABLE([thread-safety],
  59 AS_HELP_STRING([--enable-thread-safety],
  60                [enable thread safety of libraries EXPERIMENTAL]),
  61                use_locks=$enableval, use_locks=no)
  62 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  63 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  64 AS_IF([test "$use_locks" = yes],
  65       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  66
  67 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  68
  69 AC_PROG_CC
  70 AC_PROG_RANLIB
  71 AC_PROG_YACC
  72 AM_PROG_LEX
  73 # Only available since automake 1.12
  74 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  75 AC_CHECK_TOOL([READELF], [readelf])
  76 AC_CHECK_TOOL([NM], [nm])
  77
  78 # We use -std=gnu99 but have explicit checks for some language constructs
  79 # and GNU extensions since some compilers claim GNU99 support, but don't
  80 # really support all language extensions. In particular we need
  81 # Mixed Declarations and Code
  82 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
  83 # Nested Functions
  84 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
  85 # Arrays of Variable Length
  86 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
  87 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
  88 old_CFLAGS="$CFLAGS"
  89 CFLAGS="$CFLAGS -std=gnu99"
  90 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
  91 int foo (int a)
  92 {
  93   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
  94 }
  95
  96 double bar (double a, double b)
  97 {
  98   double square (double z) { return z * z; }
  99   return square (a) + square (b);
 100 }
 101
 102 void baz (int n)
 103 {
 104   struct S { int x[[n]]; };
 105 }])],
 106                   ac_cv_c99=yes, ac_cv_c99=no)
 107 CFLAGS="$old_CFLAGS"])
 108 AS_IF([test "x$ac_cv_c99" != xyes],
 109       AC_MSG_ERROR([gcc with GNU99 support required]))
 110
 111 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 112 # Use the same flags that we use for our DSOs, so the test is representative.
 113 # Some old compiler/linker/libc combinations fail some ways and not others.
 114 save_CFLAGS="$CFLAGS"
 115 save_LDFLAGS="$LDFLAGS"
 116 CFLAGS="-fPIC $CFLAGS"
 117 LDFLAGS="-shared -Wl,-z,defs,-z,relro $LDFLAGS"
 118 AC_LINK_IFELSE([dnl
 119 AC_LANG_PROGRAM([[#include <stdlib.h>
 120 #undef __thread
 121 static __thread int a; int foo (int b) { return a + b; }]],
 122                 [[exit (foo (0));]])],
 123                ac_cv_tls=yes, ac_cv_tls=no)
 124 CFLAGS="$save_CFLAGS"
 125 LDFLAGS="$save_LDFLAGS"])
 126 AS_IF([test "x$ac_cv_tls" != xyes],
 127       AC_MSG_ERROR([__thread support required]))
 128
 129 dnl This test must come as early as possible after the compiler configuration
 130 dnl tests, because the choice of the file model can (in principle) affect
 131 dnl whether functions and headers are available, whether they work, etc.
 132 AC_SYS_LARGEFILE
 133
 134 dnl Enable the linker to be build as a native-only linker.  By default it
 135 dnl can handle all architectures but this comes at a cost.  A native
 136 dnl will be slightly faster, small, and has fewer dependencies.
 137 native_ld=no
 138 AC_ARG_ENABLE([generic],
 139 AS_HELP_STRING([--disable-generic], [do not build generic linker]), [dnl
 140 if test "$enable_generic" = no; then
 141   case "$host_cpu" in
 142    i?86)
 143     AC_DEFINE(NATIVE_ELF, 32)
 144     native_ld=yes
 145     base_cpu=i386
 146     ;;
 147    *)
 148     AC_MSG_ERROR([no machine-specific linker for this configuration available])
 149     ;;
 150   esac
 151 fi])
 152 AH_TEMPLATE([NATIVE_ELF],
 153 [Define to 32 or 64 if a specific implementation is wanted.])
 154 AM_CONDITIONAL(NATIVE_LD, test "$native_ld" = yes)
 155 dnl The automake generated Makefile cannot deal with macros in the name
 156 dnl of files if at any time there is no such file, even if the filename
 157 dnl would not be used.
 158 AS_IF([test -z "$base_cpu"], [base_cpu=none])
 159 AC_SUBST(base_cpu)
 160 dnl Support to work around automake's inflexible dependency generation.
 161 dnl See src/Makefile.am for more information.
 162 AM_CONDITIONAL(NEVER, false)
 163
 164 dnl enable debugging of branch prediction.
 165 AC_ARG_ENABLE([debugpred],
 166 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 167 [use_debugpred=$enableval], [use_debugpred=no])
 168 case $use_debugpred in
 169  yes) use_debugpred_val=1 ;;
 170  *)   use_debugpred_val=0 ;;
 171 esac
 172 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 173
 174 dnl Enable gprof suport.
 175 AC_ARG_ENABLE([gprof],
 176 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 177 if test "$use_gprof" = yes; then
 178   CFLAGS="$CFLAGS -pg"
 179   LDFLAGS="$LDFLAGS -pg"
 180 fi
 181 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 182
 183 # Enable gcov suport.
 184 AC_ARG_ENABLE([gcov],
 185 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 186 if test "$use_gcov" = yes; then
 187   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 188   LDFLAGS="$LDFLAGS -fprofile-arcs"
 189 fi
 190 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 191
 192 AC_ARG_ENABLE([sanitize-undefined],
 193               AS_HELP_STRING([--enable-sanitize-undefined],
 194                              [Use gcc undefined behaviour sanitizer]),
 195                              [use_undefined=$enableval], [use_undefined=no])
 196 if test "$use_undefined" = yes; then
 197   old_CFLAGS="$CFLAGS"
 198   old_CXXFLAGS="$CXXFLAGS"
 199   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 200   # We want to fail immediately on first error, don't try to recover.
 201   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 202   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 203   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 204   AS_IF([test "x$use_undefined" != xyes],
 205         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 206         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 207 fi
 208 case $use_undefined in
 209  yes) check_undefined_val=1 ;;
 210  *)   check_undefined_val=0 ;;
 211 esac
 212 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 213                    [Building with -fsanitize=undefined or not])
 214
 215 AC_ARG_ENABLE([valgrind],
 216 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 217 [use_valgrind=$enableval], [use_valgrind=no])
 218 if test "$use_valgrind" = yes; then
 219   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 220   if test "$HAVE_VALGRIND" = "no"; then
 221     AC_MSG_ERROR([valgrind not found])
 222   fi
 223 fi
 224 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 225
 226 AM_CONDITIONAL(BUILD_STATIC, [dnl
 227 test "$use_gprof" = yes -o "$use_gcov" = yes])
 228
 229 AC_ARG_ENABLE([tests-rpath],
 230 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 231                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 232 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 233
 234 LIBEBL_SUBDIR="$PACKAGE"
 235 AC_ARG_ENABLE([libebl-subdir],
 236 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 237 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 238 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 239 AC_SUBST([LIBEBL_SUBDIR])
 240 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 241 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 242
 243 dnl zlib is mandatory.
 244 save_LIBS="$LIBS"
 245 LIBS=
 246 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 247 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR("zlib not found")])
 248 LIBS="$save_LIBS"
 249
 250 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 251 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 252 save_LIBS="$LIBS"
 253 LIBS=
 254 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 255 # We need this since bzip2 doesn't have a pkgconfig file.
 256 BZ2_LIB="$LIBS"
 257 AC_SUBST([BZ2_LIB])
 258 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 259 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 260 AC_SUBST([LIBLZMA])
 261 zip_LIBS="$LIBS"
 262 LIBS="$save_LIBS"
 263 AC_SUBST([zip_LIBS])
 264
 265 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 266 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 267 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 268 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 269       [enable_demangler=yes],[enable_demangler=no])
 270
 271 AC_ARG_ENABLE([textrelcheck],
 272 AS_HELP_STRING([--disable-textrelcheck],
 273                [Disable textrelcheck being a fatal error]))
 274 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 275 AS_IF([test "x$enable_textrelcheck" != "xno"],
 276       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 277
 278 AC_ARG_ENABLE([symbol-versioning],
 279 AS_HELP_STRING([--disable-symbol-versioning],
 280                [Disable symbol versioning in shared objects]))
 281 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 282 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 283       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 284        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 285
 286 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 287 old_CFLAGS="$CFLAGS"
 288 CFLAGS="$CFLAGS -Wstack-usage=262144"
 289 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 290                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 291 CFLAGS="$old_CFLAGS"])
 292 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 293
 294 dnl Check if we have argp available from our libc
 295 AC_LINK_IFELSE(
 296         [AC_LANG_PROGRAM(
 297                 [#include <argp.h>],
 298                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,argv,0,0,0); return 0;]
 299                 )],
 300         [libc_has_argp="true"],
 301         [libc_has_argp="false"]
 302 )
 303
 304 dnl If our libc doesn't provide argp, then test for libargp
 305 if test "$libc_has_argp" = "false" ; then
 306         AC_MSG_WARN("libc does not have argp")
 307         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 308
 309         if test "$have_argp" = "false"; then
 310                 AC_MSG_ERROR("no libargp found")
 311         else
 312                 argp_LDADD="-largp"
 313         fi
 314 else
 315         argp_LDADD=""
 316 fi
 317 AC_SUBST([argp_LDADD])
 318
 319 dnl The directories with content.
 320
 321 dnl Documentation.
 322 dnl Commented out for now.
 323 dnl AC_CONFIG_FILES([doc/Makefile])
 324
 325 dnl Support library.
 326 AC_CONFIG_FILES([lib/Makefile])
 327
 328 dnl ELF library.
 329 AC_CONFIG_FILES([libelf/Makefile])
 330
 331 dnl Higher-level ELF support library.
 332 AC_CONFIG_FILES([libebl/Makefile])
 333
 334 dnl DWARF-ELF Lower-level Functions support library.
 335 AC_CONFIG_FILES([libdwelf/Makefile])
 336
 337 dnl DWARF library.
 338 AC_CONFIG_FILES([libdw/Makefile])
 339
 340 dnl Higher-level DWARF support library.
 341 AC_CONFIG_FILES([libdwfl/Makefile])
 342
 343 dnl CPU handling library.
 344 AC_CONFIG_FILES([libcpu/Makefile])
 345
 346 dnl Assembler library.
 347 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 348 AC_CONFIG_FILES([libasm/Makefile])
 349
 350 dnl CPU-specific backend libraries.
 351 AC_CONFIG_FILES([backends/Makefile])
 352
 353 dnl Tools.
 354 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 355
 356 dnl Test suite.
 357 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 358 AC_CONFIG_FILES([tests/Makefile])
 359
 360 dnl pkgconfig files
 361 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 362
 363 # Get the definitions necessary to create the Makefiles in the po
 364 # subdirectories.  This is a small subset of the gettext rules.
 365 AC_SUBST(USE_NLS, yes)
 366 AM_PO_SUBDIRS
 367
 368 dnl Appended to the config.h file.
 369 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 370 AH_BOTTOM([#include <eu-config.h>])
 371
 372 dnl Version compatibility header.
 373 AC_CONFIG_FILES([version.h:config/version.h.in])
 374 AC_SUBST([eu_version])
 375
 376 # 1.234<whatever> -> 1234<whatever>
 377 case "$PACKAGE_VERSION" in
 378 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 379 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 380 esac
 381 case "$eu_version" in
 382 *.*)
 383   # 1234.567 -> "1234", "567"
 384   eu_extra_version="${eu_version#*.}"
 385   eu_version="${eu_version%%.*}"
 386   case "$eu_extra_version" in
 387   [[0-9]][[0-9]][[0-9]]) ;;
 388   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 389   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 390   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 391   esac
 392   ;;
 393 *)
 394   eu_extra_version=000
 395   ;;
 396 esac
 397
 398 case "$eu_version" in
 399       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 400 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 401 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 402 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 403 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 404 esac
 405
 406 # Round up to the next release API (x.y) version.
 407 eu_version=$(( (eu_version + 999) / 1000 ))
 408
 409 dnl Unique ID for this build.
 410 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 411 AC_SUBST([MODVERSION])
 412 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 413 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 414
 415 AC_CHECK_SIZEOF(long)
 416
 417 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 418 # of the user_regs_struct from sys/user.h. They are structurally the same
 419 # but we get either one or the other.
 420 AC_CHECK_TYPE([struct user_regs_struct],
 421               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 422               [[#include <sys/ptrace.h>]
 423                [#include <sys/time.h>]
 424                [#include <sys/user.h>]])
 425 if test "$sys_user_has_user_regs" = "yes"; then
 426   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 427             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 428 fi
 429
 430 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 431 # Likewise in a 32-bit build on a host where $CC -m64 works.
 432 utrace_BIARCH
 433 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 434 CC_BIARCH="$CC $utrace_biarch"
 435 AC_SUBST([CC_BIARCH])
 436
 437 # In maintainer mode we really need flex and bison.
 438 # Otherwise we really need a release dir with maintainer files generated.
 439 if test "x$enable_maintainer_mode" = xyes; then
 440   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 441   if test "$HAVE_FLEX" = "no"; then
 442     AC_MSG_ERROR([flex needed in maintainer mode])
 443   fi
 444   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 445   if test "$HAVE_BISON" = "no"; then
 446     AC_MSG_ERROR([bison needed in maintainer mode])
 447   fi
 448 else
 449   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 450     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 451   fi
 452 fi
 453
 454 # The testfiles are all compressed, we need bunzip2 when running make check
 455 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 456 if test "$HAVE_BUNZIP2" = "no"; then
 457   AC_MSG_WARN([No bunzip2, needed to run make check])
 458 fi
 459
 460 AC_OUTPUT
 461
 462 AC_MSG_NOTICE([
 463 =====================================================================
 464         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 465 =====================================================================
 466
 467     Prefix                             : ${prefix}
 468     Program prefix ("eu-" recommended) : ${program_prefix}
 469     Source code location               : ${srcdir}
 470     Maintainer mode                    : ${enable_maintainer_mode}
 471     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 472     build arch                         : ${ac_cv_build}
 473
 474   RECOMMENDED FEATURES (should all be yes)
 475     gzip support                       : ${with_zlib}
 476     bzip2 support                      : ${with_bzlib}
 477     lzma/xz support                    : ${with_lzma}
 478     libstdc++ demangle support         : ${enable_demangler}
 479     File textrel check                 : ${enable_textrelcheck}
 480     Symbol versioning                  : ${enable_symbol_versioning}
 481
 482   NOT RECOMMENDED FEATURES (should all be no)
 483     Experimental thread safety         : ${use_locks}
 484
 485   OTHER FEATURES
 486     Deterministic archives by default  : ${default_ar_deterministic}
 487     Native language support            : ${USE_NLS}
 488
 489   EXTRA TEST FEATURES (used with make check)
 490     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 491     debug branch prediction            : ${use_debugpred}
 492     gprof support                      : ${use_gprof}
 493     gcov support                       : ${use_gcov}
 494     run all tests under valgrind       : ${use_valgrind}
 495     gcc undefined behaviour sanitizer  : ${use_undefined}
 496     use rpath in tests                 : ${tests_use_rpath}
 497     test biarch                        : ${utrace_cv_cc_biarch}
 498 ])