dali-toolkit/internal/graphics/shaders/color-visual-shader.frag

   1 #if defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE) || defined(IS_REQUIRED_BLUR)
   2 INPUT mediump vec2 vPosition;
   3 INPUT mediump vec2 vRectSize;
   4 INPUT mediump vec2 vOptRectSize;
   5 #ifdef IS_REQUIRED_ROUNDED_CORNER
   6 INPUT mediump vec4 vCornerRadius;
   7 #endif
   8 #endif
   9
  10 uniform lowp vec4 uColor;
  11 uniform lowp vec3 mixColor;
  12 #ifdef IS_REQUIRED_BLUR
  13 uniform mediump float blurRadius;
  14 #elif defined(IS_REQUIRED_BORDERLINE)
  15 uniform mediump float borderlineWidth;
  16 uniform mediump float borderlineOffset;
  17 uniform lowp vec4 borderlineColor;
  18 uniform lowp vec4 uActorColor;
  19 #endif
  20
  21
  22 #if defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE) || defined(IS_REQUIRED_BLUR)
  23 // Global values both rounded corner and borderline use
  24
  25 // radius of rounded corner on this quadrant
  26 mediump float gRadius = 0.0;
  27
  28 // fragment coordinate. NOTE : vec2(0.0, 0.0) is vRectSize, the corner of visual
  29 mediump vec2 gFragmentPosition = vec2(0.0, 0.0);
  30 // center coordinate of rounded corner circle. vec2(gCenterPosition, gCenterPosition).
  31 mediump float gCenterPosition = 0.0;
  32 // relative coordinate of gFragmentPosition from gCenterPosition.
  33 mediump vec2 gDiff = vec2(0.0, 0.0);
  34 // potential value what our algorithm use.
  35 mediump float gPotential = 0.0;
  36
  37 // threshold of potential
  38 mediump float gPotentialRange = 0.0;
  39 mediump float gMaxOutlinePotential = 0.0;
  40 mediump float gMinOutlinePotential = 0.0;
  41 mediump float gMaxInlinePotential = 0.0;
  42 mediump float gMinInlinePotential = 0.0;
  43
  44 void calculateCornerRadius()
  45 {
  46 #ifdef IS_REQUIRED_ROUNDED_CORNER
  47   gRadius =
  48   mix(
  49     mix(vCornerRadius.x, vCornerRadius.y, sign(vPosition.x) * 0.5 + 0.5),
  50     mix(vCornerRadius.w, vCornerRadius.z, sign(vPosition.x) * 0.5 + 0.5),
  51     sign(vPosition.y) * 0.5 + 0.5
  52   );
  53 #endif
  54 }
  55
  56 void calculatePosition()
  57 {
  58   gFragmentPosition = abs(vPosition) - vRectSize;
  59   gCenterPosition = -gRadius;
  60 #ifdef IS_REQUIRED_BLUR
  61 #elif defined(IS_REQUIRED_BORDERLINE)
  62   gCenterPosition += borderlineWidth * (clamp(borderlineOffset, -1.0, 1.0) + 1.0) * 0.5;
  63 #endif
  64   gDiff = gFragmentPosition - gCenterPosition;
  65 }
  66
  67 void calculatePotential()
  68 {
  69   gPotential = length(max(gDiff, 0.0)) + min(0.0, max(gDiff.x, gDiff.y));
  70 }
  71
  72 void setupMinMaxPotential()
  73 {
  74   gPotentialRange = 1.0;
  75
  76   gMaxOutlinePotential = gRadius + gPotentialRange;
  77   gMinOutlinePotential = gRadius - gPotentialRange;
  78
  79 #ifdef IS_REQUIRED_BLUR
  80   gMaxInlinePotential = gMaxOutlinePotential;
  81   gMinInlinePotential = gMinOutlinePotential;
  82 #elif defined(IS_REQUIRED_BORDERLINE)
  83   gMaxInlinePotential = gMaxOutlinePotential - borderlineWidth;
  84   gMinInlinePotential = gMinOutlinePotential - borderlineWidth;
  85 #else
  86   gMaxInlinePotential = gMaxOutlinePotential;
  87   gMinInlinePotential = gMinOutlinePotential;
  88 #endif
  89
  90   // reduce defect near edge of rounded corner.
  91   gMaxOutlinePotential += clamp(-min(gDiff.x, gDiff.y)/ max(1.0, gRadius) , 0.0, 1.0);
  92   gMinOutlinePotential += clamp(-min(gDiff.x, gDiff.y)/ max(1.0, gRadius) , 0.0, 1.0);
  93 }
  94
  95 void PreprocessPotential()
  96 {
  97   calculateCornerRadius();
  98   calculatePosition();
  99   calculatePotential();
 100
 101   setupMinMaxPotential();
 102 }
 103 #endif
 104
 105 #ifdef IS_REQUIRED_BLUR
 106 #elif defined(IS_REQUIRED_BORDERLINE)
 107 lowp vec4 convertBorderlineColor(lowp vec4 textureColor)
 108 {
 109   mediump float potential = gPotential;
 110
 111   // default opacity of borderline is 0.0
 112   mediump float borderlineOpacity = 0.0;
 113
 114   // calculate borderline opacity by potential
 115   if(potential > gMinInlinePotential)
 116   {
 117     // potential is inside borderline range.
 118     borderlineOpacity = smoothstep(gMinInlinePotential, gMaxInlinePotential, potential);
 119
 120     // Muliply borderlineWidth to resolve very thin borderline
 121     borderlineOpacity *= min(1.0, borderlineWidth);
 122   }
 123
 124   lowp vec3  borderlineColorRGB   = borderlineColor.rgb * uActorColor.rgb;
 125   lowp float borderlineColorAlpha = borderlineColor.a * uActorColor.a;
 126   // NOTE : color-visual is always not preMultiplied.
 127
 128   // Calculate inside of borderline when alpha is between (0.0  1.0). So we need to apply texture color.
 129   // If borderlineOpacity is exactly 0.0, we always use whole texture color. In this case, we don't need to run below code.
 130   // But if borderlineOpacity > 0.0 and borderlineColor.a == 0.0, we need to apply tCornerRadius.
 131   if(borderlineOpacity > 0.0 && borderlineColor.a * borderlineOpacity < 1.0)
 132   {
 133     mediump float tCornerRadius = -gCenterPosition + gPotentialRange;
 134     mediump float MaxTexturelinePotential = tCornerRadius + gPotentialRange;
 135     mediump float MinTexturelinePotential = tCornerRadius - gPotentialRange;
 136     if(potential > MaxTexturelinePotential)
 137     {
 138       // potential is out of texture range.
 139       textureColor = vec4(0.0);
 140     }
 141     else
 142     {
 143       // potential is in texture range.
 144       lowp float textureAlphaScale = mix(1.0, 0.0, smoothstep(MinTexturelinePotential, MaxTexturelinePotential, potential));
 145       textureColor.a *= textureAlphaScale;
 146       textureColor.rgb *= textureColor.a;
 147     }
 148
 149     // NOTE : color-visual is always not preMultiplied.
 150     borderlineColorAlpha *= borderlineOpacity;
 151     borderlineColorRGB *= borderlineColorAlpha;
 152     // We use pre-multiplied color to reduce operations.
 153     // In here, textureColor and borderlineColorRGB is pre-multiplied color now.
 154
 155     // Manual blend operation with premultiplied colors.
 156     // Final alpha = borderlineColorAlpha + (1.0 - borderlineColorAlpha) * textureColor.a.
 157     // (Final rgb * alpha) =  borderlineColorRGB + (1.0 - borderlineColorAlpha) * textureColor.rgb
 158     // If preMultipliedAlpha == 1.0, just return vec4(rgb*alpha, alpha)
 159     // Else, return vec4((rgb*alpha) / alpha, alpha)
 160
 161     lowp float finalAlpha = mix(textureColor.a, 1.0, borderlineColorAlpha);
 162     lowp vec3  finalMultipliedRGB = borderlineColorRGB + (1.0 - borderlineColorAlpha) * textureColor.rgb;
 163     // TODO : Need to find some way without division
 164     return vec4(finalMultipliedRGB / finalAlpha, finalAlpha);
 165   }
 166   return mix(textureColor, vec4(borderlineColorRGB, borderlineColorAlpha), borderlineOpacity);
 167 }
 168 #endif
 169
 170 #ifdef IS_REQUIRED_BLUR
 171 #elif defined(IS_REQUIRED_ROUNDED_CORNER)
 172 mediump float calculateCornerOpacity()
 173 {
 174   mediump float potential = gPotential;
 175
 176   // default opacity is 1.0
 177   mediump float opacity = 1.0;
 178
 179   // calculate borderline opacity by potential
 180   if(potential > gMaxOutlinePotential)
 181   {
 182     // potential is out of borderline range. just discard here
 183     discard;
 184   }
 185   else if(potential > gMinOutlinePotential)
 186   {
 187     opacity = 1.0 - smoothstep(gMinOutlinePotential, gMaxOutlinePotential, potential);
 188   }
 189   return opacity;
 190 }
 191 #endif
 192
 193 #ifdef IS_REQUIRED_BLUR
 194 mediump float calculateBlurOpacity()
 195 {
 196 // Don't use borderline!
 197   mediump vec2 v = gDiff;
 198   mediump float cy = gRadius + blurRadius;
 199   mediump float cr = gRadius + blurRadius;
 200
 201 #ifdef IS_REQUIRED_ROUNDED_CORNER
 202   // This routine make perfect circle. If corner radius is not exist, we don't consider prefect circle.
 203   cy = min(cy, min(vRectSize.x, vRectSize.y) - gRadius);
 204 #endif
 205   v = vec2(min(v.x, v.y), max(v.x, v.y));
 206   v = v + cy;
 207
 208   mediump float potential = 0.0;
 209   mediump float alias = min(gRadius, 1.0);
 210   mediump float potentialMin = cy + gRadius - blurRadius - alias;
 211   mediump float potentialMax = cy + gRadius + blurRadius + alias;
 212
 213   // move center of circles for reduce defact
 214   mediump float cyDiff = min(cy, 0.2 * blurRadius);
 215   cy -= cyDiff;
 216   cr += cyDiff;
 217
 218   mediump float diffFromBaseline = cy * v.y - (cy + cr) * v.x;
 219
 220   if(diffFromBaseline > 0.0)
 221   {
 222     // out of calculation bound.
 223     potential = v.y;
 224
 225     // for anti-alias when blurRaidus = 0.0
 226     mediump float heuristicBaselineScale = max(1.0 , cr * (cr + cy));
 227     mediump float potentialDiff = min(alias, diffFromBaseline / heuristicBaselineScale);
 228     potentialMin += potentialDiff;
 229     potentialMax -= potentialDiff;
 230   }
 231   else
 232   {
 233     // get some circle centered (x, x) and radius (r = cr / cy * x)
 234     // s.t. point v is on that circle
 235     // highest point of that circle is (x, x + r) and potential is x + r
 236
 237     // solve (v.x - x)^2 + (v.y - x)^2 = (cr / cy * x)^2
 238 #ifdef IS_REQUIRED_ROUNDED_CORNER
 239     // Note : lowspec HW cannot calculate here. need to reduce numeric error
 240     highp float A = (cr * cr - 2.0 * cy * cy);
 241     highp float B = cy * (v.x + v.y);
 242     highp float V = dot(v,v);
 243     highp float D = B * B + A * V;
 244     potential = V * (cr + cy) / (sqrt(D) + B);
 245 #else
 246     // We can simplify this value cause cy = 0.8 * blurRadius, cr = 1.2 * blurRadius
 247     // potential = 5.0*(sqrt(4.0*(v.x+v.y)^2 + dot(v,v)) - 2.0*(v.x+v.y));
 248     //           = 10.0*(v.x+v.y) * (sqrt(1.0 + (length(v) / (2.0*(v.x+v.y)))^2) - 1.0);
 249     //           = 10.0*(v.x+v.y) * (sqrt(1.25 - x + x^2) - 1.0);
 250     //          ~= 10.0*(v.x+v.y) * (0.11803399 - 0.44721360x + 0.35777088x^2 - 0.14310x^3 + O(x^5)) (Taylor series)
 251     //          ~= -1.0557281 * (v.x + v.y) + 2.236068 * length(v) - ~~~ (here, x <= 0.5 * (1.0 - sqrt(0.5)) < 0.1464467)
 252     // Note : This simplify need cause we should use it on lowspec HW.
 253     mediump float x = 0.5 * (1.0 - length(v) / (v.x + v.y));
 254     potential = -1.0557281 * (v.x + v.y) + 2.236068 * length(v) + 10.0 * (v.x + v.y) * (0.35777088 - 0.14310 * x) * x * x;
 255 #endif
 256   }
 257
 258   return 1.0 - smoothstep(potentialMin, potentialMax, potential);
 259 }
 260 #endif
 261
 262 void main()
 263 {
 264   lowp vec4 targetColor = vec4(mixColor, 1.0) * uColor;
 265
 266 #if defined(IS_REQUIRED_BLUR) || defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE)
 267   // skip most potential calculate for performance
 268   if(abs(vPosition.x) < vOptRectSize.x && abs(vPosition.y) < vOptRectSize.y)
 269   {
 270     OUT_COLOR = targetColor;
 271   }
 272   else
 273   {
 274     PreprocessPotential();
 275 #endif
 276
 277 #ifdef IS_REQUIRED_BLUR
 278 #elif defined(IS_REQUIRED_BORDERLINE)
 279     targetColor = convertBorderlineColor(targetColor);
 280 #endif
 281     OUT_COLOR = targetColor;
 282
 283 #ifdef IS_REQUIRED_BLUR
 284     mediump float opacity = calculateBlurOpacity();
 285     OUT_COLOR.a *= opacity;
 286 #elif defined(IS_REQUIRED_ROUNDED_CORNER)
 287     mediump float opacity = calculateCornerOpacity();
 288     OUT_COLOR.a *= opacity;
 289 #endif
 290
 291 #if defined(IS_REQUIRED_BLUR) || defined(IS_REQUIRED_ROUNDED_CORNER) || defined(IS_REQUIRED_BORDERLINE)
 292   }
 293 #endif
 294 }