build/tizen/dali-scene-loader/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 set(name "dali2-scene-loader")
   3
   4 project(${name} CXX)
   5
   6 set(${name}_VERSION_MAJOR 2)
   7 set(${name}_VERSION_MINOR 0)
   8 set(${name}_VERSION_PATCH 0)
   9 set(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  10
  11 SET(DALI_SCENE_LOADER_VERSION ${${name}_VERSION} )
  12
  13 if(CMAKE_BUILD_TYPE MATCHES Debug)
  14         add_definitions("-DDEBUG_ENABLED")
  15 endif()
  16
  17 ADD_DEFINITIONS( "-DBUILDING_DALI_SCENE_LOADER" )
  18
  19 foreach(flag ${PKGS_CFLAGS})
  20         set(extra_flags "${extra_flags} ${flag}")
  21 endforeach(flag)
  22
  23 set(prj_cxx_std c++17)
  24 if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
  25         set(extra_flags "${extra_flags} -fPIC -std=${prj_cxx_std}")
  26 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  27         set(extra_flags "${extra_flags} -fPIC -std=${prj_cxx_std}")
  28 elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  29         set(extra_flags "${extra_flags} /std:${prj_cxx_std} /vmg /D_USE_MATH_DEFINES /D_CRT_SECURE_NO_WARNINGS /MP /GS /Oi /GL /EHsc")
  30 endif()
  31
  32 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${extra_flags}")
  33
  34 set(prefix ${CMAKE_INSTALL_PREFIX})
  35
  36 set(repo_root_dir "${CMAKE_CURRENT_LIST_DIR}/../../../")
  37 set(scene_loader_dir "${repo_root_dir}/dali-scene-loader")
  38
  39 option(ENABLE_PKG_CONFIGURE "Use pkgconfig" ON)
  40 option(ENABLE_COVERAGE "Coverage" OFF)
  41
  42 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
  43   ADD_COMPILE_OPTIONS( --coverage )
  44   SET(ENABLE_COVERAGE ON)
  45   SET(COVERAGE --coverage)
  46 ENDIF()
  47
  48 if (ENABLE_PKG_CONFIGURE)
  49         find_package(PkgConfig REQUIRED)
  50
  51         pkg_check_modules(DALICORE REQUIRED dali2-core)
  52         pkg_check_modules(DALIADAPTOR REQUIRED dali2-adaptor)
  53
  54         # Configure the pkg-config file
  55         # Requires the following variables to be setup:
  56         # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  57         set( LIB_DIR $ENV{libdir} )
  58         if( NOT LIB_DIR )
  59                 set( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  60         endif()
  61         if( NOT LIB_DIR )
  62                 set( LIB_DIR ${prefix}/lib )
  63         endif()
  64
  65         set(PREFIX ${prefix})
  66         set(EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  67         set(DEV_INCLUDE_PATH ${INCLUDE_DIR})
  68
  69         set(core_pkg_cfg_file dali2-scene-loader.pc)
  70         configure_file(${CMAKE_CURRENT_LIST_DIR}/${core_pkg_cfg_file}.in ${core_pkg_cfg_file} @ONLY)
  71 endif()
  72
  73 set(scene_loader_src_files "")
  74 include("${scene_loader_dir}/internal/file.list")
  75 include("${scene_loader_dir}/public-api/file.list")
  76
  77 set(prefix_include_dir "${prefix}/include")
  78 include_directories(${repo_root_dir}
  79         ${prefix_include_dir}
  80 )
  81
  82 # Generate source files for shaders
  83 SET(SHADER_SOURCE_DIR "${scene_loader_dir}/internal/graphics/shaders/")
  84 SET(SHADER_GENERATED_DIR "${scene_loader_dir}/internal/graphics/generated")
  85
  86 SET(GENERATED_SHADER_DIR ${scene_loader_dir}/internal/graphics/)
  87 SET_PROPERTY(DIRECTORY PROPERTY ADDITIONAL_MAKE_CLEAN_FILES
  88              "${GENERATED_SHADER_DIR}/generated/"
  89              "${GENERATED_SHADER_DIR}/builtin-shader-extern-gen.h")
  90
  91 IF( WIN32)
  92   # When Using VCPKG, the default is always set to Debug if CMAKE_BUILD_TYPE is not set
  93   IF( NOT CMAKE_BUILD_TYPE )
  94     SET(SHADER_GENERATOR_BINARY ${CMAKE_CURRENT_BINARY_DIR}/../Debug/${SHADER_GENERATOR_NAME})
  95   ELSE()
  96     SET(SHADER_GENERATOR_BINARY ${CMAKE_CURRENT_BINARY_DIR}/../${CMAKE_BUILD_TYPE}/${SHADER_GENERATOR_NAME})
  97   ENDIF()
  98 ELSE()
  99   SET(SHADER_GENERATOR_BINARY ${CMAKE_CURRENT_BINARY_DIR}/../${SHADER_GENERATOR_NAME})
 100 ENDIF()
 101
 102 SET( BUILT_IN_SHADER_GEN_CPP "${GENERATED_SHADER_DIR}/generated/builtin-shader-gen.cpp")
 103 ADD_CUSTOM_COMMAND(OUTPUT ${BUILT_IN_SHADER_GEN_CPP}
 104                    DEPENDS ${SHADER_GENERATOR_BINARY}
 105                    COMMAND ${SHADER_GENERATOR_BINARY} ${SHADER_SOURCE_DIR} ${SHADER_GENERATED_DIR})
 106
 107 SET( scene_loader_src_files ${scene_loader_src_files} ${BUILT_IN_SHADER_GEN_CPP} )
 108
 109 add_library(${name} SHARED ${scene_loader_src_files})
 110
 111 target_link_libraries(${name} ${DALICORE_LDFLAGS} ${DALIADAPTOR_LDFLAGS}
 112         dali2-toolkit
 113         ${COVERAGE})
 114
 115 if( ANDROID )
 116         target_link_libraries(${name} log)
 117 endif()
 118
 119 IF( INSTALL_CMAKE_MODULES )
 120         SET_TARGET_PROPERTIES( ${name}
 121                 PROPERTIES
 122                 VERSION ${DALI_SCENE_LOADER_VERSION}
 123                 SOVERSION ${${name}_VERSION_MAJOR}
 124                 CLEAN_DIRECT_OUPUT 1
 125         )
 126
 127         IF( ENABLE_DEBUG )
 128                 SET( BIN_DIR "${BIN_DIR}/debug" )
 129                 SET( LIB_DIR "${LIB_DIR}/debug" )
 130         ENDIF()
 131
 132         # Install the library files.
 133         INSTALL( TARGETS ${name}
 134                 EXPORT ${name}-targets
 135                 LIBRARY DESTINATION ${LIB_DIR}
 136                 ARCHIVE DESTINATION ${LIB_DIR}
 137                 RUNTIME DESTINATION ${BIN_DIR}
 138         )
 139
 140         # Install the cmake modules.
 141         INSTALL(
 142                 EXPORT ${name}-targets
 143                 NAMESPACE ${name}::
 144                 FILE ${name}-targets.cmake
 145                 DESTINATION share/${name}
 146         )
 147
 148         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 149                 include(CMakeFindDependencyMacro)
 150                 include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 151         ")
 152         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 153
 154         # Install the pdb file.
 155         IF( ENABLE_DEBUG AND WIN32 )
 156                 install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 157         ENDIF()
 158 ELSE()
 159         # Install the library so file and symlinks
 160         INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 161 ENDIF()
 162
 163 file(GLOB scene_loader_include_files ${scene_loader_public_api_dir})
 164 install(DIRECTORY ${scene_loader_include_files}
 165         DESTINATION "${prefix_include_dir}/dali-scene-loader"
 166         FILES_MATCHING PATTERN "*.h"
 167 )
 168
 169 if (ENABLE_PKG_CONFIGURE)
 170         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${core_pkg_cfg_file}
 171                 DESTINATION ${LIB_DIR}/pkgconfig
 172         )
 173 endif()