dali-toolkit/internal/graphics/shaders/color-visual-blur-edge-shader.frag

   1 INPUT mediump vec2 vPosition;
   2 INPUT mediump vec2 vRectSize;
   3 INPUT mediump float vCornerRadius;
   4
   5 uniform lowp vec4 uColor;
   6 uniform lowp vec3 mixColor;
   7 uniform mediump float blurRadius;
   8
   9 void main()
  10 {
  11   OUT_COLOR = vec4(mixColor, 1.0) * uColor;
  12
  13   mediump vec2 v = abs(vPosition) - vRectSize;
  14   mediump float cy = vCornerRadius + blurRadius;
  15   mediump float cr = vCornerRadius + blurRadius;
  16
  17   cy = min(cy, min(vRectSize.x, vRectSize.y));
  18   v = vec2(min(v.x, v.y), max(v.x, v.y));
  19   v = v + cy;
  20
  21   mediump float blur = 1.0;
  22   mediump float potential = 0.0;
  23   mediump float alias = min(vCornerRadius, 1.0);
  24   mediump float potentialMin = cy + vCornerRadius - blurRadius - alias;
  25   mediump float potentialMax = cy + vCornerRadius + blurRadius + alias;
  26
  27   // move center of circles for reduce defact
  28   mediump float cyDiff = min(cy, 0.2 * blurRadius);
  29   cy -= cyDiff;
  30   cr += cyDiff;
  31
  32   mediump float diffFromBaseline = cy * v.y - (cy + cr) * v.x;
  33
  34   if(diffFromBaseline > 0.0)
  35   {
  36     // out of calculation bound.
  37     potential = v.y;
  38
  39     // for anti-alias when blurRaidus = 0.0
  40     mediump float heuristicBaselineScale = max(1.0 , cr * (cr + cy));
  41     mediump float potentialDiff = min(alias, diffFromBaseline / heuristicBaselineScale);
  42     potentialMin += potentialDiff;
  43     potentialMax -= potentialDiff;
  44   }
  45   else
  46   {
  47     // get some circle centered (x, x) and radius (r = cr / cy * x)
  48     // s.t. point v is on that circle
  49     // highest point of that circle is (x, x + r) and potential is x + r
  50
  51     // solve (v.x - x)^2 + (v.y - x)^2 = (cr / cy * x)^2
  52
  53     mediump float A = (cr * cr - 2.0 * cy * cy);
  54     mediump float B = cy * (v.x + v.y);
  55     mediump float V = dot(v,v);
  56     mediump float D = B * B + A * V;
  57     potential = V * (cr + cy) / (sqrt(D) + B);
  58   }
  59
  60   blur = 1.0 - smoothstep(potentialMin, potentialMax, potential);
  61   OUT_COLOR.a *= blur;
  62 }