binaries can be disabled

git-svn-id: svn+ssh://svn.enlightenment.org/var/svn/e/trunk/edje@45170 7cbeb6ba-43b4-40fd-8cce-4c39aea84d33

diff --git a/configure.ac b/configure.ac
index ac2e6ef..8725ceb 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -69,33 +69,9 @@ AC_ARG_ENABLE([amalgamation],
 )
 AM_CONDITIONAL(EDJE_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 
-AC_ARG_ENABLE([edje-cc],
-   [AC_HELP_STRING([--disable-edje-cc], [disable building of edje_cc])],
-   [
-    if test "x${enableval}" = "xyes" ; then
-       have_edje_cc="yes"
-    else
-       have_edje_cc="no"
-    fi
-   ]
-)
-AC_MSG_CHECKING(whether to build edje_cc)
-AC_MSG_RESULT([${have_edje_cc}])
-
-AM_CONDITIONAL(BUILD_EDJE_CC, test "x${have_edje_cc}" = "xyes")
-AM_CONDITIONAL(BUILD_EDJE_DECC, test "x${have_edje_cc}" = "xyes")
-
-EDJE_CC_PRG=""
-EDJE_DECC_PRG=""
-EDJE_RECC_PRG=""
-if test "x${have_edje_cc}" = "xyes"; then
-   EDJE_CC_PRG="edje_cc"
-   EDJE_DECC_PRG="edje_decc"
-   EDJE_RECC_PRG="edje_recc"
-fi
-AC_SUBST(EDJE_CC_PRG)
-AC_SUBST(EDJE_DECC_PRG)
-AC_SUBST(EDJE_RECC_PRG)
+EFL_ENABLE_BIN([edje-cc])
+EFL_ENABLE_BIN([edje-decc])
+EFL_ENABLE_BIN([edje-recc])
 
 # Optional EDJE_PROGRAM_CACHE (use much more ram, but increase speed in some cases)
 want_edje_program_cache="no"
@@ -358,7 +334,9 @@ echo "  EDJE_PROGRAM_CACHE...: $want_edje_program_cache"
 echo "  EDJE_CALC_CACHE......: $want_edje_calc_cache"
 echo "  Fixed point..........: $want_fixed_point"
 echo
-echo "  Build binaries.......: $have_edje_cc"
+echo "  Build edje_cc........: $have_edje_cc"
+echo "  Build edje_decc......: $have_edje_decc"
+echo "  Build edje_recc......: $have_edje_recc"
 echo
 echo "  Documentation........: ${build_doc}"
 echo

diff --git a/m4/efl_binary.m4 b/m4/efl_binary.m4
new file mode 100644 (file)
index 0000000..0fe85ab
--- /dev/null
+++ b/m4/efl_binary.m4
@@ -0,0 +1,44 @@
+dnl Copyright (C) 2010 Vincent Torri <vtorri at univ-evry dot fr>
+dnl That code is public domain and can be freely used or copied.
+
+dnl Macro that check if a binary is built or not
+
+dnl Usage: EFL_ENABLE_BIN(binary)
+dnl Call AC_SUBST(BINARY_PRG) (BINARY is the uppercase of binary, - being tranformed into _)
+dnl Define have_binary (- is tranformed into _)
+dnl Define conditional BUILD_BINARY (BINARY is the uppercase of binary, - being tranformed into _)
+
+AC_DEFUN([EFL_ENABLE_BIN],
+[
+
+m4_pushdef([UP], m4_translit([[$1]], [-a-z], [_A-Z]))dnl
+m4_pushdef([DOWN], m4_translit([[$1]], [-A-Z], [_a-z]))dnl
+
+have_[]m4_defn([DOWN])="yes"
+
+dnl configure option
+
+AC_ARG_ENABLE([$1],
+   [AC_HELP_STRING([--disable-$1], [disable building of ]DOWN)],
+   [
+    if test "x${enableval}" = "xyes" ; then
+       have_[]m4_defn([DOWN])="yes"
+    else
+       have_[]m4_defn([DOWN])="no"
+    fi
+   ])
+
+AC_MSG_CHECKING([whether to build ]DOWN[ binary])
+AC_MSG_RESULT([$have_[]m4_defn([DOWN])])
+
+if test "x$have_[]m4_defn([DOWN])" = "xyes"; then
+   UP[]_PRG=DOWN[${EXEEXT}]
+fi
+
+AC_SUBST(UP[]_PRG)
+
+AM_CONDITIONAL(BUILD_[]UP, test "x$have_[]m4_defn([DOWN])" = "xyes")
+
+AS_IF([test "x$have_[]m4_defn([DOWN])" = "xyes"], [$2], [$3])
+
+])

diff --git a/src/bin/Makefile.am b/src/bin/Makefile.am
index 6a93499..86e9208 100644 (file)
--- a/src/bin/Makefile.am
+++ b/src/bin/Makefile.am
@@ -13,26 +13,11 @@ AM_CPPFLAGS = \
 @ECORE_FILE_CFLAGS@ \
 @EVIL_CFLAGS@
 
-if BUILD_EDJE_CC
-EDJE_CC = edje_cc
-else
-EDJE_CC =
-endif
-
-if BUILD_EDJE_DECC
-EDJE_DECC = edje_decc
-else
-EDJE_DECC =
-endif
-
-bin_SCRIPTS = \
-@EDJE_RECC_PRG@
-
-bin_PROGRAMS = $(EDJE_CC) $(EDJE_DECC)
-
-EXTRA_PROGRAMS = \
-edje_cc \
-edje_decc
+bin_SCRIPTS = @EDJE_RECC_PRG@
+
+bin_PROGRAMS = @EDJE_CC_PRG@ @EDJE_DECC_PRG@
+
+EXTRA_PROGRAMS = edje_cc edje_decc
 
 edje_cc_SOURCES = \
 edje_cc.c \