build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-toolkit")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   endif()
  16 endif()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  23
  24 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  28 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  29 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
  30 OPTION(ENABLE_I18N               "Turns on internationalisation" OFF)
  31 OPTION(ENABLE_COVERAGE           "Coverage" OFF)
  32 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  33 OPTION(ENABLE_LINK_TEST          "Enable the link test" ON)
  34 OPTION(INSTALL_DOXYGEN_DOC       "Install doxygen doc" ON)
  35 OPTION(CONFIGURE_AUTOMATED_TESTS "Configure automated tests" ON)
  36 OPTION(USE_DEFAULT_RESOURCE_DIR  "Whether to use the default resource folders. Otherwise set environment variables for DALI_IMAGE_DIR, DALI_SOUND_DIR, DALI_STYLE_DIR, DALI_STYLE_IMAGE_DIR and DALI_DATA_READ_ONLY_DIR" ON)
  37 OPTION(BUILD_SCENE_LOADER        "Whether to build dali-scene-loader." ON)
  38
  39 IF( ENABLE_PKG_CONFIGURE )
  40   FIND_PACKAGE( PkgConfig REQUIRED )
  41
  42   PKG_CHECK_MODULES(DALICORE REQUIRED dali2-core)
  43   PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali2-adaptor)
  44 ENDIF()
  45
  46 IF( INSTALL_DOXYGEN_DOC )
  47   FIND_PACKAGE( Doxygen QUIET )
  48 ENDIF()
  49
  50 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  51   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  52   FIND_PACKAGE( dali2-core REQUIRED)
  53   FIND_PACKAGE( dali2-adaptor REQUIRED)
  54 ENDIF()
  55
  56 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  57
  58 # Define non-boolean options to CMake
  59 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  60
  61 # from root/build/tizen, get back to root
  62 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  63
  64 # Deployment folder should come from spec file or command line:
  65 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  66 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  67
  68 # Make sure the path is absolute
  69 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  70
  71 # Set DALi style
  72 SET( dali_style ${WITH_STYLE} )
  73
  74 # Style folder
  75 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  76 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  77
  78 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  79 SET( toolkit_styles_dir ${STYLE_DIR} )
  80 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  81
  82 IF( DEFINED ENV{DALI_DATA_RW_DIR} )
  83   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR} )
  84 ELSE()
  85   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  86 ENDIF()
  87
  88 IF( DEFINED ENV{DALI_DATA_RO_DIR} )
  89   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR} )
  90 ELSE()
  91   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  92 ENDIF()
  93
  94 # Set up compiler definitions
  95
  96 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  97   SET( ENABLE_DEBUG ON )
  98 ENDIF()
  99
 100 IF( ENABLE_DEBUG )
 101   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
 102   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
 103   SET( ENABLE_EXPORTALL ON )
 104 ELSE()
 105   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
 106 ENDIF()
 107
 108 IF( ENABLE_I18N )
 109   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
 110 ENDIF( ENABLE_I18N )
 111
 112 IF( WIN32 )
 113   ADD_DEFINITIONS( "-DBUILDING_DALI_TOOLKIT" )
 114
 115   IF( USE_DEFAULT_RESOURCE_DIR )
 116     SET( INSTALL_SHARE_DIR "${PREFIX}/share" )
 117     IF( VCPKG_TOOLKIT_BUILD )
 118       SET( INSTALL_SHARE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/share" )
 119     ENDIF()
 120
 121     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/images/\"
 122                      -DDALI_SOUND_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/sounds/\"
 123                      -DDALI_STYLE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/\"
 124                      -DDALI_STYLE_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/images/\"
 125                      -DDALI_DATA_READ_ONLY_DIR=\"${INSTALL_SHARE_DIR}/\" )
 126   ENDIF()
 127 ELSEIF( UNIX )
 128   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
 129   IF( USE_DEFAULT_RESOURCE_DIR )
 130     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
 131                      -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
 132                      -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
 133                      -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
 134                      -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
 135   ENDIF()
 136
 137   IF("${ARCH}" STREQUAL "arm")
 138     ADD_DEFINITIONS("-DTARGET")
 139   ENDIF("${ARCH}" STREQUAL "arm")
 140
 141   IF( NOT ${ENABLE_EXPORTALL} )
 142     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 143   ENDIF( NOT ${ENABLE_EXPORTALL} )
 144 ENDIF()
 145
 146 IF( NOT USE_DEFAULT_RESOURCE_DIR )
 147   ADD_DEFINITIONS( -DDALI_IMAGE_DIR=0
 148                    -DDALI_SOUND_DIR=0
 149                    -DDALI_STYLE_DIR=0
 150                    -DDALI_STYLE_IMAGE_DIR=0
 151                    -DDALI_DATA_READ_ONLY_DIR=0 )
 152 ENDIF()
 153
 154 IF( ENABLE_TRACE )
 155   ADD_DEFINITIONS("-DTRACE_ENABLED")
 156 ENDIF()
 157
 158 # Remove below when thorvg is ready
 159 ADD_DEFINITIONS( "-DNO_THORVG" )
 160
 161 # Set paths
 162 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 163 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 164 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 165 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 166 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 167 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 168 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 169
 170 # Set up the include dir
 171 SET( INCLUDE_DIR $ENV{includedir} )
 172 IF( NOT INCLUDE_DIR )
 173   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 174 ENDIF()
 175 IF( NOT INCLUDE_DIR )
 176   SET( INCLUDE_DIR ${PREFIX}/include )
 177 ENDIF()
 178
 179 # Set up the lib dir
 180 SET( LIB_DIR $ENV{libdir} )
 181 IF( NOT LIB_DIR )
 182   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 183 ENDIF()
 184 IF( NOT LIB_DIR )
 185   SET( LIB_DIR ${PREFIX}/lib )
 186 ENDIF()
 187
 188 # Set up the bin dir
 189 SET( BIN_DIR $ENV{bindir} )
 190 IF( NOT BIN_DIR )
 191   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 192 ENDIF()
 193 IF( NOT BIN_DIR )
 194   SET( BIN_DIR ${PREFIX}/bin )
 195 ENDIF()
 196
 197 IF( ENABLE_PKG_CONFIGURE )
 198   # Configure the pkg-config file
 199   # Requires the following variables to be setup:
 200   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 201   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 202   SET( CORE_PKG_CFG_FILE dali2-toolkit.pc )
 203   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 204 ENDIF()
 205
 206 IF( WIN32 )
 207   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 208   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 209   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 210 ELSE()
 211   # Set up compiler flags and warnings
 212   ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 213
 214   # TODO: Clang is a lot more strict with warnings, we should address
 215   # those issues at some point.
 216   IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 217     ADD_COMPILE_OPTIONS( -Werror )
 218   ENDIF()
 219
 220   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal -Wno-class-memaccess )
 221
 222   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 223     ADD_COMPILE_OPTIONS( --coverage )
 224     SET(ENABLE_COVERAGE ON)
 225     SET(COVERAGE --coverage)
 226   ENDIF()
 227
 228   IF( NOT ${ENABLE_EXPORTALL} )
 229     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 230   ENDIF( NOT ${ENABLE_EXPORTALL} )
 231 ENDIF()
 232
 233
 234 INCLUDE_DIRECTORIES(
 235   ${ROOT_SRC_DIR}
 236   ${DALICORE_INCLUDE_DIRS}
 237   ${DALIADAPTOR_INCLUDE_DIRS}
 238   ${VCPKG_INCLUDE_DIR}
 239   ${INCLUDE_DIR}
 240 )
 241
 242 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 243 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 244
 245 SET(SOURCES "")
 246
 247 # could use INCLUDE to get the source lists a different way;
 248 # would then need to specify a build folder somehow...
 249 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
 250 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
 251 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
 252 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
 253 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
 254 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
 255 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
 256 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 257
 258 # Platforms with highp shader support can use vector based text
 259 IF( NOT DEFINED ENABLE_VECTOR_BASED_TEXT_RENDERING )
 260   SET(ENABLE_VECTOR_BASED_TEXT_RENDERING ON)
 261 ENDIF()
 262
 263 IF( ENABLE_VECTOR_BASED_TEXT_RENDERING )
 264   ADD_DEFINITIONS( "-DENABLE_VECTOR_BASED_TEXT_RENDERING" )
 265   INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/text/rendering/vector-based/file.list )
 266 ENDIF()
 267
 268 SET(LIBTYPE SHARED)
 269 IF(DEFINED STATIC)
 270   SET(LIBTYPE STATIC)
 271 ENDIF()
 272
 273 IF( WIN32 )
 274   SET( DALICORE_LDFLAGS
 275         "${DALICORE_LDFLAGS}"
 276         dali2-core::dali2-core )
 277
 278   FIND_PACKAGE( pthreads REQUIRED )
 279   FIND_PACKAGE( curl REQUIRED )
 280   FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 281   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 282
 283   FIND_PACKAGE( png REQUIRED )
 284   FIND_PACKAGE( gif REQUIRED )
 285   FIND_PACKAGE( jpeg REQUIRED )
 286   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 287
 288   FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 289   FIND_PACKAGE( freetype REQUIRED )
 290   FIND_PACKAGE( harfbuzz REQUIRED )
 291   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 292
 293   FIND_PACKAGE( unofficial-angle REQUIRED )
 294   FIND_PACKAGE( unofficial-cairo REQUIRED )
 295
 296   FIND_PACKAGE( WebP REQUIRED )
 297
 298   SET( DALIADAPTOR_LDFLAGS
 299        "${DALIADAPTOR_LDFLAGS}"
 300        dali2-adaptor::dali2-adaptor )
 301 ENDIF()
 302
 303
 304 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 305 TARGET_LINK_LIBRARIES( ${name}
 306   ${DALICORE_LDFLAGS}
 307   ${DALIADAPTOR_LDFLAGS}
 308   ${COVERAGE}
 309 )
 310
 311 IF( ANDROID )
 312   TARGET_LINK_LIBRARIES( ${name} log )
 313 ENDIF()
 314
 315 SET_TARGET_PROPERTIES( ${name}
 316   PROPERTIES
 317   VERSION ${DALI_TOOLKIT_VERSION}
 318   SOVERSION ${${name}_VERSION_MAJOR}
 319   CLEAN_DIRECT_OUPUT 1
 320 )
 321
 322 IF( INSTALL_CMAKE_MODULES )
 323   IF( ENABLE_DEBUG )
 324     SET( BIN_DIR "${BIN_DIR}/debug" )
 325     SET( LIB_DIR "${LIB_DIR}/debug" )
 326   ENDIF()
 327
 328   # Install the library files.
 329   INSTALL( TARGETS ${name}
 330     EXPORT ${name}-targets
 331     LIBRARY DESTINATION ${LIB_DIR}
 332     ARCHIVE DESTINATION ${LIB_DIR}
 333     RUNTIME DESTINATION ${BIN_DIR}
 334   )
 335
 336   # Install the cmake modules.
 337   INSTALL(
 338     EXPORT ${name}-targets
 339     NAMESPACE ${name}::
 340     FILE ${name}-targets.cmake
 341     DESTINATION share/${name}
 342   )
 343
 344   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 345     include(CMakeFindDependencyMacro)
 346     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 347   ")
 348   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 349
 350   # Install the pdb file.
 351   IF( ENABLE_DEBUG )
 352     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 353   ENDIF()
 354 ELSE()
 355   # Install the library so file and symlinks
 356   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 357 ENDIF()
 358
 359 # Install the pkg-config file
 360 IF( ENABLE_PKG_CONFIGURE )
 361   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 362 ENDIF()
 363
 364 # Glob for resources
 365 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 366   FOREACH( PATTERN ${FILE_LIST} )
 367     FILE(GLOB FILES ${PATTERN} )
 368     FOREACH( FILE ${FILES} )
 369       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 370       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 371       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 372         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 373         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 374       ELSE()
 375         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 376       ENDIF()
 377     ENDFOREACH()
 378   ENDFOREACH()
 379 ENDMACRO()
 380
 381 # macro for installing headers by replacing prefix. (TODO, investigate
 382 # if there is a CMAKE way of doing this automatically)
 383 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 384   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 385   FOREACH(HEADER ${${HEADER_LIST}})
 386     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 387     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 388     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 389   ENDFOREACH(HEADER)
 390 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 391
 392 # Install headers using lists defined by ADD_SUBDIRECTORY
 393 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 394 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 395 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 396 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 397
 398 # Install dali-toolkit.h
 399 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${INCLUDE_DIR}/dali-toolkit )
 400
 401 # package doxygen file (contains doxygen grouping information)
 402 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
 403
 404 # On some platforms we want to install the data files to different location compare to
 405 # the data location used runtime. For example, on Android we want the toolkit library to load
 406 # the files from /data/data/com.sec.dali_demo/files but to install the files into ${PREFIX}/files
 407 # for SDK to pick them up for the archive.
 408 IF( DEFINED ENV{DALI_DATA_RW_INSTALL_DIR} )
 409   SET( dataReadWriteInstallDir $ENV{DALI_DATA_RW_INSTALL_DIR} )
 410 ELSE()
 411   SET( dataReadWriteInstallDir ${dataReadWriteDir} )
 412 ENDIF()
 413
 414 IF( DEFINED ENV{DALI_DATA_RO_INSTALL_DIR} )
 415   SET( dataReadOnlyInstallDir $ENV{DALI_DATA_RO_INSTALL_DIR} )
 416 ELSE()
 417   SET( dataReadOnlyInstallDir ${dataReadOnlyDir} )
 418 ENDIF()
 419
 420 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles" )
 421 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/images" )
 422 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/sounds" )
 423 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles/images" )
 424
 425 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
 426 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 427 # target names duplication with other DALi modules.
 428 IF( ENABLE_COVERAGE )
 429   FIND_PROGRAM( LCOV_BIN "lcov" )
 430   IF( LCOV_BIN )
 431
 432     # Define custom rules for coverage
 433     SET(COVERAGE_DIR .cov)
 434     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 435
 436     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 437     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 438     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 439     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 440     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 441       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 442     ENDIF()
 443
 444     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
 445
 446     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 447       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" "*/dali-env/*" "*solid-color-actor*" "*/dali-toolkit/third-party/*" \"*/dali-scene-loader/third-party/*\" -o dali.info )
 448
 449     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 450       DEPENDS cov_data )
 451
 452     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 453
 454     # Define custom rule for distclean
 455     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
 456     ADD_CUSTOM_COMMAND(
 457           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
 458           COMMENT "distribution clean"
 459           COMMAND find
 460           ARGS    .
 461           -not -name config.cmake -and \(
 462           -name tester.c -or
 463           -name Testing -or
 464           -name CMakeFiles -or
 465           -name doc -or
 466           -name cmake.depends -or
 467           -name cmake.check_depends -or
 468           -name CMakeCache.txt -or
 469           -name cmake.check_cache -or
 470           -name *.cmake -or
 471           -name Makefile -or
 472           -name core -or
 473           -name core.* -or
 474           -name gmon.out -or
 475           -name install_manifest.txt -or
 476           -name *.pc -or
 477           -name *.gcov -or
 478           -name *.gcno -or
 479           -name *.gcda -or
 480           -name *~ -or
 481           -name libdali*.so* \)
 482           | grep -v TC | xargs rm -rf
 483           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
 484           VERBATIM
 485           )
 486
 487   ENDIF( LCOV_BIN )
 488 ENDIF()
 489
 490 # Build documentation if doxygen tool is available
 491 SET( doxygenEnabled OFF )
 492 IF( DOXYGEN_FOUND )
 493   SET( doxygenEnabled ON )
 494   # 'prefix' is used by doxygen in-files.
 495   SET( prefix ${PREFIX} )
 496   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 497   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 498   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 499   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 500   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 501   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 502   ADD_CUSTOM_TARGET( doc_doxygen ALL
 503                      DEPENDS ${name}
 504                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 505                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 506                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 507                      COMMENT "Generating API documentation with Doxygen"
 508                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 509                      VERBATIM )
 510   ADD_CUSTOM_TARGET( doc_doxygen_internal
 511                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 512                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 513                      COMMENT "Generating Internal API documentation with Doxygen"
 514                      VERBATIM )
 515
 516 ENDIF()
 517
 518 IF( CONFIGURE_AUTOMATED_TESTS )
 519   # Configure automated tests
 520   CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 521                   ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 522 ENDIF()
 523
 524 IF ( BUILD_SCENE_LOADER )
 525   ADD_SUBDIRECTORY( ${CMAKE_CURRENT_SOURCE_DIR}/dali-scene-loader )
 526 ENDIF()
 527
 528 # Configuration Messages
 529 MESSAGE( STATUS "Configuration:\n" )
 530 MESSAGE( STATUS "Prefix:                        " ${PREFIX} )
 531 MESSAGE( STATUS "Lib Dir:                       " ${LIB_DIR} )
 532 MESSAGE( STATUS "Include Dir:                   " ${INCLUDE_DIR} )
 533 MESSAGE( STATUS "Debug build:                   " ${ENABLE_DEBUG} )
 534 MESSAGE( STATUS "Export all symbols:            " ${ENABLE_EXPORTALL} )
 535 MESSAGE( STATUS "Coverage:                      " ${ENABLE_COVERAGE} )
 536 MESSAGE( STATUS "Trace:                         " ${ENABLE_TRACE} )
 537 MESSAGE( STATUS "Doxygen:                       " ${doxygenEnabled} )
 538 MESSAGE( STATUS "Data Dir (Read/Write):         " ${dataReadWriteDir} )
 539 MESSAGE( STATUS "Data Dir (Read Only):          " ${dataReadOnlyDir} )
 540 MESSAGE( STATUS "Data Install Dir (Read/Write): " ${dataReadWriteInstallDir} )
 541 MESSAGE( STATUS "Data Install Dir (Read Only):  " ${dataReadOnlyInstallDir} )
 542 MESSAGE( STATUS "Style Dir:                     " ${STYLE_DIR} )
 543 MESSAGE( STATUS "Style:                         " ${dali_style} )
 544 MESSAGE( STATUS "i18n:                          " ${ENABLE_I18N} )
 545 MESSAGE( STATUS "Use pkg configure:             " ${ENABLE_PKG_CONFIGURE} )
 546 MESSAGE( STATUS "Vector Based Text Rendering:   " ${ENABLE_VECTOR_BASED_TEXT_RENDERING} )
 547 MESSAGE( STATUS "Enable link test:              " ${ENABLE_LINK_TEST} )
 548 MESSAGE( STATUS "Configure automated tests:     " ${CONFIGURE_AUTOMATED_TESTS} )
 549 MESSAGE( STATUS "Build Dali Scene Loader:       " ${BUILD_SCENE_LOADER} )
 550 MESSAGE( STATUS "CXXFLAGS:                      " ${CMAKE_CXX_FLAGS} )
 551 MESSAGE( STATUS "LDFLAGS:                       " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )
 552
 553 MESSAGE( " Folder       INSTALL_SHARE_DIR : [" ${INSTALL_SHARE_DIR} "]" )
 554 MESSAGE( " Folder          DALI_IMAGE_DIR : [" ${DALI_IMAGE_DIR} "]" )
 555 MESSAGE( " Folder          DALI_STYLE_DIR : [" ${DALI_STYLE_DIR} "]" )
 556 MESSAGE( " Folder    DALI_STYLE_IMAGE_DIR : [" ${DALI_STYLE_IMAGE_DIR} "]" )
 557 MESSAGE( " Folder          DALI_SOUND_DIR : [" ${DALI_SOUND_DIR} "]" )
 558 MESSAGE( " Folder DALI_DATA_READ_ONLY_DIR : [" ${DALI_DATA_READ_ONLY_DIR} "]" )