dali-toolkit/internal/graphics/shaders/color-visual-shader.vert

   1 INPUT mediump vec2 aPosition;
   2 #if defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE) || defined(IS_REQUIRED_BLUR)
   3 OUTPUT mediump vec2 vPosition;
   4 OUTPUT mediump vec2 vRectSize;
   5 OUTPUT mediump vec2 vOptRectSize;
   6 #ifdef IS_REQUIRED_ROUNDED_CORNER
   7 OUTPUT mediump vec4 vCornerRadius;
   8 #endif
   9 #endif
  10
  11 uniform highp mat4 uMvpMatrix;
  12 uniform highp vec3 uSize;
  13
  14 //Visual size and offset
  15 uniform mediump vec2 offset;
  16 uniform highp vec2 size;
  17 uniform mediump vec4 offsetSizeMode;
  18 uniform mediump vec2 origin;
  19 uniform mediump vec2 anchorPoint;
  20 #if !defined(IS_REQUIRED_BLUR) && defined(IS_REQUIRED_BORDERLINE)
  21 uniform mediump float borderlineWidth;
  22 uniform mediump float borderlineOffset;
  23 #endif
  24 #ifdef IS_REQUIRED_BLUR
  25 uniform mediump float blurRadius;
  26 #endif
  27 #ifdef IS_REQUIRED_ROUNDED_CORNER
  28 uniform mediump vec4 cornerRadius;
  29 uniform mediump float cornerRadiusPolicy;
  30 #endif
  31 uniform mediump vec2 extraSize;
  32
  33 vec4 ComputeVertexPosition()
  34 {
  35   vec2 visualSize = mix(size * uSize.xy, size, offsetSizeMode.zw ) + extraSize;
  36   vec2 visualOffset = mix(offset * uSize.xy, offset, offsetSizeMode.xy);
  37
  38 #if defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE) || defined(IS_REQUIRED_BLUR)
  39   vRectSize = visualSize * 0.5;
  40   vOptRectSize = vRectSize;
  41 #endif
  42
  43 #ifdef IS_REQUIRED_ROUNDED_CORNER
  44 #if !defined(IS_REQUIRED_BLUR) && defined(IS_REQUIRED_BORDERLINE)
  45   mediump float minSize = min(visualSize.x, visualSize.y) + (1.0 + clamp(borderlineOffset, -1.0, 1.0)) * borderlineWidth;
  46 #else
  47   mediump float minSize = min(visualSize.x, visualSize.y);
  48 #endif
  49   vCornerRadius = mix(cornerRadius * minSize, cornerRadius, cornerRadiusPolicy);
  50   vCornerRadius = min(vCornerRadius, minSize * 0.5);
  51   // Optimize fragment shader. 0.2929 ~= 1.0 - sqrt(0.5)
  52   mediump float maxRadius = max(max(vCornerRadius.x, vCornerRadius.y), max(vCornerRadius.z, vCornerRadius.w));
  53   vOptRectSize -= 0.2929 * maxRadius + 1.0;
  54 #endif
  55
  56 #ifdef IS_REQUIRED_BLUR
  57   vPosition = aPosition * (visualSize + 2.0 * blurRadius);
  58   vOptRectSize -= blurRadius + 1.0;
  59 #elif defined(IS_REQUIRED_BORDERLINE)
  60   vPosition = aPosition * (visualSize + (1.0 + clamp(borderlineOffset, -1.0, 1.0))* borderlineWidth);
  61   vOptRectSize -= (1.0 - clamp(borderlineOffset, -1.0, 1.0)) * 0.5 * borderlineWidth + 1.0;
  62 #elif defined(IS_REQUIRED_ROUNDED_CORNER)
  63   vPosition = aPosition * visualSize;
  64 #else
  65   mediump vec2 vPosition = aPosition * visualSize;
  66 #endif
  67   return vec4(vPosition + anchorPoint * visualSize + visualOffset + origin * uSize.xy, 0.0, 1.0);
  68 }
  69
  70 void main()
  71 {
  72   gl_Position = uMvpMatrix * ComputeVertexPosition();
  73 }