From: Colin Walters <walters@verbum.org>
Date: Tue, 7 Aug 2012 21:26:43 +0000 (-0400)
Subject: build: Switch back to using AS_IF for conditionals
X-Git-Tag: 2.33.10~84
X-Git-Url: http://review.tizen.org/git/?a=commitdiff_plain;h=ddfcfa66ae602c11ce9c4bfc426a79d668653278;p=platform%2Fupstream%2Fglib.git

build: Switch back to using AS_IF for conditionals

See https://bugzilla.gnome.org/show_bug.cgi?id=674483

https://bugzilla.gnome.org/show_bug.cgi?id=681413
---

diff --git a/configure.ac b/configure.ac
index c44f668..f300fa0 100644
--- a/configure.ac
+++ b/configure.ac
@@ -2598,48 +2598,48 @@ AC_ARG_ENABLE(man,
                               [generate man pages [default=auto]])],,
               enable_man=maybe)
 
-if test "$enable_man" != no; then
+AS_IF([test "$enable_man" != no], [
   AC_PATH_PROG([XSLTPROC], [xsltproc])
-  if test -z "$XSLTPROC"; then
-    if test "$enable_man" = yes ; then
+  AS_IF([test -z "$XSLTPROC"], [
+    AS_IF([test "$enable_man" = yes], [
       AC_MSG_ERROR([xsltproc is required for --enable-man])
-    fi
+    ])
     enable_man=no
-  fi
-fi
+  ])
+])
 
-if test "$enable_man" != no; then
+AS_IF([ test "$enable_man" != no ], [
   dnl check for DocBook DTD in the local catalog
   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
-  if test "$have_docbook_dtd" != yes; then
-    if test "$enable_man" = yes ; then
+  AS_IF([test "$have_docbook_dtd" != yes], [
+    AS_IF([test "$enable_man" = yes ], [
       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
-    fi
+    ])
     enable_man=no
-  fi
-fi
+  ])
+])
 
-if test "$enable_man" != no; then
+AS_IF([test "$enable_man" != no], [
   dnl check for DocBook XSL stylesheets in the local catalog
   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
-  if test "$have_docbook_dtd" != yes; then
-    if test "$enable_man" = yes ; then
+  AS_IF([ test "$have_docbook_dtd" != yes ], [
+    AS_IF([ test "$enable_man" = yes ], [
       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
-    fi
+    ])
     enable_man=no
-  fi
-fi
+  ])
+])
 
 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
 
 AC_MSG_CHECKING([whether to generate man pages])
-if test "$enable_man" != no; then
+AS_IF([ test "$enable_man" != no ], [
   AC_MSG_RESULT([yes])
-else
+], [
   AC_MSG_RESULT([no])
-fi
+])
 
 dnl
 dnl Tracing