build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-toolkit")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   endif()
  16 endif()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  23
  24 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  28 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  29 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
  30 OPTION(ENABLE_I18N               "Turns on internationalisation" OFF)
  31 OPTION(ENABLE_COVERAGE           "Coverage" OFF)
  32 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  33 OPTION(ENABLE_LINK_TEST          "Enable the link test" ON)
  34 OPTION(INSTALL_DOXYGEN_DOC       "Install doxygen doc" ON)
  35 OPTION(CONFIGURE_AUTOMATED_TESTS "Configure automated tests" ON)
  36 OPTION(USE_DEFAULT_RESOURCE_DIR  "Whether to use the default resource folders. Otherwise set environment variables for DALI_IMAGE_DIR, DALI_SOUND_DIR, DALI_STYLE_DIR, DALI_STYLE_IMAGE_DIR and DALI_DATA_READ_ONLY_DIR" ON)
  37
  38 IF( ENABLE_PKG_CONFIGURE )
  39   FIND_PACKAGE( PkgConfig REQUIRED )
  40
  41   PKG_CHECK_MODULES(DALICORE REQUIRED dali2-core)
  42   PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali2-adaptor)
  43 ENDIF()
  44
  45 IF( INSTALL_DOXYGEN_DOC )
  46   FIND_PACKAGE( Doxygen QUIET )
  47 ENDIF()
  48
  49 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  50   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  51   FIND_PACKAGE( dali2-core REQUIRED)
  52   FIND_PACKAGE( dali2-adaptor REQUIRED)
  53 ENDIF()
  54
  55 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  56
  57 # Define non-boolean options to CMake
  58 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  59
  60 # from root/build/tizen, get back to root
  61 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  62
  63 # Deployment folder should come from spec file or command line:
  64 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  65 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  66
  67 # Make sure the path is absolute
  68 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  69
  70 # Set DALi style
  71 SET( dali_style ${WITH_STYLE} )
  72
  73 # Style folder
  74 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  75 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  76
  77 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  78 SET( toolkit_styles_dir ${STYLE_DIR} )
  79 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  80
  81 IF( DEFINED ENV{DALI_DATA_RW_DIR} )
  82   SET( dataReadWriteDir $ENV{DALI_DATA_RW_DIR} )
  83 ELSE()
  84   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  85 ENDIF()
  86
  87 IF( DEFINED ENV{DALI_DATA_RO_DIR} )
  88   SET( dataReadOnlyDir $ENV{DALI_DATA_RO_DIR} )
  89 ELSE()
  90   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  91 ENDIF()
  92
  93 # Set up compiler definitions
  94
  95 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  96   SET( ENABLE_DEBUG ON )
  97 ENDIF()
  98
  99 IF( ENABLE_DEBUG )
 100   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
 101   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
 102   SET( ENABLE_EXPORTALL ON )
 103 ELSE()
 104   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
 105 ENDIF()
 106
 107 IF( ENABLE_I18N )
 108   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
 109 ENDIF( ENABLE_I18N )
 110
 111 IF( WIN32 )
 112   ADD_DEFINITIONS( "-DBUILDING_DALI_TOOLKIT" )
 113
 114   IF( USE_DEFAULT_RESOURCE_DIR )
 115     SET( INSTALL_SHARE_DIR "${PREFIX}/share" )
 116     IF( VCPKG_TOOLKIT_BUILD )
 117       SET( INSTALL_SHARE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/share" )
 118     ENDIF()
 119
 120     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/images/\"
 121                      -DDALI_SOUND_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/sounds/\"
 122                      -DDALI_STYLE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/\"
 123                      -DDALI_STYLE_IMAGE_DIR=\"${INSTALL_SHARE_DIR}/dali/toolkit/styles/images/\"
 124                      -DDALI_DATA_READ_ONLY_DIR=\"${INSTALL_SHARE_DIR}/\" )
 125   ENDIF()
 126 ELSEIF( UNIX )
 127   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
 128   IF( USE_DEFAULT_RESOURCE_DIR )
 129     ADD_DEFINITIONS( -DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
 130                      -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
 131                      -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
 132                      -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
 133                      -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
 134   ENDIF()
 135
 136   IF("${ARCH}" STREQUAL "arm")
 137     ADD_DEFINITIONS("-DTARGET")
 138   ENDIF("${ARCH}" STREQUAL "arm")
 139
 140   IF( NOT ${ENABLE_EXPORTALL} )
 141     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 142   ENDIF( NOT ${ENABLE_EXPORTALL} )
 143 ENDIF()
 144
 145 IF( NOT USE_DEFAULT_RESOURCE_DIR )
 146   ADD_DEFINITIONS( -DDALI_IMAGE_DIR=0
 147                    -DDALI_SOUND_DIR=0
 148                    -DDALI_STYLE_DIR=0
 149                    -DDALI_STYLE_IMAGE_DIR=0
 150                    -DDALI_DATA_READ_ONLY_DIR=0 )
 151 ENDIF()
 152
 153 IF( ENABLE_TRACE )
 154   ADD_DEFINITIONS("-DTRACE_ENABLED")
 155 ENDIF()
 156
 157 # Remove below when thorvg is ready
 158 ADD_DEFINITIONS( "-DNO_THORVG" )
 159
 160 # Set paths
 161 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 162 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 163 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 164 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 165 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 166 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 167 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 168
 169 # Set up the include dir
 170 SET( INCLUDE_DIR $ENV{includedir} )
 171 IF( NOT INCLUDE_DIR )
 172   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 173 ENDIF()
 174 IF( NOT INCLUDE_DIR )
 175   SET( INCLUDE_DIR ${PREFIX}/include )
 176 ENDIF()
 177
 178 # Set up the lib dir
 179 SET( LIB_DIR $ENV{libdir} )
 180 IF( NOT LIB_DIR )
 181   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 182 ENDIF()
 183 IF( NOT LIB_DIR )
 184   SET( LIB_DIR ${PREFIX}/lib )
 185 ENDIF()
 186
 187 # Set up the bin dir
 188 SET( BIN_DIR $ENV{bindir} )
 189 IF( NOT BIN_DIR )
 190   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 191 ENDIF()
 192 IF( NOT BIN_DIR )
 193   SET( BIN_DIR ${PREFIX}/bin )
 194 ENDIF()
 195
 196 IF( ENABLE_PKG_CONFIGURE )
 197   # Configure the pkg-config file
 198   # Requires the following variables to be setup:
 199   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 200   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 201   SET( CORE_PKG_CFG_FILE dali2-toolkit.pc )
 202   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 203 ENDIF()
 204
 205 IF( WIN32 )
 206   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 207   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 208   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 209 ELSE()
 210   # Set up compiler flags and warnings
 211   ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 212
 213   # TODO: Clang is a lot more strict with warnings, we should address
 214   # those issues at some point.
 215   IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 216     ADD_COMPILE_OPTIONS( -Werror )
 217   ENDIF()
 218
 219   ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal -Wno-class-memaccess )
 220
 221   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 222     ADD_COMPILE_OPTIONS( --coverage )
 223     SET(ENABLE_COVERAGE ON)
 224     SET(COVERAGE --coverage)
 225   ENDIF()
 226
 227   IF( NOT ${ENABLE_EXPORTALL} )
 228     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 229   ENDIF( NOT ${ENABLE_EXPORTALL} )
 230 ENDIF()
 231
 232
 233 INCLUDE_DIRECTORIES(
 234   ${ROOT_SRC_DIR}
 235   ${DALICORE_INCLUDE_DIRS}
 236   ${DALIADAPTOR_INCLUDE_DIRS}
 237   ${VCPKG_INCLUDE_DIR}
 238   ${INCLUDE_DIR}
 239 )
 240
 241 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 242 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 243
 244 SET(SOURCES "")
 245
 246 # could use INCLUDE to get the source lists a different way;
 247 # would then need to specify a build folder somehow...
 248 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file.list )
 249 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file.list )
 250 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file.list )
 251 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file.list )
 252 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file.list )
 253 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file.list )
 254 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file.list )
 255 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 256
 257 # Platforms with highp shader support can use vector based text
 258 IF( NOT DEFINED ENABLE_VECTOR_BASED_TEXT_RENDERING )
 259   SET(ENABLE_VECTOR_BASED_TEXT_RENDERING ON)
 260 ENDIF()
 261
 262 IF( ENABLE_VECTOR_BASED_TEXT_RENDERING )
 263   ADD_DEFINITIONS( "-DENABLE_VECTOR_BASED_TEXT_RENDERING" )
 264   INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/text/rendering/vector-based/file.list )
 265 ENDIF()
 266
 267 SET(LIBTYPE SHARED)
 268 IF(DEFINED STATIC)
 269   SET(LIBTYPE STATIC)
 270 ENDIF()
 271
 272 IF( WIN32 )
 273   SET( DALICORE_LDFLAGS
 274         "${DALICORE_LDFLAGS}"
 275         dali2-core::dali2-core )
 276
 277   FIND_PACKAGE( pthreads REQUIRED )
 278   FIND_PACKAGE( curl REQUIRED )
 279   FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 280   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 281
 282   FIND_PACKAGE( png REQUIRED )
 283   FIND_PACKAGE( gif REQUIRED )
 284   FIND_PACKAGE( jpeg REQUIRED )
 285   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 286
 287   FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 288   FIND_PACKAGE( freetype REQUIRED )
 289   FIND_PACKAGE( harfbuzz REQUIRED )
 290   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 291
 292   FIND_PACKAGE( unofficial-angle REQUIRED )
 293   FIND_PACKAGE( unofficial-cairo REQUIRED )
 294
 295   FIND_PACKAGE( WebP REQUIRED )
 296
 297   SET( DALIADAPTOR_LDFLAGS
 298        "${DALIADAPTOR_LDFLAGS}"
 299        dali2-adaptor::dali2-adaptor )
 300 ENDIF()
 301
 302
 303 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 304 TARGET_LINK_LIBRARIES( ${name}
 305   ${DALICORE_LDFLAGS}
 306   ${DALIADAPTOR_LDFLAGS}
 307   ${COVERAGE}
 308 )
 309
 310 IF( ANDROID )
 311   TARGET_LINK_LIBRARIES( ${name} log )
 312 ENDIF()
 313
 314 SET_TARGET_PROPERTIES( ${name}
 315   PROPERTIES
 316   VERSION ${DALI_TOOLKIT_VERSION}
 317   SOVERSION ${${name}_VERSION_MAJOR}
 318   CLEAN_DIRECT_OUPUT 1
 319 )
 320
 321 IF( INSTALL_CMAKE_MODULES )
 322   IF( ENABLE_DEBUG )
 323     SET( BIN_DIR "${BIN_DIR}/debug" )
 324     SET( LIB_DIR "${LIB_DIR}/debug" )
 325   ENDIF()
 326
 327   # Install the library files.
 328   INSTALL( TARGETS ${name}
 329     EXPORT ${name}-targets
 330     LIBRARY DESTINATION ${LIB_DIR}
 331     ARCHIVE DESTINATION ${LIB_DIR}
 332     RUNTIME DESTINATION ${BIN_DIR}
 333   )
 334
 335   # Install the cmake modules.
 336   INSTALL(
 337     EXPORT ${name}-targets
 338     NAMESPACE ${name}::
 339     FILE ${name}-targets.cmake
 340     DESTINATION share/${name}
 341   )
 342
 343   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 344     include(CMakeFindDependencyMacro)
 345     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 346   ")
 347   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 348
 349   # Install the pdb file.
 350   IF( ENABLE_DEBUG )
 351     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 352   ENDIF()
 353 ELSE()
 354   # Install the library so file and symlinks
 355   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 356 ENDIF()
 357
 358 # Install the pkg-config file
 359 IF( ENABLE_PKG_CONFIGURE )
 360   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 361 ENDIF()
 362
 363 # Glob for resources
 364 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 365   FOREACH( PATTERN ${FILE_LIST} )
 366     FILE(GLOB FILES ${PATTERN} )
 367     FOREACH( FILE ${FILES} )
 368       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 369       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 370       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 371         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 372         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 373       ELSE()
 374         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 375       ENDIF()
 376     ENDFOREACH()
 377   ENDFOREACH()
 378 ENDMACRO()
 379
 380 # macro for installing headers by replacing prefix. (TODO, investigate
 381 # if there is a CMAKE way of doing this automatically)
 382 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 383   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 384   FOREACH(HEADER ${${HEADER_LIST}})
 385     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 386     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 387     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 388   ENDFOREACH(HEADER)
 389 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 390
 391 # Install headers using lists defined by ADD_SUBDIRECTORY
 392 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 393 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 394 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 395 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 396
 397 # Install dali-toolkit.h
 398 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${INCLUDE_DIR}/dali-toolkit )
 399
 400 # package doxygen file (contains doxygen grouping information)
 401 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
 402
 403 # On some platforms we want to install the data files to different location compare to
 404 # the data location used runtime. For example, on Android we want the toolkit library to load
 405 # the files from /data/data/com.sec.dali_demo/files but to install the files into ${PREFIX}/files
 406 # for SDK to pick them up for the archive.
 407 IF( DEFINED ENV{DALI_DATA_RW_INSTALL_DIR} )
 408   SET( dataReadWriteInstallDir $ENV{DALI_DATA_RW_INSTALL_DIR} )
 409 ELSE()
 410   SET( dataReadWriteInstallDir ${dataReadWriteDir} )
 411 ENDIF()
 412
 413 IF( DEFINED ENV{DALI_DATA_RO_INSTALL_DIR} )
 414   SET( dataReadOnlyInstallDir $ENV{DALI_DATA_RO_INSTALL_DIR} )
 415 ELSE()
 416   SET( dataReadOnlyInstallDir ${dataReadOnlyDir} )
 417 ENDIF()
 418
 419 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles" )
 420 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/images" )
 421 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/sounds" )
 422 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyInstallDir}" "./toolkit/styles/images" )
 423
 424 # The DALI_TOOLKIT_PREFIX must be set if this CMakeLists.txt is executed
 425 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 426 # target names duplication with other DALi modules.
 427 IF( ENABLE_COVERAGE )
 428   FIND_PROGRAM( LCOV_BIN "lcov" )
 429   IF( LCOV_BIN )
 430
 431     # Define custom rules for coverage
 432     SET(COVERAGE_DIR .cov)
 433     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 434
 435     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 436     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 437     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 438     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 439     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 440       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 441     ENDIF()
 442
 443     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}rename_cov_data ./rename-cov-data )
 444
 445     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 446       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" "*/dali-env/*" "*solid-color-actor*" "*/dali-toolkit/third-party/*" -o dali.info )
 447
 448     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 449       DEPENDS cov_data )
 450
 451     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 452
 453     # Define custom rule for distclean
 454     ADD_CUSTOM_TARGET( ${DALI_TOOLKIT_PREFIX}distclean @echo cleaning for source distribution )
 455     ADD_CUSTOM_COMMAND(
 456           DEPENDS ${DALI_TOOLKIT_PREFIX}clean
 457           COMMENT "distribution clean"
 458           COMMAND find
 459           ARGS    .
 460           -not -name config.cmake -and \(
 461           -name tester.c -or
 462           -name Testing -or
 463           -name CMakeFiles -or
 464           -name doc -or
 465           -name cmake.depends -or
 466           -name cmake.check_depends -or
 467           -name CMakeCache.txt -or
 468           -name cmake.check_cache -or
 469           -name *.cmake -or
 470           -name Makefile -or
 471           -name core -or
 472           -name core.* -or
 473           -name gmon.out -or
 474           -name install_manifest.txt -or
 475           -name *.pc -or
 476           -name *.gcov -or
 477           -name *.gcno -or
 478           -name *.gcda -or
 479           -name *~ -or
 480           -name libdali*.so* \)
 481           | grep -v TC | xargs rm -rf
 482           TARGET  ${DALI_TOOLKIT_PREFIX}distclean
 483           VERBATIM
 484           )
 485
 486   ENDIF( LCOV_BIN )
 487 ENDIF()
 488
 489 # Build documentation if doxygen tool is available
 490 SET( doxygenEnabled OFF )
 491 IF( DOXYGEN_FOUND )
 492   SET( doxygenEnabled ON )
 493   # 'prefix' is used by doxygen in-files.
 494   SET( prefix ${PREFIX} )
 495   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 496   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 497   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 498   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 499   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 500   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 501   ADD_CUSTOM_TARGET( doc_doxygen ALL
 502                      DEPENDS ${name}
 503                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 504                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 505                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 506                      COMMENT "Generating API documentation with Doxygen"
 507                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 508                      VERBATIM )
 509   ADD_CUSTOM_TARGET( doc_doxygen_internal
 510                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 511                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 512                      COMMENT "Generating Internal API documentation with Doxygen"
 513                      VERBATIM )
 514
 515 ENDIF()
 516
 517 IF( CONFIGURE_AUTOMATED_TESTS )
 518   # Configure automated tests
 519   CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 520                   ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 521 ENDIF()
 522
 523 # Configuration Messages
 524 MESSAGE( STATUS "Configuration:\n" )
 525 MESSAGE( STATUS "Prefix:                        " ${PREFIX} )
 526 MESSAGE( STATUS "Lib Dir:                       " ${LIB_DIR} )
 527 MESSAGE( STATUS "Include Dir:                   " ${INCLUDE_DIR} )
 528 MESSAGE( STATUS "Debug build:                   " ${ENABLE_DEBUG} )
 529 MESSAGE( STATUS "Export all symbols:            " ${ENABLE_EXPORTALL} )
 530 MESSAGE( STATUS "Coverage:                      " ${ENABLE_COVERAGE} )
 531 MESSAGE( STATUS "Trace:                         " ${ENABLE_TRACE} )
 532 MESSAGE( STATUS "Doxygen:                       " ${doxygenEnabled} )
 533 MESSAGE( STATUS "Data Dir (Read/Write):         " ${dataReadWriteDir} )
 534 MESSAGE( STATUS "Data Dir (Read Only):          " ${dataReadOnlyDir} )
 535 MESSAGE( STATUS "Data Install Dir (Read/Write): " ${dataReadWriteInstallDir} )
 536 MESSAGE( STATUS "Data Install Dir (Read Only):  " ${dataReadOnlyInstallDir} )
 537 MESSAGE( STATUS "Style Dir:                     " ${STYLE_DIR} )
 538 MESSAGE( STATUS "Style:                         " ${dali_style} )
 539 MESSAGE( STATUS "i18n:                          " ${ENABLE_I18N} )
 540 MESSAGE( STATUS "Use pkg configure:             " ${ENABLE_PKG_CONFIGURE} )
 541 MESSAGE( STATUS "Vector Based Text Rendering:   " ${ENABLE_VECTOR_BASED_TEXT_RENDERING} )
 542 MESSAGE( STATUS "Enable link test:              " ${ENABLE_LINK_TEST} )
 543 MESSAGE( STATUS "Configure automated tests:     " ${CONFIGURE_AUTOMATED_TESTS} )
 544 MESSAGE( STATUS "CXXFLAGS:                      " ${CMAKE_CXX_FLAGS} )
 545 MESSAGE( STATUS "LDFLAGS:                       " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )
 546
 547 MESSAGE( " Folder       INSTALL_SHARE_DIR : [" ${INSTALL_SHARE_DIR} "]" )
 548 MESSAGE( " Folder          DALI_IMAGE_DIR : [" ${DALI_IMAGE_DIR} "]" )
 549 MESSAGE( " Folder          DALI_STYLE_DIR : [" ${DALI_STYLE_DIR} "]" )
 550 MESSAGE( " Folder    DALI_STYLE_IMAGE_DIR : [" ${DALI_STYLE_IMAGE_DIR} "]" )
 551 MESSAGE( " Folder          DALI_SOUND_DIR : [" ${DALI_SOUND_DIR} "]" )
 552 MESSAGE( " Folder DALI_DATA_READ_ONLY_DIR : [" ${DALI_DATA_READ_ONLY_DIR} "]" )