dali-toolkit/internal/graphics/shaders/color-visual-blur-edge-shader.frag

   1 INPUT mediump vec2 vPosition;
   2 INPUT mediump vec2 vRectSize;
   3 INPUT mediump vec2 vOptRectSize;
   4 INPUT mediump vec4 vCornerRadius;
   5
   6 uniform lowp vec4 uColor;
   7 uniform lowp vec3 mixColor;
   8 uniform mediump float blurRadius;
   9
  10 void main()
  11 {
  12   OUT_COLOR = vec4(mixColor, 1.0) * uColor;
  13   if(abs(vPosition.x) < vOptRectSize.x && abs(vPosition.y) < vOptRectSize.y)
  14   {
  15     return;
  16   }
  17
  18   mediump float radius =
  19   mix(
  20     mix(vCornerRadius.x, vCornerRadius.y, sign(vPosition.x) * 0.5 + 0.5),
  21     mix(vCornerRadius.w, vCornerRadius.z, sign(vPosition.x) * 0.5 + 0.5),
  22     sign(vPosition.y) * 0.5 + 0.5
  23   );
  24
  25   mediump vec2 v = abs(vPosition) - vRectSize + radius;
  26   mediump float cy = radius + blurRadius;
  27   mediump float cr = radius + blurRadius;
  28
  29   cy = min(cy, min(vRectSize.x, vRectSize.y) - radius);
  30   v = vec2(min(v.x, v.y), max(v.x, v.y));
  31   v = v + cy;
  32
  33   mediump float blur = 1.0;
  34   mediump float potential = 0.0;
  35   mediump float alias = min(radius, 1.0);
  36   mediump float potentialMin = cy + radius - blurRadius - alias;
  37   mediump float potentialMax = cy + radius + blurRadius + alias;
  38
  39   // move center of circles for reduce defact
  40   mediump float cyDiff = min(cy, 0.2 * blurRadius);
  41   cy -= cyDiff;
  42   cr += cyDiff;
  43
  44   mediump float diffFromBaseline = cy * v.y - (cy + cr) * v.x;
  45
  46   if(diffFromBaseline > 0.0)
  47   {
  48     // out of calculation bound.
  49     potential = v.y;
  50
  51     // for anti-alias when blurRaidus = 0.0
  52     mediump float heuristicBaselineScale = max(1.0 , cr * (cr + cy));
  53     mediump float potentialDiff = min(alias, diffFromBaseline / heuristicBaselineScale);
  54     potentialMin += potentialDiff;
  55     potentialMax -= potentialDiff;
  56   }
  57   else
  58   {
  59     // get some circle centered (x, x) and radius (r = cr / cy * x)
  60     // s.t. point v is on that circle
  61     // highest point of that circle is (x, x + r) and potential is x + r
  62
  63     // solve (v.x - x)^2 + (v.y - x)^2 = (cr / cy * x)^2
  64
  65     mediump float A = (cr * cr - 2.0 * cy * cy);
  66     mediump float B = cy * (v.x + v.y);
  67     mediump float V = dot(v,v);
  68     mediump float D = B * B + A * V;
  69     potential = V * (cr + cy) / (sqrt(D) + B);
  70   }
  71
  72   blur = 1.0 - smoothstep(potentialMin, potentialMax, potential);
  73   OUT_COLOR.a *= blur;
  74 }