EFL_VERSION([1], [7], [99], [dev])
AC_INIT([eldbus], [efl_version], [enlightenment-devel@lists.sourceforge.net])

AC_PREREQ([2.60])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_MACRO_DIR([m4])

AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([foreign subdir-objects])

m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

PKG_PROG_PKG_CONFIG

EFL_COMPILER_FLAG([-Wall])
EFL_COMPILER_FLAG([-Wextra])
EFL_COMPILER_FLAG([-Wshadow])
EFL_COMPILER_FLAG([-Wno-unused-parameter])
EFL_COMPILER_FLAG([-Wvla])
EFL_COMPILER_FLAG([-Wundef])
EFL_COMPILER_FLAG([-Wformat=2])
EFL_COMPILER_FLAG([-Wlogical-op])
EFL_COMPILER_FLAG([-Wsign-compare])
EFL_COMPILER_FLAG([-Wformat-security])
EFL_COMPILER_FLAG([-Wmissing-include-dirs])
EFL_COMPILER_FLAG([-Wformat-nonliteral])
EFL_COMPILER_FLAG([-Wold-style-definition])
EFL_COMPILER_FLAG([-Wpointer-arith])
EFL_COMPILER_FLAG([-Winit-self])
EFL_COMPILER_FLAG([-Wdeclaration-after-statement])
EFL_COMPILER_FLAG([-Wmissing-declarations])
EFL_COMPILER_FLAG([-Wmissing-noreturn])
EFL_COMPILER_FLAG([-Wendif-labels])
EFL_COMPILER_FLAG([-Wstrict-aliasing=2])
EFL_COMPILER_FLAG([-Wwrite-strings])
EFL_COMPILER_FLAG([-Wno-long-long])
EFL_COMPILER_FLAG([-Wno-overlength-strings])
EFL_COMPILER_FLAG([-Wno-missing-field-initializers])
EFL_COMPILER_FLAG([-Wno-nested-externs])
EFL_COMPILER_FLAG([-Wchar-subscripts])
EFL_COMPILER_FLAG([-Wtype-limits])
EFL_COMPILER_FLAG([-Wuninitialized])

AC_LANG_C

AC_PROG_CC
AC_PROG_MKDIR_P
AM_PROG_CC_C_O

AC_DISABLE_STATIC
define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
AC_PROG_LIBTOOL

# doxygen program for documentation building
EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])

EFL_INIT

PKG_CHECK_MODULES([EINA], [eina >= 1.7.0])
PKG_CHECK_MODULES([ECORE], [ecore >= 1.7.0])
PKG_CHECK_MODULES([DBUS], [dbus-1])

with_max_log_level="EINA_LOG_LEVEL_DBG"
AC_ARG_WITH(maximum-log-level,
   [AC_HELP_STRING([--with-maximum-log-level=NUMBER],
                   [limit log level, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
   [with_max_log_level="${withval}"], [:])
AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${with_max_log_level}, [if set, logging is limited to this amount.])

EFL_ENABLE_BIN([eldbus-codegen], ["yes"])

if test "x${have_eldbus_codegen}" = "xyes" ; then
	PKG_CHECK_MODULES([ELDBUS_CODEGEN],
		[eina >= 1.6.99
		 ecore >= 1.6.99],
		[have_eldbus_codegen="yes"],
		[have_eldbus_codegen="no"])
fi

AC_CONFIG_FILES([
Makefile
eldbus.spec
doc/Makefile
doc/Doxyfile
])

AC_OUTPUT