build/tizen-cmake/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-toolkit")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 FIND_PACKAGE( PkgConfig REQUIRED )
  10 FIND_PACKAGE( Doxygen REQUIRED )
  11
  12 PKG_CHECK_MODULES(DALICORE REQUIRED dali-core)
  13 PKG_CHECK_MODULES(DALIADAPTOR REQUIRED dali-adaptor)
  14
  15 # API VERSION (Not DALi release version)
  16 SET(${name}_VERSION_MAJOR 0)
  17 SET(${name}_VERSION_MINOR 0)
  18 SET(${name}_VERSION_PATCH 0)
  19 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH} )
  20
  21 SET(DALI_TOOLKIT_VERSION ${${name}_VERSION} )
  22
  23 # Define options to CMake
  24 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  25 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  26 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  27 OPTION(ENABLE_I18N           "Turns on internationalisation" OFF)
  28 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  29
  30 # Define non-boolean options to CMake
  31 SET(WITH_STYLE               "480x800" CACHE STRING "Select the style folder to use")
  32 SET(ENABLE_PROFILE           "UBUNTU" CACHE STRING "Select the variant of tizen")
  33
  34 # Style folder
  35 SET( STYLE_BASE_DIR ${ROOT_SRC_DIR}/dali-toolkit/styles )
  36 SET( STYLE_DIR ${STYLE_BASE_DIR}/${dali_style} )
  37
  38 SET( toolkit_styles_base_dir ${STYLE_BASE_DIR} )
  39 SET( toolkit_styles_dir ${STYLE_DIR} )
  40 SET( toolkit_style_images_dir ${STYLE_DIR}/images )
  41
  42 IF( ${DALI_DATA_RW_DIR} )
  43   SET( dataReadWriteDir ${DALI_DATA_RW_DIR}/ )
  44 ELSE()
  45   SET( dataReadWriteDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  46 ENDIF()
  47
  48 IF( ${DALI_DATA_RO_DIR} )
  49   SET( dataReadOnlyDir ${DALI_DATA_RO_DIR}/ )
  50 ELSE()
  51   SET( dataReadOnlyDir ${CMAKE_INSTALL_PREFIX}/share/dali/ )
  52 ENDIF()
  53
  54 # Set up compiler definitions
  55 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  56   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  57   SET( ENABLE_DEBUG ON )
  58 ELSE()
  59   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  60 ENDIF()
  61
  62 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  63 ADD_DEFINITIONS(-DDALI_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/images/\"
  64                 -DDALI_SOUND_DIR=\"${dataReadOnlyDir}/toolkit/sounds/\"
  65                 -DDALI_STYLE_DIR=\"${dataReadOnlyDir}/toolkit/styles/\"
  66                 -DDALI_STYLE_IMAGE_DIR=\"${dataReadOnlyDir}/toolkit/styles/images/\"
  67                 -DDALI_DATA_READ_ONLY_DIR=\"${dataReadOnlyDir}\" )
  68
  69 IF("${ARCH}" STREQUAL "arm")
  70   ADD_DEFINITIONS("-DTARGET")
  71 ENDIF("${ARCH}" STREQUAL "arm")
  72
  73 IF( ENABLE_DEBUG )
  74   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  75   SET( ENABLE_EXPORTALL ON )
  76 ENDIF( ENABLE_DEBUG )
  77
  78 IF( NOT ${ENABLE_EXPORTALL} )
  79   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  80 ENDIF( NOT ${ENABLE_EXPORTALL} )
  81
  82 IF( ENABLE_I18N )
  83   ADD_DEFINITIONS( "-DDGETTEXT_ENABLED" )
  84 ENDIF( ENABLE_I18N )
  85
  86 # Platforms with highp shader support can use vector based text
  87 IF( "${PROFILE}" STREQUAL "UBUNTU" )
  88   SET( ENABLE_VECTOR_BASED_TEXT_RENDERING 1 )
  89 ENDIF()
  90
  91 # Deployment folder should come from spec file or command line:
  92 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  93 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  94
  95 # from root/build/tizen, get back to root
  96 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  97
  98 # Make sure the path is absolute
  99 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 100
 101 # Set DALi style
 102 SET( dali_style ${WITH_STYLE} )
 103
 104 # Set paths
 105 SET( toolkit_images_dir  ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common )
 106 SET( toolkit_sounds_dir  ${ROOT_SRC_DIR}/dali-toolkit/sounds )
 107 SET( toolkit_src_dir     ${ROOT_SRC_DIR}/dali-toolkit/internal )
 108 SET( public_api_src_dir  ${ROOT_SRC_DIR}/dali-toolkit/public-api )
 109 SET( devel_api_src_dir   ${ROOT_SRC_DIR}/dali-toolkit/devel-api )
 110 SET( third_party_src_dir ${ROOT_SRC_DIR}/dali-toolkit/third-party )
 111 SET( package_doxy_dir    ${ROOT_SRC_DIR}/doc )
 112
 113 # Set up the include dir
 114 SET( INCLUDE_DIR $ENV{includedir} )
 115 IF( NOT INCLUDE_DIR )
 116   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 117 ENDIF()
 118 IF( NOT INCLUDE_DIR )
 119   SET( INCLUDE_DIR ${PREFIX}/include )
 120 ENDIF()
 121
 122 # Set up the lib dir
 123 SET( LIB_DIR $ENV{libdir} )
 124 IF( NOT LIB_DIR )
 125   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 126 ENDIF()
 127 IF( NOT LIB_DIR )
 128   SET( LIB_DIR ${PREFIX}/lib )
 129 ENDIF()
 130
 131 # Configure the pkg-config file
 132 # Requires the following variables to be setup:
 133 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 134 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 135 SET( CORE_PKG_CFG_FILE dali-toolkit.pc )
 136 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 137
 138 # Set up compiler flags and warnings
 139 ADD_COMPILE_OPTIONS( -std=c++11 )
 140 ADD_COMPILE_OPTIONS( -Wno-ignored-qualifiers )
 141
 142 # TODO: Clang is a lot more strict with warnings, we should address
 143 # those issues at some point.
 144 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 145   ADD_COMPILE_OPTIONS( -Werror )
 146 ENDIF()
 147
 148 ADD_COMPILE_OPTIONS( -Wall -Wno-unused-parameter -Wno-float-equal )
 149
 150 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 151   ADD_COMPILE_OPTIONS( --coverage )
 152   SET(ENABLE_COVERAGE ON)
 153   SET(COVERAGE --coverage)
 154 ENDIF()
 155
 156 IF( ENABLE_TRACE )
 157   ADD_DEFINITIONS("-DTRACE_ENABLED")
 158 ENDIF()
 159
 160 INCLUDE_DIRECTORIES(
 161   ${ROOT_SRC_DIR}
 162   ${DALICORE_INCLUDE_DIRS}
 163   ${DALIADAPTOR_INCLUDE_DIRS}
 164 )
 165
 166 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 167 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 168
 169 SET(SOURCES "")
 170
 171 # could use INCLUDE to get the source lists a different way;
 172 # would then need to specify a build folder somehow...
 173 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/sounds/file-list.cmake )
 174 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/file-list.cmake )
 175 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/styles/images-common/file-list.cmake )
 176 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/internal/file-list.cmake )
 177 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/public-api/file-list.cmake )
 178 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/devel-api/file-list.cmake )
 179 INCLUDE( ${ROOT_SRC_DIR}/dali-toolkit/third-party/file-list.cmake )
 180 INCLUDE( ${ROOT_SRC_DIR}/doc/file-list.cmake )
 181
 182 SET(LIBTYPE SHARED)
 183 IF(DEFINED STATIC)
 184   SET(LIBTYPE STATIC)
 185 ENDIF()
 186
 187 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 188
 189 TARGET_LINK_LIBRARIES( ${name}
 190   ${DALICORE_LDFLAGS}
 191   ${DALIADAPTOR_LDFLAGS}
 192   ${COVERAGE}
 193 )
 194
 195 SET_TARGET_PROPERTIES( ${name}
 196   PROPERTIES
 197   VERSION ${DALI_TOOLKIT_VERSION}
 198   SOVERSION ${${name}_VERSION_MAJOR}
 199   CLEAN_DIRECT_OUPUT 1
 200 )
 201
 202 # Install the library so file and symlinks
 203 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 204
 205 # Install the pkg-config file
 206 INSTALL( FILES ${CMAKE_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 207
 208 # Glob for resources
 209 MACRO( COPY_RESOURCES FILE_LIST SRC_RELATIVE_DIRECTORY DESTINATION EXPLICIT_DESTINATION )
 210   FOREACH( PATTERN ${FILE_LIST} )
 211     FILE(GLOB FILES ${PATTERN} )
 212     FOREACH( FILE ${FILES} )
 213       STRING(REPLACE ${SRC_RELATIVE_DIRECTORY} ${DESTINATION} NEWFILE ${FILE} )
 214       GET_FILENAME_COMPONENT(NEWDIR ${NEWFILE} DIRECTORY)
 215       IF( "${EXPLICIT_DESTINATION}" STREQUAL "" )
 216         STRING( REPLACE "dali-toolkit" "toolkit" NEWDIR2 ${NEWDIR} )
 217         INSTALL( FILES ${FILE} DESTINATION ${NEWDIR2} )
 218       ELSE()
 219         INSTALL( FILES ${FILE} DESTINATION ${DESTINATION}/${EXPLICIT_DESTINATION} )
 220       ENDIF()
 221     ENDFOREACH()
 222   ENDFOREACH()
 223 ENDMACRO()
 224
 225 # macro for installing headers by replacing prefix. (TODO, investigate
 226 # if there is a CMAKE way of doing this automatically)
 227 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 228   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 229   FOREACH(HEADER ${${HEADER_LIST}})
 230     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 231     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 232     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 233   ENDFOREACH(HEADER)
 234 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 235
 236 # Install headers using lists defined by ADD_SUBDIRECTORY
 237 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 238 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 239 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali-toolkit "dali-toolkit")
 240 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali-toolkit/doc" )
 241
 242 # Install dali-toolkit.h
 243 INSTALL( FILES ${ROOT_SRC_DIR}/dali-toolkit/dali-toolkit.h DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit )
 244
 245 # package doxygen file (contains doxygen grouping information)
 246 INSTALL( FILES ${package_doxy_files} DESTINATION ${DEV_INCLUDE_PATH}/dali-toolkit/doc )
 247
 248 COPY_RESOURCES( "${dali_toolkit_style_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/styles" )
 249 COPY_RESOURCES( "${dali_toolkit_image_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/images" )
 250 COPY_RESOURCES( "${dali_toolkit_sound_files}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/sounds" )
 251 COPY_RESOURCES( "${dali_toolkit_style_images}" "${ROOT_SRC_DIR}" "${dataReadOnlyDir}" "./toolkit/styles/images" )
 252
 253 IF( UNIX )
 254   FIND_PROGRAM( LCOV_BIN "lcov" )
 255   IF( LCOV_BIN )
 256
 257     # Define custom rules for coverage
 258     SET(COVERAGE_DIR .cov)
 259     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 260
 261     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 262     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 263     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 264     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 265     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 266       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 267     ENDIF()
 268
 269     ADD_CUSTOM_TARGET( rename_cov_data ./rename-cov-data )
 270
 271     ADD_CUSTOM_TARGET( cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 272       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 273
 274     ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 275       DEPENDS cov_data )
 276
 277     ADD_CUSTOM_TARGET( reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 278
 279     # Define custom rule for distclean
 280     ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 281     ADD_CUSTOM_COMMAND(
 282           DEPENDS clean
 283           COMMENT "distribution clean"
 284           COMMAND find
 285           ARGS    .
 286           -not -name config.cmake -and \(
 287           -name tester.c -or
 288           -name Testing -or
 289           -name CMakeFiles -or
 290           -name doc -or
 291           -name cmake.depends -or
 292           -name cmake.check_depends -or
 293           -name CMakeCache.txt -or
 294           -name cmake.check_cache -or
 295           -name *.cmake -or
 296           -name Makefile -or
 297           -name core -or
 298           -name core.* -or
 299           -name gmon.out -or
 300           -name install_manifest.txt -or
 301           -name *.pc -or
 302           -name *.gcov -or
 303           -name *.gcno -or
 304           -name *.gcda -or
 305           -name *~ -or
 306           -name libdali*.so* \)
 307           | grep -v TC | xargs rm -rf
 308           TARGET  distclean
 309           VERBATIM
 310           )
 311
 312   ENDIF( LCOV_BIN )
 313 ENDIF( UNIX )
 314
 315 # Build documentation if doxygen tool is available
 316 IF( DOXYGEN_FOUND )
 317   # 'prefix' is used by doxygen in-files.
 318   SET( prefix ${PREFIX} )
 319   SET( DOXYGEN_DOCS_DIR ${ROOT_SRC_DIR}/docs )
 320   SET( DOXYGEN_ROOT_DIR ${ROOT_SRC_DIR} )
 321   SET( DOXYGEN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs )
 322   SET( DOXYGEN_INTERNAL_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/docs-internal )
 323   CONFIGURE_FILE( ${DOXYGEN_SRC_DIR}/dali.doxy.in ${DOXYGEN_SRC_DIR}/dali.doxy @ONLY )
 324   CONFIGURE_FILE( ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy.in ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy @ONLY )
 325   ADD_CUSTOM_TARGET( doc_doxygen ALL
 326                      DEPENDS ${name}
 327                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_SRC_DIR}/dali.doxy
 328                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_SRC_DIR}/dali.doxy
 329                      COMMAND ${CMAKE_COMMAND} -P ${DOXYGEN_SRC_DIR}/check_for_errors.cmake
 330                      COMMENT "Generating API documentation with Doxygen"
 331                      WORKING_DIRECTORY ${DOXYGEN_SRC_DIR}
 332                      VERBATIM )
 333   ADD_CUSTOM_TARGET( doc_doxygen_internal
 334                      COMMAND ${DOXYGEN_EXECUTABLE} -u ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 335                      COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_INTERNAL_SRC_DIR}/dali-internal.doxy
 336                      COMMENT "Generating Internal API documentation with Doxygen"
 337                      VERBATIM )
 338
 339 ENDIF()
 340
 341 # Configure automated tests
 342 CONFIGURE_FILE( ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt.in
 343                 ${ROOT_SRC_DIR}/automated-tests/CMakeLists.txt @ONLY )
 344
 345 # Configuration Messages
 346 MESSAGE( STATUS "Configuration:\n" )
 347 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 348 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 349 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 350 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 351 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 352 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 353 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 354 MESSAGE( STATUS "Data Dir (Read/Write): " ${dataReadWriteDir} )
 355 MESSAGE( STATUS "Data Dir (Read Only):  " ${dataReadOnlyDir} )
 356 MESSAGE( STATUS "Style Dir:             " ${STYLE_DIR} )
 357 MESSAGE( STATUS "Style:                 " ${dali_style} )
 358 MESSAGE( STATUS "i18n:                  " ${ENABLE_I18N} )
 359 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 360 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )