AC_INIT([at-spi2-core], [2.25.90], [accessibility-atspi@lists.linux-foundation.org])
AC_PREREQ([2.59])
AC_CONFIG_AUX_DIR(config)
AC_CONFIG_MACRO_DIR([m4])

AT_SPI_CORE_MAJOR_VERSION=0
AT_SPI_CORE_MINOR_VERSION=1
AT_SPI_CORE_MICRO_VERSION=3
AT_SPI_CORE_VERSION="$AT_SPI_CORE_MAJOR_VERSION.$AT_SPI_CORE_MINOR_VERSION"
AC_SUBST(AT_SPI_CORE_VERSION)

LT_RELEASE=$AT_SPI_CORE_VERSION
LT_CURRENT=0
LT_REVISION=1
LT_AGE=0
LT_VERSION_INFO='-version-info ${LT_CURRENT}:${LT_REVISION}:${LT_AGE}'
AC_SUBST(LT_VERSION_INFO)
AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

AM_INIT_AUTOMAKE([1.13 -Wall -Wno-portability foreign subdir-objects no-dist-gzip dist-xz])

# Support silent build rules. Disable
# by either passing --disable-silent-rules to configure or passing V=1
# to make
AM_SILENT_RULES([yes])

AM_PROG_CC_C_O
LT_INIT([disable-static])
PKG_PROG_PKG_CONFIG

AC_CONFIG_HEADERS([config.h])

AC_PROG_SED

AM_GNU_GETTEXT_VERSION([0.19.8])
AM_GNU_GETTEXT([external])

GETTEXT_PACKAGE="${PACKAGE}"
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
                   ["$GETTEXT_PACKAGE"],
                   [The prefix for our gettext translation domains.])

PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0])
AC_SUBST(DBUS_LIBS)
AC_SUBST(DBUS_CFLAGS)

PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.36.0])
AC_SUBST(GLIB_LIBS)
AC_SUBST(GLIB_CFLAGS)

# Use pkg-config to find the glib-mkenums script
GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
AC_SUBST(GLIB_MKENUMS)

PKG_CHECK_MODULES(GOBJ, [gobject-2.0 >= 2.0.0])
AC_SUBST(GOBJ_LIBS)
AC_SUBST(GOBJ_CFLAGS)

PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.28])
AC_SUBST(GIO_LIBS)
AC_SUBST(GIO_CFLAGS)

# --------------------------------------------------------------------
# Find DL functionality

AC_CHECK_LIB(c, dlopen, DL_LIBS="",
        AC_CHECK_LIB(dl, dlopen, DL_LIBS="-ldl",
                AC_MSG_ERROR([Could not find a library with the dlopen function])
        )
)

AC_SUBST(DL_LIBS)

AC_ARG_ENABLE(x11,
              [AS_HELP_STRING([--disable-x11],
                              [disable the X11 backend])],,
			      [enable_x11=auto])

AS_IF([test "x$enable_x11" = xno], [
  AM_CONDITIONAL(USE_X11, false)
], [
  PKG_CHECK_MODULES(X11, [x11], [
    AC_DEFINE(HAVE_X11, 1, [Define to use X11])
    AC_SUBST(HAVE_X11)
    have_x11=yes
  ], [
    AS_IF([test "x$enable_x11" = xyes], [
      AC_MSG_ERROR([Unable to find X11 development files])
    ])
    have_x11=no
  ])

  # Check for additional X11 extensions
  AS_IF([test "x$have_x11" = xyes], [
    # XTest (mandatory)
    PKG_CHECK_MODULES(XTST, [xtst])
    X11_CFLAGS="$X11_CFLAGS $XTST_CFLAGS"
    X11_LIBS="$X11_LIBS $XTST_LIBS"

    # XInput (mandatory)
    PKG_CHECK_MODULES(XINPUT, [xi])
    X11_CFLAGS="$X11_CFLAGS $XINPUT_CFLAGS"
    X11_LIBS="$X11_LIBS $XINPUT_LIBS"

    # XKB (optional)
    PKG_CHECK_MODULES(XKB, [xkbcommon-x11], [
      AC_DEFINE(HAVE_XKB, 1, [Define to use XKB])
      X11_CFLAGS="$X11_CFLAGS $XKB_CFLAGS"
      X11_LIBS="$X11_LIBS $XKB_LIBS"
    ], [])
  ])

  AC_SUBST(X11_CFLAGS)
  AC_SUBST(X11_LIBS)

  AM_CONDITIONAL(USE_X11, test "x$have_x11" = xyes)
])

AC_ARG_WITH([dbus_daemondir],
	[AS_HELP_STRING([--with-dbus-daemondir=<directory>],
		[Directory where the DBUS daemon is installed])],
    [DBUS_DAEMON="$with_dbus_daemondir/dbus-daemon"],
    [AC_PATH_PROG([DBUS_DAEMON], [dbus-daemon], [XXXDBUSDAEMONNOTFOUND],
		[$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR]dnl
[/libexec$PATH_SEPARATOR/usr/libexec$PATH_SEPARATOR/usr/local/bin]dnl
[$PATH_SEPARATOR/usr/pkg/bin])]
	)
if test "$DBUS_DAEMON" = "XXXDBUSDAEMONNOTFOUND"; then
	DBUS_DAEMON = "$bindir/dbus-daemon"
	AC_MSG_WARN([at-spi2 relies on dbus, and the dbus-daemon was not found])
	AC_MSG_WARN([we assume that it will be installed in "$bindir"])
fi
AC_SUBST(DBUS_DAEMON)

AC_ARG_WITH(dbus-services,
           [AS_HELP_STRING([--with-dbus-services=<directory>],
           [where D-BUS services directory is])])
if ! test -z "$with_dbus_services" ; then
           DBUS_SERVICES_DIR="$with_dbus_services"
else
           DBUS_SERVICES_DIR="$datadir/dbus-1/services"
fi
AC_SUBST(DBUS_SERVICES_DIR)

GOBJECT_INTROSPECTION_CHECK([1.32.0])

AC_SUBST(LIBTOOL_EXPORT_OPTIONS)

dnl find sizes & alignments
orig_CPPFLAGS=$CPPFLAGS
CPPFLAGS="$CPPFLAGS $DBUS_CFLAGS"
AC_CHECK_ALIGNOF(char)
AC_CHECK_ALIGNOF(dbus_bool_t, [#include <dbus/dbus.h>])
AC_CHECK_ALIGNOF(dbus_int16_t, [#include <dbus/dbus.h>])
AC_CHECK_ALIGNOF(dbus_int32_t, [#include <dbus/dbus.h>])
AC_CHECK_ALIGNOF(dbus_int64_t, [#include <dbus/dbus.h>])
AC_CHECK_ALIGNOF(double, [#include <dbus/dbus.h>])
AC_CHECK_ALIGNOF(dbind_pointer, [AC_INCLUDES_DEFAULT
typedef void *dbind_pointer;])
AC_CHECK_ALIGNOF(dbind_struct, [AC_INCLUDES_DEFAULT
typedef struct {char s1;} dbind_struct;])

GTK_DOC_CHECK([1.25])

if test "x$GCC" = xyes; then
	CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
fi

CPPFLAGS=$orig_CPPFLAGS 

AC_CONFIG_FILES([
        Makefile
        po/Makefile.in
	xml/Makefile
	dbind/Makefile
	atspi/Makefile
	registryd/Makefile
	bus/Makefile
        doc/Makefile
        doc/libatspi/Makefile
        doc/libatspi/version.xml
        test/Makefile
        atspi-2.pc
])

AC_OUTPUT