[dali_2.1.25] Merge branch 'devel/master'
[platform/core/uifw/dali-toolkit.git] / dali-toolkit / internal / graphics / shaders / image-visual-shader.vert
1 #ifndef IS_REQUIRED_ROUNDED_CORNER
2 #define IS_REQUIRED_ROUNDED_CORNER 0
3 #endif
4 #ifndef IS_REQUIRED_BORDERLINE
5 #define IS_REQUIRED_BORDERLINE 0
6 #endif
7 #ifndef IS_REQUIRED_ALPHA_MASKING
8 #define IS_REQUIRED_ALPHA_MASKING 0
9 #endif
10
11 INPUT mediump vec2 aPosition;
12 OUTPUT mediump vec2 vTexCoord;
13 #if IS_REQUIRED_ROUNDED_CORNER || IS_REQUIRED_BORDERLINE
14 OUTPUT mediump vec2 vPosition;
15 OUTPUT mediump vec2 vRectSize;
16 OUTPUT mediump vec2 vOptRectSize;
17 #if IS_REQUIRED_ROUNDED_CORNER
18 OUTPUT mediump vec4 vCornerRadius;
19 #endif
20 #endif
21
22 uniform highp mat4 uMvpMatrix;
23 uniform highp vec3 uSize;
24 uniform mediump vec4 pixelArea;
25
26 //Visual size and offset
27 uniform mediump vec2 offset;
28 uniform highp vec2 size;
29 uniform mediump vec4 offsetSizeMode;
30 uniform mediump vec2 origin;
31 uniform mediump vec2 anchorPoint;
32 #if IS_REQUIRED_BORDERLINE
33 uniform mediump float borderlineWidth;
34 uniform mediump float borderlineOffset;
35 #endif
36 #if IS_REQUIRED_ROUNDED_CORNER
37 uniform mediump vec4 cornerRadius;
38 uniform mediump float cornerRadiusPolicy;
39 #endif
40 #if IS_REQUIRED_ALPHA_MASKING
41 OUTPUT  mediump vec2  vMaskTexCoord;
42 uniform lowp    float cropToMask;
43 uniform mediump vec2  maskTextureRatio;
44 #endif
45 uniform mediump vec2 extraSize;
46
47 vec4 ComputeVertexPosition()
48 {
49   vec2 visualSize = mix(uSize.xy * size, size, offsetSizeMode.zw) + extraSize;
50   vec2 visualOffset = mix(offset, offset/uSize.xy, offsetSizeMode.xy);
51
52 #if IS_REQUIRED_ROUNDED_CORNER || IS_REQUIRED_BORDERLINE
53   vRectSize = visualSize * 0.5;
54   vOptRectSize = vRectSize;
55 #endif
56
57 #if IS_REQUIRED_ROUNDED_CORNER
58 #if IS_REQUIRED_BORDERLINE
59   mediump float minSize = min(visualSize.x, visualSize.y) + (1.0 + clamp(borderlineOffset, -1.0, 1.0)) * borderlineWidth;
60 #else
61   mediump float minSize = min(visualSize.x, visualSize.y);
62 #endif
63   vCornerRadius = mix(cornerRadius * minSize, cornerRadius, cornerRadiusPolicy);
64   vCornerRadius = min(vCornerRadius, minSize * 0.5);
65   // Optimize fragment shader. 0.2929 ~= 1.0 - sqrt(0.5)
66   mediump float maxRadius = max(max(vCornerRadius.x, vCornerRadius.y), max(vCornerRadius.z, vCornerRadius.w));
67   vOptRectSize -= 0.2929 * maxRadius + 1.0;
68 #endif
69
70 #if IS_REQUIRED_BORDERLINE
71   vPosition = aPosition * (visualSize + (1.0 + clamp(borderlineOffset, -1.0, 1.0)) * borderlineWidth);
72   vOptRectSize -= (1.0 - clamp(borderlineOffset, -1.0, 1.0)) * 0.5 * borderlineWidth + 1.0;
73 #elif IS_REQUIRED_ROUNDED_CORNER
74   vPosition = aPosition * visualSize;
75 #else
76   mediump vec2 vPosition = aPosition * visualSize;
77 #endif
78
79   vec4 finalPixelArea = pixelArea;
80 #if IS_REQUIRED_ALPHA_MASKING
81   finalPixelArea = mix(pixelArea,
82                        vec4(
83                             vec2(0.5) + (pixelArea.xy - vec2(0.5)) * maskTextureRatio,
84                             pixelArea.zw * maskTextureRatio
85                        ),
86                        cropToMask);
87   vMaskTexCoord = pixelArea.xy + pixelArea.zw * (vPosition.xy / max(vec2(1.0), visualSize) + vec2(0.5));
88 #endif
89   vTexCoord = finalPixelArea.xy + finalPixelArea.zw * (vPosition.xy / max(vec2(1.0), visualSize) + vec2(0.5));
90
91   return vec4(vPosition + anchorPoint * visualSize + (visualOffset + origin) * uSize.xy, 0.0, 1.0);
92 }
93
94 void main()
95 {
96   gl_Position = uMvpMatrix * ComputeVertexPosition();
97 }