dali-toolkit/internal/graphics/shaders/bubble-effect-color-adjuster.frag

   1 precision highp float;
   2 uniform vec3 uHSVDelta;
   3 uniform float uIgnoreAlpha;
   4 varying mediump vec2 vTexCoord;
   5 uniform sampler2D sTexture;
   6
   7 float rand(vec2 co)
   8 {
   9   return fract(sin(dot(co.xy ,vec2(12.9898,78.233))) * 43758.5453);
  10 }
  11
  12 vec3 rgb2hsv(vec3 c)
  13 {
  14   vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
  15   vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
  16   vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));
  17
  18   float d = q.x - min(q.w, q.y);
  19   float e = 1.0e-10;
  20   return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
  21 }
  22
  23 vec3 hsv2rgb(vec3 c)
  24 {
  25   vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
  26   vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
  27   return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
  28 }
  29
  30 void main()
  31 {
  32   vec4 color = texture2D(sTexture, vTexCoord);
  33   vec3 hsvColor = rgb2hsv( color.rgb );
  34   // modify the hsv Value
  35   hsvColor += uHSVDelta * rand(vTexCoord);
  36   // if the new vale exceeds one, then decrease it
  37   hsvColor -= max(hsvColor*2.0 - vec3(2.0), 0.0);
  38   // if the new vale drops below zero, then increase it
  39   hsvColor -= min(hsvColor*2.0, 0.0);
  40   color.rgb = hsv2rgb( hsvColor );
  41   // uIgnoreAlpha decide the result alpha will be 1.0 or source's alpha
  42   color.a += uIgnoreAlpha;
  43   gl_FragColor = color;
  44 }