Removed TouchEvent from dali-core
[platform/core/uifw/dali-toolkit.git] / build / tizen / CMakeLists.txt
1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
3
4 SET(name "dali2-toolkit")
5
6 PROJECT(${name})
7 SET(PKG_NAME ${name})
8
9 SET(GCC_COMPILER_VERSION_REQUIRED "6")
10 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
11   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
12     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
13   endif()
14 endif()
15
16 # API VERSION (Not DALi release version)
17 SET(${name}_VERSION_MAJOR 2)
18 SET(${name}_VERSION_MINOR 0)
19 SET(${name}_VERSION_PATCH 0)
20 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
21
22 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
23
24 # Define options to CMake
25 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
26 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
27 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
28 OPTION(ENABLE_I18N               "Turns on internationalisation" OFF)
29 OPTION(ENABLE_COVERAGE           "Coverage" OFF)
30 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
31 OPTION(ENABLE_LINK_TEST          "Enable the link test" ON)
32 OPTION(INSTALL_DOXYGEN_DOC       "Install doxygen doc" ON)
33 OPTION(CONFIGURE_AUTOMATED_TESTS "Configure automated tests" ON)
34 OPTION(USE_DEFAULT_RESOURCE_DIR  "Whether to use the default resource folders. Otherwise set environment variables for DALI_IMAGE_DIR, DALI_SOUND_DIR, DALI_STYLE_DIR, DALI_STYLE_IMAGE_DIR and DALI_DATA_READ_ONLY_DIR" ON)
35
36 IF( ENABLE_PKG_CONFIGURE )
37   FIND_PACKAGE( PkgConfig REQUIRED )
38
39   PKG_CHECK_MODULES(DALICORE REQUIRED dali2-core)
40   PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali2-adaptor)
41 ENDIF()
42
43 IF( INSTALL_DOXYGEN_DOC )
44   FIND_PACKAGE( Doxygen QUIET )
45 ENDIF()
46
47 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
48   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
49   FIND_PACKAGE( dali2-core REQUIRED)
50   FIND_PACKAGE( dali2-adaptor REQUIRED)
51 ENDIF()
52
53 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
54
55 # Define non-boolean options to CMake
56 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
57
58 # from root/build/tizen, get back to root
59 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
60
61 # Deployment folder should come from spec file or command line:
62 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
63 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
64
65 # Make sure the path is absolute
66 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
67
68 # Set DALi style
69 SET( dali_style ${WITH_STYLE} )
70
71 # Style folder
72 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
73 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
74
75 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
76 SET( toolkit_styles_dir ${STYLE_DIR} )
77 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
78
79 IF( DEFINED ENV{DALI_DATA_RW_DIR} )
80   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR} )
81 ELSE()
82   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
83 ENDIF()
84
85 IF( DEFINED ENV{DALI_DATA_RO_DIR} )
86   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR} )
87 ELSE()
88   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
89 ENDIF()
90
91 # Set up compiler definitions
92
93 IF(CMAKE_BUILD_TYPE MATCHES Debug)
94   SET( ENABLE_DEBUG ON )
95 ENDIF()
96
97 IF( ENABLE_DEBUG )
98   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
99   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
100   SET( ENABLE_EXPORTALL ON )
101 ELSE()
102   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
103 ENDIF()
104
105 IF( ENABLE_I18N )
106   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
107 ENDIF( ENABLE_I18N )
108
109 IF( WIN32 )
110   ADD_DEFINITIONS( "-DBUILDING_DALI_TOOLKIT" )
111
112   IF( USE_DEFAULT_RESOURCE_DIR )
113     SET( INSTALL_SHARE_DIR "${PREFIX}/share" )
114     IF( VCPKG_TOOLKIT_BUILD )
115       SET( INSTALL_SHARE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/share" )
116     ENDIF()
117
118     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/images/\"
119                      -DDALI_SOUND_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/sounds/\"
120                      -DDALI_STYLE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/\"
121                      -DDALI_STYLE_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/images/\"
122                      -DDALI_DATA_READ_ONLY_DIR=\"${INSTALL_SHARE_DIR}/\" )
123   ENDIF()
124 ELSEIF( UNIX )
125   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
126   IF( USE_DEFAULT_RESOURCE_DIR )
127     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
128                      -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
129                      -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
130                      -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
131                      -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
132   ENDIF()
133
134   IF("${ARCH}" STREQUAL "arm")
135     ADD_DEFINITIONS("-DTARGET")
136   ENDIF("${ARCH}" STREQUAL "arm")
137
138   IF( NOT ${ENABLE_EXPORTALL} )
139     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
140   ENDIF( NOT ${ENABLE_EXPORTALL} )
141 ENDIF()
142
143 IF( NOT USE_DEFAULT_RESOURCE_DIR )
144   ADD_DEFINITIONS( -DDALI_IMAGE_DIR=0
145                    -DDALI_SOUND_DIR=0
146                    -DDALI_STYLE_DIR=0
147                    -DDALI_STYLE_IMAGE_DIR=0
148                    -DDALI_DATA_READ_ONLY_DIR=0 )
149 ENDIF()
150
151 IF( ENABLE_TRACE )
152   ADD_DEFINITIONS("-DTRACE_ENABLED")
153 ENDIF()
154
155 # Set paths
156 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
157 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
158 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
159 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
160 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
161 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
162 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
163
164 # Set up the include dir
165 SET( INCLUDE_DIR $ENV{includedir} )
166 IF( NOT INCLUDE_DIR )
167   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
168 ENDIF()
169 IF( NOT INCLUDE_DIR )
170   SET( INCLUDE_DIR ${PREFIX}/include )
171 ENDIF()
172
173 # Set up the lib dir
174 SET( LIB_DIR $ENV{libdir} )
175 IF( NOT LIB_DIR )
176   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
177 ENDIF()
178 IF( NOT LIB_DIR )
179   SET( LIB_DIR ${PREFIX}/lib )
180 ENDIF()
181
182 # Set up the bin dir
183 SET( BIN_DIR $ENV{bindir} )
184 IF( NOT BIN_DIR )
185   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
186 ENDIF()
187 IF( NOT BIN_DIR )
188   SET( BIN_DIR ${PREFIX}/bin )
189 ENDIF()
190
191 IF( ENABLE_PKG_CONFIGURE )
192   # Configure the pkg-config file
193   # Requires the following variables to be setup:
194   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
195   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
196   SET( CORE_PKG_CFG_FILE dali2-toolkit.pc )
197   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
198 ENDIF()
199
200 IF( WIN32 )
201   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
202   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
203   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
204 ELSE()
205   # Set up compiler flags and warnings
206   ADD_COMPILE_OPTIONS( -std=c++11 )
207   ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
208
209   # TODO: Clang is a lot more strict with warnings, we should address
210   # those issues at some point.
211   IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
212     ADD_COMPILE_OPTIONS( -Werror )
213   ENDIF()
214
215   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal -Wno-class-memaccess )
216
217   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
218     ADD_COMPILE_OPTIONS( --coverage )
219     SET(ENABLE_COVERAGE ON)
220     SET(COVERAGE --coverage)
221   ENDIF()
222
223   IF( NOT ${ENABLE_EXPORTALL} )
224     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
225   ENDIF( NOT ${ENABLE_EXPORTALL} )
226 ENDIF()
227
228
229 INCLUDE_DIRECTORIES(
230   ${ROOT_SRC_DIR}
231   ${DALICORE_INCLUDE_DIRS}
232   ${DALIADAPTOR_INCLUDE_DIRS}
233   ${VCPKG_INCLUDE_DIR}
234   ${INCLUDE_DIR}
235 )
236
237 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
238 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
239
240 SET(SOURCES "")
241
242 # could use INCLUDE to get the source lists a different way;
243 # would then need to specify a build folder somehow...
244 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
245 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
246 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
247 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
248 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
249 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
250 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
251 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
252
253 # Platforms with highp shader support can use vector based text
254 IF( NOT DEFINED ENABLE_VECTOR_BASED_TEXT_RENDERING )
255   SET(ENABLE_VECTOR_BASED_TEXT_RENDERING ON)
256 ENDIF()
257
258 IF( ENABLE_VECTOR_BASED_TEXT_RENDERING )
259   ADD_DEFINITIONS( "-DENABLE_VECTOR_BASED_TEXT_RENDERING" )
260   INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/text/rendering/vector-based/file.list )
261 ENDIF()
262
263 SET(LIBTYPE SHARED)
264 IF(DEFINED STATIC)
265   SET(LIBTYPE STATIC)
266 ENDIF()
267
268 IF( WIN32 )
269   SET( DALICORE_LDFLAGS
270         "${DALICORE_LDFLAGS}"
271         dali2-core::dali2-core )
272
273   FIND_PACKAGE( pthreads REQUIRED )
274   FIND_PACKAGE( curl REQUIRED )
275   FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
276   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
277
278   FIND_PACKAGE( png REQUIRED )
279   FIND_PACKAGE( gif REQUIRED )
280   FIND_PACKAGE( jpeg REQUIRED )
281   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
282
283   FIND_PACKAGE( unofficial-fontconfig REQUIRED )
284   FIND_PACKAGE( freetype REQUIRED )
285   FIND_PACKAGE( harfbuzz REQUIRED )
286   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
287
288   FIND_PACKAGE( unofficial-angle REQUIRED )
289   FIND_PACKAGE( unofficial-cairo REQUIRED )
290
291   FIND_PACKAGE( WebP REQUIRED )
292
293   SET( DALIADAPTOR_LDFLAGS
294        "${DALIADAPTOR_LDFLAGS}"
295        dali2-adaptor::dali2-adaptor )
296 ENDIF()
297
298
299 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
300 TARGET_LINK_LIBRARIES( ${name}
301   ${DALICORE_LDFLAGS}
302   ${DALIADAPTOR_LDFLAGS}
303   ${COVERAGE}
304 )
305
306 IF( ANDROID )
307   TARGET_LINK_LIBRARIES( ${name} log )
308 ENDIF()
309
310 SET_TARGET_PROPERTIES( ${name}
311   PROPERTIES
312   VERSION ${DALI_TOOLKIT_VERSION}
313   SOVERSION ${${name}_VERSION_MAJOR}
314   CLEAN_DIRECT_OUPUT 1
315 )
316
317 IF( INSTALL_CMAKE_MODULES )
318   IF( ENABLE_DEBUG )
319     SET( BIN_DIR "${BIN_DIR}/debug" )
320     SET( LIB_DIR "${LIB_DIR}/debug" )
321   ENDIF()
322
323   # Install the library files.
324   INSTALL( TARGETS ${name}
325     EXPORT ${name}-targets
326     LIBRARY DESTINATION ${LIB_DIR}
327     ARCHIVE DESTINATION ${LIB_DIR}
328     RUNTIME DESTINATION ${BIN_DIR}
329   )
330
331   # Install the cmake modules.
332   INSTALL(
333     EXPORT ${name}-targets
334     NAMESPACE ${name}::
335     FILE ${name}-targets.cmake
336     DESTINATION share/${name}
337   )
338
339   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
340     include(CMakeFindDependencyMacro)
341     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
342   ")
343   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
344
345   # Install the pdb file.
346   IF( ENABLE_DEBUG )
347     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
348   ENDIF()
349 ELSE()
350   # Install the library so file and symlinks
351   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
352 ENDIF()
353
354 # Install the pkg-config file
355 IF( ENABLE_PKG_CONFIGURE )
356   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
357 ENDIF()
358
359 # Glob for resources
360 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
361   FOREACH( PATTERN ${FILE_LIST} )
362     FILE(GLOB FILES ${PATTERN} )
363     FOREACH( FILE ${FILES} )
364       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
365       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
366       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
367         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
368         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
369       ELSE()
370         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
371       ENDIF()
372     ENDFOREACH()
373   ENDFOREACH()
374 ENDMACRO()
375
376 # macro for installing headers by replacing prefix. (TODO, investigate
377 # if there is a CMAKE way of doing this automatically)
378 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
379   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
380   FOREACH(HEADER ${${HEADER_LIST}})
381     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
382     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
383     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
384   ENDFOREACH(HEADER)
385 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
386
387 # Install headers using lists defined by ADD_SUBDIRECTORY
388 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
389 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
390 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
391 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
392
393 # Install dali-toolkit.h
394 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${INCLUDE_DIR}/dali-toolkit )
395
396 # package doxygen file (contains doxygen grouping information)
397 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
398
399 # On some platforms we want to install the data files to different location compare to
400 # the data location used runtime. For example, on Android we want the toolkit library to load
401 # the files from /data/data/com.sec.dali_demo/files but to install the files into ${PREFIX}/files
402 # for SDK to pick them up for the archive.
403 IF( DEFINED ENV{DALI_DATA_RW_INSTALL_DIR} )
404   SET( dataReadWriteInstallDir $ENV{DALI_DATA_RW_INSTALL_DIR} )
405 ELSE()
406   SET( dataReadWriteInstallDir ${dataReadWriteDir} )
407 ENDIF()
408
409 IF( DEFINED ENV{DALI_DATA_RO_INSTALL_DIR} )
410   SET( dataReadOnlyInstallDir $ENV{DALI_DATA_RO_INSTALL_DIR} )
411 ELSE()
412   SET( dataReadOnlyInstallDir ${dataReadOnlyDir} )
413 ENDIF()
414
415 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles" )
416 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/images" )
417 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/sounds" )
418 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles/images" )
419
420 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
421 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
422 # target names duplication with other DALi modules.
423 IF( ENABLE_COVERAGE )
424   FIND_PROGRAM( LCOV_BIN "lcov" )
425   IF( LCOV_BIN )
426
427     # Define custom rules for coverage
428     SET(COVERAGE_DIR .cov)
429     SET(COVERAGE_OUTPUT_DIR doc/coverage)
430
431     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
432     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
433     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
434     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
435     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
436       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
437     ENDIF()
438
439     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
440
441     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
442       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" "*/dali-env/*" "*solid-color-actor*" "*/dali-toolkit/third-party/*" -o dali.info )
443
444     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
445       DEPENDS cov_data )
446
447     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
448
449     # Define custom rule for distclean
450     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
451     ADD_CUSTOM_COMMAND(
452           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
453           COMMENT "distribution clean"
454           COMMAND find
455           ARGS    .
456           -not -name config.cmake -and \(
457           -name tester.c -or
458           -name Testing -or
459           -name CMakeFiles -or
460           -name doc -or
461           -name cmake.depends -or
462           -name cmake.check_depends -or
463           -name CMakeCache.txt -or
464           -name cmake.check_cache -or
465           -name *.cmake -or
466           -name Makefile -or
467           -name core -or
468           -name core.* -or
469           -name gmon.out -or
470           -name install_manifest.txt -or
471           -name *.pc -or
472           -name *.gcov -or
473           -name *.gcno -or
474           -name *.gcda -or
475           -name *~ -or
476           -name libdali*.so* \)
477           | grep -v TC | xargs rm -rf
478           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
479           VERBATIM
480           )
481
482   ENDIF( LCOV_BIN )
483 ENDIF()
484
485 # Build documentation if doxygen tool is available
486 SET( doxygenEnabled OFF )
487 IF( DOXYGEN_FOUND )
488   SET( doxygenEnabled ON )
489   # 'prefix' is used by doxygen in-files.
490   SET( prefix ${PREFIX} )
491   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
492   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
493   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
494   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
495   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
496   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
497   ADD_CUSTOM_TARGET( doc_doxygen ALL
498                      DEPENDS ${name}
499                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
500                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
501                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
502                      COMMENT "Generating API documentation with Doxygen"
503                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
504                      VERBATIM )
505   ADD_CUSTOM_TARGET( doc_doxygen_internal
506                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
507                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
508                      COMMENT "Generating Internal API documentation with Doxygen"
509                      VERBATIM )
510
511 ENDIF()
512
513 IF( CONFIGURE_AUTOMATED_TESTS )
514   # Configure automated tests
515   CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
516                   ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
517 ENDIF()
518
519 # Configuration Messages
520 MESSAGE( STATUS "Configuration:\n" )
521 MESSAGE( STATUS "Prefix:                        " ${PREFIX} )
522 MESSAGE( STATUS "Lib Dir:                       " ${LIB_DIR} )
523 MESSAGE( STATUS "Include Dir:                   " ${INCLUDE_DIR} )
524 MESSAGE( STATUS "Debug build:                   " ${ENABLE_DEBUG} )
525 MESSAGE( STATUS "Export all symbols:            " ${ENABLE_EXPORTALL} )
526 MESSAGE( STATUS "Coverage:                      " ${ENABLE_COVERAGE} )
527 MESSAGE( STATUS "Trace:                         " ${ENABLE_TRACE} )
528 MESSAGE( STATUS "Doxygen:                       " ${doxygenEnabled} )
529 MESSAGE( STATUS "Data Dir (Read/Write):         " ${dataReadWriteDir} )
530 MESSAGE( STATUS "Data Dir (Read Only):          " ${dataReadOnlyDir} )
531 MESSAGE( STATUS "Data Install Dir (Read/Write): " ${dataReadWriteInstallDir} )
532 MESSAGE( STATUS "Data Install Dir (Read Only):  " ${dataReadOnlyInstallDir} )
533 MESSAGE( STATUS "Style Dir:                     " ${STYLE_DIR} )
534 MESSAGE( STATUS "Style:                         " ${dali_style} )
535 MESSAGE( STATUS "i18n:                          " ${ENABLE_I18N} )
536 MESSAGE( STATUS "Use pkg configure:             " ${ENABLE_PKG_CONFIGURE} )
537 MESSAGE( STATUS "Vector Based Text Rendering:   " ${ENABLE_VECTOR_BASED_TEXT_RENDERING} )
538 MESSAGE( STATUS "Enable link test:              " ${ENABLE_LINK_TEST} )
539 MESSAGE( STATUS "Configure automated tests:     " ${CONFIGURE_AUTOMATED_TESTS} )
540 MESSAGE( STATUS "CXXFLAGS:                      " ${CMAKE_CXX_FLAGS} )
541 MESSAGE( STATUS "LDFLAGS:                       " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )
542
543 MESSAGE( " Folder       INSTALL_SHARE_DIR : [" ${INSTALL_SHARE_DIR} "]" )
544 MESSAGE( " Folder          DALI_IMAGE_DIR : [" ${DALI_IMAGE_DIR} "]" )
545 MESSAGE( " Folder          DALI_STYLE_DIR : [" ${DALI_STYLE_DIR} "]" )
546 MESSAGE( " Folder    DALI_STYLE_IMAGE_DIR : [" ${DALI_STYLE_IMAGE_DIR} "]" )
547 MESSAGE( " Folder          DALI_SOUND_DIR : [" ${DALI_SOUND_DIR} "]" )
548 MESSAGE( " Folder DALI_DATA_READ_ONLY_DIR : [" ${DALI_DATA_READ_ONLY_DIR} "]" )