From: Jim Meyering <jim@meyering.net>
Date: Mon, 15 Sep 1997 03:20:53 +0000 (+0000)
Subject: .
X-Git-Tag: TEXTUTILS-1_22a~52
X-Git-Url: http://review.tizen.org/git/?a=commitdiff_plain;h=bf886f22b7da99893a6db940659f5238e89928d4;p=platform%2Fupstream%2Fcoreutils.git

.
---

diff --git a/m4/realloc.m4 b/m4/realloc.m4
new file mode 100644
index 0000000..b4afe93
--- /dev/null
+++ b/m4/realloc.m4
@@ -0,0 +1,33 @@
+#serial 1
+
+dnl From Jim Meyering.
+dnl Determine whether realloc accepts 0 as its first argument.
+dnl If it doesn't, arrange to use the replacement function.
+dnl
+dnl If you use this macro in a package, you should
+dnl add the following two lines to acconfig.h:
+dnl  /* Define to rpl_realloc if the replacement function should be used.  */
+dnl  #undef realloc
+dnl
+
+AC_DEFUN(jm_FUNC_REALLOC,
+[
+ AC_CACHE_CHECK([for working realloc], jm_cv_func_working_realloc,
+  [AC_TRY_RUN([
+    char *realloc ();
+    int
+    main ()
+    {
+      exit (realloc (0, 1) ? 0 : 1);
+    }
+	  ],
+	 jm_cv_func_working_realloc=yes,
+	 jm_cv_func_working_realloc=no,
+	 dnl When crosscompiling, assume realloc is broken.
+	 jm_cv_func_working_realloc=no)
+  ])
+  if test $jm_cv_func_working_realloc = no; then
+    LIBOBJS="$LIBOBJS realloc.o"
+    AC_DEFINE_UNQUOTED(realloc, rpl_realloc)
+  fi
+])