# Initialize
AC_PREREQ(2.61)
AC_INIT(Decarta, 0.1, [sangho.g.park@samsung.com])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_SRCDIR([decarta/decarta_config.c])
AM_INIT_AUTOMAKE([1.10.2 foreign -Wall])

# Check programs for making executable
AC_PROG_CC
AM_PROG_CC_C_O
AC_PROG_INSTALL

# Check programs for making libraries.
AM_PROG_LIBTOOL

# Check host system
m4_define([v_maj], [0])
m4_define([v_min], [7])
m4_define([v_mic], [0])
AC_CANONICAL_HOST
case "$host_os" in
   mingw32ce* | cegcc*)
    MODULE_ARCH="$host_os-$host_cpu"
    ;;
    *)
    MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
    ;;
esac
AC_SUBST(MODULE_ARCH)
AC_DEFINE_UNQUOTED(MODULE_ARCH, "$MODULE_ARCH", "Module architecture")

# Add default build options to CFLAGS, LDFLAGS
if test "x$GCC" = "xyes"; then
	CFLAGS="$CFLAGS -Wall"
	LDFLAGS="$LDFLAGS -Wl,-z,defs -Wl,--as-needed -Wl,--hash-style=both"
fi

# Add -g option to CFLAGS
AC_ARG_ENABLE([debug],
        [AC_HELP_STRING([--enable-debug],[turn on debugging [default=no]])],
        [case "${enableval}" in
         yes) enable_dbg=yes ;;
         no) enable_dbg=no ;;
         *) AC_MSG_ERROR([Bad value ${enableval} for --enable-debug]) ;;
       esac],[enable_dbg=no])
if ([test "x$enable_dbg" = xyes]); then
	CFLAGS="$CFLAGS -g"
fi

# Check GCC EFL visibility
AC_MSG_CHECKING(for ELF visibility)
AC_COMPILE_IFELSE(
	[AC_LANG_PROGRAM([[
		__attribute__((visibility("default")))
		int var=10;
	]])],
	[has_visibility=yes
	AC_DEFINE([EXPORT_API], [__attribute__((visibility("default")))], [Symbol visibility prefix])
	CFLAGS="$CFLAGS -fvisibility=hidden"],
	[has_visibility=no
	AC_DEFINE([EXPORT_API], [], [Symbol visibility prefix])	]
)
AC_MSG_RESULT($has_visibility)

# Checks libraries
PKG_CHECK_MODULES(DOCRYPT, [glib-2.0])
AC_SUBST(DOCRYPT_LIBS)
AC_SUBST(DOCRYPT_CFLAGS)

AC_CHECK_HEADERS([gcrypt.h])
PKG_CHECK_MODULES(CRYPT, [glib-2.0])
AC_SUBST(CRYPT_LIBS)
AC_SUBST(CRYPT_CFLAGS)
AC_SEARCH_LIBS([gcry_cipher_open],[gcrypt],[CRYPT_LIBS="$CRYPT_LIBS -lgcrypt"])
AC_SEARCH_LIBS([gpg_strerror],[gpg-error],[CRYPT_LIBS="$CRYPT_LIBS -lgpg-error"])

PKG_CHECK_MODULES(DECARTA, [glib-2.0 libsoup-2.4 libxml-2.0 gconf-2.0])
AC_SUBST(DECARTA_LIBS)
AC_SUBST(DECARTA_CFLAGS)

PKG_CHECK_MODULES(LOCATION_MOD, [glib-2.0 gmodule-2.0 vconf location])
AC_SUBST(LOCATION_MOD_LIBS)
AC_SUBST(LOCATION_MOD_CFLAGS)

PKG_CHECK_MODULES(ELM_MOD, [glib-2.0 elementary])
AC_SUBST(ELM_MOD_LIBS)
AC_SUBST(ELM_MOD_CFLAGS)

PKG_CHECK_MODULES(TEST, [glib-2.0 gconf-2.0 location])
AC_SUBST(TEST_LIBS)
AC_SUBST(TEST_CFLAGS)

# Check dlog libraris
AC_ARG_ENABLE([dlog],
        [AC_HELP_STRING([--enable-dlog],[show dlog message [default=no]])],
        [case "${enableval}" in
         yes) enable_dlog=yes ;;
         no) enable_dlog=no ;;
         *) AC_MSG_ERROR([Bad value ${enableval} for --enable-dlog]) ;;
       esac],[enable_dlog=no])
if ([test "x$enable_dlog" = xyes]); then
	PKG_CHECK_MODULES(DLOG, [dlog], have_dlog="yes", have_dlog="no")
	AC_SUBST(DLOG_LIBS)
	AC_SUBST(DLOG_CFLAGS)
	if test "x$have_dlog" = "xyes"; then
		DECARTA_CFLAGS="$DECARTA_CFLAGS -DDECARTA_DLOG_DEBUG $DLOG_CFLAGS"
		DECARTA_LIBS="$DECARTA_LIBS $DLOG_LIBS"
		LOCATION_MOD_CFLAGS="$LOCATION_MOD_CFLAGS -DDECARTA_DLOG_DEBUG $DLOG_CFLAGS"
		LOCATION_MOD_LIBS="$LOCATION_MOD_LIBS $DLOG_LIBS"
	fi
fi

# Check application path for installing configuration file
if ([test "x$APP_DIR" = x]); then
	AC_DEFINE([APP_PATH],["/opt/apps"], [application path for reading conf file])
else
	AC_DEFINE_UNQUOTED([APP_PATH],["$APP_DIR"], [application path for reading conf file])
fi

if ([test "x$APP_CONF_DIR" = x]); then
	AC_DEFINE([APP_CONF_PATH],["res/.decarta"], [application path for reading conf file])
else
	AC_DEFINE_UNQUOTED([APP_CONF_PATH],["$APP_CONF_DIR"], [application path for reading conf file])
fi

if ([test "x$DEF_CONF_DIR" = x]); then
	AC_DEFINE([DEF_CONF_PATH],["/etc/decarta"], [default application path for reading conf file])
else
	AC_DEFINE_UNQUOTED([DEF_CONF_PATH],["$DEF_CONF_DIR"], [default application path for reading conf file])
fi
DEF_CONF_PATH="$DEF_CONF_DIR"
AC_SUBST(DEF_CONF_PATH)

# Generate files
AC_CONFIG_FILES([
decarta.pc
Makefile
crypt/Makefile
decarta/Makefile
elm_module/Makefile
location_module/Makefile
tests/Makefile
])

AC_OUTPUT