Add Android NDK r11 toolchain as new default

New NDK r11 toolchain fixes libc++ on x86 enabling glslang support in
Android builds.

Change-Id: I5141b97f3152cfb1420a116cae40d671477ed254
(cherry picked from commit de7fb14fc30a8dd60e0215c333950b6a996c825a)

diff --git a/android/scripts/common.py b/android/scripts/common.py
index 777d23f..1680b41 100644 (file)
--- a/android/scripts/common.py
+++ b/android/scripts/common.py
@@ -241,8 +241,8 @@ NATIVE_LIB_NAME                     = "libdeqp.so"
 
 def selectNDKPath ():
        candidates =  [
-               os.path.expanduser("~/android-ndk-r10e"),
-               "C:/android/android-ndk-r10e",
+               os.path.expanduser("~/android-ndk-r11"),
+               "C:/android/android-ndk-r11",
                os.environ.get("ANDROID_NDK_PATH", None), # If not defined, return None
        ]
 
@@ -262,7 +262,7 @@ def noneSafePathJoin (*components):
 # NDK paths
 ANDROID_NDK_PATH                               = selectNDKPath()
 ANDROID_NDK_HOST_OS                            = getNDKHostOsName(ANDROID_NDK_PATH)
-ANDROID_NDK_TOOLCHAIN_VERSION  = "r10e" # Toolchain file is selected based on this
+ANDROID_NDK_TOOLCHAIN_VERSION  = "r11" # Toolchain file is selected based on this
 
 # Native code build settings
 CMAKE_GENERATOR                        = selectByOS({

diff --git a/framework/delibs/cmake/toolchain-android-r11.cmake b/framework/delibs/cmake/toolchain-android-r11.cmake
new file mode 100644 (file)
index 0000000..b74781e
--- /dev/null
+++ b/framework/delibs/cmake/toolchain-android-r11.cmake
@@ -0,0 +1,173 @@
+# Platform defines.
+set(CMAKE_SYSTEM_NAME Linux)
+
+set_property(GLOBAL PROPERTY TARGET_SUPPORTS_SHARED_LIBS TRUE)
+
+set(CMAKE_CROSSCOMPILING 1)
+
+# NDK installation path
+if (NOT DEFINED ANDROID_NDK_PATH)
+       message(FATAL_ERROR "Please provide ANDROID_NDK_PATH")
+endif ()
+
+# Host os (for toolchain binaries)
+if (NOT DEFINED ANDROID_NDK_HOST_OS)
+       message(STATUS "Warning: ANDROID_NDK_HOST_OS is not set")
+       if (WIN32)
+               set(ANDROID_NDK_HOST_OS "windows")
+       elseif (UNIX)
+               set(ANDROID_NDK_HOST_OS "linux-86")
+       endif ()
+endif ()
+
+# Compile target
+set(ANDROID_ABI                        "armeabi-v7a"                   CACHE STRING "Android ABI")
+set(ANDROID_NDK_TARGET "android-${DE_ANDROID_API}")
+
+# dE defines
+set(DE_OS "DE_OS_ANDROID")
+
+if (NOT DEFINED DE_COMPILER)
+       set(DE_COMPILER "DE_COMPILER_CLANG")
+endif ()
+
+if (NOT DEFINED DE_ANDROID_API)
+       set(DE_ANDROID_API 9)
+endif ()
+
+set(COMMON_C_FLAGS             "-D__STDC_INT64__")
+set(COMMON_CXX_FLAGS   "${COMMON_C_FLAGS} -frtti -fexceptions")
+set(COMMON_LINKER_FLAGS        "")
+set(ARM_C_FLAGS                        "-D__ARM_ARCH_5__ -D__ARM_ARCH_5T__ -D__ARM_ARCH_5E__ -D__ARM_ARCH_5TE__ ")
+
+# ABI-dependent bits
+if (ANDROID_ABI STREQUAL "x86")
+       set(DE_CPU                                      "DE_CPU_X86")
+       set(CMAKE_SYSTEM_PROCESSOR      i686-android-linux)
+
+       set(ANDROID_CC_PATH                     "${ANDROID_NDK_PATH}/toolchains/x86-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
+       set(CROSS_COMPILE                       "${ANDROID_CC_PATH}bin/i686-linux-android-")
+       set(ANDROID_SYSROOT                     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-x86")
+
+       set(CMAKE_FIND_ROOT_PATH
+               "${ANDROID_CC_PATH}i686-linux-android"
+               "${ANDROID_CC_PATH}lib/gcc/i686-linux-android/4.9"
+               )
+
+       set(TARGET_C_FLAGS                      "-march=i686 -msse3 -mstackrealign -mfpmath=sse")
+       set(TARGET_LINKER_FLAGS         "")
+       set(LLVM_TRIPLE                         "i686-none-linux-android")
+
+elseif (ANDROID_ABI STREQUAL "armeabi" OR
+               ANDROID_ABI STREQUAL "armeabi-v7a")
+       set(DE_CPU                                      "DE_CPU_ARM")
+       set(CMAKE_SYSTEM_PROCESSOR      arm-linux-androideabi)
+
+       set(ANDROID_CC_PATH     "${ANDROID_NDK_PATH}/toolchains/arm-linux-androideabi-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
+       set(CROSS_COMPILE       "${ANDROID_CC_PATH}bin/arm-linux-androideabi-")
+       set(ANDROID_SYSROOT     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-arm")
+
+       if (ANDROID_ABI STREQUAL "armeabi-v7a")
+               set(TARGET_C_FLAGS              "${ARM_C_FLAGS} -march=armv7-a -mfpu=vfpv3-d16 -mfloat-abi=softfp")
+               set(TARGET_LINKER_FLAGS "-Wl,--fix-cortex-a8 -march=armv7-a")
+               set(LLVM_TRIPLE                 "armv7-none-linux-androideabi")
+
+       else () # armeabi
+               set(TARGET_C_FLAGS              "${ARM_C_FLAGS} -march=armv5te -mfloat-abi=softfp")
+               set(TARGET_LINKER_FLAGS "-Wl,--fix-cortex-a8 -march=armv5te")
+               set(LLVM_TRIPLE                 "armv5te-none-linux-androideabi")
+       endif ()
+
+       set(CMAKE_FIND_ROOT_PATH
+               "${ANDROID_CC_PATH}arm-linux-androideabi"
+               )
+
+elseif (ANDROID_ABI STREQUAL "arm64-v8a")
+       set(DE_CPU                                      "DE_CPU_ARM_64")
+       set(CMAKE_SYSTEM_PROCESSOR      aarch64-linux-android)
+       set(CMAKE_SIZEOF_VOID_P         8)
+
+       set(ANDROID_CC_PATH     "${ANDROID_NDK_PATH}/toolchains/aarch64-linux-android-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
+       set(CROSS_COMPILE       "${ANDROID_CC_PATH}bin/aarch64-linux-android-")
+       set(ANDROID_SYSROOT     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-arm64")
+
+       set(CMAKE_FIND_ROOT_PATH
+               "${ANDROID_CC_PATH}arm-linux-androideabi"
+               )
+
+       set(TARGET_C_FLAGS              "-march=armv8-a")
+       set(TARGET_LINKER_FLAGS "-Wl,--fix-cortex-a53-835769 -Wl,--fix-cortex-a53-835769 -march=armv8-a")
+       set(LLVM_TRIPLE                 "aarch64-none-linux-android")
+
+       if (DE_COMPILER STREQUAL "DE_COMPILER_GCC")
+               set(TARGET_C_FLAGS "${TARGET_C_FLAGS} -mabi=lp64")
+       endif ()
+
+else ()
+       message(FATAL_ERROR "Unknown ABI \"${ANDROID_ABI}\"")
+endif ()
+
+# Use LLVM libc++ for full C++11 support
+set(ANDROID_CXX_LIBRARY                "${ANDROID_NDK_PATH}/sources/cxx-stl/llvm-libc++/libs/${ANDROID_ABI}/libc++_static.a")
+set(CXX_INCLUDES                       "-I${ANDROID_NDK_PATH}/sources/cxx-stl/llvm-libc++/libcxx/include")
+set(CMAKE_FIND_ROOT_PATH       "" ${CMAKE_FIND_ROOT_PATH})
+
+set(CMAKE_FIND_ROOT_PATH ${CMAKE_FIND_ROOT_PATH} ${ANDROID_SYSROOT})
+
+include(CMakeForceCompiler)
+
+if (DE_COMPILER STREQUAL "DE_COMPILER_GCC")
+       if (ANDROID_NDK_HOST_OS STREQUAL "linux-x86" OR
+               ANDROID_NDK_HOST_OS STREQUAL "linux-x86_64" OR
+               ANDROID_NDK_HOST_OS STREQUAL "darwin-x86")
+               cmake_force_c_compiler("${CROSS_COMPILE}gcc"            GNU)
+               cmake_force_cxx_compiler("${CROSS_COMPILE}g++"          GNU)
+       elseif (ANDROID_NDK_HOST_OS STREQUAL "windows")
+               cmake_force_c_compiler("${CROSS_COMPILE}gcc.exe"        GNU)
+               cmake_force_cxx_compiler("${CROSS_COMPILE}g++.exe"      GNU)
+       else ()
+               message(FATAL_ERROR "Unknown ANDROID_NDK_HOST_OS")
+       endif ()
+
+       set(TARGET_C_FLAGS              "-mandroid ${TARGET_C_FLAGS}")
+
+elseif (DE_COMPILER STREQUAL "DE_COMPILER_CLANG")
+       set(LLVM_PATH "${ANDROID_NDK_PATH}/toolchains/llvm/prebuilt/${ANDROID_NDK_HOST_OS}/")
+
+       if (ANDROID_NDK_HOST_OS STREQUAL "linux-x86" OR
+               ANDROID_NDK_HOST_OS STREQUAL "linux-x86_64" OR
+               ANDROID_NDK_HOST_OS STREQUAL "darwin-x86" OR
+               ANDROID_NDK_HOST_OS STREQUAL "darwin-x86_64")
+               cmake_force_c_compiler("${LLVM_PATH}bin/clang"                  Clang)
+               cmake_force_cxx_compiler("${LLVM_PATH}bin/clang++"              Clang)
+               set(CMAKE_AR "${CROSS_COMPILE}ar" CACHE FILEPATH "Archiver")
+               set(CMAKE_RANLIB "${CROSS_COMPILE}ranlib" CACHE FILEPATH "Indexer")
+
+       elseif (ANDROID_NDK_HOST_OS STREQUAL "windows" OR
+                       ANDROID_NDK_HOST_OS STREQUAL "windows-x86_64")
+               cmake_force_c_compiler("${LLVM_PATH}bin/clang.exe"              Clang)
+               cmake_force_cxx_compiler("${LLVM_PATH}bin/clang++.exe"  Clang)
+               set(CMAKE_AR "${CROSS_COMPILE}ar.exe" CACHE FILEPATH "Archiver")
+               set(CMAKE_RANLIB "${CROSS_COMPILE}ranlib.exe" CACHE FILEPATH "Indexer")
+
+       else ()
+               message(FATAL_ERROR "Unknown ANDROID_NDK_HOST_OS")
+       endif ()
+
+       set(TARGET_C_FLAGS              "-target ${LLVM_TRIPLE} -gcc-toolchain ${ANDROID_CC_PATH} ${TARGET_C_FLAGS}")
+       set(TARGET_LINKER_FLAGS "-target ${LLVM_TRIPLE} -gcc-toolchain ${ANDROID_CC_PATH} ${TARGET_LINKER_FLAGS}")
+
+endif ()
+
+set(CMAKE_SHARED_LIBRARY_C_FLAGS       "")
+set(CMAKE_SHARED_LIBRARY_CXX_FLAGS     "")
+
+set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
+set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
+set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
+
+# \note Without CACHE STRING FORCE cmake ignores these.
+set(CMAKE_C_FLAGS                              "--sysroot=${ANDROID_SYSROOT} ${COMMON_C_FLAGS} ${TARGET_C_FLAGS}" CACHE STRING "" FORCE)
+set(CMAKE_CXX_FLAGS                            "--sysroot=${ANDROID_SYSROOT} ${COMMON_CXX_FLAGS} ${TARGET_C_FLAGS} ${CXX_INCLUDES} -I${ANDROID_NDK_PATH}/sources/android/support/include" CACHE STRING "" FORCE)
+set(CMAKE_SHARED_LINKER_FLAGS  "-nodefaultlibs -Wl,-shared,-Bsymbolic -Wl,--no-undefined ${COMMON_LINKER_FLAGS} ${TARGET_LINKER_FLAGS}" CACHE STRING "" FORCE)
+set(CMAKE_EXE_LINKER_FLAGS             "-nodefaultlibs ${COMMON_LINKER_FLAGS} ${TARGET_LINKER_FLAGS}" CACHE STRING "" FORCE)