build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-toolkit")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  10 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  11   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  12     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  13   endif()
  14 endif()
  15
  16 # API VERSION (Not DALi release version)
  17 SET(${name}_VERSION_MAJOR 2)
  18 SET(${name}_VERSION_MINOR 0)
  19 SET(${name}_VERSION_PATCH 0)
  20 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  21
  22 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  23
  24 # Define options to CMake
  25 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  26 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  27 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
  28 OPTION(ENABLE_I18N               "Turns on internationalisation" OFF)
  29 OPTION(ENABLE_COVERAGE           "Coverage" OFF)
  30 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  31 OPTION(ENABLE_LINK_TEST          "Enable the link test" ON)
  32 OPTION(INSTALL_DOXYGEN_DOC       "Install doxygen doc" ON)
  33 OPTION(CONFIGURE_AUTOMATED_TESTS "Configure automated tests" ON)
  34 OPTION(USE_DEFAULT_RESOURCE_DIR  "Whether to use the default resource folders. Otherwise set environment variables for DALI_IMAGE_DIR, DALI_SOUND_DIR, DALI_STYLE_DIR, DALI_STYLE_IMAGE_DIR and DALI_DATA_READ_ONLY_DIR" ON)
  35
  36 IF( ENABLE_PKG_CONFIGURE )
  37   FIND_PACKAGE( PkgConfig REQUIRED )
  38
  39   PKG_CHECK_MODULES(DALICORE REQUIRED dali2-core)
  40   PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali2-adaptor)
  41 ENDIF()
  42
  43 IF( INSTALL_DOXYGEN_DOC )
  44   FIND_PACKAGE( Doxygen QUIET )
  45 ENDIF()
  46
  47 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  48   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  49   FIND_PACKAGE( dali2-core REQUIRED)
  50   FIND_PACKAGE( dali2-adaptor REQUIRED)
  51 ENDIF()
  52
  53 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  54
  55 # Define non-boolean options to CMake
  56 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  57
  58 # from root/build/tizen, get back to root
  59 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  60
  61 # Deployment folder should come from spec file or command line:
  62 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  63 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  64
  65 # Make sure the path is absolute
  66 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  67
  68 # Set DALi style
  69 SET( dali_style ${WITH_STYLE} )
  70
  71 # Style folder
  72 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  73 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  74
  75 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  76 SET( toolkit_styles_dir ${STYLE_DIR} )
  77 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  78
  79 IF( DEFINED ENV{DALI_DATA_RW_DIR} )
  80   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR} )
  81 ELSE()
  82   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  83 ENDIF()
  84
  85 IF( DEFINED ENV{DALI_DATA_RO_DIR} )
  86   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR} )
  87 ELSE()
  88   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  89 ENDIF()
  90
  91 # Set up compiler definitions
  92
  93 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  94   SET( ENABLE_DEBUG ON )
  95 ENDIF()
  96
  97 IF( ENABLE_DEBUG )
  98   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  99   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
 100   SET( ENABLE_EXPORTALL ON )
 101 ELSE()
 102   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
 103 ENDIF()
 104
 105 IF( ENABLE_I18N )
 106   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
 107 ENDIF( ENABLE_I18N )
 108
 109 IF( WIN32 )
 110   ADD_DEFINITIONS( "-DBUILDING_DALI_TOOLKIT" )
 111
 112   IF( USE_DEFAULT_RESOURCE_DIR )
 113     SET( INSTALL_SHARE_DIR "${PREFIX}/share" )
 114     IF( VCPKG_TOOLKIT_BUILD )
 115       SET( INSTALL_SHARE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/share" )
 116     ENDIF()
 117
 118     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/images/\"
 119                      -DDALI_SOUND_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/sounds/\"
 120                      -DDALI_STYLE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/\"
 121                      -DDALI_STYLE_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/images/\"
 122                      -DDALI_DATA_READ_ONLY_DIR=\"${INSTALL_SHARE_DIR}/\" )
 123   ENDIF()
 124 ELSEIF( UNIX )
 125   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
 126   IF( USE_DEFAULT_RESOURCE_DIR )
 127     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
 128                      -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
 129                      -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
 130                      -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
 131                      -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
 132   ENDIF()
 133
 134   IF("${ARCH}" STREQUAL "arm")
 135     ADD_DEFINITIONS("-DTARGET")
 136   ENDIF("${ARCH}" STREQUAL "arm")
 137
 138   IF( NOT ${ENABLE_EXPORTALL} )
 139     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 140   ENDIF( NOT ${ENABLE_EXPORTALL} )
 141 ENDIF()
 142
 143 IF( NOT USE_DEFAULT_RESOURCE_DIR )
 144   ADD_DEFINITIONS( -DDALI_IMAGE_DIR=0
 145                    -DDALI_SOUND_DIR=0
 146                    -DDALI_STYLE_DIR=0
 147                    -DDALI_STYLE_IMAGE_DIR=0
 148                    -DDALI_DATA_READ_ONLY_DIR=0 )
 149 ENDIF()
 150
 151 IF( ENABLE_TRACE )
 152   ADD_DEFINITIONS("-DTRACE_ENABLED")
 153 ENDIF()
 154
 155 # Set paths
 156 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 157 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 158 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 159 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 160 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 161 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 162 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 163
 164 # Set up the include dir
 165 SET( INCLUDE_DIR $ENV{includedir} )
 166 IF( NOT INCLUDE_DIR )
 167   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 168 ENDIF()
 169 IF( NOT INCLUDE_DIR )
 170   SET( INCLUDE_DIR ${PREFIX}/include )
 171 ENDIF()
 172
 173 # Set up the lib dir
 174 SET( LIB_DIR $ENV{libdir} )
 175 IF( NOT LIB_DIR )
 176   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 177 ENDIF()
 178 IF( NOT LIB_DIR )
 179   SET( LIB_DIR ${PREFIX}/lib )
 180 ENDIF()
 181
 182 # Set up the bin dir
 183 SET( BIN_DIR $ENV{bindir} )
 184 IF( NOT BIN_DIR )
 185   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 186 ENDIF()
 187 IF( NOT BIN_DIR )
 188   SET( BIN_DIR ${PREFIX}/bin )
 189 ENDIF()
 190
 191 IF( ENABLE_PKG_CONFIGURE )
 192   # Configure the pkg-config file
 193   # Requires the following variables to be setup:
 194   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 195   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 196   SET( CORE_PKG_CFG_FILE dali2-toolkit.pc )
 197   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 198 ENDIF()
 199
 200 IF( WIN32 )
 201   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 202   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 203   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 204 ELSE()
 205   # Set up compiler flags and warnings
 206   ADD_COMPILE_OPTIONS( -std=c++11 )
 207   ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 208
 209   # TODO: Clang is a lot more strict with warnings, we should address
 210   # those issues at some point.
 211   IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 212     ADD_COMPILE_OPTIONS( -Werror )
 213   ENDIF()
 214
 215   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal -Wno-class-memaccess )
 216
 217   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 218     ADD_COMPILE_OPTIONS( --coverage )
 219     SET(ENABLE_COVERAGE ON)
 220     SET(COVERAGE --coverage)
 221   ENDIF()
 222
 223   IF( NOT ${ENABLE_EXPORTALL} )
 224     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 225   ENDIF( NOT ${ENABLE_EXPORTALL} )
 226 ENDIF()
 227
 228
 229 INCLUDE_DIRECTORIES(
 230   ${ROOT_SRC_DIR}
 231   ${DALICORE_INCLUDE_DIRS}
 232   ${DALIADAPTOR_INCLUDE_DIRS}
 233   ${VCPKG_INCLUDE_DIR}
 234   ${INCLUDE_DIR}
 235 )
 236
 237 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 238 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 239
 240 SET(SOURCES "")
 241
 242 # could use INCLUDE to get the source lists a different way;
 243 # would then need to specify a build folder somehow...
 244 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
 245 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
 246 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
 247 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
 248 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
 249 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
 250 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
 251 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 252
 253 # Platforms with highp shader support can use vector based text
 254 IF( ENABLE_VECTOR_BASED_TEXT_RENDERING )
 255   INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/text/rendering/vector-based/file.list )
 256 ENDIF()
 257
 258 SET(LIBTYPE SHARED)
 259 IF(DEFINED STATIC)
 260   SET(LIBTYPE STATIC)
 261 ENDIF()
 262
 263 IF( WIN32 )
 264   SET( DALICORE_LDFLAGS
 265         "${DALICORE_LDFLAGS}"
 266         dali2-core::dali2-core )
 267
 268   FIND_PACKAGE( pthreads REQUIRED )
 269   FIND_PACKAGE( curl REQUIRED )
 270   FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 271   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 272
 273   FIND_PACKAGE( png REQUIRED )
 274   FIND_PACKAGE( gif REQUIRED )
 275   FIND_PACKAGE( jpeg REQUIRED )
 276   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 277
 278   FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 279   FIND_PACKAGE( freetype REQUIRED )
 280   FIND_PACKAGE( harfbuzz REQUIRED )
 281   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 282
 283   FIND_PACKAGE( unofficial-angle REQUIRED )
 284   FIND_PACKAGE( unofficial-cairo REQUIRED )
 285
 286   FIND_PACKAGE( WebP REQUIRED )
 287
 288   SET( DALIADAPTOR_LDFLAGS
 289        "${DALIADAPTOR_LDFLAGS}"
 290        dali2-adaptor::dali2-adaptor )
 291 ENDIF()
 292
 293
 294 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 295 TARGET_LINK_LIBRARIES( ${name}
 296   ${DALICORE_LDFLAGS}
 297   ${DALIADAPTOR_LDFLAGS}
 298   ${COVERAGE}
 299 )
 300
 301 IF( ANDROID )
 302   TARGET_LINK_LIBRARIES( ${name} log )
 303 ENDIF()
 304
 305 SET_TARGET_PROPERTIES( ${name}
 306   PROPERTIES
 307   VERSION ${DALI_TOOLKIT_VERSION}
 308   SOVERSION ${${name}_VERSION_MAJOR}
 309   CLEAN_DIRECT_OUPUT 1
 310 )
 311
 312 IF( INSTALL_CMAKE_MODULES )
 313   IF( ENABLE_DEBUG )
 314     SET( BIN_DIR "${BIN_DIR}/debug" )
 315     SET( LIB_DIR "${LIB_DIR}/debug" )
 316   ENDIF()
 317
 318   # Install the library files.
 319   INSTALL( TARGETS ${name}
 320     EXPORT ${name}-targets
 321     LIBRARY DESTINATION ${LIB_DIR}
 322     ARCHIVE DESTINATION ${LIB_DIR}
 323     RUNTIME DESTINATION ${BIN_DIR}
 324   )
 325
 326   # Install the cmake modules.
 327   INSTALL(
 328     EXPORT ${name}-targets
 329     NAMESPACE ${name}::
 330     FILE ${name}-targets.cmake
 331     DESTINATION share/${name}
 332   )
 333
 334   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 335     include(CMakeFindDependencyMacro)
 336     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 337   ")
 338   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 339
 340   # Install the pdb file.
 341   IF( ENABLE_DEBUG )
 342     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}.pdb DESTINATION ${BIN_DIR} )
 343   ENDIF()
 344 ELSE()
 345   # Install the library so file and symlinks
 346   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 347 ENDIF()
 348
 349 # Install the pkg-config file
 350 IF( ENABLE_PKG_CONFIGURE )
 351   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 352 ENDIF()
 353
 354 # Glob for resources
 355 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 356   FOREACH( PATTERN ${FILE_LIST} )
 357     FILE(GLOB FILES ${PATTERN} )
 358     FOREACH( FILE ${FILES} )
 359       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 360       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 361       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 362         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 363         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 364       ELSE()
 365         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 366       ENDIF()
 367     ENDFOREACH()
 368   ENDFOREACH()
 369 ENDMACRO()
 370
 371 # macro for installing headers by replacing prefix. (TODO, investigate
 372 # if there is a CMAKE way of doing this automatically)
 373 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 374   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 375   FOREACH(HEADER ${${HEADER_LIST}})
 376     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 377     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 378     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 379   ENDFOREACH(HEADER)
 380 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 381
 382 # Install headers using lists defined by ADD_SUBDIRECTORY
 383 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 384 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 385 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 386 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 387
 388 # Install dali-toolkit.h
 389 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${INCLUDE_DIR}/dali-toolkit )
 390
 391 # package doxygen file (contains doxygen grouping information)
 392 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
 393
 394 # On some platforms we want to install the data files to different location compare to
 395 # the data location used runtime. For example, on Android we want the toolkit library to load
 396 # the files from /data/data/com.sec.dali_demo/files but to install the files into ${PREFIX}/files
 397 # for SDK to pick them up for the archive.
 398 IF( DEFINED ENV{DALI_DATA_RW_INSTALL_DIR} )
 399   SET( dataReadWriteInstallDir $ENV{DALI_DATA_RW_INSTALL_DIR} )
 400 ELSE()
 401   SET( dataReadWriteInstallDir ${dataReadWriteDir} )
 402 ENDIF()
 403
 404 IF( DEFINED ENV{DALI_DATA_RO_INSTALL_DIR} )
 405   SET( dataReadOnlyInstallDir $ENV{DALI_DATA_RO_INSTALL_DIR} )
 406 ELSE()
 407   SET( dataReadOnlyInstallDir ${dataReadOnlyDir} )
 408 ENDIF()
 409
 410 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles" )
 411 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/images" )
 412 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/sounds" )
 413 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles/images" )
 414
 415 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
 416 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 417 # target names duplication with other DALi modules.
 418 IF( ENABLE_COVERAGE )
 419   FIND_PROGRAM( LCOV_BIN "lcov" )
 420   IF( LCOV_BIN )
 421
 422     # Define custom rules for coverage
 423     SET(COVERAGE_DIR .cov)
 424     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 425
 426     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 427     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 428     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 429     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 430     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 431       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 432     ENDIF()
 433
 434     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
 435
 436     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 437       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" "*/dali-env/*" "*solid-color-actor*" "*/dali-toolkit/third-party/*" -o dali.info )
 438
 439     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 440       DEPENDS cov_data )
 441
 442     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 443
 444     # Define custom rule for distclean
 445     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
 446     ADD_CUSTOM_COMMAND(
 447           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
 448           COMMENT "distribution clean"
 449           COMMAND find
 450           ARGS    .
 451           -not -name config.cmake -and \(
 452           -name tester.c -or
 453           -name Testing -or
 454           -name CMakeFiles -or
 455           -name doc -or
 456           -name cmake.depends -or
 457           -name cmake.check_depends -or
 458           -name CMakeCache.txt -or
 459           -name cmake.check_cache -or
 460           -name *.cmake -or
 461           -name Makefile -or
 462           -name core -or
 463           -name core.* -or
 464           -name gmon.out -or
 465           -name install_manifest.txt -or
 466           -name *.pc -or
 467           -name *.gcov -or
 468           -name *.gcno -or
 469           -name *.gcda -or
 470           -name *~ -or
 471           -name libdali*.so* \)
 472           | grep -v TC | xargs rm -rf
 473           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
 474           VERBATIM
 475           )
 476
 477   ENDIF( LCOV_BIN )
 478 ENDIF()
 479
 480 # Build documentation if doxygen tool is available
 481 SET( doxygenEnabled OFF )
 482 IF( DOXYGEN_FOUND )
 483   SET( doxygenEnabled ON )
 484   # 'prefix' is used by doxygen in-files.
 485   SET( prefix ${PREFIX} )
 486   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 487   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 488   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 489   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 490   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 491   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 492   ADD_CUSTOM_TARGET( doc_doxygen ALL
 493                      DEPENDS ${name}
 494                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 495                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 496                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 497                      COMMENT "Generating API documentation with Doxygen"
 498                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 499                      VERBATIM )
 500   ADD_CUSTOM_TARGET( doc_doxygen_internal
 501                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 502                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 503                      COMMENT "Generating Internal API documentation with Doxygen"
 504                      VERBATIM )
 505
 506 ENDIF()
 507
 508 IF( CONFIGURE_AUTOMATED_TESTS )
 509   # Configure automated tests
 510   CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 511                   ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 512 ENDIF()
 513
 514 # Configuration Messages
 515 MESSAGE( STATUS "Configuration:\n" )
 516 MESSAGE( STATUS "Prefix:                        " ${PREFIX} )
 517 MESSAGE( STATUS "Lib Dir:                       " ${LIB_DIR} )
 518 MESSAGE( STATUS "Include Dir:                   " ${INCLUDE_DIR} )
 519 MESSAGE( STATUS "Debug build:                   " ${ENABLE_DEBUG} )
 520 MESSAGE( STATUS "Export all symbols:            " ${ENABLE_EXPORTALL} )
 521 MESSAGE( STATUS "Coverage:                      " ${ENABLE_COVERAGE} )
 522 MESSAGE( STATUS "Trace:                         " ${ENABLE_TRACE} )
 523 MESSAGE( STATUS "Doxygen:                       " ${doxygenEnabled} )
 524 MESSAGE( STATUS "Data Dir (Read/Write):         " ${dataReadWriteDir} )
 525 MESSAGE( STATUS "Data Dir (Read Only):          " ${dataReadOnlyDir} )
 526 MESSAGE( STATUS "Data Install Dir (Read/Write): " ${dataReadWriteInstallDir} )
 527 MESSAGE( STATUS "Data Install Dir (Read Only):  " ${dataReadOnlyInstallDir} )
 528 MESSAGE( STATUS "Style Dir:                     " ${STYLE_DIR} )
 529 MESSAGE( STATUS "Style:                         " ${dali_style} )
 530 MESSAGE( STATUS "i18n:                          " ${ENABLE_I18N} )
 531 MESSAGE( STATUS "Use pkg configure:             " ${ENABLE_PKG_CONFIGURE} )
 532 MESSAGE( STATUS "Enable link test:              " ${ENABLE_LINK_TEST} )
 533 MESSAGE( STATUS "Configure automated tests:     " ${CONFIGURE_AUTOMATED_TESTS} )
 534 MESSAGE( STATUS "CXXFLAGS:                      " ${CMAKE_CXX_FLAGS} )
 535 MESSAGE( STATUS "LDFLAGS:                       " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )
 536
 537 MESSAGE( " Folder       INSTALL_SHARE_DIR : [" ${INSTALL_SHARE_DIR} "]" )
 538 MESSAGE( " Folder          DALI_IMAGE_DIR : [" ${DALI_IMAGE_DIR} "]" )
 539 MESSAGE( " Folder          DALI_STYLE_DIR : [" ${DALI_STYLE_DIR} "]" )
 540 MESSAGE( " Folder    DALI_STYLE_IMAGE_DIR : [" ${DALI_STYLE_IMAGE_DIR} "]" )
 541 MESSAGE( " Folder          DALI_SOUND_DIR : [" ${DALI_SOUND_DIR} "]" )
 542 MESSAGE( " Folder DALI_DATA_READ_ONLY_DIR : [" ${DALI_DATA_READ_ONLY_DIR} "]" )