build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-toolkit")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   endif()
  16 endif()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  23
  24 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  28 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  29 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
  30 OPTION(ENABLE_I18N               "Turns on internationalisation" OFF)
  31 OPTION(ENABLE_COVERAGE           "Coverage" OFF)
  32 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  33 OPTION(ENABLE_LINK_TEST          "Enable the link test" ON)
  34 OPTION(INSTALL_DOXYGEN_DOC       "Install doxygen doc" ON)
  35 OPTION(CONFIGURE_AUTOMATED_TESTS "Configure automated tests" ON)
  36 OPTION(USE_DEFAULT_RESOURCE_DIR  "Whether to use the default resource folders. Otherwise set environment variables for DALI_IMAGE_DIR, DALI_SOUND_DIR, DALI_STYLE_DIR, DALI_STYLE_IMAGE_DIR and DALI_DATA_READ_ONLY_DIR" ON)
  37 OPTION(BUILD_SCENE_LOADER        "Whether to build dali-scene-loader." ON)
  38
  39 IF( ENABLE_PKG_CONFIGURE )
  40   FIND_PACKAGE( PkgConfig REQUIRED )
  41
  42   PKG_CHECK_MODULES(DALICORE REQUIRED dali2-core)
  43   PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali2-adaptor)
  44 ENDIF()
  45
  46 IF( INSTALL_DOXYGEN_DOC )
  47   FIND_PACKAGE( Doxygen QUIET )
  48 ENDIF()
  49
  50 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  51   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  52   FIND_PACKAGE( dali2-core REQUIRED)
  53   FIND_PACKAGE( dali2-adaptor REQUIRED)
  54 ENDIF()
  55
  56 IF ( APPLE )
  57   FIND_PACKAGE( dali2-core REQUIRED)
  58   FIND_PACKAGE( dali2-adaptor REQUIRED)
  59 ENDIF()
  60
  61 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  62
  63 # Define non-boolean options to CMake
  64 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  65
  66 # from root/build/tizen, get back to root
  67 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  68
  69 # Deployment folder should come from spec file or command line:
  70 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  71 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  72
  73 # Make sure the path is absolute
  74 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  75
  76 # Set DALi style
  77 SET( dali_style ${WITH_STYLE} )
  78
  79 # Style folder
  80 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  81 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  82
  83 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  84 SET( toolkit_styles_dir ${STYLE_DIR} )
  85 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  86
  87 IF( DEFINED ENV{DALI_DATA_RW_DIR} )
  88   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR} )
  89 ELSE()
  90   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  91 ENDIF()
  92
  93 IF( DEFINED ENV{DALI_DATA_RO_DIR} )
  94   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR} )
  95 ELSE()
  96   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  97 ENDIF()
  98
  99 # Set up compiler definitions
 100
 101 IF(CMAKE_BUILD_TYPE MATCHES Debug)
 102   SET( ENABLE_DEBUG ON )
 103 ENDIF()
 104
 105 IF( ENABLE_DEBUG )
 106   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
 107   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
 108   SET( ENABLE_EXPORTALL ON )
 109 ELSE()
 110   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
 111 ENDIF()
 112
 113 IF( ENABLE_I18N )
 114   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
 115 ENDIF( ENABLE_I18N )
 116
 117 IF( WIN32 )
 118   ADD_DEFINITIONS( "-DBUILDING_DALI_TOOLKIT" )
 119
 120   IF( USE_DEFAULT_RESOURCE_DIR )
 121     SET( INSTALL_SHARE_DIR "${PREFIX}/share" )
 122     IF( VCPKG_TOOLKIT_BUILD )
 123       SET( INSTALL_SHARE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/share" )
 124     ENDIF()
 125
 126     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/images/\"
 127                      -DDALI_SOUND_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/sounds/\"
 128                      -DDALI_STYLE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/\"
 129                      -DDALI_STYLE_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/images/\"
 130                      -DDALI_DATA_READ_ONLY_DIR=\"${INSTALL_SHARE_DIR}/\" )
 131   ENDIF()
 132 ELSEIF( UNIX )
 133   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
 134   IF( USE_DEFAULT_RESOURCE_DIR )
 135     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
 136                      -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
 137                      -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
 138                      -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
 139                      -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
 140   ENDIF()
 141
 142   IF("${ARCH}" STREQUAL "arm")
 143     ADD_DEFINITIONS("-DTARGET")
 144   ENDIF("${ARCH}" STREQUAL "arm")
 145
 146   IF( NOT ${ENABLE_EXPORTALL} )
 147     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 148   ENDIF( NOT ${ENABLE_EXPORTALL} )
 149 ENDIF()
 150
 151 IF( NOT USE_DEFAULT_RESOURCE_DIR )
 152   ADD_DEFINITIONS( -DDALI_IMAGE_DIR=0
 153                    -DDALI_SOUND_DIR=0
 154                    -DDALI_STYLE_DIR=0
 155                    -DDALI_STYLE_IMAGE_DIR=0
 156                    -DDALI_DATA_READ_ONLY_DIR=0 )
 157 ENDIF()
 158
 159 IF( ENABLE_TRACE )
 160   ADD_DEFINITIONS("-DTRACE_ENABLED")
 161 ENDIF()
 162
 163 # Remove below when thorvg is ready
 164 ADD_DEFINITIONS( "-DNO_THORVG" )
 165
 166 # Set paths
 167 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 168 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 169 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 170 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 171 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 172 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 173 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 174
 175 # Set up the include dir
 176 SET( INCLUDE_DIR $ENV{includedir} )
 177 IF( NOT INCLUDE_DIR )
 178   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 179 ENDIF()
 180 IF( NOT INCLUDE_DIR )
 181   SET( INCLUDE_DIR ${PREFIX}/include )
 182 ENDIF()
 183
 184 # Set up the lib dir
 185 SET( LIB_DIR $ENV{libdir} )
 186 IF( NOT LIB_DIR )
 187   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 188 ENDIF()
 189 IF( NOT LIB_DIR )
 190   SET( LIB_DIR ${PREFIX}/lib )
 191 ENDIF()
 192
 193 # Set up the bin dir
 194 SET( BIN_DIR $ENV{bindir} )
 195 IF( NOT BIN_DIR )
 196   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 197 ENDIF()
 198 IF( NOT BIN_DIR )
 199   SET( BIN_DIR ${PREFIX}/bin )
 200 ENDIF()
 201
 202 IF( ENABLE_PKG_CONFIGURE )
 203   # Configure the pkg-config file
 204   # Requires the following variables to be setup:
 205   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 206   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 207   SET( CORE_PKG_CFG_FILE dali2-toolkit.pc )
 208   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 209 ENDIF()
 210
 211 IF( WIN32 )
 212   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 213   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 214   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 215 ELSE()
 216   INCLUDE(CheckCXXCompilerFlag)
 217
 218   # Set up compiler flags and warnings
 219   ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 220
 221   # TODO: Clang is a lot more strict with warnings, we should address
 222   # those issues at some point.
 223   # Matches "Clang" or "AppleClang"
 224   IF( NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 225     ADD_COMPILE_OPTIONS( -Werror )
 226   ENDIF()
 227
 228   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal )
 229   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal )
 230   CHECK_CXX_COMPILER_FLAG(-Wno-class-memaccess HAVE_NO_CLASS_MEMACCESS)
 231   IF (HAVE_NO_CLASS_MEMACCESS)
 232     ADD_COMPILE_OPTIONS( -Wno-class-memaccess )
 233   ENDIF()
 234
 235   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 236     ADD_COMPILE_OPTIONS( --coverage )
 237     SET(ENABLE_COVERAGE ON)
 238     SET(COVERAGE --coverage)
 239   ENDIF()
 240
 241   IF( NOT ${ENABLE_EXPORTALL} )
 242     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 243   ENDIF( NOT ${ENABLE_EXPORTALL} )
 244 ENDIF()
 245
 246
 247 INCLUDE_DIRECTORIES(
 248   ${ROOT_SRC_DIR}
 249   ${DALICORE_INCLUDE_DIRS}
 250   ${DALIADAPTOR_INCLUDE_DIRS}
 251   ${VCPKG_INCLUDE_DIR}
 252   ${INCLUDE_DIR}
 253 )
 254
 255 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 256 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 257
 258 SET(SOURCES "")
 259
 260 # could use INCLUDE to get the source lists a different way;
 261 # would then need to specify a build folder somehow...
 262 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
 263 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
 264 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
 265 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
 266 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
 267 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
 268 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
 269 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 270
 271 # Platforms with highp shader support can use vector based text
 272 IF( NOT DEFINED ENABLE_VECTOR_BASED_TEXT_RENDERING )
 273   SET(ENABLE_VECTOR_BASED_TEXT_RENDERING ON)
 274 ENDIF()
 275
 276 IF( ENABLE_VECTOR_BASED_TEXT_RENDERING )
 277   ADD_DEFINITIONS( "-DENABLE_VECTOR_BASED_TEXT_RENDERING" )
 278   INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/text/rendering/vector-based/file.list )
 279 ENDIF()
 280
 281 SET(LIBTYPE SHARED)
 282 IF(DEFINED STATIC)
 283   SET(LIBTYPE STATIC)
 284 ENDIF()
 285
 286 # Generate source files for shaders
 287 SET(SHADER_SOURCE_DIR "${ROOT_SRC_DIR}/dali-toolkit/internal/graphics/shaders/")
 288 SET(SHADER_GENERATED_DIR "${ROOT_SRC_DIR}/dali-toolkit/internal/graphics/generated")
 289
 290 SET(GENERATED_SHADER_DIR ${ROOT_SRC_DIR}/dali-toolkit/internal/graphics/)
 291 SET_PROPERTY(DIRECTORY PROPERTY ADDITIONAL_MAKE_CLEAN_FILES
 292              "${GENERATED_SHADER_DIR}/generated/"
 293              "${GENERATED_SHADER_DIR}/builtin-shader-extern-gen.h")
 294
 295 SET(SHADER_GENERATOR_NAME dali-shader-generator)
 296 SET(SHADER_GENERATOR_SOURCES ${ROOT_SRC_DIR}/dali-toolkit/shader-generator/shader-generator.cpp)
 297
 298 IF(NOT ANDROID)
 299   ADD_EXECUTABLE(${SHADER_GENERATOR_NAME} ${SHADER_GENERATOR_SOURCES})
 300   INSTALL(TARGETS ${SHADER_GENERATOR_NAME} RUNTIME DESTINATION bin)
 301 ELSE()
 302   # Need to build dali-shader-generator using the host compiler, not the android cross-compiler so
 303   # that it can be run on the host machine
 304   OPTION(ANDROID_HOST_COMPILER "Provide the host compiler used by Android (Mandatory)")
 305   IF(${ANDROID_HOST_COMPILER} STREQUAL "OFF")
 306     MESSAGE(FATAL_ERROR "-DANDROID_HOST_COMPILER=\"Compiler\" must be set")
 307   ENDIF()
 308
 309   ADD_CUSTOM_COMMAND(OUTPUT ${SHADER_GENERATOR_NAME}
 310                      COMMAND ${ANDROID_HOST_COMPILER} -o ${CMAKE_CURRENT_BINARY_DIR}/${SHADER_GENERATOR_NAME} -std=c++17 ${SHADER_GENERATOR_SOURCES})
 311   INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/${SHADER_GENERATOR_NAME}
 312           PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
 313           DESTINATION bin)
 314 ENDIF()
 315
 316 SET(BUILT_IN_SHADER_GEN_CPP "${GENERATED_SHADER_DIR}/generated/builtin-shader-gen.cpp")
 317 ADD_CUSTOM_COMMAND(OUTPUT ${BUILT_IN_SHADER_GEN_CPP}
 318                    DEPENDS ${SHADER_GENERATOR_NAME}
 319                    COMMAND ${CMAKE_CURRENT_BINARY_DIR}/${SHADER_GENERATOR_NAME} ${SHADER_SOURCE_DIR} ${SHADER_GENERATED_DIR})
 320
 321 SET(SOURCES ${SOURCES} ${BUILT_IN_SHADER_GEN_CPP})
 322
 323 IF( WIN32 OR APPLE )
 324   SET( DALICORE_LDFLAGS
 325         "${DALICORE_LDFLAGS}"
 326         dali2-core::dali2-core )
 327
 328   FIND_PACKAGE( curl REQUIRED )
 329   FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 330   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 331
 332   FIND_PACKAGE( png REQUIRED )
 333   FIND_PACKAGE( gif REQUIRED )
 334   FIND_PACKAGE( jpeg REQUIRED )
 335   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 336
 337   FIND_PACKAGE( freetype REQUIRED )
 338   FIND_PACKAGE( harfbuzz REQUIRED )
 339   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 340
 341   FIND_PACKAGE( unofficial-angle REQUIRED )
 342
 343   IF(WIN32)
 344     FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 345   ENDIF()
 346
 347   FIND_PACKAGE( unofficial-cairo REQUIRED )
 348   FIND_PACKAGE( WebP REQUIRED )
 349
 350   SET( DALIADAPTOR_LDFLAGS
 351        "${DALIADAPTOR_LDFLAGS}"
 352        dali2-adaptor::dali2-adaptor )
 353 ENDIF()
 354
 355 IF ( WIN32 )
 356   FIND_PACKAGE( pthreads REQUIRED )
 357 ENDIF()
 358
 359 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 360 TARGET_LINK_LIBRARIES( ${name}
 361   ${DALICORE_LDFLAGS}
 362   ${DALIADAPTOR_LDFLAGS}
 363   ${COVERAGE}
 364 )
 365
 366 IF( ANDROID )
 367   TARGET_LINK_LIBRARIES( ${name} log )
 368 ENDIF()
 369
 370 SET_TARGET_PROPERTIES( ${name}
 371   PROPERTIES
 372   VERSION ${DALI_TOOLKIT_VERSION}
 373   SOVERSION ${${name}_VERSION_MAJOR}
 374   CLEAN_DIRECT_OUPUT 1
 375 )
 376
 377 IF( INSTALL_CMAKE_MODULES )
 378   IF( ENABLE_DEBUG )
 379     SET( BIN_DIR "${BIN_DIR}/debug" )
 380     SET( LIB_DIR "${LIB_DIR}/debug" )
 381   ENDIF()
 382
 383   # Install the library files.
 384   INSTALL( TARGETS ${name}
 385     EXPORT ${name}-targets
 386     LIBRARY DESTINATION ${LIB_DIR}
 387     ARCHIVE DESTINATION ${LIB_DIR}
 388     RUNTIME DESTINATION ${BIN_DIR}
 389   )
 390
 391   # Install the cmake modules.
 392   INSTALL(
 393     EXPORT ${name}-targets
 394     NAMESPACE ${name}::
 395     FILE ${name}-targets.cmake
 396     DESTINATION share/${name}
 397   )
 398
 399   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 400     include(CMakeFindDependencyMacro)
 401     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 402   ")
 403   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 404
 405   # Install the pdb file.
 406   IF( ENABLE_DEBUG AND WIN32 )
 407     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 408   ENDIF()
 409 ELSE()
 410   # Install the library so file and symlinks
 411   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 412 ENDIF()
 413
 414 # Install the pkg-config file
 415 IF( ENABLE_PKG_CONFIGURE )
 416   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 417 ENDIF()
 418
 419 # Glob for resources
 420 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 421   FOREACH( PATTERN ${FILE_LIST} )
 422     FILE(GLOB FILES ${PATTERN} )
 423     FOREACH( FILE ${FILES} )
 424       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 425       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 426       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 427         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 428         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 429       ELSE()
 430         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 431       ENDIF()
 432     ENDFOREACH()
 433   ENDFOREACH()
 434 ENDMACRO()
 435
 436 # macro for installing headers by replacing prefix. (TODO, investigate
 437 # if there is a CMAKE way of doing this automatically)
 438 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 439   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 440   FOREACH(HEADER ${${HEADER_LIST}})
 441     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 442     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 443     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 444   ENDFOREACH(HEADER)
 445 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 446
 447 # Install headers using lists defined by ADD_SUBDIRECTORY
 448 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 449 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 450 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 451 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 452
 453 # Install dali-toolkit.h
 454 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${INCLUDE_DIR}/dali-toolkit )
 455
 456 # package doxygen file (contains doxygen grouping information)
 457 INSTALL( FILES ${package_doxy_files} DESTINATION ${INCLUDE_DIR}/dali-toolkit/doc )
 458
 459 # On some platforms we want to install the data files to different location compare to
 460 # the data location used runtime. For example, on Android we want the toolkit library to load
 461 # the files from /data/data/com.sec.dali_demo/files but to install the files into ${PREFIX}/files
 462 # for SDK to pick them up for the archive.
 463 IF( DEFINED ENV{DALI_DATA_RW_INSTALL_DIR} )
 464   SET( dataReadWriteInstallDir $ENV{DALI_DATA_RW_INSTALL_DIR} )
 465 ELSE()
 466   SET( dataReadWriteInstallDir ${dataReadWriteDir} )
 467 ENDIF()
 468
 469 IF( DEFINED ENV{DALI_DATA_RO_INSTALL_DIR} )
 470   SET( dataReadOnlyInstallDir $ENV{DALI_DATA_RO_INSTALL_DIR} )
 471 ELSE()
 472   SET( dataReadOnlyInstallDir ${dataReadOnlyDir} )
 473 ENDIF()
 474
 475 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles" )
 476 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/images" )
 477 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/sounds" )
 478 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles/images" )
 479
 480 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
 481 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 482 # target names duplication with other DALi modules.
 483 IF( ENABLE_COVERAGE )
 484   FIND_PROGRAM( LCOV_BIN "lcov" )
 485   IF( LCOV_BIN )
 486
 487     # Define custom rules for coverage
 488     SET(COVERAGE_DIR .cov)
 489     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 490
 491     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 492     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 493     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 494     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 495     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 496       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 497     ENDIF()
 498
 499     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
 500
 501     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 502       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"*/dali-env/*\" \"*solid-color-actor*\" \"*/dali-toolkit/third-party/*\" \"*/dali-scene-loader/third-party/*\" -o dali.info )
 503
 504     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml -p ${ROOT_SRC_DIR} ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 505       DEPENDS cov_data )
 506
 507     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 508
 509     # Define custom rule for distclean
 510     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
 511     ADD_CUSTOM_COMMAND(
 512           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
 513           COMMENT "distribution clean"
 514           COMMAND find
 515           ARGS    .
 516           -not -name config.cmake -and \(
 517           -name tester.c -or
 518           -name Testing -or
 519           -name CMakeFiles -or
 520           -name doc -or
 521           -name cmake.depends -or
 522           -name cmake.check_depends -or
 523           -name CMakeCache.txt -or
 524           -name cmake.check_cache -or
 525           -name *.cmake -or
 526           -name Makefile -or
 527           -name core -or
 528           -name core.* -or
 529           -name gmon.out -or
 530           -name install_manifest.txt -or
 531           -name *.pc -or
 532           -name *.gcov -or
 533           -name *.gcno -or
 534           -name *.gcda -or
 535           -name *~ -or
 536           -name libdali*.so* \)
 537           | grep -v TC | xargs rm -rf
 538           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
 539           VERBATIM
 540           )
 541
 542   ENDIF( LCOV_BIN )
 543 ENDIF()
 544
 545 IF ( BUILD_SCENE_LOADER )
 546   ADD_SUBDIRECTORY( ${CMAKE_CURRENT_SOURCE_DIR}/dali-scene-loader )
 547 ENDIF()
 548
 549
 550 # Build documentation if doxygen tool is available
 551 SET( doxygenEnabled OFF )
 552 IF( DOXYGEN_FOUND )
 553   SET( doxygenEnabled ON )
 554   # 'prefix' is used by doxygen in-files.
 555   SET( prefix ${PREFIX} )
 556   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 557   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 558   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 559   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 560   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 561   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 562
 563   IF ( BUILD_SCENE_LOADER )
 564     ADD_CUSTOM_TARGET( doc_doxygen ALL
 565       DEPENDS ${name} dali2-scene-loader
 566       COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 567       COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 568       COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 569       COMMENT "Generating API documentation with Doxygen"
 570       WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 571       VERBATIM )
 572   ELSE()
 573     ADD_CUSTOM_TARGET( doc_doxygen ALL
 574       DEPENDS ${name}
 575       COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 576       COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 577       COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 578       COMMENT "Generating API documentation with Doxygen"
 579       WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 580       VERBATIM )
 581   ENDIF()
 582
 583   # Following target is optional - it doesn't run by default
 584   # Build using "make doc_doxygen_internal".
 585   ADD_CUSTOM_TARGET( doc_doxygen_internal
 586                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 587                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 588                      COMMENT "Generating Internal API documentation with Doxygen"
 589                      VERBATIM )
 590
 591 ENDIF()
 592
 593 IF( CONFIGURE_AUTOMATED_TESTS )
 594   # Configure automated tests
 595   CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 596                   ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 597 ENDIF()
 598
 599
 600 # Configuration Messages
 601 MESSAGE( STATUS "Configuration:\n" )
 602 MESSAGE( STATUS "Prefix:                        " ${PREFIX} )
 603 MESSAGE( STATUS "Lib Dir:                       " ${LIB_DIR} )
 604 MESSAGE( STATUS "Include Dir:                   " ${INCLUDE_DIR} )
 605 MESSAGE( STATUS "Debug build:                   " ${ENABLE_DEBUG} )
 606 MESSAGE( STATUS "Export all symbols:            " ${ENABLE_EXPORTALL} )
 607 MESSAGE( STATUS "Coverage:                      " ${ENABLE_COVERAGE} )
 608 MESSAGE( STATUS "Trace:                         " ${ENABLE_TRACE} )
 609 MESSAGE( STATUS "Doxygen:                       " ${doxygenEnabled} )
 610 MESSAGE( STATUS "Data Dir (Read/Write):         " ${dataReadWriteDir} )
 611 MESSAGE( STATUS "Data Dir (Read Only):          " ${dataReadOnlyDir} )
 612 MESSAGE( STATUS "Data Install Dir (Read/Write): " ${dataReadWriteInstallDir} )
 613 MESSAGE( STATUS "Data Install Dir (Read Only):  " ${dataReadOnlyInstallDir} )
 614 MESSAGE( STATUS "Style Dir:                     " ${STYLE_DIR} )
 615 MESSAGE( STATUS "Style:                         " ${dali_style} )
 616 MESSAGE( STATUS "i18n:                          " ${ENABLE_I18N} )
 617 MESSAGE( STATUS "Use pkg configure:             " ${ENABLE_PKG_CONFIGURE} )
 618 MESSAGE( STATUS "Vector Based Text Rendering:   " ${ENABLE_VECTOR_BASED_TEXT_RENDERING} )
 619 MESSAGE( STATUS "Enable link test:              " ${ENABLE_LINK_TEST} )
 620 MESSAGE( STATUS "Configure automated tests:     " ${CONFIGURE_AUTOMATED_TESTS} )
 621 MESSAGE( STATUS "Build Dali Scene Loader:       " ${BUILD_SCENE_LOADER} )
 622 MESSAGE( STATUS "CXXFLAGS:                      " ${CMAKE_CXX_FLAGS} )
 623 MESSAGE( STATUS "LDFLAGS:                       " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )
 624
 625 MESSAGE( " Folder       INSTALL_SHARE_DIR : [" ${INSTALL_SHARE_DIR} "]" )
 626 MESSAGE( " Folder          DALI_IMAGE_DIR : [" ${DALI_IMAGE_DIR} "]" )
 627 MESSAGE( " Folder          DALI_STYLE_DIR : [" ${DALI_STYLE_DIR} "]" )
 628 MESSAGE( " Folder    DALI_STYLE_IMAGE_DIR : [" ${DALI_STYLE_IMAGE_DIR} "]" )
 629 MESSAGE( " Folder          DALI_SOUND_DIR : [" ${DALI_SOUND_DIR} "]" )
 630 MESSAGE( " Folder DALI_DATA_READ_ONLY_DIR : [" ${DALI_DATA_READ_ONLY_DIR} "]" )