build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-toolkit")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 FIND_PACKAGE( PkgConfig REQUIRED )
  10 FIND_PACKAGE( Doxygen QUIET )
  11
  12 PKG_CHECK_MODULES(DALICORE REQUIRED dali-core)
  13 PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali-adaptor)
  14
  15 # API VERSION (Not DALi release version)
  16 SET(${name}_VERSION_MAJOR 0)
  17 SET(${name}_VERSION_MINOR 0)
  18 SET(${name}_VERSION_PATCH 0)
  19 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  20
  21 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  22
  23 # Define options to CMake
  24 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  25 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  26 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  27 OPTION(ENABLE_I18N           "Turns on internationalisation" OFF)
  28 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  29
  30 # Define non-boolean options to CMake
  31 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  32
  33 # from root/build/tizen, get back to root
  34 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  35
  36 # Make sure the path is absolute
  37 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  38
  39 # Set DALi style
  40 SET( dali_style ${WITH_STYLE} )
  41
  42 # Style folder
  43 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  44 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  45
  46 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  47 SET( toolkit_styles_dir ${STYLE_DIR} )
  48 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  49
  50 IF( $ENV{DALI_DATA_RW_DIR} )
  51   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR}/ )
  52 ELSE()
  53   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  54 ENDIF()
  55
  56 IF( $ENV{DALI_DATA_RO_DIR} )
  57   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR}/ )
  58 ELSE()
  59   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  60 ENDIF()
  61
  62 # Set up compiler definitions
  63 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  64   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  65   SET( ENABLE_DEBUG ON )
  66 ELSE()
  67   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  68 ENDIF()
  69
  70 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  71 ADD_DEFINITIONS(-DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
  72                 -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
  73                 -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
  74                 -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
  75                 -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
  76
  77 IF("${ARCH}" STREQUAL "arm")
  78   ADD_DEFINITIONS("-DTARGET")
  79 ENDIF("${ARCH}" STREQUAL "arm")
  80
  81 IF( ENABLE_DEBUG )
  82   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  83   SET( ENABLE_EXPORTALL ON )
  84 ENDIF( ENABLE_DEBUG )
  85
  86 IF( NOT ${ENABLE_EXPORTALL} )
  87   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  88 ENDIF( NOT ${ENABLE_EXPORTALL} )
  89
  90 IF( ENABLE_I18N )
  91   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
  92 ENDIF( ENABLE_I18N )
  93
  94 # Platforms with highp shader support can use vector based text
  95 IF( "${PROFILE}" STREQUAL "UBUNTU" )
  96   SET( ENABLE_VECTOR_BASED_TEXT_RENDERING 1 )
  97 ENDIF()
  98
  99 # Deployment folder should come from spec file or command line:
 100 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
 101 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
 102
 103 # Set paths
 104 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 105 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 106 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 107 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 108 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 109 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 110 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 111
 112 # Set up the include dir
 113 SET( INCLUDE_DIR $ENV{includedir} )
 114 IF( NOT INCLUDE_DIR )
 115   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 116 ENDIF()
 117 IF( NOT INCLUDE_DIR )
 118   SET( INCLUDE_DIR ${PREFIX}/include )
 119 ENDIF()
 120
 121 # Set up the lib dir
 122 SET( LIB_DIR $ENV{libdir} )
 123 IF( NOT LIB_DIR )
 124   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 125 ENDIF()
 126 IF( NOT LIB_DIR )
 127   SET( LIB_DIR ${PREFIX}/lib )
 128 ENDIF()
 129
 130 # Configure the pkg-config file
 131 # Requires the following variables to be setup:
 132 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 133 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 134 SET( CORE_PKG_CFG_FILE dali-toolkit.pc )
 135 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 136
 137 # Set up compiler flags and warnings
 138 ADD_COMPILE_OPTIONS( -std=c++11 )
 139 ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 140
 141 # TODO: Clang is a lot more strict with warnings, we should address
 142 # those issues at some point.
 143 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 144   ADD_COMPILE_OPTIONS( -Werror )
 145 ENDIF()
 146
 147 ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal )
 148
 149 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 150   ADD_COMPILE_OPTIONS( --coverage )
 151   SET(ENABLE_COVERAGE ON)
 152   SET(COVERAGE --coverage)
 153 ENDIF()
 154
 155 IF( ENABLE_TRACE )
 156   ADD_DEFINITIONS("-DTRACE_ENABLED")
 157 ENDIF()
 158
 159 INCLUDE_DIRECTORIES(
 160   ${ROOT_SRC_DIR}
 161   ${DALICORE_INCLUDE_DIRS}
 162   ${DALIADAPTOR_INCLUDE_DIRS}
 163 )
 164
 165 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 166 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 167
 168 SET(SOURCES "")
 169
 170 # could use INCLUDE to get the source lists a different way;
 171 # would then need to specify a build folder somehow...
 172 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
 173 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
 174 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
 175 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
 176 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
 177 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
 178 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
 179 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 180
 181 SET(LIBTYPE SHARED)
 182 IF(DEFINED STATIC)
 183   SET(LIBTYPE STATIC)
 184 ENDIF()
 185
 186 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 187
 188 TARGET_LINK_LIBRARIES( ${name}
 189   ${DALICORE_LDFLAGS}
 190   ${DALIADAPTOR_LDFLAGS}
 191   ${COVERAGE}
 192 )
 193
 194 SET_TARGET_PROPERTIES( ${name}
 195   PROPERTIES
 196   VERSION ${DALI_TOOLKIT_VERSION}
 197   SOVERSION ${${name}_VERSION_MAJOR}
 198   CLEAN_DIRECT_OUPUT 1
 199 )
 200
 201 # Install the library so file and symlinks
 202 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 203
 204 # Install the pkg-config file
 205 INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 206
 207 # Glob for resources
 208 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 209   FOREACH( PATTERN ${FILE_LIST} )
 210     FILE(GLOB FILES ${PATTERN} )
 211     FOREACH( FILE ${FILES} )
 212       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 213       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 214       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 215         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 216         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 217       ELSE()
 218         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 219       ENDIF()
 220     ENDFOREACH()
 221   ENDFOREACH()
 222 ENDMACRO()
 223
 224 # macro for installing headers by replacing prefix. (TODO, investigate
 225 # if there is a CMAKE way of doing this automatically)
 226 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 227   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 228   FOREACH(HEADER ${${HEADER_LIST}})
 229     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 230     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 231     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 232   ENDFOREACH(HEADER)
 233 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 234
 235 # Install headers using lists defined by ADD_SUBDIRECTORY
 236 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 237 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 238 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 239 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 240
 241 # Install dali-toolkit.h
 242 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit )
 243
 244 # package doxygen file (contains doxygen grouping information)
 245 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
 246
 247 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/styles" )
 248 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/images" )
 249 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/sounds" )
 250 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/styles/images" )
 251
 252 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
 253 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 254 # target names duplication with other DALi modules.
 255 IF( UNIX )
 256   FIND_PROGRAM( LCOV_BIN "lcov" )
 257   IF( LCOV_BIN )
 258
 259     # Define custom rules for coverage
 260     SET(COVERAGE_DIR .cov)
 261     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 262
 263     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 264     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 265     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 266     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 267     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 268       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 269     ENDIF()
 270
 271     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
 272
 273     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 274       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" "*/dali-env/*" "*solid-color-actor*" "*/dali-toolkit/third-party/*" -o dali.info )
 275
 276     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 277       DEPENDS cov_data )
 278
 279     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 280
 281     # Define custom rule for distclean
 282     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
 283     ADD_CUSTOM_COMMAND(
 284           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
 285           COMMENT "distribution clean"
 286           COMMAND find
 287           ARGS    .
 288           -not -name config.cmake -and \(
 289           -name tester.c -or
 290           -name Testing -or
 291           -name CMakeFiles -or
 292           -name doc -or
 293           -name cmake.depends -or
 294           -name cmake.check_depends -or
 295           -name CMakeCache.txt -or
 296           -name cmake.check_cache -or
 297           -name *.cmake -or
 298           -name Makefile -or
 299           -name core -or
 300           -name core.* -or
 301           -name gmon.out -or
 302           -name install_manifest.txt -or
 303           -name *.pc -or
 304           -name *.gcov -or
 305           -name *.gcno -or
 306           -name *.gcda -or
 307           -name *~ -or
 308           -name libdali*.so* \)
 309           | grep -v TC | xargs rm -rf
 310           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
 311           VERBATIM
 312           )
 313
 314   ENDIF( LCOV_BIN )
 315 ENDIF( UNIX )
 316
 317 # Build documentation if doxygen tool is available
 318 SET( doxygenEnabled OFF )
 319 IF( DOXYGEN_FOUND )
 320   SET( doxygenEnabled ON )
 321   # 'prefix' is used by doxygen in-files.
 322   SET( prefix ${PREFIX} )
 323   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 324   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 325   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 326   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 327   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 328   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 329   ADD_CUSTOM_TARGET( doc_doxygen ALL
 330                      DEPENDS ${name}
 331                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 332                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 333                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 334                      COMMENT "Generating API documentation with Doxygen"
 335                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 336                      VERBATIM )
 337   ADD_CUSTOM_TARGET( doc_doxygen_internal
 338                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 339                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 340                      COMMENT "Generating Internal API documentation with Doxygen"
 341                      VERBATIM )
 342
 343 ENDIF()
 344
 345 # Configure automated tests
 346 CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 347                 ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 348
 349 # Configuration Messages
 350 MESSAGE( STATUS "Configuration:\n" )
 351 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 352 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 353 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 354 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 355 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 356 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 357 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 358 MESSAGE( STATUS "Doxygen:               " ${doxygenEnabled} )
 359 MESSAGE( STATUS "Data Dir (Read/Write): " ${dataReadWriteDir} )
 360 MESSAGE( STATUS "Data Dir (Read Only):  " ${dataReadOnlyDir} )
 361 MESSAGE( STATUS "Style Dir:             " ${STYLE_DIR} )
 362 MESSAGE( STATUS "Style:                 " ${dali_style} )
 363 MESSAGE( STATUS "i18n:                  " ${ENABLE_I18N} )
 364 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 365 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )