From: Tim-Philipp Müller <tim@centricular.com>
Date: Mon, 26 Jun 2017 08:38:46 +0000 (+0100)
Subject: meson: tests: icles: simplify build file
X-Git-Tag: 1.19.3~509^2~2023
X-Git-Url: http://review.tizen.org/git/?a=commitdiff_plain;h=0fd4a11711a234457bb2d4276176c6dd818f2a9b;p=platform%2Fupstream%2Fgstreamer.git

meson: tests: icles: simplify build file
---

diff --git a/tests/icles/meson.build b/tests/icles/meson.build
index 1615c96..0769706 100644
--- a/tests/icles/meson.build
+++ b/tests/icles/meson.build
@@ -1,55 +1,37 @@
+tests = [
+  ['equalizer-test'],
+  ['test-accurate-seek', gstapp_dep],
+  ['test-segment-seeks'],
+  ['videocrop-test'],
+  ['videobox-test'],
+  ['videocrop2-test'],
+]
+
 gtk_dep = dependency('gtk+-3.0', version : '>= 3.0.0', required : false)
 if gtk_dep.found()
-  executable('gdkpixbufsink-test', 'gdkpixbufsink-test.c',
-    dependencies: [gst_dep, gtk_dep],
-    c_args : gst_plugins_good_args,
-    include_directories : [configinc],
-    install: false)
-
-  executable('gdkpixbufoverlay-test', 'gdkpixbufoverlay-test.c',
-    dependencies: [gstvideo_dep, gst_dep, gtk_dep, libm],
-    c_args : gst_plugins_good_args,
-    include_directories : [configinc],
-    install: false)
+  tests += [
+    ['gdkpixbufsink-test', gtk_dep],
+    ['gdkpixbufoverlay-test', [gstvideo_dep, gtk_dep]],
+  ]
 endif
 
 if cdata.has('HAVE_GST_V4L2')
-  executable('v4l2src-test', 'v4l2src-test.c',
-    dependencies: [gstvideo_dep, gst_dep, libm],
-    c_args : gst_plugins_good_args,
-    include_directories : [configinc],
-    install: false)
+  tests += [['v4l2src-test', gstvideo_dep]]
 endif
 
 if get_variable('have_oss4', false)
-  executable('test-oss4', 'test-oss4.c',
-    dependencies: gst_dep,
-    c_args : gst_plugins_good_args,
-    include_directories : [configinc],
-    install: false)
+  tests += [['test-oss4']]
 endif
 
 if get_variable('x11_dep', dependency('', required: false)).found()
-  executable('ximagesrc-test', 'ximagesrc-test.c',
-    dependencies: [gst_dep, libm],
-    c_args : gst_plugins_good_args,
-    include_directories : [configinc],
-    install: false)
+  tests += [['ximagesrc-test']]
 endif
 
-
-tests = [
-  ['equalizer-test'],
-  ['test-accurate-seek', gstapp_dep],
-  ['test-segment-seeks'],
-  ['videocrop-test'],
-  ['videobox-test'],
-  ['videocrop2-test'],
-]
-
 foreach t : tests
-  executable(t.get(0), t.get(0) + '.c',
-    dependencies: [gst_dep, libm] + [t.get(1, [])],
+  test_name = t.get(0)
+  extra_deps = t.get(1, [])
+  executable(test_name, test_name + '.c',
+    dependencies: [gst_dep, libm, extra_deps],
     c_args : gst_plugins_good_args,
     include_directories : [configinc],
     install: false)