build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-toolkit")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 14)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   endif()
  16 endif()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  23
  24 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  28 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  29 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
  30 OPTION(ENABLE_I18N               "Turns on internationalisation" OFF)
  31 OPTION(ENABLE_COVERAGE           "Coverage" OFF)
  32 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  33 OPTION(ENABLE_LINK_TEST          "Enable the link test" ON)
  34 OPTION(INSTALL_DOXYGEN_DOC       "Install doxygen doc" ON)
  35 OPTION(CONFIGURE_AUTOMATED_TESTS "Configure automated tests" ON)
  36 OPTION(USE_DEFAULT_RESOURCE_DIR  "Whether to use the default resource folders. Otherwise set environment variables for DALI_IMAGE_DIR, DALI_SOUND_DIR, DALI_STYLE_DIR, DALI_STYLE_IMAGE_DIR and DALI_DATA_READ_ONLY_DIR" ON)
  37
  38 IF( ENABLE_PKG_CONFIGURE )
  39   FIND_PACKAGE( PkgConfig REQUIRED )
  40
  41   PKG_CHECK_MODULES(DALICORE REQUIRED dali2-core)
  42   PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali2-adaptor)
  43 ENDIF()
  44
  45 IF( INSTALL_DOXYGEN_DOC )
  46   FIND_PACKAGE( Doxygen QUIET )
  47 ENDIF()
  48
  49 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  50   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  51   FIND_PACKAGE( dali2-core REQUIRED)
  52   FIND_PACKAGE( dali2-adaptor REQUIRED)
  53 ENDIF()
  54
  55 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  56
  57 # Define non-boolean options to CMake
  58 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  59
  60 # from root/build/tizen, get back to root
  61 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  62
  63 # Deployment folder should come from spec file or command line:
  64 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  65 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  66
  67 # Make sure the path is absolute
  68 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  69
  70 # Set DALi style
  71 SET( dali_style ${WITH_STYLE} )
  72
  73 # Style folder
  74 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  75 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  76
  77 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  78 SET( toolkit_styles_dir ${STYLE_DIR} )
  79 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  80
  81 IF( DEFINED ENV{DALI_DATA_RW_DIR} )
  82   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR} )
  83 ELSE()
  84   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  85 ENDIF()
  86
  87 IF( DEFINED ENV{DALI_DATA_RO_DIR} )
  88   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR} )
  89 ELSE()
  90   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  91 ENDIF()
  92
  93 # Set up compiler definitions
  94
  95 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  96   SET( ENABLE_DEBUG ON )
  97 ENDIF()
  98
  99 IF( ENABLE_DEBUG )
 100   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
 101   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
 102   SET( ENABLE_EXPORTALL ON )
 103 ELSE()
 104   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
 105 ENDIF()
 106
 107 IF( ENABLE_I18N )
 108   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
 109 ENDIF( ENABLE_I18N )
 110
 111 IF( WIN32 )
 112   ADD_DEFINITIONS( "-DBUILDING_DALI_TOOLKIT" )
 113
 114   IF( USE_DEFAULT_RESOURCE_DIR )
 115     SET( INSTALL_SHARE_DIR "${PREFIX}/share" )
 116     IF( VCPKG_TOOLKIT_BUILD )
 117       SET( INSTALL_SHARE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/share" )
 118     ENDIF()
 119
 120     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/images/\"
 121                      -DDALI_SOUND_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/sounds/\"
 122                      -DDALI_STYLE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/\"
 123                      -DDALI_STYLE_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/images/\"
 124                      -DDALI_DATA_READ_ONLY_DIR=\"${INSTALL_SHARE_DIR}/\" )
 125   ENDIF()
 126 ELSEIF( UNIX )
 127   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
 128   IF( USE_DEFAULT_RESOURCE_DIR )
 129     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
 130                      -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
 131                      -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
 132                      -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
 133                      -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
 134   ENDIF()
 135
 136   IF("${ARCH}" STREQUAL "arm")
 137     ADD_DEFINITIONS("-DTARGET")
 138   ENDIF("${ARCH}" STREQUAL "arm")
 139
 140   IF( NOT ${ENABLE_EXPORTALL} )
 141     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 142   ENDIF( NOT ${ENABLE_EXPORTALL} )
 143 ENDIF()
 144
 145 IF( NOT USE_DEFAULT_RESOURCE_DIR )
 146   ADD_DEFINITIONS( -DDALI_IMAGE_DIR=0
 147                    -DDALI_SOUND_DIR=0
 148                    -DDALI_STYLE_DIR=0
 149                    -DDALI_STYLE_IMAGE_DIR=0
 150                    -DDALI_DATA_READ_ONLY_DIR=0 )
 151 ENDIF()
 152
 153 IF( ENABLE_TRACE )
 154   ADD_DEFINITIONS("-DTRACE_ENABLED")
 155 ENDIF()
 156
 157 # Set paths
 158 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 159 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 160 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 161 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 162 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 163 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 164 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 165
 166 # Set up the include dir
 167 SET( INCLUDE_DIR $ENV{includedir} )
 168 IF( NOT INCLUDE_DIR )
 169   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 170 ENDIF()
 171 IF( NOT INCLUDE_DIR )
 172   SET( INCLUDE_DIR ${PREFIX}/include )
 173 ENDIF()
 174
 175 # Set up the lib dir
 176 SET( LIB_DIR $ENV{libdir} )
 177 IF( NOT LIB_DIR )
 178   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 179 ENDIF()
 180 IF( NOT LIB_DIR )
 181   SET( LIB_DIR ${PREFIX}/lib )
 182 ENDIF()
 183
 184 # Set up the bin dir
 185 SET( BIN_DIR $ENV{bindir} )
 186 IF( NOT BIN_DIR )
 187   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 188 ENDIF()
 189 IF( NOT BIN_DIR )
 190   SET( BIN_DIR ${PREFIX}/bin )
 191 ENDIF()
 192
 193 IF( ENABLE_PKG_CONFIGURE )
 194   # Configure the pkg-config file
 195   # Requires the following variables to be setup:
 196   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 197   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 198   SET( CORE_PKG_CFG_FILE dali2-toolkit.pc )
 199   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 200 ENDIF()
 201
 202 IF( WIN32 )
 203   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 204   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 205   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 206 ELSE()
 207   # Set up compiler flags and warnings
 208   ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 209
 210   # TODO: Clang is a lot more strict with warnings, we should address
 211   # those issues at some point.
 212   IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 213     ADD_COMPILE_OPTIONS( -Werror )
 214   ENDIF()
 215
 216   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal -Wno-class-memaccess )
 217
 218   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 219     ADD_COMPILE_OPTIONS( --coverage )
 220     SET(ENABLE_COVERAGE ON)
 221     SET(COVERAGE --coverage)
 222   ENDIF()
 223
 224   IF( NOT ${ENABLE_EXPORTALL} )
 225     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 226   ENDIF( NOT ${ENABLE_EXPORTALL} )
 227 ENDIF()
 228
 229
 230 INCLUDE_DIRECTORIES(
 231   ${ROOT_SRC_DIR}
 232   ${DALICORE_INCLUDE_DIRS}
 233   ${DALIADAPTOR_INCLUDE_DIRS}
 234   ${VCPKG_INCLUDE_DIR}
 235   ${INCLUDE_DIR}
 236 )
 237
 238 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 239 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 240
 241 SET(SOURCES "")
 242
 243 # could use INCLUDE to get the source lists a different way;
 244 # would then need to specify a build folder somehow...
 245 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
 246 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
 247 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
 248 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
 249 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
 250 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
 251 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
 252 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 253
 254 # Platforms with highp shader support can use vector based text
 255 IF( NOT DEFINED ENABLE_VECTOR_BASED_TEXT_RENDERING )
 256   SET(ENABLE_VECTOR_BASED_TEXT_RENDERING ON)
 257 ENDIF()
 258
 259 IF( ENABLE_VECTOR_BASED_TEXT_RENDERING )
 260   ADD_DEFINITIONS( "-DENABLE_VECTOR_BASED_TEXT_RENDERING" )
 261   INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/text/rendering/vector-based/file.list )
 262 ENDIF()
 263
 264 SET(LIBTYPE SHARED)
 265 IF(DEFINED STATIC)
 266   SET(LIBTYPE STATIC)
 267 ENDIF()
 268
 269 IF( WIN32 )
 270   SET( DALICORE_LDFLAGS
 271         "${DALICORE_LDFLAGS}"
 272         dali2-core::dali2-core )
 273
 274   FIND_PACKAGE( pthreads REQUIRED )
 275   FIND_PACKAGE( curl REQUIRED )
 276   FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 277   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 278
 279   FIND_PACKAGE( png REQUIRED )
 280   FIND_PACKAGE( gif REQUIRED )
 281   FIND_PACKAGE( jpeg REQUIRED )
 282   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 283
 284   FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 285   FIND_PACKAGE( freetype REQUIRED )
 286   FIND_PACKAGE( harfbuzz REQUIRED )
 287   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 288
 289   FIND_PACKAGE( unofficial-angle REQUIRED )
 290   FIND_PACKAGE( unofficial-cairo REQUIRED )
 291
 292   FIND_PACKAGE( WebP REQUIRED )
 293
 294   SET( DALIADAPTOR_LDFLAGS
 295        "${DALIADAPTOR_LDFLAGS}"
 296        dali2-adaptor::dali2-adaptor )
 297 ENDIF()
 298
 299
 300 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 301 TARGET_LINK_LIBRARIES( ${name}
 302   ${DALICORE_LDFLAGS}
 303   ${DALIADAPTOR_LDFLAGS}
 304   ${COVERAGE}
 305 )
 306
 307 IF( ANDROID )
 308   TARGET_LINK_LIBRARIES( ${name} log )
 309 ENDIF()
 310
 311 SET_TARGET_PROPERTIES( ${name}
 312   PROPERTIES
 313   VERSION ${DALI_TOOLKIT_VERSION}
 314   SOVERSION ${${name}_VERSION_MAJOR}
 315   CLEAN_DIRECT_OUPUT 1
 316 )
 317
 318 IF( INSTALL_CMAKE_MODULES )
 319   IF( ENABLE_DEBUG )
 320     SET( BIN_DIR "${BIN_DIR}/debug" )
 321     SET( LIB_DIR "${LIB_DIR}/debug" )
 322   ENDIF()
 323
 324   # Install the library files.
 325   INSTALL( TARGETS ${name}
 326     EXPORT ${name}-targets
 327     LIBRARY DESTINATION ${LIB_DIR}
 328     ARCHIVE DESTINATION ${LIB_DIR}
 329     RUNTIME DESTINATION ${BIN_DIR}
 330   )
 331
 332   # Install the cmake modules.
 333   INSTALL(
 334     EXPORT ${name}-targets
 335     NAMESPACE ${name}::
 336     FILE ${name}-targets.cmake
 337     DESTINATION share/${name}
 338   )
 339
 340   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 341     include(CMakeFindDependencyMacro)
 342     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 343   ")
 344   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 345
 346   # Install the pdb file.
 347   IF( ENABLE_DEBUG )
 348     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 349   ENDIF()
 350 ELSE()
 351   # Install the library so file and symlinks
 352   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 353 ENDIF()
 354
 355 # Install the pkg-config file
 356 IF( ENABLE_PKG_CONFIGURE )
 357   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 358 ENDIF()
 359
 360 # Glob for resources
 361 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 362   FOREACH( PATTERN ${FILE_LIST} )
 363     FILE(GLOB FILES ${PATTERN} )
 364     FOREACH( FILE ${FILES} )
 365       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 366       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 367       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 368         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 369         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 370       ELSE()
 371         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 372       ENDIF()
 373     ENDFOREACH()
 374   ENDFOREACH()
 375 ENDMACRO()
 376
 377 # macro for installing headers by replacing prefix. (TODO, investigate
 378 # if there is a CMAKE way of doing this automatically)
 379 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 380   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 381   FOREACH(HEADER ${${HEADER_LIST}})
 382     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 383     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 384     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 385   ENDFOREACH(HEADER)
 386 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 387
 388 # Install headers using lists defined by ADD_SUBDIRECTORY
 389 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 390 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 391 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 392 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 393
 394 # Install dali-toolkit.h
 395 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${INCLUDE_DIR}/dali-toolkit )
 396
 397 # package doxygen file (contains doxygen grouping information)
 398 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
 399
 400 # On some platforms we want to install the data files to different location compare to
 401 # the data location used runtime. For example, on Android we want the toolkit library to load
 402 # the files from /data/data/com.sec.dali_demo/files but to install the files into ${PREFIX}/files
 403 # for SDK to pick them up for the archive.
 404 IF( DEFINED ENV{DALI_DATA_RW_INSTALL_DIR} )
 405   SET( dataReadWriteInstallDir $ENV{DALI_DATA_RW_INSTALL_DIR} )
 406 ELSE()
 407   SET( dataReadWriteInstallDir ${dataReadWriteDir} )
 408 ENDIF()
 409
 410 IF( DEFINED ENV{DALI_DATA_RO_INSTALL_DIR} )
 411   SET( dataReadOnlyInstallDir $ENV{DALI_DATA_RO_INSTALL_DIR} )
 412 ELSE()
 413   SET( dataReadOnlyInstallDir ${dataReadOnlyDir} )
 414 ENDIF()
 415
 416 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles" )
 417 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/images" )
 418 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/sounds" )
 419 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles/images" )
 420
 421 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
 422 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 423 # target names duplication with other DALi modules.
 424 IF( ENABLE_COVERAGE )
 425   FIND_PROGRAM( LCOV_BIN "lcov" )
 426   IF( LCOV_BIN )
 427
 428     # Define custom rules for coverage
 429     SET(COVERAGE_DIR .cov)
 430     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 431
 432     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 433     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 434     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 435     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 436     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 437       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 438     ENDIF()
 439
 440     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
 441
 442     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 443       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" "*/dali-env/*" "*solid-color-actor*" "*/dali-toolkit/third-party/*" -o dali.info )
 444
 445     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 446       DEPENDS cov_data )
 447
 448     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 449
 450     # Define custom rule for distclean
 451     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
 452     ADD_CUSTOM_COMMAND(
 453           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
 454           COMMENT "distribution clean"
 455           COMMAND find
 456           ARGS    .
 457           -not -name config.cmake -and \(
 458           -name tester.c -or
 459           -name Testing -or
 460           -name CMakeFiles -or
 461           -name doc -or
 462           -name cmake.depends -or
 463           -name cmake.check_depends -or
 464           -name CMakeCache.txt -or
 465           -name cmake.check_cache -or
 466           -name *.cmake -or
 467           -name Makefile -or
 468           -name core -or
 469           -name core.* -or
 470           -name gmon.out -or
 471           -name install_manifest.txt -or
 472           -name *.pc -or
 473           -name *.gcov -or
 474           -name *.gcno -or
 475           -name *.gcda -or
 476           -name *~ -or
 477           -name libdali*.so* \)
 478           | grep -v TC | xargs rm -rf
 479           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
 480           VERBATIM
 481           )
 482
 483   ENDIF( LCOV_BIN )
 484 ENDIF()
 485
 486 # Build documentation if doxygen tool is available
 487 SET( doxygenEnabled OFF )
 488 IF( DOXYGEN_FOUND )
 489   SET( doxygenEnabled ON )
 490   # 'prefix' is used by doxygen in-files.
 491   SET( prefix ${PREFIX} )
 492   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 493   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 494   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 495   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 496   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 497   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 498   ADD_CUSTOM_TARGET( doc_doxygen ALL
 499                      DEPENDS ${name}
 500                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 501                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 502                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 503                      COMMENT "Generating API documentation with Doxygen"
 504                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 505                      VERBATIM )
 506   ADD_CUSTOM_TARGET( doc_doxygen_internal
 507                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 508                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 509                      COMMENT "Generating Internal API documentation with Doxygen"
 510                      VERBATIM )
 511
 512 ENDIF()
 513
 514 IF( CONFIGURE_AUTOMATED_TESTS )
 515   # Configure automated tests
 516   CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 517                   ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 518 ENDIF()
 519
 520 # Configuration Messages
 521 MESSAGE( STATUS "Configuration:\n" )
 522 MESSAGE( STATUS "Prefix:                        " ${PREFIX} )
 523 MESSAGE( STATUS "Lib Dir:                       " ${LIB_DIR} )
 524 MESSAGE( STATUS "Include Dir:                   " ${INCLUDE_DIR} )
 525 MESSAGE( STATUS "Debug build:                   " ${ENABLE_DEBUG} )
 526 MESSAGE( STATUS "Export all symbols:            " ${ENABLE_EXPORTALL} )
 527 MESSAGE( STATUS "Coverage:                      " ${ENABLE_COVERAGE} )
 528 MESSAGE( STATUS "Trace:                         " ${ENABLE_TRACE} )
 529 MESSAGE( STATUS "Doxygen:                       " ${doxygenEnabled} )
 530 MESSAGE( STATUS "Data Dir (Read/Write):         " ${dataReadWriteDir} )
 531 MESSAGE( STATUS "Data Dir (Read Only):          " ${dataReadOnlyDir} )
 532 MESSAGE( STATUS "Data Install Dir (Read/Write): " ${dataReadWriteInstallDir} )
 533 MESSAGE( STATUS "Data Install Dir (Read Only):  " ${dataReadOnlyInstallDir} )
 534 MESSAGE( STATUS "Style Dir:                     " ${STYLE_DIR} )
 535 MESSAGE( STATUS "Style:                         " ${dali_style} )
 536 MESSAGE( STATUS "i18n:                          " ${ENABLE_I18N} )
 537 MESSAGE( STATUS "Use pkg configure:             " ${ENABLE_PKG_CONFIGURE} )
 538 MESSAGE( STATUS "Vector Based Text Rendering:   " ${ENABLE_VECTOR_BASED_TEXT_RENDERING} )
 539 MESSAGE( STATUS "Enable link test:              " ${ENABLE_LINK_TEST} )
 540 MESSAGE( STATUS "Configure automated tests:     " ${CONFIGURE_AUTOMATED_TESTS} )
 541 MESSAGE( STATUS "CXXFLAGS:                      " ${CMAKE_CXX_FLAGS} )
 542 MESSAGE( STATUS "LDFLAGS:                       " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )
 543
 544 MESSAGE( " Folder       INSTALL_SHARE_DIR : [" ${INSTALL_SHARE_DIR} "]" )
 545 MESSAGE( " Folder          DALI_IMAGE_DIR : [" ${DALI_IMAGE_DIR} "]" )
 546 MESSAGE( " Folder          DALI_STYLE_DIR : [" ${DALI_STYLE_DIR} "]" )
 547 MESSAGE( " Folder    DALI_STYLE_IMAGE_DIR : [" ${DALI_STYLE_IMAGE_DIR} "]" )
 548 MESSAGE( " Folder          DALI_SOUND_DIR : [" ${DALI_SOUND_DIR} "]" )
 549 MESSAGE( " Folder DALI_DATA_READ_ONLY_DIR : [" ${DALI_DATA_READ_ONLY_DIR} "]" )